@etherisc/gif-next 0.0.2-cc253b3 → 0.0.2-cd89a0b-062

package/contracts/types/ObjectType.sol

@@ -0,0 +1,131 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+type ObjectType is uint8;
+
+// type bindings
+using {
+    eqObjectType as ==,
+    neObjectType as !=,
+    ObjectTypeLib.toInt,
+    ObjectTypeLib.gtz
+} for ObjectType global;
+
+// general pure free functions
+
+function PROTOCOL() pure returns (ObjectType) {
+    return toObjectType(10);
+}
+
+function REGISTRY() pure returns (ObjectType) {
+    return toObjectType(20);
+}
+
+function TOKEN() pure returns (ObjectType) {
+    return toObjectType(30);
+}
+
+function SERVICE() pure returns (ObjectType) {
+    return toObjectType(40);
+}
+
+function INSTANCE() pure returns (ObjectType) {
+    return toObjectType(50);
+}
+
+function STAKE() pure returns (ObjectType) {
+    return toObjectType(60);
+}
+
+function COMPONENT() pure returns (ObjectType) {
+    return toObjectType(100);
+}
+
+function TREASURY() pure returns (ObjectType) {
+    return toObjectType(101);
+}
+
+function PRODUCT() pure returns (ObjectType) {
+    return toObjectType(110);
+}
+
+function DISTRIBUTION() pure returns (ObjectType) {
+    return toObjectType(120);
+}
+
+function ORACLE() pure returns (ObjectType) {
+    return toObjectType(130);
+}
+
+function POOL() pure returns (ObjectType) {
+    return toObjectType(140);
+}
+
+function RISK() pure returns (ObjectType) {
+    return toObjectType(200);
+}
+
+function POLICY() pure returns (ObjectType) {
+    return toObjectType(210);
+}
+
+function REFERRAL() pure returns (ObjectType) {
+    return toObjectType(212);
+}
+
+function CLAIM() pure returns (ObjectType) {
+    return toObjectType(214);
+}
+
+function PAYOUT() pure returns (ObjectType) {
+    return toObjectType(216);
+}
+
+function BUNDLE() pure returns (ObjectType) {
+    return toObjectType(220);
+}
+
+/// @dev Converts the uint8 to a ObjectType.
+function toObjectType(uint256 objectType) pure returns (ObjectType) {
+    return ObjectType.wrap(uint8(objectType));
+}
+
+/// @dev Return the ObjectType zero (0)
+function zeroObjectType() pure returns (ObjectType) {
+    return ObjectType.wrap(0);
+}
+
+// pure free functions for operators
+function eqObjectType(ObjectType a, ObjectType b) pure returns (bool isSame) {
+    return ObjectType.unwrap(a) == ObjectType.unwrap(b);
+}
+
+function neObjectType(
+    ObjectType a,
+    ObjectType b
+) pure returns (bool isDifferent) {
+    return ObjectType.unwrap(a) != ObjectType.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library ObjectTypeLib {
+    /// @dev Converts the NftId to a uint256.
+    function toInt(ObjectType objectType) public pure returns (uint96) {
+        return uint96(ObjectType.unwrap(objectType));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(ObjectType a) public pure returns (bool) {
+        return ObjectType.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(ObjectType a) public pure returns (bool) {
+        return ObjectType.unwrap(a) == 0;
+    }
+
+    /// @dev Returns true if the values are equal (==).
+    function eq(ObjectType a, ObjectType b) public pure returns (bool isSame) {
+        return eqObjectType(a, b);
+    }
+}

package/contracts/types/ReferralId.sol

@@ -0,0 +1,48 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {REFERRAL} from "./ObjectType.sol";
+
+type ReferralId is bytes8;
+
+// type bindings
+using {
+    eqReferralId as ==, 
+    neReferralId as !=,
+    ReferralIdLib.toKey32
+} for ReferralId global;
+
+// general pure free functions
+
+// @dev Returns true iff risk ids a and b are identical
+function eqReferralId(ReferralId a, ReferralId b) pure returns (bool isSame) {
+    return ReferralId.unwrap(a) == ReferralId.unwrap(b);
+}
+
+// @dev Returns true iff risk ids a and b are different
+function neReferralId(ReferralId a, ReferralId b) pure returns (bool isDifferent) {
+    return ReferralId.unwrap(a) != ReferralId.unwrap(b);
+}
+
+library ReferralIdLib {
+
+    function zeroReferralId() public pure returns (ReferralId) {
+        return ReferralId.wrap(bytes8(0));
+    }
+
+    // @dev Converts a role string into a role id.
+    function toReferralId(string memory referral) public pure returns (ReferralId) {
+        return ReferralId.wrap(bytes8(keccak256(abi.encode(referral))));
+    }
+
+    /// @dev Returns the key32 value for the specified id
+    function toKey32(ReferralId id) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(REFERRAL(), toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified id
+    function toKeyId(ReferralId id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(ReferralId.unwrap(id)));
+    }
+}

package/contracts/types/RiskId.sol

@@ -0,0 +1,43 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {RISK} from "./ObjectType.sol";
+
+type RiskId is bytes8;
+
+// type bindings
+using {
+    eqRiskId as ==, 
+    neRiskId as !=,
+    RiskIdLib.toKey32
+} for RiskId global;
+
+// general pure free functions
+
+// @dev Returns true iff risk ids a and b are identical
+function eqRiskId(RiskId a, RiskId b) pure returns (bool isSame) {
+    return RiskId.unwrap(a) == RiskId.unwrap(b);
+}
+
+// @dev Returns true iff risk ids a and b are different
+function neRiskId(RiskId a, RiskId b) pure returns (bool isDifferent) {
+    return RiskId.unwrap(a) != RiskId.unwrap(b);
+}
+
+library RiskIdLib {
+    // @dev Converts a role string into a role id.
+    function toRiskId(string memory risk) public pure returns (RiskId) {
+        return RiskId.wrap(bytes8(keccak256(abi.encode(risk))));
+    }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(RiskId id) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(RISK(), toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(RiskId id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(RiskId.unwrap(id)));
+    }
+}

package/contracts/types/RoleId.sol

@@ -0,0 +1,38 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+type RoleId is bytes8;
+
+// type bindings
+using {
+    eqRoleId as ==, 
+    neRoleId as !=
+} for RoleId global;
+
+// general pure free functions
+function DISTRIBUTION_OWNER_ROLE_NAME() pure returns (string memory) { return "DistributionOwnerRole"; }
+function ORACLE_OWNER_ROLE_NAME() pure returns (string memory) { return "OracleOwnerRole"; }
+function POOL_OWNER_ROLE_NAME() pure returns (string memory) { return "PoolOwnerRole"; }
+function PRODUCT_OWNER_ROLE_NAME() pure returns (string memory) { return "ProductOwnerRole"; }
+
+function DISTRIBUTION_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("DistributionOwnerRole"); }
+function ORACLE_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("OracleOwnerRole"); }
+function POOL_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("PoolOwnerRole"); }
+function PRODUCT_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("ProductOwnerRole"); }
+
+// @dev Returns true iff role ids a and b are identical
+function eqRoleId(RoleId a, RoleId b) pure returns (bool isSame) {
+    return RoleId.unwrap(a) == RoleId.unwrap(b);
+}
+
+// @dev Returns true iff role ids a and b are different
+function neRoleId(RoleId a, RoleId b) pure returns (bool isDifferent) {
+    return RoleId.unwrap(a) != RoleId.unwrap(b);
+}
+
+library RoleIdLib {
+    // @dev Converts a role string into a role id.
+    function toRoleId(string memory role) public pure returns (RoleId) {
+        return RoleId.wrap(bytes8(keccak256(abi.encode(role))));
+    }
+}

package/contracts/types/StateId.sol

@@ -0,0 +1,101 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// uint96 allows for chain ids up to 13 digits
+type StateId is uint8;
+
+// type bindings
+using {
+    eqStateId as ==, 
+    neStateId as !=, 
+    StateIdLib.eqz,
+    StateIdLib.gtz,
+    StateIdLib.toInt
+} for StateId global;
+
+// general pure free functions
+function APPLIED() pure returns (StateId) {
+    return toStateId(10);
+}
+
+function REVOKED() pure returns (StateId) {
+    return toStateId(20);
+}
+
+function DECLINED() pure returns (StateId) {
+    return toStateId(30);
+}
+
+function UNDERWRITTEN() pure returns (StateId) {
+    return toStateId(40);
+}
+
+function CONFIRMED() pure returns (StateId) {
+    return toStateId(50);
+}
+
+function EXPECTED() pure returns (StateId) {
+    return toStateId(60);
+}
+
+function ACTIVE() pure returns (StateId) {
+    return toStateId(100);
+}
+
+function PAUSED() pure returns (StateId) {
+    return toStateId(110);
+}
+
+function CLOSED() pure returns (StateId) {
+    return toStateId(200);
+}
+
+function ARCHIVED() pure returns (StateId) {
+    return toStateId(210);
+}
+
+function PAID() pure returns (StateId) {
+    return toStateId(220);
+}
+
+/// @dev Converts the uint8 to a StateId.
+function toStateId(uint256 id) pure returns (StateId) {
+    return StateId.wrap(uint8(id));
+}
+
+/// @dev Return the StateId zero (0)
+function zeroStateId() pure returns (StateId) {
+    return StateId.wrap(0);
+}
+
+// pure free functions for operators
+function eqStateId(StateId a, StateId b) pure returns (bool isSame) {
+    return StateId.unwrap(a) == StateId.unwrap(b);
+}
+
+function neStateId(StateId a, StateId b) pure returns (bool isDifferent) {
+    return StateId.unwrap(a) != StateId.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library StateIdLib {
+    /// @dev Converts the NftId to a uint256.
+    function toInt(StateId stateId) public pure returns (uint96) {
+        return uint96(StateId.unwrap(stateId));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(StateId a) public pure returns (bool) {
+        return StateId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(StateId a) public pure returns (bool) {
+        return StateId.unwrap(a) == 0;
+    }
+
+    /// @dev Returns true if the values are equal (==).
+    function eq(StateId a, StateId b) public pure returns (bool isSame) {
+        return eqStateId(a, b);
+    }
+}

package/contracts/types/Timestamp.sol

@@ -0,0 +1,123 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+type Timestamp is uint40;
+
+using {
+    gtTimestamp as >,
+    gteTimestamp as >=,
+    ltTimestamp as <,
+    lteTimestamp as <=,
+    eqTimestamp as ==,
+    neTimestamp as !=,
+    TimestampLib.gtz,
+    TimestampLib.eqz,
+    TimestampLib.addSeconds
+} for Timestamp global;
+
+/// @dev return true if Timestamp a is after Timestamp b
+function gtTimestamp(Timestamp a, Timestamp b) pure returns (bool) {
+    return Timestamp.unwrap(a) > Timestamp.unwrap(b);
+}
+
+/// @dev return true if Timestamp a is after or equal to Timestamp b
+function gteTimestamp(Timestamp a, Timestamp b) pure returns (bool) {
+    return Timestamp.unwrap(a) >= Timestamp.unwrap(b);
+}
+
+/// @dev return true if Timestamp a is before Timestamp b
+function ltTimestamp(Timestamp a, Timestamp b) pure returns (bool) {
+    return Timestamp.unwrap(a) < Timestamp.unwrap(b);
+}
+
+/// @dev return true if Timestamp a is before or equal to Timestamp b
+function lteTimestamp(Timestamp a, Timestamp b) pure returns (bool) {
+    return Timestamp.unwrap(a) <= Timestamp.unwrap(b);
+}
+
+/// @dev return true if Timestamp a is equal to Timestamp b
+function eqTimestamp(Timestamp a, Timestamp b) pure returns (bool) {
+    return Timestamp.unwrap(a) == Timestamp.unwrap(b);
+}
+
+/// @dev return true if Timestamp a is not equal to Timestamp b
+function neTimestamp(Timestamp a, Timestamp b) pure returns (bool) {
+    return Timestamp.unwrap(a) != Timestamp.unwrap(b);
+}
+
+/// @dev Converts the uint256 to a Timestamp.
+function toTimestamp(uint256 timestamp) pure returns (Timestamp) {
+    return Timestamp.wrap(uint40(timestamp));
+}
+
+function blockTimestamp() view returns (Timestamp) {
+    return toTimestamp(block.timestamp);
+}
+
+/// @dev Return the Timestamp zero (0)
+function zeroTimestamp() pure returns (Timestamp) {
+    return toTimestamp(0);
+}
+
+library TimestampLib {
+    /// @dev return true if Timestamp a is after Timestamp b
+    function gt(Timestamp a, Timestamp b) public pure returns (bool isAfter) {
+        return gtTimestamp(a, b);
+    }
+
+    /// @dev return true if Timestamp a is after or the same than Timestamp b
+    function gte(
+        Timestamp a,
+        Timestamp b
+    ) public pure returns (bool isAfterOrSame) {
+        return gteTimestamp(a, b);
+    }
+
+    /// @dev return true if Timestamp a is before Timestamp b
+    function lt(Timestamp a, Timestamp b) public pure returns (bool isBefore) {
+        return ltTimestamp(a, b);
+    }
+
+    /// @dev return true if Timestamp a is before or the same than Timestamp b
+    function lte(
+        Timestamp a,
+        Timestamp b
+    ) public pure returns (bool isBeforeOrSame) {
+        return lteTimestamp(a, b);
+    }
+
+    /// @dev return true if Timestamp a is equal to Timestamp b
+    function eq(Timestamp a, Timestamp b) public pure returns (bool isSame) {
+        return eqTimestamp(a, b);
+    }
+
+    /// @dev return true if Timestamp a is not equal to Timestamp b
+    function ne(
+        Timestamp a,
+        Timestamp b
+    ) public pure returns (bool isDifferent) {
+        return neTimestamp(a, b);
+    }
+
+    /// @dev return true if Timestamp is larger than 0
+    function gtz(Timestamp timestamp) public pure returns (bool) {
+        return Timestamp.unwrap(timestamp) > 0;
+    }
+
+    /// @dev return true if Timestamp equals 0
+    function eqz(Timestamp timestamp) public pure returns (bool) {
+        return Timestamp.unwrap(timestamp) == 0;
+    }
+
+    /// @dev return true if Timestamp a is not equal to Timestamp b
+    function addSeconds(
+        Timestamp timestamp,
+        uint256 timeDelta
+    ) public pure returns (Timestamp) {
+        return toTimestamp(Timestamp.unwrap(timestamp) + uint40(timeDelta));
+    }
+
+    function toInt(Timestamp timestamp) public pure returns (uint256) {
+        return uint256(uint40(Timestamp.unwrap(timestamp)));
+    }
+}

package/contracts/types/UFixed.sol

@@ -0,0 +1,209 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";
+
+/// @dev UFixed is a fixed point number with 18 decimals precision.
+type UFixed is uint256;
+
+using {
+    addUFixed as +,
+    subUFixed as -,
+    mulUFixed as *,
+    divUFixed as /,
+    gtUFixed as >,
+    gteUFixed as >=,
+    ltUFixed as <,
+    lteUFixed as <=,
+    eqUFixed as ==,
+    UFixedMathLib.toInt
+} for UFixed global;
+
+function addUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    return UFixed.wrap(UFixed.unwrap(a) + UFixed.unwrap(b));
+}
+
+function subUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    require(a >= b, "ERROR:UFM-010:NEGATIVE_RESULT");
+    return UFixed.wrap(UFixed.unwrap(a) - UFixed.unwrap(b));
+}
+
+function mulUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    return
+        UFixed.wrap(Math.mulDiv(UFixed.unwrap(a), UFixed.unwrap(b), 10 ** 18));
+}
+
+function divUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    require(UFixed.unwrap(b) > 0, "ERROR:UFM-020:DIVISOR_ZERO");
+
+    return
+        UFixed.wrap(Math.mulDiv(UFixed.unwrap(a), 10 ** 18, UFixed.unwrap(b)));
+}
+
+function gtUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) > UFixed.unwrap(b);
+}
+
+function gteUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) >= UFixed.unwrap(b);
+}
+
+function ltUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) < UFixed.unwrap(b);
+}
+
+function lteUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) <= UFixed.unwrap(b);
+}
+
+function eqUFixed(UFixed a, UFixed b) pure returns (bool isEqual) {
+    return UFixed.unwrap(a) == UFixed.unwrap(b);
+}
+
+function gtzUFixed(UFixed a) pure returns (bool isZero) {
+    return UFixed.unwrap(a) > 0;
+}
+
+function eqzUFixed(UFixed a) pure returns (bool isZero) {
+    return UFixed.unwrap(a) == 0;
+}
+
+function deltaUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    if (a > b) {
+        return a - b;
+    }
+
+    return b - a;
+}
+
+library UFixedMathLib {
+    int8 public constant EXP = 18;
+    uint256 public constant MULTIPLIER = 10 ** uint256(int256(EXP));
+    uint256 public constant MULTIPLIER_HALF = MULTIPLIER / 2;
+
+    /// @dev returns the rounding mode DOWN - 0.4 becomes 0, 0.5 becomes 0, 0.6 becomes 0
+    function ROUNDING_DOWN() public pure returns (uint8) {
+        return uint8(0);
+    }
+
+    /// @dev returns the rounding mode UP - 0.4 becomes 1, 0.5 becomes 1, 0.6 becomes 1
+    function ROUNDING_UP() public pure returns (uint8) {
+        return uint8(1);
+    }
+
+    /// @dev returns the rounding mode HALF_UP - 0.4 becomes 0, 0.5 becomes 1, 0.6 becomes 1
+    function ROUNDING_HALF_UP() public pure returns (uint8) {
+        return uint8(2);
+    }
+
+    /// @dev Converts the uint256 to a UFixed.
+    function toUFixed(uint256 a) public pure returns (UFixed) {
+        return UFixed.wrap(a * MULTIPLIER);
+    }
+
+    /// @dev Converts the uint256 to a UFixed with given exponent.
+    function toUFixed(uint256 a, int8 exp) public pure returns (UFixed) {
+        require(EXP + exp >= 0, "ERROR:FM-010:EXPONENT_TOO_SMALL");
+        require(EXP + exp <= 64, "ERROR:FM-011:EXPONENT_TOO_LARGE");
+
+        return UFixed.wrap(a * 10 ** uint8(EXP + exp));
+    }
+
+    /// @dev returns the decimals precision of the UFixed type
+    function decimals() public pure returns (uint256) {
+        return uint8(EXP);
+    }
+
+    /// @dev Converts a UFixed to a uint256.
+    function toInt(UFixed a) public pure returns (uint256) {
+        return toIntWithRounding(a, ROUNDING_HALF_UP());
+    }
+
+    /// @dev Converts a UFixed to a uint256 with given rounding mode.
+    function toIntWithRounding(UFixed a, uint8 rounding) public pure returns (uint256) {
+        if (rounding == ROUNDING_HALF_UP()) {
+            return
+                Math.mulDiv(
+                    UFixed.unwrap(a) + MULTIPLIER_HALF,
+                    1,
+                    MULTIPLIER,
+                    Math.Rounding.Down
+                );
+        } else if (rounding == ROUNDING_DOWN()) {
+            return
+                Math.mulDiv(
+                    UFixed.unwrap(a),
+                    1,
+                    MULTIPLIER,
+                    Math.Rounding.Down
+                );
+        } else {
+            return
+                Math.mulDiv(UFixed.unwrap(a), 1, MULTIPLIER, Math.Rounding.Up);
+        }
+    }
+
+    /// @dev adds two UFixed numbers
+    function add(UFixed a, UFixed b) public pure returns (UFixed) {
+        return addUFixed(a, b);
+    }
+
+    /// @dev subtracts two UFixed numbers
+    function sub(UFixed a, UFixed b) public pure returns (UFixed) {
+        return subUFixed(a, b);
+    }
+
+    /// @dev multiplies two UFixed numbers
+    function mul(UFixed a, UFixed b) public pure returns (UFixed) {
+        return mulUFixed(a, b);
+    }
+
+    /// @dev divides two UFixed numbers
+    function div(UFixed a, UFixed b) public pure returns (UFixed) {
+        return divUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is greater than UFixed b
+    function gt(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return gtUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is greater than or equal to UFixed b
+    function gte(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return gteUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is less than UFixed b
+    function lt(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return ltUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is less than or equal to UFixed b
+    function lte(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return lteUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is equal to UFixed b
+    function eq(UFixed a, UFixed b) public pure returns (bool isEqual) {
+        return eqUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is not zero
+    function gtz(UFixed a) public pure returns (bool isZero) {
+        return gtzUFixed(a);
+    }
+
+    /// @dev return true if UFixed a is zero
+    function eqz(UFixed a) public pure returns (bool isZero) {
+        return eqzUFixed(a);
+    }
+
+    function zero() public pure returns (UFixed) {
+        return UFixed.wrap(0);
+    }
+
+    /// @dev return the absolute delta between two UFixed numbers
+    function delta(UFixed a, UFixed b) public pure returns (UFixed) {
+        return deltaUFixed(a, b);
+    }
+}