@etherisc/gif-next 0.0.2-af8c650-079 → 0.0.2-afc3897-527

package/contracts/test/TestRegisterable.sol

@@ -1,19 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {NftId} from "../../contracts/types/NftId.sol";
-import {ObjectType, TOKEN} from "../../contracts/types/ObjectType.sol";
-import {IRegistry} from "../../contracts/registry/IRegistry.sol";
-import {Registerable} from "../../contracts/shared/Registerable.sol";
-
-contract TestRegisterable is Registerable {
-
-    constructor(address registry, NftId registryNftId)
-        Registerable(registry, registryNftId)
-    // solhint-disable-next-line no-empty-blocks
-    {}
-
-    function getType() external pure override returns (ObjectType) {
-        return TOKEN();
-    }
-}

package/contracts/test/TestRoleId.sol

@@ -1,14 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {RoleId, toRoleId, PRODUCT_OWNER_ROLE_NAME, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE_NAME, POOL_OWNER_ROLE} from "../../contracts/types/RoleId.sol";
-
-contract TestRoleId {
-    function getRole(string memory roleName) external pure returns (RoleId) { return toRoleId(roleName); }
-
-    function getProductOwnerRoleName() external pure returns (string memory) { return PRODUCT_OWNER_ROLE_NAME(); }
-    function getProductOwnerRole() external pure returns (RoleId) { return PRODUCT_OWNER_ROLE(); } 
-
-    function getPoolOwnerRoleName() external pure returns (string memory) { return POOL_OWNER_ROLE_NAME(); }
-    function getPoolOwnerRole() external pure returns (RoleId) { return POOL_OWNER_ROLE(); } 
-}

package/contracts/test/TestService.sol

@@ -1,32 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {NftId} from "../../contracts/types/NftId.sol";
-import {Version, VersionLib} from "../../contracts/types/Version.sol";
-import {ServiceBase} from "../../contracts/instance/service/ServiceBase.sol";
-
-import {IVersionable} from "../../contracts/shared/IVersionable.sol";
-import {Versionable} from "../../contracts/shared/Versionable.sol";
-
-contract TestService is ServiceBase {
-
-    string public constant NAME = "TestService";
-
-    constructor(address registry, NftId registryNftId)
-        ServiceBase(registry, registryNftId)
-    // solhint-disable-next-line no-empty-blocks
-    {}
-
-    function getVersion()
-        public 
-        pure 
-        virtual override (IVersionable, Versionable)
-        returns(Version)
-    {
-        return VersionLib.toVersion(3,0,0);
-    }
-
-    function getName() external pure override returns(string memory name) {
-        return NAME;
-    }
-}

package/contracts/test/TestToken.sol

@@ -1,26 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
-
-contract TestUsdc is ERC20 {
-
-    // https://etherscan.io/token/0xc719d010b63e5bbf2c0551872cd5316ed26acd83#readContract
-    string public constant NAME = "USDC - Test";
-    string public constant SYMBOL = "USDC";
-    uint8 public constant DECIMALS = 6;
-    uint256 public constant INITIAL_SUPPLY = 10**9 * 10**DECIMALS; // 1 Billion 1'000'000'000
-    // decimals == 18 (openzeppelin erc20 default)
-    constructor()
-        ERC20(NAME, SYMBOL)
-    {
-        _mint(
-            _msgSender(),
-            INITIAL_SUPPLY
-        );   
-    }
-
-    function decimals() public pure override returns(uint8) {
-        return DECIMALS;
-    }
-}

package/contracts/test/TestVersion.sol

@@ -1,44 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Version, VersionPart, VersionLib} from "../types/Version.sol";
-
-contract TestVersion {
-
-    function createVersion(uint major, uint minor, uint patch) external pure returns(Version) {
-        return VersionLib.toVersion(major, minor, patch);
-    }
-
-    function createVersionPart(uint versionPart) external pure returns(VersionPart) {
-        return VersionLib.toVersionPart(uint8(versionPart));
-    }
-
-    function getVersionParts(Version version)
-        external
-        pure
-        returns(
-            VersionPart major,
-            VersionPart minor,
-            VersionPart patch
-        )
-    {
-        return version.toVersionParts();
-    }
-
-    function getMajorPart(Version version) external pure returns(VersionPart major) {
-        return version.toMajorPart();
-    }
-
-    function getZeroVersion() external pure returns(Version) {
-        return VersionLib.zeroVersion();
-    }
-
-    function isSameVersion(Version a, Version b) external pure returns(bool) {
-        return a == b;
-    }
-
-    function isLargerVersion(Version a, Version b) external pure returns(bool) {
-        return a > b;
-    }
-
-}

package/contracts/test/TestVersionable.sol

@@ -1,17 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Version, VersionLib} from "../../contracts/types/Version.sol";
-import {Versionable} from "../../contracts/shared/Versionable.sol";
-
-contract TestVersionable is Versionable {
-
-    function getVersion()
-        public 
-        pure 
-        virtual override
-        returns(Version)
-    {
-        return VersionLib.toVersion(3,0,0);
-    }
-}

package/contracts/types/ChainId.sol

@@ -1,38 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-/// @dev bytes5 (uint40) allows for chain ids up to 13 digits
-type ChainId is bytes5;
-
-// type bindings
-using {eqChainId as ==, neChainId as !=, ChainIdLib.toInt} for ChainId global;
-
-// general pure free functions
-/// @dev Converts the uint256 to a ChainId.
-function toChainId(uint256 chainId) pure returns (ChainId) {
-    return ChainId.wrap(bytes5(uint40(chainId)));
-}
-
-/// @dev Return the ChainId for the chain the contract is deployed to
-function thisChainId() view returns (ChainId) {
-    return toChainId(block.chainid);
-}
-
-// pure free functions for operators
-/// @dev Returns true if the values are equal (==).
-function eqChainId(ChainId a, ChainId b) pure returns (bool isSame) {
-    return ChainId.unwrap(a) == ChainId.unwrap(b);
-}
-
-/// @dev Returns true if the values are not equal (!=).
-function neChainId(ChainId a, ChainId b) pure returns (bool isDifferent) {
-    return ChainId.unwrap(a) != ChainId.unwrap(b);
-}
-
-// library functions that operate on user defined type
-library ChainIdLib {
-    /// @dev Converts the ChainId to a uint256.
-    function toInt(ChainId chainId) internal pure returns (uint256) {
-        return uint256(uint40(ChainId.unwrap(chainId)));
-    }
-}

package/contracts/types/Fee.sol

@@ -1,51 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {UFixed, UFixedMathLib} from "./UFixed.sol";
-
-struct Fee {
-    UFixed fractionalFee;
-    uint256 fixedFee;
-}
-
-library FeeLib {
-
-    function calculateFee(
-        uint256 amount,
-        Fee memory fee
-    )
-        public
-        pure
-        returns (
-            uint256 feeAmount, 
-            uint256 netAmount
-        )
-    {
-        UFixed fractionalAmount = UFixedMathLib.toUFixed(amount) *
-            fee.fractionalFee;
-        feeAmount = fractionalAmount.toInt() + fee.fixedFee;
-        netAmount = amount - feeAmount;
-    }
-
-    /// @dev Converts the uint256 to a fee struct.
-    function toFee(
-        UFixed fractionalFee,
-        uint256 fixedFee
-    ) public pure returns (Fee memory fee) {
-        return Fee(fractionalFee, fixedFee);
-    }
-
-    /// @dev Return the zero fee struct (0, 0)
-    function zeroFee() public pure returns (Fee memory fee) {
-        return Fee(UFixed.wrap(0), 0);
-    }
-
-    // pure free functions for operators
-    function feeIsSame(Fee memory a, Fee memory b) public pure returns (bool isSame) {
-        return a.fixedFee == b.fixedFee && a.fractionalFee == b.fractionalFee;
-    }
-
-    function feeIsZero(Fee memory fee) public pure returns (bool) {
-        return fee.fixedFee == 0 && UFixed.unwrap(fee.fractionalFee) == 0;
-    }
-}

package/contracts/types/NftId.sol

@@ -1,57 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-// uint96 allows for chain ids up to 13 digits
-type NftId is uint96;
-
-// type bindings
-using {
-    eqNftId as ==, 
-    neNftId as !=, 
-    NftIdLib.toInt,
-    NftIdLib.gtz,
-    NftIdLib.eqz
-} for NftId global;
-
-// general pure free functions
-/// @dev Converts the uint256 to a NftId.
-function toNftId(uint256 id) pure returns (NftId) {
-    return NftId.wrap(uint96(id));
-}
-
-/// @dev Return the NftId zero (0)
-function zeroNftId() pure returns (NftId) {
-    return NftId.wrap(0);
-}
-
-// pure free functions for operators
-function eqNftId(NftId a, NftId b) pure returns (bool isSame) {
-    return NftId.unwrap(a) == NftId.unwrap(b);
-}
-
-function neNftId(NftId a, NftId b) pure returns (bool isDifferent) {
-    return NftId.unwrap(a) != NftId.unwrap(b);
-}
-
-// library functions that operate on user defined type
-library NftIdLib {
-    /// @dev Converts the NftId to a uint256.
-    function toInt(NftId nftId) public pure returns (uint96) {
-        return uint96(NftId.unwrap(nftId));
-    }
-
-    /// @dev Returns true if the value is non-zero (> 0).
-    function gtz(NftId a) public pure returns (bool) {
-        return NftId.unwrap(a) > 0;
-    }
-
-    /// @dev Returns true if the value is zero (== 0).
-    function eqz(NftId a) public pure returns (bool) {
-        return NftId.unwrap(a) == 0;
-    }
-
-    /// @dev Returns true if the values are equal (==).
-    function eq(NftId a, NftId b) public pure returns (bool isSame) {
-        return eqNftId(a, b);
-    }
-}

package/contracts/types/NftIdSet.sol

@@ -1,60 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {NftId} from "../types/NftId.sol";
-
-// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
-library LibNftIdSet {
-
-    struct Set {
-        NftId[] ids;
-        mapping(NftId nftid => uint256 index) at;
-    }
-
-    function add(Set storage set, NftId nftId) external returns(bool added) {
-        if (set.at[nftId] == 0) {
-            set.ids.push(nftId);
-            set.at[nftId] = set.ids.length;
-            return true;
-        } else {
-            return false;
-        }
-    }
-
-    function remove(Set storage set, NftId nftId) external returns(bool removed) {
-        uint256 nftIdIndex = set.at[nftId];
-
-        if (nftIdIndex > 0) {
-            uint256 toDeleteIndex = nftIdIndex - 1;
-            uint256 lastIndex = set.ids.length - 1;
-
-            if (lastIndex != toDeleteIndex) {
-                NftId lastId = set.ids[lastIndex];
-                set.ids[toDeleteIndex] = lastId;
-                set.at[lastId] = nftIdIndex; // Replace lastValue's index to valueIndex
-            }
-
-            set.ids.pop();
-            delete set.at[nftId];
-            return true;
-        } else {
-            return false;
-        }
-    }
-
-    function isEmpty(Set storage set) external view returns(bool empty) {
-        return set.ids.length == 0;
-    }
-
-    function contains(Set storage set, NftId nftId) external view returns(bool inSet) {
-        return set.at[nftId] > 0;
-    }
-
-    function getLength(Set storage set) external view returns(uint256 length) {
-        return set.ids.length;
-    }
-
-    function getElementAt(Set storage set, uint256 index) external view returns(NftId nftId) {
-        return set.ids[index];
-    }
-}

package/contracts/types/ObjectType.sol

@@ -1,115 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-type ObjectType is uint8;
-
-// type bindings
-using {
-    eqObjectType as ==,
-    neObjectType as !=,
-    ObjectTypeLib.toInt,
-    ObjectTypeLib.gtz
-} for ObjectType global;
-
-// general pure free functions
-
-function PROTOCOL() pure returns (ObjectType) {
-    return toObjectType(10);
-}
-
-function REGISTRY() pure returns (ObjectType) {
-    return toObjectType(20);
-}
-
-function TOKEN() pure returns (ObjectType) {
-    return toObjectType(30);
-}
-
-function SERVICE() pure returns (ObjectType) {
-    return toObjectType(40);
-}
-
-function INSTANCE() pure returns (ObjectType) {
-    return toObjectType(50);
-}
-
-function STAKE() pure returns (ObjectType) {
-    return toObjectType(60);
-}
-
-function PRODUCT() pure returns (ObjectType) {
-    return toObjectType(100);
-}
-
-function DISTRIBUTOR() pure returns (ObjectType) {
-    return toObjectType(110);
-}
-
-function ORACLE() pure returns (ObjectType) {
-    return toObjectType(120);
-}
-
-function POOL() pure returns (ObjectType) {
-    return toObjectType(130);
-}
-
-function POLICY() pure returns (ObjectType) {
-    return toObjectType(200);
-}
-
-function BUNDLE() pure returns (ObjectType) {
-    return toObjectType(210);
-}
-
-function CLAIM() pure returns (ObjectType) {
-    return toObjectType(201);
-}
-
-function PAYOUT() pure returns (ObjectType) {
-    return toObjectType(202);
-}
-
-/// @dev Converts the uint8 to a ObjectType.
-function toObjectType(uint256 objectType) pure returns (ObjectType) {
-    return ObjectType.wrap(uint8(objectType));
-}
-
-/// @dev Return the ObjectType zero (0)
-function zeroObjectType() pure returns (ObjectType) {
-    return ObjectType.wrap(0);
-}
-
-// pure free functions for operators
-function eqObjectType(ObjectType a, ObjectType b) pure returns (bool isSame) {
-    return ObjectType.unwrap(a) == ObjectType.unwrap(b);
-}
-
-function neObjectType(
-    ObjectType a,
-    ObjectType b
-) pure returns (bool isDifferent) {
-    return ObjectType.unwrap(a) != ObjectType.unwrap(b);
-}
-
-// library functions that operate on user defined type
-library ObjectTypeLib {
-    /// @dev Converts the NftId to a uint256.
-    function toInt(ObjectType objectType) public pure returns (uint96) {
-        return uint96(ObjectType.unwrap(objectType));
-    }
-
-    /// @dev Returns true if the value is non-zero (> 0).
-    function gtz(ObjectType a) public pure returns (bool) {
-        return ObjectType.unwrap(a) > 0;
-    }
-
-    /// @dev Returns true if the value is zero (== 0).
-    function eqz(ObjectType a) public pure returns (bool) {
-        return ObjectType.unwrap(a) == 0;
-    }
-
-    /// @dev Returns true if the values are equal (==).
-    function eq(ObjectType a, ObjectType b) public pure returns (bool isSame) {
-        return eqObjectType(a, b);
-    }
-}

package/contracts/types/RoleId.sol

@@ -1,36 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-type RoleId is bytes8;
-
-// type bindings
-using {
-    eqRoleId as ==, 
-    neRoleId as !=
-} for RoleId global;
-
-// general pure free functions
-function DISTRIBUTOR_OWNER_ROLE_NAME() pure returns (string memory) { return "DistributorOwnerRole"; }
-function ORACLE_OWNER_ROLE_NAME() pure returns (string memory) { return "OracleOwnerRole"; }
-function POOL_OWNER_ROLE_NAME() pure returns (string memory) { return "PoolOwnerRole"; }
-function PRODUCT_OWNER_ROLE_NAME() pure returns (string memory) { return "ProductOwnerRole"; }
-
-function DISTRIBUTOR_OWNER_ROLE() pure returns (RoleId) { return toRoleId("DistributorOwnerRole"); }
-function ORACLE_OWNER_ROLE() pure returns (RoleId) { return toRoleId("OracleOwnerRole"); }
-function POOL_OWNER_ROLE() pure returns (RoleId) { return toRoleId("PoolOwnerRole"); }
-function PRODUCT_OWNER_ROLE() pure returns (RoleId) { return toRoleId("ProductOwnerRole"); }
-
-// @dev Converts a role string into a role id.
-function toRoleId(string memory role) pure returns (RoleId) {
-    return RoleId.wrap(bytes8(keccak256(abi.encode(role))));
-}
-
-// @dev Returns true iff role ids a and b are identical
-function eqRoleId(RoleId a, RoleId b) pure returns (bool isSame) {
-    return RoleId.unwrap(a) == RoleId.unwrap(b);
-}
-
-// @dev Returns true iff role ids a and b are different
-function neRoleId(RoleId a, RoleId b) pure returns (bool isDifferent) {
-    return RoleId.unwrap(a) != RoleId.unwrap(b);
-}

package/contracts/types/Version.sol

@@ -1,95 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-type VersionPart is uint8;
-
-using {
-    versionPartGt as >,
-    versionPartEq as ==,
-    VersionPartLib.toInt
-}
-    for VersionPart global;
-
-function versionPartGt(VersionPart a, VersionPart b) pure returns(bool isGreaterThan) { return VersionPart.unwrap(a) > VersionPart.unwrap(b); }
-function versionPartEq(VersionPart a, VersionPart b) pure returns(bool isSame) { return VersionPart.unwrap(a) == VersionPart.unwrap(b); }
-
-library VersionPartLib {
-    function toInt(VersionPart x) external pure returns(uint) { return VersionPart.unwrap(x); }
-}
-
-type Version is uint24; // contains major,minor,patch version parts
-
-using {
-    versionGt as >,
-    versionEq as ==,
-    VersionLib.toInt,
-    VersionLib.toMajorPart,
-    VersionLib.toVersionParts
-}
-    for Version global;
-
-function versionGt(Version a, Version b) pure returns(bool isGreaterThan) { return Version.unwrap(a) > Version.unwrap(b); }
-function versionEq(Version a, Version b) pure returns(bool isSame) { return Version.unwrap(a) == Version.unwrap(b); }
-
-library VersionLib {
-    function toInt(Version version) external pure returns(uint) { return Version.unwrap(version); }
-
-    function toMajorPart(Version version)
-        external    
-        pure 
-        returns(VersionPart major)
-    { 
-        uint24 versionInt = Version.unwrap(version);
-        uint8 majorInt = uint8(versionInt >> 16);
-        return VersionPart.wrap(majorInt);
-    }
-
-    function toVersionParts(Version version)
-        external
-        pure
-        returns(
-            VersionPart major,
-            VersionPart minor,
-            VersionPart patch
-        )
-    {
-        uint24 versionInt = Version.unwrap(version);
-        uint8 majorInt = uint8(versionInt >> 16);
-
-        versionInt -= majorInt << 16;
-        uint8 minorInt = uint8(versionInt >> 8);
-        uint8 patchInt = uint8(versionInt - (minorInt << 8));
-
-        return (
-            VersionPart.wrap(majorInt),
-            VersionPart.wrap(minorInt),
-            VersionPart.wrap(patchInt)
-        );
-    }
-
-    function toVersionPart(uint256 versionPart) external pure returns(VersionPart) { 
-        return VersionPart.wrap(uint8(versionPart)); 
-    }
-
-    function toVersion(
-        uint256 major,
-        uint256 minor,
-        uint256 patch
-    )
-        external
-        pure
-        returns(Version)
-    {
-        require(
-            major < 256 && minor < 256 && patch < 256,
-            "ERROR:VRS-010:VERSION_PART_TOO_BIG");
-
-        return Version.wrap(
-            uint24(
-                (major << 16) + (minor << 8) + patch));
-    }
-
-    function zeroVersion() external pure returns(Version) {
-        return Version.wrap(0);
-    }
-}