@etherisc/gif-next 0.0.2-e0ff180-567 → 0.0.2-e14821a-976

package/contracts/instance/RiskSet.sol

@@ -0,0 +1,126 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32} from "../type/Key32.sol";
+import {LibNftIdSet} from "../type/NftIdSet.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectSet} from "./base/ObjectSet.sol";
+import {ObjectSetHelperLib} from "./base/ObjectSetHelperLib.sol";
+import {RiskIdLib, RiskId} from "../type/RiskId.sol";
+
+/// @dev RiskSet manages the risks and its active policies per product.
+contract RiskSet is
+    ObjectSet
+{
+
+    event LogRiskSetPolicyLinked(RiskId riskId, NftId policyNftId);
+    event LogRiskSetPolicyUnlinked(RiskId riskId, NftId policyNftId);
+
+    event LogRiskSetRiskAdded(NftId productNftId, RiskId riskId);
+    event LogRiskSetRiskActive(NftId poolNftId,  RiskId riskId);
+    event LogRiskSetRiskPaused(NftId poolNftId,  RiskId riskId);
+
+    error ErrorRiskSetRiskLocked(RiskId riskId, NftId policyNftId); 
+    error ErrorRiskSetRiskUnknown(RiskId riskId);
+    error ErrorRiskSetRiskNotRegistered(RiskId riskId);
+
+    mapping(RiskId riskId => LibNftIdSet.Set policies) internal _activePolicies;
+
+    /// @dev links a policy to its bundle
+    function linkPolicy(NftId productNftId, RiskId riskId, NftId policyNftId) external restricted() {
+
+        // ensure risk is active (in active set) and registered with this instance
+        if (!_isActive(productNftId, riskId.toKey32())) {
+            revert ErrorRiskSetRiskLocked(riskId, policyNftId);
+        }
+
+        LibNftIdSet.add(_activePolicies[riskId], policyNftId);
+        emit LogRiskSetPolicyLinked(riskId, policyNftId);
+    }
+
+    /// @dev Unlinks a policy from its risk.
+    function unlinkPolicy(NftId productNftId, RiskId riskId, NftId policyNftId) external restricted() {
+
+        // ensure risk is registered with this instance
+        if (!_contains(productNftId, riskId.toKey32())) {
+            revert ErrorRiskSetRiskUnknown(riskId);
+        }
+
+        LibNftIdSet.remove(_activePolicies[riskId], policyNftId);
+        emit LogRiskSetPolicyUnlinked(riskId, policyNftId);
+    }
+
+    /// @dev add a new risk to a product registered with this instance
+    // the corresponding product is fetched via instance reader
+    function add(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+
+        // ensure product is registered with instance
+        if(productNftId.eqz()) {
+            revert ErrorRiskSetRiskNotRegistered(riskId);
+        }
+
+        _add(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskAdded(productNftId, riskId);
+    }
+
+    /// @dev Applications linked to active risks may be underwritten
+    function activate(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+        _activate(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskActive(productNftId, riskId);
+    }
+
+    /// @dev Applications linked to paused/archived risks may not be underwritten
+    function deactivate(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+        _deactivate(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskPaused(productNftId, riskId);
+    }
+
+    function checkRisk(NftId productNftId, RiskId riskId)
+        public
+        view 
+        returns (bool exists, bool active)
+    {
+        Key32 riskKey32 = riskId.toKey32();
+        exists = _contains(productNftId, riskKey32);
+
+        if (exists) {
+            active = _isActive(productNftId, riskKey32);
+        }
+    }
+
+    function hasRisk(NftId productNftId, RiskId riskId)
+        public
+        view 
+        returns (bool)
+    {
+        Key32 riskKey32 = riskId.toKey32();
+        return _contains(productNftId, riskKey32);
+    }
+
+    function risks(NftId productNftId) external view returns(uint256) {
+        return _objects(productNftId);
+    }
+
+    function getRiskId(NftId productNftId, uint256 idx) external view returns(RiskId riskId) {
+        return RiskIdLib.toRiskId(_getObject(productNftId, idx).toKeyId());
+    }
+    
+    function activeRisks(NftId productNftId) external view returns(uint256) {
+        return _activeObjs(productNftId);
+    }
+
+    function getActiveRiskId(NftId productNftId, uint256 idx) external view returns(RiskId riskId) {
+        return RiskIdLib.toRiskId(_getActiveObject(productNftId, idx).toKeyId());
+    }
+
+    function linkedPolicies(RiskId riskId) external view returns(uint256) {
+        return LibNftIdSet.size(_activePolicies[riskId]);
+    }
+
+    function getLinkedPolicyNftId(RiskId riskId, uint256 idx) external view returns(NftId policyNftId) {
+        return LibNftIdSet.getElementAt(_activePolicies[riskId], idx);
+    }
+}

package/contracts/instance/TargetNames.sol

@@ -0,0 +1,10 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+string constant INSTANCE_TARGET_NAME = "Instance";
+string constant INSTANCE_ADMIN_TARGET_NAME = "InstanceAdmin";
+string constant INSTANCE_STORE_TARGET_NAME = "InstanceStore";
+string constant PRODUCT_STORE_TARGET_NAME = "ProductStore";
+string constant BUNDLE_SET_TARGET_NAME = "BundleSet";
+string constant RISK_SET_TARGET_NAME = "RiskSet";
+

package/contracts/instance/base/BalanceStore.sol

@@ -0,0 +1,121 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber, BlocknumberLib} from "../../type/Blocknumber.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Amount} from "../../type/Amount.sol";
+
+contract BalanceStore {
+
+    error ErrorBalanceStoreTargetAlreadyRegistered(NftId targetNftId);
+    error ErrorBalanceStoreTargetNotRegistered(NftId targetNftId);
+
+    event LogBalanceStoreTargetRegistered(NftId targetNftId);
+
+    event LogBalanceStoreFeesIncreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+    event LogBalanceStoreFeesDecreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+
+    event LogBalanceStoreLockedIncreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+    event LogBalanceStoreLockedDecreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+
+    event LogBalanceStoreBalanceIncreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+    event LogBalanceStoreBalanceDecreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+
+    mapping(NftId nftId => Amount balance) private _balanceAmount;
+    mapping(NftId nftId => Amount locked) private _lockedAmount;
+    mapping(NftId nftId => Amount fees) private _feeAmount;
+
+    // used to indicate if the target has been registered as well as when it was last updated (not used externally atm)    
+    mapping(NftId nftId => Blocknumber lastUpdatedIn) private _lastUpdatedIn;
+
+    modifier onlyRegisteredTarget(NftId targetNftId) {
+        if (!_lastUpdatedIn[targetNftId].gtz()) {
+            revert ErrorBalanceStoreTargetNotRegistered(targetNftId);
+        }
+        _;
+    }
+
+    function getBalanceAmount(NftId targetNftId) external view returns (Amount balanceAmount) { return _balanceAmount[targetNftId]; }
+    function getLockedAmount(NftId targetNftId) external view returns (Amount lockedAmount) { return _lockedAmount[targetNftId]; }
+    function getFeeAmount(NftId targetNftId) external view returns (Amount feeAmount) { return _feeAmount[targetNftId]; }
+
+    function getAmounts(NftId targetNftId)
+        external
+        view
+        returns (
+            Amount balanceAmount,
+            Amount lockedAmount,
+            Amount feeAmount
+        )
+    {
+        balanceAmount = _balanceAmount[targetNftId];
+        lockedAmount = _lockedAmount[targetNftId];
+        feeAmount = _feeAmount[targetNftId];
+    }
+
+    function _registerBalanceTarget(NftId targetNftId) internal {
+        if (_lastUpdatedIn[targetNftId].gtz()) {
+            revert ErrorBalanceStoreTargetAlreadyRegistered(targetNftId);
+        }
+
+        _setLastUpdatedIn(targetNftId);
+
+        emit LogBalanceStoreTargetRegistered(targetNftId);
+    }
+
+    //--- fee management ----------------------------------------------------//
+    function _increaseFees(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _feeAmount[targetNftId] + amount;
+        _feeAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreFeesIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    function _decreaseFees(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _feeAmount[targetNftId] - amount;
+        _feeAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreFeesDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    //--- locked management -------------------------------------------------//
+    function _increaseLocked(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _lockedAmount[targetNftId] + amount;
+        _lockedAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreLockedIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    function _decreaseLocked(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _lockedAmount[targetNftId] - amount;
+        _lockedAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreLockedDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    //--- balance management ------------------------------------------------//
+    function _increaseBalance(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _balanceAmount[targetNftId] + amount;
+        _balanceAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreBalanceIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    function _decreaseBalance(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _balanceAmount[targetNftId] - amount;
+        _balanceAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreBalanceDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    //--- internal/private functions ----------------------------------------//
+    function _setLastUpdatedIn(NftId targetNftId) internal {
+        _lastUpdatedIn[targetNftId] = BlocknumberLib.current();
+    }
+}

package/contracts/instance/base/Cloneable.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+
+abstract contract Cloneable is 
+    AccessManagedUpgradeable
+{
+    IRegistry internal _registry;
+
+    /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
+    function __Cloneable_init(
+        address authority,
+        address registry
+    )
+        internal 
+        onlyInitializing
+    {
+        __AccessManaged_init(authority);
+        _registry = IRegistry(registry);
+    }
+
+    function getRegistry() external view returns (IRegistry) {
+        return _registry;
+    }
+}

package/contracts/instance/base/ObjectCounter.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber, BlocknumberLib} from "../../type/Blocknumber.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Amount} from "../../type/Amount.sol";
+import {RequestId, RequestIdLib} from "../../type/RequestId.sol";
+
+contract ObjectCounter {
+
+    // TODO refactor risk id
+    // mapping(NftId productNftId => uint64 risks) private _riskCounter;
+
+    uint256 private _requestCounter = 0;
+
+    function _createNextRequestId() internal returns (RequestId requestId) {
+        _requestCounter++;
+        requestId = RequestIdLib.toRequestId(_requestCounter);
+    }
+}

package/contracts/instance/base/ObjectLifecycle.sol

@@ -0,0 +1,109 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+
+import {COMPONENT, BUNDLE, POLICY, REQUEST, RISK, CLAIM, PAYOUT, POOL, PREMIUM, PRODUCT, DISTRIBUTION, DISTRIBUTOR, DISTRIBUTOR_TYPE, REFERRAL, FEE} from "../../type/ObjectType.sol";
+import {ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, COLLATERALIZED, REVOKED, SUBMITTED, CONFIRMED, DECLINED, EXPECTED, PAID, FULFILLED, FAILED, CANCELLED} from "../../type/StateId.sol";
+import {Lifecycle} from "../../shared/Lifecycle.sol";
+
+contract ObjectLifecycle is
+    Lifecycle,
+    Initializable
+{
+    function _initializeLifecycle() internal onlyInitializing
+    {
+        _setupLifecycle();
+    }
+
+    function _setupLifecycle()
+        internal
+        override
+    {
+        _setupBundleLifecycle();
+        _setupComponentLifecycle();
+        _setupPolicyLifecycle();
+        _setupPremiumLifecycle();
+        _setupClaimLifecycle();
+        _setupPayoutLifecycle();
+        _setupRiskLifecycle();
+        _setupRequestLifecycle();
+
+        // setup dummy lifecycles to manage with key value store 
+        _setUpPoolLifecycle();
+        _setUpProductLifecycle();
+        _setUpDistributionLifecycle();
+    }
+
+    function _setupComponentLifecycle() private {
+        setInitialState(COMPONENT(), ACTIVE());
+        setStateTransition(COMPONENT(), ACTIVE(), PAUSED());
+        setStateTransition(COMPONENT(), PAUSED(), ACTIVE());
+        setStateTransition(COMPONENT(), PAUSED(), ARCHIVED());
+    }
+
+    function _setupBundleLifecycle() private {
+        setInitialState(BUNDLE(), ACTIVE());
+        setStateTransition(BUNDLE(), ACTIVE(), CLOSED());
+    }
+
+    function _setupPolicyLifecycle() private {
+        setInitialState(POLICY(), APPLIED());
+        setStateTransition(POLICY(), APPLIED(), REVOKED());
+        setStateTransition(POLICY(), APPLIED(), DECLINED());
+        setStateTransition(POLICY(), APPLIED(), COLLATERALIZED());
+        setStateTransition(POLICY(), COLLATERALIZED(), CLOSED());
+    }
+
+    function _setupPremiumLifecycle() private {
+        setInitialState(PREMIUM(), EXPECTED());
+        setStateTransition(PREMIUM(), EXPECTED(), PAID());
+    }
+
+    function _setupClaimLifecycle() private {
+        setInitialState(CLAIM(), SUBMITTED());
+        setStateTransition(CLAIM(), SUBMITTED(), REVOKED());
+        setStateTransition(CLAIM(), SUBMITTED(), CONFIRMED());
+        setStateTransition(CLAIM(), SUBMITTED(), DECLINED());
+        setStateTransition(CLAIM(), CONFIRMED(), CLOSED());
+        setStateTransition(CLAIM(), CONFIRMED(), CANCELLED());
+    }
+
+    function _setupPayoutLifecycle() private {
+        setInitialState(PAYOUT(), EXPECTED());
+        setStateTransition(PAYOUT(), EXPECTED(), PAID());
+        setStateTransition(PAYOUT(), EXPECTED(), CANCELLED());
+    }
+
+    function _setupRiskLifecycle() private {
+        setInitialState(RISK(), ACTIVE());
+        setStateTransition(RISK(), ACTIVE(), CLOSED());
+    }
+
+    function _setupRequestLifecycle() private {
+        setInitialState(REQUEST(), ACTIVE());
+        setStateTransition(REQUEST(), ACTIVE(), FULFILLED());
+        setStateTransition(REQUEST(), ACTIVE(), FAILED());
+        setStateTransition(REQUEST(), FAILED(), FULFILLED());
+        setStateTransition(REQUEST(), ACTIVE(), CANCELLED());
+    }
+
+    // dummy lifecycle only
+    function _setUpPoolLifecycle() private {
+        setInitialState(POOL(), ACTIVE());
+    }
+
+    // dummy lifecycle only
+    function _setUpProductLifecycle() private {
+        setInitialState(PRODUCT(), ACTIVE());
+        setInitialState(FEE(), ACTIVE());
+    }
+
+    // dummy lifecycles only
+    function _setUpDistributionLifecycle() private {
+        setInitialState(DISTRIBUTION(), ACTIVE());
+        setInitialState(DISTRIBUTOR(), ACTIVE());
+        setInitialState(DISTRIBUTOR_TYPE(), ACTIVE());
+        setInitialState(REFERRAL(), ACTIVE());
+    }
+}

package/contracts/instance/base/ObjectSet.sol

@@ -0,0 +1,77 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Cloneable} from "./Cloneable.sol";
+
+import {LibKey32Set} from "../../type/Key32Set.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Key32} from "../../type/Key32.sol";
+
+contract ObjectSet is
+    Cloneable
+{
+    using LibKey32Set for LibKey32Set.Set;
+
+    event LogObjectSetInitialized(address instance);
+
+    error ErrorObjectSetNftIdInvalid(NftId instanceNftId);
+
+    mapping(NftId compnentNftId => LibKey32Set.Set objects) internal _activeObjects;
+    mapping(NftId compnentNftId => LibKey32Set.Set objects) internal _allObjects;
+    address internal _instanceAddress;
+
+    /// @dev This initializer needs to be called from the instance itself.
+    function initialize(address authority, address registry) 
+        external
+        initializer()
+    {
+        _instanceAddress = msg.sender;
+        __Cloneable_init(authority, registry);
+        
+        emit LogObjectSetInitialized(address(_instanceAddress));
+    }
+
+    function getInstanceAddress() external view returns (address) {
+        return _instanceAddress;
+    }
+
+    function _add(NftId componentNftId, Key32 key) internal {
+        LibKey32Set.Set storage allSet = _allObjects[componentNftId];
+        LibKey32Set.Set storage activeSet = _activeObjects[componentNftId];
+
+        allSet.add(key);
+        activeSet.add(key);
+    }
+
+    function _activate(NftId componentNftId, Key32 key) internal {
+        _activeObjects[componentNftId].add(key);
+    }
+
+    function _deactivate(NftId componentNftId, Key32 key) internal {
+        _activeObjects[componentNftId].remove(key);
+    }
+
+    function _objects(NftId componentNftId) internal view returns (uint256) {
+        return _allObjects[componentNftId].size();
+    }
+
+    function _contains(NftId componentNftId, Key32 key) internal view returns (bool) {
+        return _allObjects[componentNftId].contains(key);
+    }
+
+    function _getObject(NftId componentNftId, uint256 idx) internal view returns (Key32) {
+        return _allObjects[componentNftId].getElementAt(idx);
+    }
+
+    function _activeObjs(NftId componentNftId) internal view returns (uint256)  {
+        return _activeObjects[componentNftId].size();
+    }
+
+    function _isActive(NftId componentNftId, Key32 key) internal view returns (bool) {
+        return _activeObjects[componentNftId].contains(key);
+    }
+
+    function _getActiveObject(NftId componentNftId, uint256 idx) internal view returns (Key32) {
+        return _activeObjects[componentNftId].getElementAt(idx);
+    }
+}

package/contracts/instance/base/ObjectSetHelperLib.sol

@@ -0,0 +1,30 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IBundle} from "../module/IBundle.sol";
+import {IInstance} from "../IInstance.sol";
+import {IRisk} from "../module/IRisk.sol";
+import {NftId} from "../../type/NftId.sol";
+import {RiskId} from "../../type/RiskId.sol";
+
+
+library ObjectSetHelperLib {
+
+    function getRiskInfo(address instanceAddress, RiskId riskId) public view returns (IRisk.RiskInfo memory) {
+
+        return IInstance(instanceAddress).getInstanceReader().getRiskInfo(riskId);
+    }
+
+    function getProductNftId(address instanceAddress, RiskId riskId) public view returns (NftId) {
+        return getRiskInfo(instanceAddress, riskId).productNftId;
+    }
+
+    function getBundleInfo(address instanceAddress, NftId bundleNftId) public view returns (IBundle.BundleInfo memory) {
+        return IInstance(instanceAddress).getInstanceReader().getBundleInfo(bundleNftId);
+    }
+
+    function getPoolNftId(address instanceAddress, NftId bundleNftId) public view returns (NftId) {
+        return getBundleInfo(instanceAddress, bundleNftId).poolNftId;
+    }
+
+}

package/contracts/instance/module/IBundle.sol

@@ -1,23 +1,21 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {Amount} from "../../types/Amount.sol";
-import {NftId} from "../../types/NftId.sol";
-import {Fee} from "../../types/Fee.sol";
-import {Seconds} from "../../types/Seconds.sol";
-import {Timestamp} from "../../types/Timestamp.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Fee} from "../../type/Fee.sol";
+import {Timestamp} from "../../type/Timestamp.sol";
 
 interface IBundle {
 
     struct BundleInfo {
+        // slot 0
+        Timestamp activatedAt; 
+        Timestamp expiredAt; // no new policies starting with this timestamp
+        Timestamp closedAt; // no open policies, locked amount = 0
         NftId poolNftId;
+        // slot 1
         Fee fee; // bundle fee on net premium amounts
+        // slot 2
         bytes filter; // required conditions for applications to be considered for collateralization by this bundle
-        Amount capitalAmount; // net stakings + net premiums - payouts
-        Amount lockedAmount; // capital amount linked to collateralizaion of non-closed policies (<= capital amount)
-        Amount feeAmount; // accumulated fee amount
-        Seconds lifetime;
-        Timestamp expiredAt; // no new policies starting with this timestamp
-        Timestamp closedAt; // no open policies, locked amount = 0
     }
 }

package/contracts/instance/module/IComponents.sol

@@ -1,41 +1,60 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-
-import {Amount} from "../../types/Amount.sol";
-import {Fee} from "../../types/Fee.sol";
-import {NftId} from "../../types/NftId.sol";
-import {RoleId} from "../../types/RoleId.sol";
+import {Amount} from "../../type/Amount.sol";
+import {Fee} from "../../type/Fee.sol";
+import {NftId} from "../../type/NftId.sol";
 import {TokenHandler} from "../../shared/TokenHandler.sol";
-import {UFixed} from "../../types/UFixed.sol";
+import {UFixed} from "../../type/UFixed.sol";
 
 interface IComponents {
 
     struct ComponentInfo {
+        // slot 0
         string name; // component name (needs to be unique per instance)
-        IERC20Metadata token;
+        // slot 1
         TokenHandler tokenHandler;
-        address wallet;
-        Amount balanceAmount; // calculated balance (may not necessarily match withg wallet balance)
-        Amount feeAmount; // accumulated fees belonging to component owner
-        bytes data; // will hold component type specific additional info (eg encoded pool info)
     }
 
-    struct PoolInfo {
-        NftId productNftId; // the nft of the product this pool is linked to
-        RoleId bundleOwnerRole; // the required role for bundle owners
-        // TODO maxCapitalAmount -> maxBalanceAmount
-        uint256 maxCapitalAmount; // max capital amount allowed for pool
-        uint256 balanceAmount; // current pool balance (accounting view)
-        uint256 feeAmount; // accumulated fee amount
-        bool isInterceptingBundleTransfers; // intercepts nft transfers for bundles
-        bool isExternallyManaged; // funding bundles is restricted to book keeping, actual funds may be provided as needed to support payouts
-        bool isVerifyingApplications; // underwriting requires the pool component checks/confirms the applications 
-        UFixed collateralizationLevel; // factor to calculate collateral for sum insurance (default 100%)
-        UFixed retentionLevel; // amount of collateral held in pool (default 100%)
+    struct ProductInfo {
+        // slot 0
+        bool isProcessingFundedClaims; // custom logic to react to pool events for funded claims
+        bool isInterceptingPolicyTransfers; // custom logic for policy nft transfers
+        bool hasDistribution; // flag to indicate if distribution is enabled
+        uint8 expectedNumberOfOracles; // expected number of oracles
+        uint8 numberOfOracles; // actual number of oracles
+        NftId poolNftId; // mandatory
+        NftId distributionNftId; // 0..1 (optional)
+        // slot 1
+        NftId [] oracleNftId; // 0..n (optional)
+    }
+
+    struct FeeInfo {
+        // slot 0
+        Fee productFee; // product fee on net premium
+        // slot 1
+        Fee processingFee; // product fee on payout amounts        
+        // slot 2
+        Fee distributionFee; // distribution fee for sales that do not include commissions
+        // slot 3
+        Fee minDistributionOwnerFee; // min fee required by distribution owner (not including commissions for distributors)
+        // slot 4
         Fee poolFee; // pool fee on net premium
+        // slot 5
         Fee stakingFee; // pool fee on staked capital from investor
+        // slot 6
         Fee performanceFee; // pool fee on profits from capital investors
     }
+
+    struct PoolInfo {
+        // slot 0
+        Amount maxBalanceAmount; // max balance amount allowed for pool
+        UFixed collateralizationLevel; // factor to calculate collateral for sum insurance (default 100%)
+        // slot 1
+        UFixed retentionLevel; // amount of collateral held in pool (default 100%)
+        bool isInterceptingBundleTransfers; // custom logic for bundle nft transfers
+        bool isProcessingConfirmedClaims; // custom logic for claims confirmation
+        bool isExternallyManaged; // funding bundles is restricted to book keeping, actual funds may be provided as needed to support payouts
+        bool isVerifyingApplications; // underwriting requires the pool component checks/confirms the applications 
+    }
 }