@etherisc/gif-next 0.0.2-cc253b3 → 0.0.2-cd89a0b-062

package/contracts/instance/module/treasury/TokenHandler.sol

@@ -0,0 +1,48 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin5/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+
+contract TokenHandler {
+    NftId private _productNftId;
+    IERC20Metadata private _token;
+
+    constructor(
+        NftId productNftId,
+        address token
+    )
+    {
+        _productNftId = productNftId;
+        _token = IERC20Metadata(token);
+    }
+
+    // TODO add logging
+    function transfer(
+        address from,
+        address to,
+        uint256 amount
+    )
+        external // TODO add authz (only treasury/instance/product/pool/ service)
+    {
+        // TODO switch to oz safeTransferFrom
+        _token.transferFrom(from, to, amount);
+    }
+
+    function getProductNftId()
+        external
+        view
+        returns(NftId)
+    {
+        return _productNftId;
+    }
+
+    function getToken()
+        external
+        view
+        returns(IERC20Metadata)
+    {
+        return _token;
+    }
+}

package/contracts/instance/module/treasury/TreasuryModule.sol

@@ -0,0 +1,131 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin5/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {IDistributionComponent} from "../../../components/IDistributionComponent.sol";
+import {IPoolComponent} from "../../../components/IPoolComponent.sol";
+import {IProductComponent} from "../../../components/IProductComponent.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+import {TREASURY} from "../../../types/ObjectType.sol";
+import {Fee, FeeLib} from "../../../types/Fee.sol";
+import {UFixed, UFixedMathLib} from "../../../types/UFixed.sol";
+import {TokenHandler} from "./TokenHandler.sol";
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {ITreasuryModule} from "./ITreasury.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+abstract contract TreasuryModule is
+    ModuleBase,
+    ITreasuryModule
+{
+    // relation of distributor and pool nft map to product nft
+    mapping(NftId componentNftId => NftId productNftId) internal _productNft;
+    // relation of component nft to token hanlder
+    mapping(NftId componentNftId => TokenHandler tokenHandler) internal _tokenHandler;
+    Fee internal _zeroFee;
+    
+    modifier onlyComponentOwnerService() virtual {
+        require(
+            msg.sender == address(this.getComponentOwnerService()),
+            "ERROR:CMP-001:NOT_COPONENT_OWNER_SERVICE"
+        );
+        _;
+    }
+
+    function _initializeTreasuryModule(IKeyValueStore keyValueStore) internal {
+        //_initializeModuleBase(keyValueStore);
+        _initialize(keyValueStore);
+        _zeroFee = FeeLib.zeroFee();
+    }
+
+    function registerProductSetup(
+        NftId productNftId,
+        TreasuryInfo memory setup
+    ) 
+        external
+        onlyComponentOwnerService
+    {
+        NftId poolNftId = setup.poolNftId;
+        NftId distributionNftId = setup.distributionNftId;
+
+        require(address(_tokenHandler[productNftId]) == address(0), "ERROR:TRS-012:TOKEN_HANDLER_ALREADY_REGISTERED");
+        require(_productNft[poolNftId].eqz(), "ERROR:TRS-013:POOL_ALREADY_LINKED");
+        require(_productNft[distributionNftId].eqz(), "ERROR:TRS-014:COMPENSATION_ALREADY_LINKED");
+
+        // TODO deploy TokenHandler with separate contract to save space
+        // deploy product specific handler contract
+        _tokenHandler[productNftId] = new TokenHandler(productNftId, address(setup.token));
+        _productNft[distributionNftId] = productNftId;
+        _productNft[poolNftId] = productNftId;
+
+        _create(TREASURY(), productNftId, abi.encode(setup));
+    }
+
+    function setTreasuryInfo(
+        NftId productNftId,
+        TreasuryInfo memory info
+    )
+        external
+        // TODO add authz (only component module)
+        override
+    {
+        _updateData(TREASURY(), productNftId, abi.encode(info));
+    }
+
+    function getProductNftId(
+        NftId componentNftId
+    ) external view returns (NftId productNftId) {
+        return _productNft[componentNftId];
+    }
+
+    function getTokenHandler(
+        NftId componentNftId
+    ) external view override returns (TokenHandler tokenHandler) {
+        return _tokenHandler[componentNftId];
+    }
+
+    function hasTreasuryInfo(
+        NftId productNftId
+    ) public view override returns (bool hasInfo) {
+        return _exists(TREASURY(), productNftId);
+    }
+
+    function getTreasuryInfo(
+        NftId productNftId
+    ) public view override returns (TreasuryInfo memory info) {
+        return abi.decode(_getData(TREASURY(), productNftId), (TreasuryInfo));
+    }
+
+    function calculateFeeAmount(
+        uint256 amount,
+        Fee memory fee
+    ) public pure override returns (uint256 feeAmount, uint256 netAmount) {
+        return FeeLib.calculateFee(fee, amount);
+    }
+
+    function getFee(
+        UFixed fractionalFee, 
+        uint256 fixedFee
+    ) external pure override returns (Fee memory fee) {
+        return FeeLib.toFee(fractionalFee, fixedFee);
+    }
+
+    function getZeroFee() external view override returns (Fee memory fee) {
+        return _zeroFee;
+    }
+
+    function getUFixed(
+        uint256 a
+    ) external pure override returns (UFixed) {
+        return UFixedMathLib.toUFixed(a);
+    }
+
+    function getUFixed(
+        uint256 a, 
+        int8 exp
+    ) external pure returns (UFixed)
+    {
+        return UFixedMathLib.toUFixed(a, exp);
+    }
+}

package/contracts/instance/service/ComponentOwnerService.sol

@@ -0,0 +1,272 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin5/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IInstance} from "../IInstance.sol";
+
+import {ITreasury, ITreasuryModule} from "../module/treasury/ITreasury.sol";
+import {TreasuryModule} from "../module/treasury/TreasuryModule.sol";
+import {IComponent, IComponentModule} from "../module/component/IComponent.sol";
+import {IBaseComponent} from "../../components/IBaseComponent.sol";
+import {IPoolComponent} from "../../components/IPoolComponent.sol";
+import {IKeyValueStore} from "../../instance/base/IKeyValueStore.sol";
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {RoleId, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE, DISTRIBUTION_OWNER_ROLE, ORACLE_OWNER_ROLE} from "../../types/RoleId.sol";
+import {ObjectType, TOKEN, COMPONENT, PRODUCT, ORACLE, POOL, DISTRIBUTION} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED} from "../../types/StateId.sol";
+import {Key32} from "../../types/Key32.sol";
+import {NftId, NftIdLib, zeroNftId} from "../../types/NftId.sol";
+import {Fee} from "../../types/Fee.sol";
+import {Version, VersionLib} from "../../types/Version.sol";
+import {UFixed, UFixedMathLib} from "../../types/UFixed.sol";
+
+import {IDistributionComponent} from "../../components/IDistributionComponent.sol";
+import {IPoolComponent} from "../../components/IPoolComponent.sol";
+import {IProductComponent} from "../../components/IProductComponent.sol";
+import {IService} from "../base/IService.sol";
+import {IComponentOwnerService} from "./IComponentOwnerService.sol";
+import {ServiceBase} from "../base/ServiceBase.sol";
+import {IPool, IPoolModule} from "../module/pool/IPoolModule.sol";
+
+import {IRegistryService} from "../../registry/IRegistryService.sol";
+
+contract ComponentOwnerService is
+    ServiceBase,
+    IComponentOwnerService
+{
+    using NftIdLib for NftId;
+
+    error MissingTypeRole();
+    error WalletIsZero();
+    error InvalidToken();
+    error InvalidPool();
+    error InvalidDistribution();
+    error InvalidPoolsInstance();
+    error InvalidDistributionsInstance();
+
+    error CollateralizationLevelIsZero();
+
+    string public constant NAME = "ComponentOwnerService";
+
+    modifier onlyRegisteredComponent(IBaseComponent component) {
+        NftId nftId = getRegistry().getNftId(address(component));
+        require(nftId.gtz(), "ERROR:COS-001:COMPONENT_UNKNOWN");
+        _;
+    }
+
+    constructor(
+        address registry,
+        NftId registryNftId,
+        address initialOwner
+    )
+    {
+        _initializeServiceBase(registry, registryNftId, initialOwner);
+        _registerInterface(type(IComponentOwnerService).interfaceId);
+    }
+
+    function getName() public pure override(IService, ServiceBase) returns(string memory name) {
+        return NAME;
+    }
+
+    function getRoleForType(
+        ObjectType cType
+    ) public pure override returns (RoleId role) {
+        if (cType == PRODUCT()) {
+            return PRODUCT_OWNER_ROLE();
+        }
+        if (cType == POOL()) {
+            return POOL_OWNER_ROLE();
+        }
+        if (cType == DISTRIBUTION()) {
+            return DISTRIBUTION_OWNER_ROLE();
+        }
+        if (cType == ORACLE()) {
+            return ORACLE_OWNER_ROLE();
+        }
+    }
+
+    function getRegistryService() public view virtual returns (IRegistryService) {
+        address service = getRegistry().getServiceAddress("RegistryService", getMajorVersion());
+        return IRegistryService(service);
+    }
+
+    // TODO if user passes type BUNDLE??? -> registerComponent() must catch this
+    function register(	
+        IBaseComponent component,
+        ObjectType componentType 	
+    ) external returns (NftId nftId) {	
+
+        // TODO some info parameters from component and from register may differ -> getObjectInfo() after registration?
+        (
+            IRegistry.ObjectInfo memory info,
+            bytes memory data
+        ) = getRegistryService().registerComponent(component, componentType, msg.sender);	
+
+        NftId instanceNftId = info.parentNftId;
+        address instancAddress = getRegistry().getObjectInfo(instanceNftId).objectAddress;
+        IInstance instance = IInstance(instancAddress);
+
+        RoleId typeRole = getRoleForType(componentType);
+        if(instance.hasRole(typeRole, msg.sender) == false) {
+            revert MissingTypeRole();
+        } 
+
+        // component type specific registration actions	
+        if (componentType == PRODUCT()) {	
+            _registerProduct(
+                    info.nftId, 
+                    instanceNftId,
+                    instance,
+                    data
+            );
+        } else if (componentType == POOL()) {	
+            _registerPool(
+                info.nftId,
+                instanceNftId,
+                instance,
+                data
+            );
+        }	
+        // TODO add distribution and oracle	
+    }
+
+    function lock(
+        IBaseComponent component
+    ) external override onlyRegisteredComponent(component) {
+        // TODO use msg.sender to get component and get instance via registered parent nft id
+        IInstance instance = component.getInstance();
+        NftId nftId = component.getNftId();
+        Key32 key = nftId.toKey32(COMPONENT());
+        instance.updateState(key, PAUSED());
+    }
+
+    function unlock(
+        IBaseComponent component
+    ) external override onlyRegisteredComponent(component) {
+        // TODO use msg.sender to get component and get instance via registered parent nft id
+        IInstance instance = component.getInstance();
+        NftId nftId = component.getNftId();
+        Key32 key = nftId.toKey32(COMPONENT());
+        instance.updateState(key, ACTIVE());
+    }
+
+    // Internals
+
+    function _registerProduct(
+        NftId nftId, 
+        NftId instanceNftId,
+        IInstance instance,
+        bytes memory data
+    )
+        internal
+    {
+        (
+            ITreasury.TreasuryInfo memory info,
+            address wallet
+        )  = abi.decode(data, (ITreasury.TreasuryInfo, address));
+
+        IRegistry _registry = getRegistry();
+
+        if(wallet == address(0)) {
+            revert WalletIsZero();
+        }
+
+        IRegistry.ObjectInfo memory tokenInfo = _registry.getObjectInfo(address(info.token));
+
+        if(tokenInfo.objectType != TOKEN()) {
+            revert InvalidToken();
+        } 
+
+        IRegistry.ObjectInfo memory poolInfo = _registry.getObjectInfo(info.poolNftId);
+
+        if(poolInfo.objectType != POOL()) {
+            revert InvalidPool();
+        }
+
+        if(poolInfo.parentNftId != instanceNftId) {
+            revert InvalidPoolsInstance();
+        }
+        // TODO pool have the same token
+        //ITreasury.PoolSetup memory poolSetup = instance.getPoolSetup(info.poolNftId);
+        //require(tokenInfo.objectAddress == address(poolSetup.token), "ERROR:COS-018:PRODUCT_POOL_TOKEN_MISMATCH");
+        // TODO pool is not linked
+
+        IRegistry.ObjectInfo memory distributionInfo = _registry.getObjectInfo(info.distributionNftId);
+
+        if(distributionInfo.objectType != DISTRIBUTION()) {
+            revert  InvalidDistribution();
+        } 
+
+        if(distributionInfo.parentNftId != instanceNftId) {
+            revert InvalidDistributionsInstance();
+        }
+        // TODO distribution have the same token
+        // TODO distribution is not linked
+
+        // component module
+        instance.registerComponent(
+            nftId,
+            info.token,
+            wallet // TODO move wallet into TreasuryInfo?
+        );
+
+        // treasury module
+        instance.registerProductSetup(
+            nftId, 
+            info
+        );
+    }
+
+    function _registerPool(
+        NftId nftId,
+        NftId instanceNftId,
+        IInstance instance,
+        bytes memory data
+    )
+        internal
+    {
+        (
+            IPool.PoolInfo memory info,
+            address wallet,
+            IERC20Metadata token,
+            /*poolFee*/,
+            /*stakingFee*/,
+            /*performanceFee*/
+        )  = abi.decode(data, (IPool.PoolInfo, address, IERC20Metadata, Fee, Fee, Fee));
+
+        IRegistry _registry = getRegistry();
+
+        if(wallet == address(0)) {
+            revert WalletIsZero();
+        }
+
+        ObjectType tokenType = _registry.getObjectInfo(address(token)).objectType;
+
+        if(tokenType != TOKEN()) {
+            revert InvalidToken();
+        } 
+
+        if(UFixedMathLib.eqz(info.collateralizationLevel)) { 
+            revert CollateralizationLevelIsZero();
+        }
+
+        // TODO add more validations
+
+        // component module
+        instance.registerComponent(
+            nftId,
+            token,
+            wallet
+        ); 
+
+        // pool module
+        instance.registerPool(
+            nftId, 
+            info
+        );
+    }
+}

package/contracts/instance/service/DistributionService.sol

@@ -0,0 +1,54 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {ITreasury} from "../../instance/module/treasury/ITreasury.sol";
+
+import {NftId} from "../../types/NftId.sol";
+import {Fee} from "../../types/Fee.sol";
+import {DISTRIBUTION} from "../../types/ObjectType.sol";
+import {Version, VersionLib} from "../../types/Version.sol";
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {IService} from "../base/IService.sol";
+import {ServiceBase} from "../base/ServiceBase.sol";
+import {ComponentServiceBase} from "../base/ComponentServiceBase.sol";
+import {IDistributionService} from "./IDistributionService.sol";
+
+contract DistributionService is
+    ComponentServiceBase,
+    IDistributionService
+{
+    string public constant NAME = "DistributionService";
+
+    constructor(
+        address registry,
+        NftId registryNftId,
+        address initialOwner
+    ) ComponentServiceBase(registry, registryNftId, initialOwner)
+    {
+        _registerInterface(type(IDistributionService).interfaceId);
+    }
+
+
+    function getName() public pure override(IService, ServiceBase) returns(string memory name) {
+        return NAME;
+    }
+
+    function setFees(
+        Fee memory distributionFee
+    )
+        external
+        override
+    {
+        (IRegistry.ObjectInfo memory distributionInfo, IInstance instance) = _getAndVerifyComponentInfoAndInstance(DISTRIBUTION());
+
+        NftId productNftId = instance.getProductNftId(distributionInfo.nftId);
+        ITreasury.TreasuryInfo memory treasuryInfo = instance.getTreasuryInfo(productNftId);
+        treasuryInfo.distributionFee = distributionFee;
+        instance.setTreasuryInfo(productNftId, treasuryInfo);
+    }
+}

package/contracts/instance/service/IComponentOwnerService.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {RoleId} from "../../types/RoleId.sol";
+import {IBaseComponent} from "../../components/IBaseComponent.sol";
+import {IService} from "../base/IService.sol";
+
+// TODO rename to registry service
+interface IComponentOwnerService is IService {
+
+    // TODO move to product/pool services
+    function lock(IBaseComponent component) external;
+
+    // TODO move to product/pool services
+    function unlock(IBaseComponent component) external;
+
+    function getRoleForType(ObjectType cType) external pure returns (RoleId role);
+}

package/contracts/instance/service/IDistributionService.sol

@@ -0,0 +1,12 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../types/NftId.sol";
+import {Fee} from "../../types/Fee.sol";
+import {IService} from "../base/IService.sol";
+
+interface IDistributionService is IService {
+    function setFees(
+        Fee memory distributionFee
+    ) external;
+}

package/contracts/instance/service/IPoolService.sol

@@ -0,0 +1,37 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../types/NftId.sol";
+import {Fee} from "../../types/Fee.sol";
+import {IService} from "../base/IService.sol";
+
+interface IPoolService is IService {
+    function setFees(
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    ) external;
+
+    function createBundle(
+        address owner,
+        Fee memory fee, 
+        uint256 amount,
+        uint256 lifetime, 
+        bytes calldata filter
+    ) external returns(NftId bundleNftId);
+
+    function setBundleFee(
+        NftId bundleNftId,
+        Fee memory fee
+    ) external;
+
+    // function fundBundle(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
+
+    // function defundBundle(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
+
+    // function lockBundle(NftId bundleNftId) external;
+
+    // function unlockBundle(NftId bundleNftId) external;
+
+    // function closeBundle(NftId bundleNftId) external;
+}

package/contracts/instance/service/IProductService.sol

@@ -0,0 +1,107 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRisk} from "../module/risk/IRisk.sol";
+import {IService} from "../base/IService.sol";
+
+import {NftId} from "../../types/NftId.sol";
+import {ReferralId} from "../../types/ReferralId.sol";
+import {RiskId} from "../../types/RiskId.sol";
+import {StateId} from "../../types/StateId.sol";
+import {Timestamp} from "../../types/Timestamp.sol";
+import {UFixed} from "../../types/UFixed.sol";
+import {Fee} from "../../types/Fee.sol";
+
+interface IProductService is IService {
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    ) external;
+
+    function createRisk(
+        RiskId riskId,
+        bytes memory data
+    ) external;
+
+
+    function setRiskInfo(
+        RiskId riskId,
+        IRisk.RiskInfo memory data
+    ) external;
+
+
+    function updateRiskState(
+        RiskId riskId,
+        StateId state
+    ) external;
+
+
+    function calculatePremium(
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external
+        view
+        returns (
+            uint256 premiumAmount,
+            uint256 productFeeAmount,
+            uint256 poolFeeAmount,
+            uint256 bundleFeeAmount,
+            uint256 distributionFeeAmount
+        );
+
+
+    function createApplication(
+        address applicationOwner,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    ) external returns (NftId nftId);
+
+    /**
+     * @dev revokes the application represented by {policyNftId}.
+     * an application can only be revoked in applied state.
+     * only the application holder may revoke an application.
+     */
+    function revoke(NftId policyNftId) external;
+
+    /**
+     * @dev underwrites the policy represented by {policyNftId}.
+     * optionally collects premiums and activates the policy.
+     * - premium payment is only attempted if requirePremiumPayment is set to true
+     * - activation is only done if activateAt is a non-zero timestamp
+     */
+    function underwrite(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    ) external;
+
+    // function decline(uint256 nftId) external;
+    // function expire(uint256 nftId) external;
+
+    function collectPremium(NftId policyNftId, Timestamp activateAt) external;
+
+    function activate(NftId policyNftId, Timestamp activateAt) external;
+
+
+    function close(NftId nftId) external;
+
+    // function createClaim(uint256 nftId, uint256 claimAmount) external;
+    // function confirmClaim(uint256 nftId, uint256 claimId, uint256 claimAmount) external;
+    // function declineClaim(uint256 nftId, uint256 claimId) external;
+    // function closeClaim(uint256 nftId, uint256 claimId) external;
+
+    function calculateRequiredCollateral(
+        UFixed collateralizationLevel, 
+        uint256 sumInsuredAmount
+    ) external pure returns(uint256 collateralAmount);
+
+}