@etherisc/gif-next 0.0.2-a6f9f86-582 → 0.0.2-a6faeb6-912

package/contracts/components/Product.sol

@@ -0,0 +1,289 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IRisk} from "../instance/module/IRisk.sol";
+import {ITreasury} from "../instance/module/ITreasury.sol";
+import {IProductService} from "../instance/service/IProductService.sol";
+import {IProductComponent} from "./IProductComponent.sol";
+import {NftId, zeroNftId, NftIdLib} from "../types/NftId.sol";
+import {ObjectType, PRODUCT} from "../types/ObjectType.sol";
+import {ReferralId} from "../types/Referral.sol";
+import {RiskId, RiskIdLib} from "../types/RiskId.sol";
+import {StateId} from "../types/StateId.sol";
+import {Timestamp} from "../types/Timestamp.sol";
+import {Fee, FeeLib} from "../types/Fee.sol";
+import {BaseComponent} from "./BaseComponent.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {Pool} from "../components/Pool.sol";
+import {Distribution} from "../components/Distribution.sol";
+
+import {zeroNftId} from "../types/NftId.sol";
+
+contract Product is BaseComponent, IProductComponent {
+    using NftIdLib for NftId;
+
+    IProductService internal _productService;
+    Pool internal _pool;
+    Distribution internal _distribution;
+    Fee internal _initialProductFee;
+    Fee internal _initialProcessingFee;
+    TokenHandler internal _tokenHandler;
+
+    NftId internal _poolNftId;
+    NftId internal _distributionNftId;
+
+    constructor(
+        address registry,
+        NftId instanceNftid,
+        address token,
+        bool isInterceptor,
+        address pool,
+        address distribution,
+        Fee memory productFee,
+        Fee memory processingFee,
+        address initialOwner
+    ) BaseComponent(registry, instanceNftid, token, PRODUCT(), isInterceptor, initialOwner) {
+        // TODO add validation
+        _productService = _instance.getProductService();
+        _pool = Pool(pool);
+        _distribution = Distribution(distribution);
+        _initialProductFee = productFee;
+        _initialProcessingFee = processingFee;  
+
+        _tokenHandler = new TokenHandler(token);
+
+        _poolNftId = getRegistry().getNftId(address(_pool));
+        _distributionNftId = getRegistry().getNftId(address(_distribution));
+
+        _registerInterface(type(IProductComponent).interfaceId);  
+    }
+
+
+    function calculatePremium(
+        uint256 sumInsuredAmount,
+        RiskId riskId,
+        uint256 lifetime,
+        bytes memory applicationData,
+        ReferralId referralId,
+        NftId bundleNftId
+    )
+        external 
+        view 
+        override 
+        returns (uint256 premiumAmount)
+    {
+        (premiumAmount,,,,) = _productService.calculatePremium(
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+    }
+
+
+    function calculateNetPremium(
+        uint256 sumInsuredAmount,
+        RiskId riskId,
+        uint256 lifetime,
+        bytes memory applicationData
+    )
+        external
+        view
+        virtual override
+        returns (uint256 netPremiumAmount)
+    {
+        // default 10% of sum insured
+        return sumInsuredAmount / 10;
+    }
+
+    function _toRiskId(string memory riskName) internal pure returns (RiskId riskId) {
+        return RiskIdLib.toRiskId(riskName);
+    }
+
+    function _createRisk(
+        RiskId id,
+        bytes memory data
+    ) internal {
+        _productService.createRisk(
+            id,
+            data
+        );
+    }
+
+    function _updateRisk(
+        RiskId id,
+        bytes memory data
+    ) internal {
+        _productService.updateRisk(
+            id,
+            data
+        );
+    }
+
+    function _updateRiskState(
+        RiskId id,
+        StateId state
+    ) internal {
+        _productService.updateRiskState(
+            id,
+            state
+        );
+    }
+
+    function _getRiskInfo(RiskId id) internal view returns (IRisk.RiskInfo memory info) {
+        return _instance.getInstanceReader().getRiskInfo(id);
+    }
+
+    function _createApplication(
+        address applicationOwner,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    ) internal returns (NftId nftId) {
+        nftId = _productService.createApplication(
+            applicationOwner,
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+    }
+
+    function _underwrite(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _productService.underwrite(
+            policyNftId, 
+            requirePremiumPayment, 
+            activateAt);
+    }
+
+    function _collectPremium(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _productService.collectPremium(
+            policyNftId, 
+            activateAt);
+    }
+
+    function _activate(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _productService.activate(
+            policyNftId, 
+            activateAt);
+    }
+
+    function getPoolNftId() external view override returns (NftId poolNftId) {
+        return getRegistry().getNftId(address(_pool));
+    }
+
+    function getDistributionNftId() external view override returns (NftId distributionNftId) {
+        return getRegistry().getNftId(address(_distribution));
+    }
+
+    // from product component
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    )
+        external
+        onlyOwner
+        override
+    {
+        _productService.setFees(productFee, processingFee);
+    }
+
+    function getSetupInfo() public view returns (ISetup.ProductSetupInfo memory setupInfo) {
+        InstanceReader reader = _instance.getInstanceReader();
+        return reader.getProductSetupInfo(getNftId());
+    }
+
+    // from IRegisterable
+
+    function getInitialInfo() 
+        public
+        view 
+        override (IRegisterable, Registerable)
+        returns (IRegistry.ObjectInfo memory, bytes memory)
+    {
+        // from Registerable
+        (
+            IRegistry.ObjectInfo memory productInfo, 
+            bytes memory data
+        ) = super.getInitialInfo();
+        
+        // TODO read pool & distribution fees
+        // 1) from pool -> the only option -> pool must be registered first?
+        // 2) from instance -> all fees are set into instance at product registration which is ongoing here
+        // checks are done in registryProduct() where THIS function is called
+        //require(getRegistry().getObjectInfo(_poolNftId).objectType == POOL(), "POOL_NOT_REGISTERED");
+        //require(getRegistry().getObjectInfo(_distributionNftId).objectType == DISTRIBUTION(), "DISTRIBUTION_NOT_REGISTERED");
+        
+        // from PoolComponent
+        (
+            , 
+            bytes memory poolData
+        ) = _pool.getInitialInfo();
+        
+        (
+            ISetup.PoolSetupInfo memory poolSetupInfo
+        )  = abi.decode(poolData, (ISetup.PoolSetupInfo));
+
+        // from DistributionComponent
+        (
+            , 
+            bytes memory distributionData
+        ) = _distribution.getInitialInfo();
+
+        (
+            ISetup.DistributionSetupInfo memory distributionSetupInfo
+        )  = abi.decode(distributionData, (ISetup.DistributionSetupInfo));
+
+        return (
+            productInfo,
+            abi.encode(
+                ISetup.ProductSetupInfo(
+                    _token,
+                    _tokenHandler,
+                    _distributionNftId,
+                    _poolNftId,
+                    distributionSetupInfo.distributionFee, 
+                    _initialProductFee,
+                    _initialProcessingFee,
+                    poolSetupInfo.poolFee, 
+                    poolSetupInfo.stakingFee, 
+                    poolSetupInfo.performanceFee,
+                    false,
+                    _wallet
+                )
+            )
+        );
+    }
+}

package/contracts/experiment/cloning/Cloner.sol

@@ -0,0 +1,47 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Clones} from "@openzeppelin/contracts/proxy/Clones.sol";
+
+
+contract Cloner {
+
+    Mock1 public mock1;
+    Mock2 public mock2;
+
+    constructor() {
+        mock1 = new Mock1();
+        mock2 = new Mock2();
+    }
+
+    function createClone(address master)
+        external 
+        returns (address cloned)
+    {
+        cloned = Clones.clone(master);
+    }
+}
+
+
+contract Mock1 {
+    function getValue() external virtual view returns (uint256) {
+        return 42;
+    }
+}
+
+contract Mock2 is Mock1 {
+    uint256 internal _value;
+
+    constructor() {
+        _value = 42;
+    }
+
+    function setValue(uint256 value) external virtual {
+        _value = value;
+    }
+
+    function getValue() external virtual override view returns (uint256) {
+        return _value;
+    }
+}
+

package/contracts/instance/AccessManagerUpgradeableInitializeable.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagerUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagerUpgradeable.sol";
+
+
+contract AccessManagerUpgradeableInitializeable is AccessManagerUpgradeable {
+
+    bool private _initialized;
+
+    function __AccessManagerUpgradeableInitializeable_init(address initialAdmin) public {
+        require(!_initialized, "AccessManager: already initialized");
+        
+        if (initialAdmin == address(0)) {
+            revert AccessManagerInvalidInitialAdmin(address(0));
+        }
+
+        // admin is active immediately and without any execution delay.
+        _grantRole(ADMIN_ROLE, initialAdmin, 0, 0);
+        _initialized = true;
+    }
+
+}

package/contracts/instance/BundleManager.sol

@@ -0,0 +1,129 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IInstance} from "./IInstance.sol";
+import {INSTANCE} from "../types/ObjectType.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {LibNftIdSet} from "../types/NftIdSet.sol";
+import {NftId} from "../types/NftId.sol";
+import {TimestampLib} from "../types/Timestamp.sol";
+
+import {ObjectManager} from "./ObjectManager.sol";
+
+contract BundleManager is 
+    ObjectManager
+{
+
+    event LogBundleManagerPolicyLinked(NftId bundleNftId, NftId policyNftId);
+    event LogBundleManagerPolicyUnlinked(NftId bundleNftId, NftId policyNftId);
+
+    event LogBundleManagerBundleAdded(NftId poolNftId, NftId bundleNftId);
+    event LogBundleManagerBundleUnlocked(NftId poolNftId, NftId bundleNftId);
+    event LogBundleManagerBundleLocked(NftId poolNftId, NftId bundleNftId);
+
+    error ErrorBundleManagerErrorPolicyAlreadyActivated(NftId policyNftId);
+    error ErrorBundleManagerErrorBundleLocked(NftId bundleNftId, NftId policyNftId);
+    error ErrorBundleManagerPolicyWithOpenClaims(NftId policyNftId, uint256 openClaimsCount);
+    error ErrorBundleManagerPolicyNotCloseable(NftId policyNftId);
+    error ErrorBundleManagerBundleUnknown(NftId bundleNftId);
+    error ErrorBundleManagerBundleNotRegistered(NftId bundleNftId);
+
+    mapping(NftId bundleNftId => LibNftIdSet.Set policies) internal _activePolicies;
+
+    constructor() ObjectManager() {
+    }
+
+
+    /// @dev links a policy with its bundle
+    // to link a policy it MUST NOT yet have been activated
+    // the bundle MUST be unlocked (active) for linking (underwriting) and registered with this instance
+    function linkPolicy(NftId policyNftId) external restricted() {
+        NftId bundleNftId = _instanceReader.getPolicyInfo(policyNftId).bundleNftId;
+        // decision will likely depend on the decision what to check here and what in the service
+        NftId poolNftId = _instanceReader.getBundleInfo(bundleNftId).poolNftId;
+
+        // ensure bundle is unlocked (in active set) and registered with this instance
+        if (!_isActive(poolNftId, bundleNftId)) {
+            revert ErrorBundleManagerErrorBundleLocked(bundleNftId, policyNftId);
+        }
+
+        LibNftIdSet.add(_activePolicies[bundleNftId], policyNftId);
+        emit LogBundleManagerPolicyLinked(bundleNftId, policyNftId);
+    }
+
+
+    /// @dev unlinks a policy from its bundle
+    // to unlink a policy it must closable, ie. meet one of the following criterias
+    // - the policy MUST be past its expiry period and it MUST NOT have any open claims
+    // - the policy's payoutAmount MUST be equal to its sumInsuredAmount and MUST NOT have any open claims
+    function unlinkPolicy(NftId policyNftId) external restricted() {
+        IPolicy.PolicyInfo memory policyInfo = _instanceReader.getPolicyInfo(policyNftId);
+
+        NftId bundleNftId = policyInfo.bundleNftId;
+        // decision will likely depend on the decision what to check here and what in the service
+        NftId poolNftId = _instanceReader.getBundleInfo(bundleNftId).poolNftId;
+
+        // ensure bundle is registered with this instance
+        if (!_contains(poolNftId, bundleNftId)) {
+            revert ErrorBundleManagerBundleUnknown(bundleNftId);
+        }
+
+        LibNftIdSet.remove(_activePolicies[bundleNftId], policyNftId);
+        emit LogBundleManagerPolicyUnlinked(policyInfo.bundleNftId, policyNftId);
+    }
+
+
+    /// @dev add a new bundle to a riskpool registerd with this instance
+    // the corresponding pool is fetched via instance reader
+    function add(NftId bundleNftId) external restricted() {
+        NftId poolNftId = _instanceReader.getBundleInfo(bundleNftId).poolNftId;
+
+        // ensure pool is registered with instance
+        if(poolNftId.eqz()) {
+            revert ErrorBundleManagerBundleNotRegistered(bundleNftId);
+        }
+
+        _add(poolNftId, bundleNftId);
+        emit LogBundleManagerBundleAdded(poolNftId, bundleNftId);
+    }
+
+    /// @dev unlocked (active) bundles are available to underwrite new policies
+    function unlock(NftId bundleNftId) external restricted() {
+        NftId poolNftId = _instanceReader.getBundleInfo(bundleNftId).poolNftId;
+        _activate(poolNftId, bundleNftId);
+        emit LogBundleManagerBundleUnlocked(poolNftId, bundleNftId);
+    }
+
+    /// @dev locked (deactivated) bundles may not underwrite any new policies
+    function lock(NftId bundleNftId) external restricted() {
+        NftId poolNftId = _instanceReader.getBundleInfo(bundleNftId).poolNftId;
+        _deactivate(poolNftId, bundleNftId);
+        emit LogBundleManagerBundleLocked(poolNftId, bundleNftId);
+    }
+
+    function bundles(NftId poolNftId) external view returns(uint256) {
+        return _objects(poolNftId);
+    }
+
+    function getBundleNftId(NftId poolNftId, uint256 idx) external view returns(NftId bundleNftId) {
+        return _getObject(poolNftId, idx);
+    }
+
+    function activeBundles(NftId poolNftId) external view returns(uint256) {
+        return _activeObjs(poolNftId);
+    }
+
+    function getActiveBundleNftId(NftId poolNftId, uint256 idx) external view returns(NftId bundleNftId) {
+        return _getActiveObject(poolNftId, idx);
+    }
+
+    function activePolicies(NftId bundleNftId) external view returns(uint256) {
+        return LibNftIdSet.size(_activePolicies[bundleNftId]);
+    }
+
+    function getActivePolicy(NftId bundleNftId, uint256 idx) external view returns(NftId policyNftId) {
+        return LibNftIdSet.getElementAt(_activePolicies[bundleNftId], idx);
+    }
+}

package/contracts/instance/Cloneable.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+
+abstract contract Cloneable is 
+    AccessManagedUpgradeable
+{
+    event CloneableInitialized(address authority, address registry);
+
+    error CloneableRegistryInvalid(address registry);
+
+    IRegistry internal _registry;
+
+    constructor() {
+        _registry = IRegistry(address(0));
+    }
+
+    /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
+    function initialize(
+        address authority,
+        address registry
+    )
+        public 
+        initializer
+    {
+        // check/handle access managed
+        __AccessManaged_init(authority);
+
+        // check/handle registry
+        if (registry.code.length == 0) {
+            revert CloneableRegistryInvalid(registry);
+        }
+
+        _registry = IRegistry(registry);
+
+        emit CloneableInitialized(authority, registry);
+    }
+
+    function getRegistry() external view returns (IRegistry) {
+        return _registry;
+    }
+}

package/contracts/instance/IAccessManagerSimple.sol

@@ -3,7 +3,7 @@
 
 pragma solidity ^0.8.20;
 
-import {IAccessManaged} from "@openzeppelin5/contracts/access/manager/IAccessManaged.sol";
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
 
 interface IAccessManagerSimple {
     /**

package/contracts/instance/IInstance.sol

@@ -0,0 +1,56 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {BundleManager} from "./BundleManager.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+
+import {IComponentOwnerService} from "./service/IComponentOwnerService.sol";
+import {IDistributionService} from "./service/IDistributionService.sol";
+import {IPoolService} from "./service/IPoolService.sol";
+import {IProductService} from "./service/IProductService.sol";
+import {IBundle} from "./module/IBundle.sol";
+import {ISetup} from "./module/ISetup.sol";
+import {NftId} from "../types/NftId.sol";
+import {StateId} from "../types/StateId.sol";
+import {RiskId} from "../types/RiskId.sol";
+import {IRisk} from "./module/IRisk.sol";
+import {IPolicy} from "./module/IPolicy.sol";
+import {IKeyValueStore} from "./base/IKeyValueStore.sol";
+
+
+interface IInstance is IERC165, IKeyValueStore {
+
+    function getComponentOwnerService() external view returns (IComponentOwnerService);
+    function getDistributionService() external view returns (IDistributionService);
+    function getProductService() external view returns (IProductService);
+    function getPoolService() external view returns (IPoolService);
+
+    function createDistributionSetup(NftId distributionNftId, ISetup.DistributionSetupInfo memory setup) external;
+    function updateDistributionSetup(NftId distributionNftId, ISetup.DistributionSetupInfo memory setup, StateId newState) external;
+    function updateDistributionSetupState(NftId distributionNftId, StateId newState) external;
+
+    function createPoolSetup(NftId poolNftId, ISetup.PoolSetupInfo memory setup) external;
+    function updatePoolSetup(NftId poolNftId, ISetup.PoolSetupInfo memory setup, StateId newState) external;
+    function updatePoolSetupState(NftId poolNftId, StateId newState) external;
+
+    function createBundle(NftId bundleNftId, IBundle.BundleInfo memory bundle) external;
+    function updateBundle(NftId bundleNftId, IBundle.BundleInfo memory bundle, StateId newState) external;
+    function updateBundleState(NftId bundleNftId, StateId newState) external;
+
+    function createProductSetup(NftId productNftId, ISetup.ProductSetupInfo memory setup) external;
+    function updateProductSetup(NftId productNftId, ISetup.ProductSetupInfo memory setup, StateId newState) external;
+    function updateProductSetupState(NftId productNftId, StateId newState) external;
+
+    function createRisk(RiskId riskId, IRisk.RiskInfo memory risk) external;
+    function updateRisk(RiskId riskId, IRisk.RiskInfo memory risk, StateId newState) external;
+    function updateRiskState(RiskId riskId, StateId newState) external;
+
+    function createPolicy(NftId policyNftId, IPolicy.PolicyInfo memory policy) external;
+    function updatePolicy(NftId policyNftId, IPolicy.PolicyInfo memory policy, StateId newState) external;
+    function updatePolicyState(NftId policyNftId, StateId newState) external;
+
+    function getInstanceReader() external view returns (InstanceReader);
+    function getBundleManager() external view returns (BundleManager);
+}

package/contracts/instance/IInstanceBase.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {BundleManager} from "./BundleManager.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+
+import {IComponentOwnerService} from "./service/IComponentOwnerService.sol";
+import {IDistributionService} from "./service/IDistributionService.sol";
+import {IPoolService} from "./service/IPoolService.sol";
+import {IProductService} from "./service/IProductService.sol";
+import {IBundle} from "./module/IBundle.sol";
+import {ISetup} from "./module/ISetup.sol";
+import {NftId} from "../types/NftId.sol";
+import {StateId} from "../types/StateId.sol";
+import {RiskId} from "../types/RiskId.sol";
+import {IRisk} from "./module/IRisk.sol";
+import {IPolicy} from "./module/IPolicy.sol";
+import {IKeyValueStore} from "./base/IKeyValueStore.sol";
+
+
+interface IInstanceBase is IERC165, IKeyValueStore {
+
+
+}

package/contracts/instance/IInstanceService.sol

@@ -0,0 +1,34 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+import {RoleId} from "../types/RoleId.sol";
+import {IService} from "../shared/IService.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IBaseComponent} from "../components/IBaseComponent.sol";
+
+import {AccessManagerUpgradeableInitializeable} from "./AccessManagerUpgradeableInitializeable.sol";
+import {Instance} from "./Instance.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {BundleManager} from "./BundleManager.sol";
+
+interface IInstanceService is IService {
+
+    error ErrorInstanceServiceRequestUnauhorized(address caller);
+
+    event LogInstanceCloned(address clonedAccessManagerAddress, address clonedInstanceAddress, address clonedInstanceReaderAddress, NftId clonedInstanceNftId);
+
+    function createInstanceClone()
+        external 
+        returns (
+            AccessManagerUpgradeableInitializeable clonedAccessManager, 
+            Instance clonedInstance,
+            NftId instanceNftId,
+            InstanceReader clonedInstanceReader,
+            BundleManager clonedBundleManager
+        );
+}
+