@etherisc/gif-next 0.0.2-af8c650-079 → 0.0.2-afc3897-527

package/contracts/instance/service/ProductService.sol

@@ -1,355 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {IRegistry} from "../../registry/IRegistry.sol";
-import {IPoolComponent} from "../../components/IPoolComponent.sol";
-import {IInstance} from "../../instance/IInstance.sol";
-import {IPolicy, IPolicyModule} from "../module/policy/IPolicy.sol";
-import {IPool} from "../module/pool/IPoolModule.sol";
-import {IBundle} from "../module/bundle/IBundle.sol";
-import {IProductService} from "./IProductService.sol";
-import {ITreasury, ITreasuryModule, TokenHandler} from "../../instance/module/treasury/ITreasury.sol";
-
-import {IVersionable} from "../../shared/IVersionable.sol";
-import {Versionable} from "../../shared/Versionable.sol";
-
-import {Timestamp, zeroTimestamp} from "../../types/Timestamp.sol";
-import {UFixed, UFixedMathLib} from "../../types/UFixed.sol";
-import {ObjectType, INSTANCE, PRODUCT, POLICY} from "../../types/ObjectType.sol";
-import {APPLIED, UNDERWRITTEN, ACTIVE} from "../../types/StateId.sol";
-import {NftId, NftIdLib} from "../../types/NftId.sol";
-import {Blocknumber, blockNumber} from "../../types/Blocknumber.sol";
-import {Fee, FeeLib} from "../../types/Fee.sol";
-import {Version, VersionLib} from "../../types/Version.sol";
-
-import {ComponentServiceBase} from "./ComponentServiceBase.sol";
-import {IProductService} from "./IProductService.sol";
-
-// TODO or name this ProtectionService to have Product be something more generic (loan, savings account, ...)
-contract ProductService is ComponentServiceBase, IProductService {
-    using NftIdLib for NftId;
-
-    string public constant NAME = "ProductService";
-
-    event LogProductServiceSender(address sender);
-
-    constructor(
-        address registry,
-        NftId registryNftId
-    ) ComponentServiceBase(registry, registryNftId) // solhint-disable-next-line no-empty-blocks
-    {
-        _registerInterface(type(IProductService).interfaceId);
-    }
-
-    function getVersion()
-        public 
-        pure 
-        virtual override (IVersionable, Versionable)
-        returns(Version)
-    {
-        return VersionLib.toVersion(3,0,0);
-    }
-
-    function getName() external pure override returns(string memory name) {
-        return NAME;
-    }
-
-    function setFees(
-        Fee memory policyFee,
-        Fee memory processingFee
-    )
-        external
-        override
-    {
-        (IRegistry.ObjectInfo memory productInfo, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
-        instance.setProductFees(productInfo.nftId, policyFee, processingFee);
-    }
-
-    function createApplication(
-        address applicationOwner,
-        uint256 sumInsuredAmount,
-        uint256 premiumAmount,
-        uint256 lifetime,
-        NftId bundleNftId
-    ) external override returns (NftId policyNftId) {
-        (IRegistry.ObjectInfo memory productInfo, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
-        NftId productNftId = productInfo.nftId;
-        // TODO add validations (see create bundle in pool service)
-
-        policyNftId = this.getRegistry().registerObjectForInstance(
-            productNftId,
-            POLICY(),
-            applicationOwner,
-            ""
-        );
-
-        instance.createApplication(
-            productNftId,
-            policyNftId,
-            sumInsuredAmount,
-            premiumAmount,
-            lifetime,
-            bundleNftId
-        );
-
-        // TODO add logging
-    }
-
-    function _getAndVerifyUnderwritingSetup(
-        IInstance instance,
-        IPolicy.PolicyInfo memory policyInfo
-    )
-        internal
-        view
-        returns (
-            ITreasury.ProductSetup memory productSetup,
-            IBundle.BundleInfo memory bundleInfo,
-            uint256 collateralAmount,
-            bool poolIsVerifying,
-            bytes memory bundleFilter
-        )
-    {
-        // check match between policy and bundle (via pool)
-        productSetup = instance.getProductSetup(policyInfo.productNftId);
-        bundleInfo = instance.getBundleInfo(policyInfo.bundleNftId);
-        require(bundleInfo.poolNftId == productSetup.poolNftId, "POLICY_BUNDLE_MISMATCH");
-
-        // calculate required collateral
-        NftId poolNftId = productSetup.poolNftId;
-        IPool.PoolInfo memory poolInfo = instance.getPoolInfo(poolNftId);
-
-        // obtain remaining return values
-        poolIsVerifying = poolInfo.isVerifying;
-        collateralAmount = calculateRequiredCollateral(poolInfo.collateralizationLevel, policyInfo.sumInsuredAmount);
-        bundleFilter = bundleInfo.filter;
-    }
-
-    function _lockCollateralInBundle(
-        IInstance instance,
-        IBundle.BundleInfo memory bundleInfo,
-        NftId policyNftId, 
-        uint256 collateralAmount
-    )
-        internal
-        returns (IBundle.BundleInfo memory)
-    {
-        bundleInfo.lockedAmount += collateralAmount;
-        bundleInfo.updatedIn = blockNumber();
-        instance.collateralizePolicy(bundleInfo.nftId, policyNftId, collateralAmount);
-        return bundleInfo;
-    }
-
-    function _underwriteByPool(
-        ITreasury.ProductSetup memory productSetup,
-        IPolicy.PolicyInfo memory policyInfo,
-        bytes memory bundleFilter,
-        uint256 collateralAmount
-    )
-        internal
-    {
-        address poolAddress = _registry.getObjectInfo(productSetup.poolNftId).objectAddress;
-        IPoolComponent pool = IPoolComponent(poolAddress);
-        pool.underwrite(
-            policyInfo.nftId, 
-            policyInfo.data, 
-            bundleFilter,
-            collateralAmount);
-    }
-
-
-    function underwrite(
-        NftId policyNftId,
-        bool requirePremiumPayment,
-        Timestamp activateAt
-    )
-        external 
-        override
-    {
-        // check caller is registered product
-        (
-            IRegistry.ObjectInfo memory productInfo, 
-            IInstance instance
-        ) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
-
-        // check match between policy and calling product
-        NftId productNftId = productInfo.nftId;
-        IPolicy.PolicyInfo memory policyInfo = instance.getPolicyInfo(policyNftId);
-        require(policyInfo.productNftId == productNftId, "POLICY_PRODUCT_MISMATCH");
-        require(policyInfo.state == APPLIED(), "ERROR:PRS-021:STATE_NOT_APPLIED");
-
-        (
-            ITreasury.ProductSetup memory productSetup,
-            IBundle.BundleInfo memory bundleInfo,
-            uint256 collateralAmount,
-            bool poolIsVerifying,
-            bytes memory bundleFilter
-        ) = _getAndVerifyUnderwritingSetup(
-            instance,
-            policyInfo
-        );
-
-        // lock bundle collateral
-        bundleInfo = _lockCollateralInBundle(
-            instance,
-            bundleInfo,
-            policyNftId, 
-            collateralAmount);
-
-        // collect premium
-        if(requirePremiumPayment) {
-            uint256 netPremiumAmount = _processPremiumByTreasury(
-                instance, 
-                productSetup, 
-                policyNftId, 
-                policyInfo.premiumAmount);
-
-            policyInfo.premiumPaidAmount += policyInfo.premiumAmount;
-            bundleInfo.balanceAmount += netPremiumAmount;
-        }
-
-        // set policy state to underwritten
-        // TODO add require for state change
-        policyInfo.state = UNDERWRITTEN();
-        policyInfo.updatedIn = blockNumber();
-
-        // optional activation of policy
-        if(activateAt > zeroTimestamp()) {
-            policyInfo.activatedAt = activateAt;
-            policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
-
-            // TODO add require for state change
-            policyInfo.state = ACTIVE();
-        }
-
-        instance.setPolicyInfo(policyInfo);
-        instance.setBundleInfo(bundleInfo);
-
-        // integrate pool component
-        if(poolIsVerifying) {
-            _underwriteByPool(
-                productSetup,
-                policyInfo,
-                bundleFilter,
-                collateralAmount
-            );
-        }
-
-        // TODO add logging
-    }
-
-    function calculateRequiredCollateral(UFixed collateralizationLevel, uint256 sumInsuredAmount) public pure override returns(uint256 collateralAmount) {
-        UFixed sumInsuredUFixed = UFixedMathLib.toUFixed(sumInsuredAmount);
-        UFixed collateralUFixed =  collateralizationLevel * sumInsuredUFixed;
-        return collateralUFixed.toInt();
-    } 
-
-    function collectPremium(NftId policyNftId, Timestamp activateAt) external override {
-        // check caller is registered product
-        (IRegistry.ObjectInfo memory productInfo, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
-
-        // perform actual token transfers
-        IPolicy.PolicyInfo memory policyInfo = instance.getPolicyInfo(policyNftId);
-        ITreasury.ProductSetup memory product = instance.getProductSetup(productInfo.nftId);
-
-        uint256 premiumAmount = policyInfo.premiumAmount;
-        _processPremiumByTreasury(instance, product, policyNftId, premiumAmount);
-
-        // policy level book keeping for premium paid
-        policyInfo.premiumPaidAmount += premiumAmount;
-        policyInfo.updatedIn = blockNumber();
-
-        // optional activation of policy
-        if(activateAt > zeroTimestamp()) {
-            require(
-                policyInfo.activatedAt.eqz(),
-                "ERROR:PRS-030:ALREADY_ACTIVATED");
-
-            policyInfo.activatedAt = activateAt;
-            policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
-
-            // TODO add require for state change
-            policyInfo.state = ACTIVE();
-        }
-
-        instance.setPolicyInfo(policyInfo);
-
-        // TODO add logging
-    }
-
-    function activate(NftId policyNftId, Timestamp activateAt) external override {
-        // check caller is registered product
-        (, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
-
-        IPolicy.PolicyInfo memory policyInfo = instance.getPolicyInfo(policyNftId);
-
-        require(
-            policyInfo.activatedAt.eqz(),
-            "ERROR:PRS-020:ALREADY_ACTIVATED");
-
-        policyInfo.activatedAt = activateAt;
-        policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
-
-        // TODO add require for state change
-        policyInfo.state = ACTIVE();
-
-        instance.setPolicyInfo(policyInfo);
-
-        // TODO add logging
-    }
-
-    function close(
-        NftId policyNftId
-    ) external override // solhint-disable-next-line no-empty-blocks
-    {
-
-    }
-
-    function _getPoolNftId(
-        IInstance instance,
-        NftId productNftId
-    )
-        internal
-        view
-        returns (NftId poolNftid)
-    {
-        return instance.getProductSetup(productNftId).poolNftId;
-    }
-
-    function _processPremiumByTreasury(
-        IInstance instance,
-        ITreasury.ProductSetup memory product,
-        NftId policyNftId,
-        uint256 premiumAmount
-    )
-        internal
-        returns (uint256 netPremiumAmount)
-    {
-        // process token transfer(s)
-        if(premiumAmount > 0) {
-            TokenHandler tokenHandler = instance.getTokenHandler(product.productNftId);
-            address policyOwner = _registry.getOwner(policyNftId);
-            address poolWallet = instance.getPoolSetup(product.poolNftId).wallet;
-            netPremiumAmount = premiumAmount;
-            Fee memory policyFee = product.policyFee;
-
-            if (FeeLib.feeIsZero(policyFee)) {
-                tokenHandler.transfer(
-                    policyOwner,
-                    poolWallet,
-                    premiumAmount
-                );
-            } else {
-                (uint256 feeAmount, uint256 netAmount) = instance.calculateFeeAmount(
-                    premiumAmount,
-                    policyFee
-                );
-
-                tokenHandler.transfer(policyOwner, product.wallet, feeAmount);
-                tokenHandler.transfer(policyOwner, poolWallet, netAmount);
-                netPremiumAmount = netAmount;
-            }
-        }
-
-        // TODO add logging
-    }
-}

package/contracts/instance/service/ServiceBase.sol

@@ -1,39 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-// import {IRegistry} from "../../registry/IRegistry.sol";
-// import {ITreasury, ITreasuryModule, TokenHandler} from "../../instance/module/treasury/ITreasury.sol";
-import {NftId, zeroNftId} from "../../types/NftId.sol";
-import {ObjectType, SERVICE} from "../../types/ObjectType.sol";
-import {Version, VersionPart} from "../../types/Version.sol";
-
-import {Registerable} from "../../shared/Registerable.sol";
-import {IVersionable} from "../../shared/IVersionable.sol";
-import {Versionable} from "../../shared/Versionable.sol";
-
-import {IService} from "./IService.sol";
-
-abstract contract ServiceBase is 
-    Registerable,
-    Versionable,
-    IService
-{
-
-    constructor(
-        address registry,
-        NftId registryNftId
-    )
-        Registerable(registry, registryNftId)
-        Versionable()
-    {
-        _registerInterface(type(IService).interfaceId);
-    }
-
-    function getMajorVersion() external view override returns(VersionPart majorVersion) {
-        return this.getVersion().toMajorPart();
-    }
-
-    function getType() external pure override returns (ObjectType) {
-        return SERVICE();
-    }
-}

package/contracts/registry/IChainNft.sol

@@ -1,21 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {IERC721Enumerable} from "@openzeppelin/contracts/token/ERC721/extensions/IERC721Enumerable.sol";
-
-interface IChainNft is IERC721Enumerable {
-    function mint(
-        address to,
-        string memory uri
-    ) external returns (uint256 tokenId);
-
-    function burn(uint256 tokenId) external;
-
-    function setURI(uint256 tokenId, string memory uri) external;
-
-    function exists(uint256 tokenId) external view returns (bool);
-
-    function totalMinted() external view returns (uint256);
-
-    function getRegistryAddress() external view returns (address registry);
-}

package/contracts/registry/IRegistryLinked.sol

@@ -1,8 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {IRegistry} from "../registry/IRegistry.sol";
-
-interface IRegistryLinked {
-    function getRegistry() external view returns (IRegistry registry);
-}

package/contracts/shared/ERC165.sol

@@ -1,21 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
-
-contract ERC165 is IERC165 {
-    mapping(bytes4 => bool) private _isSupported;
-
-    constructor() {
-        // register support for ERC165
-        _registerInterface(type(IERC165).interfaceId);
-    }
-
-    function supportsInterface(bytes4 interfaceId) external view override returns (bool) {
-        return _isSupported[interfaceId];
-    }
-
-    function _registerInterface(bytes4 interfaceId) internal {
-        _isSupported[interfaceId] = true;
-    }
-}

package/contracts/shared/IOwnable.sol

@@ -1,6 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-interface IOwnable {
-    function getOwner() external view returns (address owner);
-}

package/contracts/shared/IVersionable.sol

@@ -1,52 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Blocknumber, blockNumber} from "../types/Blocknumber.sol";
-import {Timestamp, blockTimestamp} from "../types/Timestamp.sol";
-import {Version, VersionPart} from "../types/Version.sol";
-
-interface IVersionable {
-
-    struct VersionInfo {
-        Version version;
-        address implementation;
-        address activatedBy;
-        Timestamp activatedAt;
-        Blocknumber activatedIn;
-    }
-
-    event LogVersionableActivated(Version version, address implementation, address activatedBy);
-
-    /**
-     * @dev IMPORTANT this function needs to be implemented by each new version
-     * any such activate implementation needs to call internal function call _activate() 
-     * any new version needs to inherit from previous version
-     */
-    function activate(address implementation, address activatedBy) external;
-
-    /**
-     * @dev returns true if the specified version has been activated for the current contract
-     */
-    function isActivated(Version version) external view returns(bool);
-
-    /**
-     * @dev returns currently active version of this contract
-     */
-    function getVersion() external pure returns(Version);
-
-    /**
-     * @dev returns the number of all deployed versions of this contract
-     */
-    function getVersionCount() external view returns(uint256 numberOfVersions);
-
-    /**
-     * @dev returns the i-th (index) version of this contract
-     */
-    function getVersion(uint256 index) external view returns(Version version);
-
-    /**
-     * @dev returns the i-th (index) version info of this contract
-     */
-    function getVersionInfo(Version version) external view returns(VersionInfo memory versionInfo);
-
-}

package/contracts/shared/Versionable.sol

@@ -1,89 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Blocknumber, blockNumber} from "../types/Blocknumber.sol";
-import {Timestamp, blockTimestamp} from "../types/Timestamp.sol";
-import {Version, VersionPart} from "../types/Version.sol";
-
-import {IVersionable} from "./IVersionable.sol";
-
-abstract contract Versionable is IVersionable {
-
-    mapping(Version version => VersionInfo info) private _versionHistory;
-    Version [] private _versions;
-
-
-    // controlled activation for controller contract
-    constructor() {
-        _activate(address(0), msg.sender);
-    }
-
-    // IMPORTANT this function needs to be implemented by each new version
-    // and needs to call internal function call _activate() 
-    function activate(address implementation, address activatedBy)
-        external
-        override
-    { 
-        _activate(implementation, activatedBy);
-    }
-
-
-    // can only be called once per contract
-    // needs bo be called inside the proxy upgrade tx
-    function _activate(
-        address implementation,
-        address activatedBy
-    )
-        internal
-    {
-        Version thisVersion = getVersion();
-        require(
-            !isActivated(thisVersion),
-            "ERROR:VRN-001:VERSION_ALREADY_ACTIVATED"
-        );
-        
-        // require increasing version number
-        if(_versions.length > 0) {
-            Version lastVersion = _versions[_versions.length - 1];
-            require(
-                thisVersion > lastVersion,
-                "ERROR:VRN-002:VERSION_NOT_INCREASING"
-            );
-        }
-
-        // update version history
-        _versions.push(thisVersion);
-        _versionHistory[thisVersion] = VersionInfo(
-            thisVersion,
-            implementation,
-            activatedBy,
-            blockTimestamp(),
-            blockNumber()
-        );
-
-        emit LogVersionableActivated(thisVersion, implementation, activatedBy);
-    }
-
-
-    function isActivated(Version _version) public override view returns(bool) {
-        return _versionHistory[_version].activatedIn.toInt() > 0;
-    }
-
-
-    function getVersion() public pure virtual returns(Version);
-
-
-    function getVersionCount() external view override returns(uint256) {
-        return _versions.length;
-    }
-
-
-    function getVersion(uint256 idx) external view override returns(Version) {
-        return _versions[idx];
-    }
-
-
-    function getVersionInfo(Version _version) external override view returns(VersionInfo memory) {
-        return _versionHistory[_version];
-    }
-}

package/contracts/test/TestFee.sol

@@ -1,25 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {UFixed, UFixedMathLib} from "../types/UFixed.sol";
-import {Fee, FeeLib} from "../types/Fee.sol";
-
-contract TestFee {
-
-    function createFee(
-        uint256 fractionalValue,
-        int8 exponent,
-        uint256 fixedValue
-    )
-        external 
-        pure 
-        returns(Fee memory fee)
-    {
-        return FeeLib.toFee(UFixedMathLib.toUFixed(fractionalValue, exponent), fixedValue);
-    }
-
-    function getZeroFee() external pure returns(Fee memory fee) {
-        return FeeLib.zeroFee();
-    }
-
-}

package/contracts/test/TestPool.sol

@@ -1,22 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {NftId} from "../../contracts/types/NftId.sol";
-import {UFixed} from "../../contracts/types/UFixed.sol";
-import {Fee} from "../../contracts/types/Fee.sol";
-import {Pool} from "../../contracts/components/Pool.sol";
-
-
-contract TestPool is Pool {
-
-    constructor(
-        address registry,
-        NftId instanceNftid,
-        address token,
-        bool isVerifying,
-        UFixed collateralizationLevel
-    )
-        Pool(registry, instanceNftid, token, isVerifying, collateralizationLevel)
-    // solhint-disable-next-line no-empty-blocks
-    {}
-}

package/contracts/test/TestProduct.sol

@@ -1,44 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Product} from "../../contracts/components/Product.sol";
-import {NftId, toNftId} from "../../contracts/types/NftId.sol";
-import {Timestamp, blockTimestamp} from "../../contracts/types/Timestamp.sol";
-import {Fee} from "../../contracts/types/Fee.sol";
-
-contract TestProduct is Product {
-
-    event LogTestProductSender(address sender);
-
-    constructor(address registry, NftId instanceNftid, address token, address pool)
-        Product(registry, instanceNftid, token, pool)
-    // solhint-disable-next-line no-empty-blocks
-    {}
-
-    function applyForPolicy(
-        uint256 sumInsuredAmount,
-        uint256 premiumAmount,
-        uint256 lifetime,
-        NftId bundleNftId
-    )
-        external
-        returns(NftId nftId)
-    {
-        nftId = _createApplication(
-            msg.sender, // policy holder
-            sumInsuredAmount,
-            premiumAmount,
-            lifetime,
-            bundleNftId
-        );
-    }
-
-    function underwrite(NftId nftId, bool requirePremiumPayment, Timestamp activateAt) external {
-        emit LogTestProductSender(msg.sender);
-        _underwrite(nftId, requirePremiumPayment, activateAt);
-    }
-
-    function collectPremium(NftId nftId, Timestamp activateAt) external {
-        _collectPremium(nftId, activateAt);
-    }
-}