@erc6900/reference-implementation 0.8.1 → 1.0.0

package/src/modules/ReplaySafeWrapper.sol

@@ -1,38 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-import {ModuleEIP712} from "./ModuleEIP712.sol";
-
-import {MessageHashUtils} from "@openzeppelin/contracts/utils/cryptography/MessageHashUtils.sol";
-
-// A contract mixin for modules that wish to use EIP-712 to wrap the hashes sent to the EIP-1271 function
-// `isValidSignature`.
-// This makes signatures generated by owners of contract accounts non-replayable across multiple accounts owned by
-// the same owner.
-abstract contract ReplaySafeWrapper is ModuleEIP712 {
-    // keccak256("ReplaySafeHash(bytes32 hash)")
-    bytes32 private constant _REPLAY_SAFE_HASH_TYPEHASH =
-        0x294a8735843d4afb4f017c76faf3b7731def145ed0025fc9b1d5ce30adf113ff;
-
-    /// @notice Wraps a hash in an EIP-712 envelope to prevent cross-account replay attacks.
-    /// Uses the ModuleEIP712 domain separator, which includes the chainId, module address, and account address.
-    /// @param account The account that will validate the message hash.
-    /// @param hash The hash to wrap.
-    /// @return The the replay-safe hash, computed by wrapping the input hash in an EIP-712 struct.
-    function replaySafeHash(address account, bytes32 hash) public view virtual returns (bytes32) {
-        return MessageHashUtils.toTypedDataHash({
-            domainSeparator: _domainSeparator(account),
-            structHash: _hashStruct(hash)
-        });
-    }
-
-    function _hashStruct(bytes32 hash) internal pure virtual returns (bytes32) {
-        bytes32 res;
-        assembly ("memory-safe") {
-            mstore(0x00, _REPLAY_SAFE_HASH_TYPEHASH)
-            mstore(0x20, hash)
-            res := keccak256(0x00, 0x40)
-        }
-        return res;
-    }
-}

package/src/modules/TokenReceiverModule.sol

@@ -1,87 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-import {IERC1155Receiver} from "@openzeppelin/contracts/interfaces/IERC1155Receiver.sol";
-import {IERC721Receiver} from "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
-
-import {ExecutionManifest, ManifestExecutionFunction} from "../interfaces/IERC6900ExecutionModule.sol";
-import {ExecutionManifest, IERC6900ExecutionModule} from "../interfaces/IERC6900ExecutionModule.sol";
-import {IERC6900Module} from "../interfaces/IERC6900Module.sol";
-import {BaseModule} from "./BaseModule.sol";
-
-/// @title Token Receiver Module
-/// @author ERC-6900 Authors
-/// @notice This module allows modular accounts to receive various types of tokens by implementing
-/// required token receiver interfaces.
-contract TokenReceiverModule is BaseModule, IERC6900ExecutionModule, IERC721Receiver, IERC1155Receiver {
-    // ┏━━━━━━━━━━━━━━━━━━━━━━━━━━━┓
-    // ┃    Execution functions    ┃
-    // ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
-
-    function onERC721Received(address, address, uint256, bytes calldata) external pure override returns (bytes4) {
-        return IERC721Receiver.onERC721Received.selector;
-    }
-
-    function onERC1155Received(address, address, uint256, uint256, bytes calldata)
-        external
-        pure
-        override
-        returns (bytes4)
-    {
-        return IERC1155Receiver.onERC1155Received.selector;
-    }
-
-    function onERC1155BatchReceived(address, address, uint256[] calldata, uint256[] calldata, bytes calldata)
-        external
-        pure
-        override
-        returns (bytes4)
-    {
-        return IERC1155Receiver.onERC1155BatchReceived.selector;
-    }
-
-    // ┏━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┓
-    // ┃    Module interface functions    ┃
-    // ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
-
-    /// @inheritdoc IERC6900Module
-    // solhint-disable-next-line no-empty-blocks
-    function onInstall(bytes calldata) external pure override {}
-
-    /// @inheritdoc IERC6900Module
-    // solhint-disable-next-line no-empty-blocks
-    function onUninstall(bytes calldata) external pure override {}
-
-    /// @inheritdoc IERC6900ExecutionModule
-    function executionManifest() external pure override returns (ExecutionManifest memory) {
-        ExecutionManifest memory manifest;
-
-        manifest.executionFunctions = new ManifestExecutionFunction[](3);
-        manifest.executionFunctions[0] = ManifestExecutionFunction({
-            executionSelector: this.onERC721Received.selector,
-            skipRuntimeValidation: true,
-            allowGlobalValidation: false
-        });
-        manifest.executionFunctions[1] = ManifestExecutionFunction({
-            executionSelector: this.onERC1155Received.selector,
-            skipRuntimeValidation: true,
-            allowGlobalValidation: false
-        });
-        manifest.executionFunctions[2] = ManifestExecutionFunction({
-            executionSelector: this.onERC1155BatchReceived.selector,
-            skipRuntimeValidation: true,
-            allowGlobalValidation: false
-        });
-
-        manifest.interfaceIds = new bytes4[](2);
-        manifest.interfaceIds[0] = type(IERC721Receiver).interfaceId;
-        manifest.interfaceIds[1] = type(IERC1155Receiver).interfaceId;
-
-        return manifest;
-    }
-
-    /// @inheritdoc IERC6900Module
-    function moduleId() external pure returns (string memory) {
-        return "erc6900.token-receiver-module.1.0.0";
-    }
-}

package/src/modules/permissions/AllowlistModule.sol

@@ -1,156 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-import {PackedUserOperation} from "@eth-infinitism/account-abstraction/interfaces/PackedUserOperation.sol";
-import {IERC165} from "@openzeppelin/contracts/interfaces/IERC165.sol";
-
-import {IERC6900Module} from "../../interfaces/IERC6900Module.sol";
-
-import {Call, IERC6900Account} from "../../interfaces/IERC6900Account.sol";
-import {IERC6900ValidationHookModule} from "../../interfaces/IERC6900ValidationHookModule.sol";
-import {BaseModule} from "../../modules/BaseModule.sol";
-
-contract AllowlistModule is IERC6900ValidationHookModule, BaseModule {
-    struct AllowlistInit {
-        address target;
-        bool hasSelectorAllowlist;
-        bytes4[] selectors;
-    }
-
-    struct AllowlistEntry {
-        bool allowed;
-        bool hasSelectorAllowlist;
-    }
-
-    mapping(uint32 entityId => mapping(address target => mapping(address account => AllowlistEntry))) public
-        targetAllowlist;
-    mapping(
-        uint32 entityId => mapping(address target => mapping(bytes4 selector => mapping(address account => bool)))
-    ) public selectorAllowlist;
-
-    event AllowlistTargetUpdated(
-        uint32 indexed entityId, address indexed account, address indexed target, AllowlistEntry entry
-    );
-    event AllowlistSelectorUpdated(
-        uint32 indexed entityId, address indexed account, bytes24 indexed targetAndSelector, bool allowed
-    );
-
-    error TargetNotAllowed();
-    error SelectorNotAllowed();
-    error NoSelectorSpecified();
-
-    function onInstall(bytes calldata data) external override {
-        (uint32 entityId, AllowlistInit[] memory init) = abi.decode(data, (uint32, AllowlistInit[]));
-
-        for (uint256 i = 0; i < init.length; i++) {
-            setAllowlistTarget(entityId, init[i].target, true, init[i].hasSelectorAllowlist);
-
-            if (init[i].hasSelectorAllowlist) {
-                for (uint256 j = 0; j < init[i].selectors.length; j++) {
-                    setAllowlistSelector(entityId, init[i].target, init[i].selectors[j], true);
-                }
-            }
-        }
-    }
-
-    function onUninstall(bytes calldata data) external override {
-        (uint32 entityId, AllowlistInit[] memory init) = abi.decode(data, (uint32, AllowlistInit[]));
-
-        for (uint256 i = 0; i < init.length; i++) {
-            setAllowlistTarget(entityId, init[i].target, false, false);
-
-            if (init[i].hasSelectorAllowlist) {
-                for (uint256 j = 0; j < init[i].selectors.length; j++) {
-                    setAllowlistSelector(entityId, init[i].target, init[i].selectors[j], false);
-                }
-            }
-        }
-    }
-
-    function preUserOpValidationHook(uint32 entityId, PackedUserOperation calldata userOp, bytes32)
-        external
-        view
-        override
-        returns (uint256)
-    {
-        checkAllowlistCalldata(entityId, userOp.callData);
-        return 0;
-    }
-
-    function preRuntimeValidationHook(uint32 entityId, address, uint256, bytes calldata data, bytes calldata)
-        external
-        view
-        override
-    {
-        checkAllowlistCalldata(entityId, data);
-        return;
-    }
-
-    // solhint-disable-next-line no-empty-blocks
-    function preSignatureValidationHook(uint32, address, bytes32, bytes calldata) external pure override {}
-
-    /// @inheritdoc IERC6900Module
-    function moduleId() external pure returns (string memory) {
-        return "erc6900.allowlist-module.0.0.1";
-    }
-
-    function setAllowlistTarget(uint32 entityId, address target, bool allowed, bool hasSelectorAllowlist) public {
-        AllowlistEntry memory entry = AllowlistEntry(allowed, hasSelectorAllowlist);
-        targetAllowlist[entityId][target][msg.sender] = entry;
-        emit AllowlistTargetUpdated(entityId, msg.sender, target, entry);
-    }
-
-    function setAllowlistSelector(uint32 entityId, address target, bytes4 selector, bool allowed) public {
-        selectorAllowlist[entityId][target][selector][msg.sender] = allowed;
-        bytes24 targetAndSelector = bytes24(bytes24(bytes20(target)) | (bytes24(selector) >> 160));
-        emit AllowlistSelectorUpdated(entityId, msg.sender, targetAndSelector, allowed);
-    }
-
-    function checkAllowlistCalldata(uint32 entityId, bytes calldata callData) public view {
-        if (bytes4(callData[:4]) == IERC6900Account.execute.selector) {
-            (address target,, bytes memory data) = abi.decode(callData[4:], (address, uint256, bytes));
-            _checkCallPermission(entityId, msg.sender, target, data);
-        } else if (bytes4(callData[:4]) == IERC6900Account.executeBatch.selector) {
-            Call[] memory calls = abi.decode(callData[4:], (Call[]));
-
-            for (uint256 i = 0; i < calls.length; i++) {
-                _checkCallPermission(entityId, msg.sender, calls[i].target, calls[i].data);
-            }
-        }
-    }
-
-    function supportsInterface(bytes4 interfaceId)
-        public
-        view
-        virtual
-        override(BaseModule, IERC165)
-        returns (bool)
-    {
-        return
-            interfaceId == type(IERC6900ValidationHookModule).interfaceId || super.supportsInterface(interfaceId);
-    }
-
-    function _checkCallPermission(uint32 entityId, address account, address target, bytes memory data)
-        internal
-        view
-    {
-        AllowlistEntry storage entry = targetAllowlist[entityId][target][account];
-        (bool allowed, bool hasSelectorAllowlist) = (entry.allowed, entry.hasSelectorAllowlist);
-
-        if (!allowed) {
-            revert TargetNotAllowed();
-        }
-
-        if (hasSelectorAllowlist) {
-            if (data.length < 4) {
-                revert NoSelectorSpecified();
-            }
-
-            bytes4 selector = bytes4(data);
-
-            if (!selectorAllowlist[entityId][target][selector][account]) {
-                revert SelectorNotAllowed();
-            }
-        }
-    }
-}

package/src/modules/permissions/ERC20TokenLimitModule.sol

@@ -1,145 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-import {UserOperationLib} from "@eth-infinitism/account-abstraction/core/UserOperationLib.sol";
-import {PackedUserOperation} from "@eth-infinitism/account-abstraction/interfaces/PackedUserOperation.sol";
-import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
-
-import {Call, IERC6900Account} from "../../interfaces/IERC6900Account.sol";
-
-import {IERC6900ExecutionHookModule} from "../../interfaces/IERC6900ExecutionHookModule.sol";
-import {IERC6900Module} from "../../interfaces/IERC6900Module.sol";
-
-import {BaseModule, IERC165} from "../BaseModule.sol";
-
-/// @title ERC20 Token Limit Module
-/// @author ERC-6900 Authors
-/// @notice This module supports an ERC20 token spend limit. This should be combined with a contract whitelist
-/// module to make sure that token transfers not tracked by the module don't happen.
-/// Note: this module is opinionated on what selectors can be called for token contracts to guard against weird
-/// edge cases like DAI. You wouldn't be able to use uni v2 pairs directly as the pair contract is also the LP
-/// token contract
-contract ERC20TokenLimitModule is BaseModule, IERC6900ExecutionHookModule {
-    using UserOperationLib for PackedUserOperation;
-
-    struct ERC20SpendLimit {
-        address token;
-        uint256 limit;
-    }
-
-    struct SpendLimit {
-        bool hasLimit;
-        uint256 limit;
-    }
-
-    mapping(uint32 entityId => mapping(address token => mapping(address account => SpendLimit))) public limits;
-
-    error ERC20NotAllowed(address);
-    error ExceededTokenLimit();
-    error InvalidCalldataLength();
-    error SelectorNotAllowed();
-    error SpendingRequestNotAllowed(bytes4);
-
-    /// @inheritdoc IERC6900ExecutionHookModule
-    function preExecutionHook(uint32 entityId, address, uint256, bytes calldata data)
-        external
-        override
-        returns (bytes memory)
-    {
-        (bytes4 selector, bytes memory callData) = _getSelectorAndCalldata(data);
-
-        if (selector == IERC6900Account.execute.selector) {
-            // when calling execute or ERC20 functions directly
-            (address token,, bytes memory innerCalldata) = abi.decode(callData, (address, uint256, bytes));
-            _decrementLimitIfApplies(entityId, token, innerCalldata);
-        } else if (selector == IERC6900Account.executeBatch.selector) {
-            Call[] memory calls = abi.decode(callData, (Call[]));
-            for (uint256 i = 0; i < calls.length; i++) {
-                _decrementLimitIfApplies(entityId, calls[i].target, calls[i].data);
-            }
-        } else {
-            revert SpendingRequestNotAllowed(selector);
-        }
-        return "";
-    }
-
-    /// @inheritdoc IERC6900Module
-    /// @param data should be encoded with the entityId of the validation and a list of ERC20 spend limits
-    function onInstall(bytes calldata data) external override {
-        (uint32 entityId, ERC20SpendLimit[] memory spendLimits) = abi.decode(data, (uint32, ERC20SpendLimit[]));
-
-        for (uint8 i = 0; i < spendLimits.length; i++) {
-            address token = spendLimits[i].token;
-            updateLimits(entityId, token, true, spendLimits[i].limit);
-        }
-    }
-
-    /// @inheritdoc IERC6900Module
-    /// @notice uninstall this module can only clear limit for one token of one entity. To clear all limits, users
-    /// are recommended to use updateLimit for each token and entityId.
-    /// @param data should be encoded with the entityId of the validation and the token address to be uninstalled
-    function onUninstall(bytes calldata data) external override {
-        (address token, uint32 entityId) = abi.decode(data, (address, uint32));
-        delete limits[entityId][token][msg.sender];
-    }
-
-    /// @inheritdoc IERC6900ExecutionHookModule
-    function postExecutionHook(uint32, bytes calldata) external pure override {
-        revert NotImplemented();
-    }
-
-    /// @inheritdoc IERC6900Module
-    function moduleId() external pure returns (string memory) {
-        return "erc6900.erc20-token-limit-module.1.0.0";
-    }
-
-    /// @notice Update the token limit of a validation
-    /// @param entityId The validation entityId to update
-    /// @param token The token address whose limit will be updated
-    /// @param newLimit The new limit of the token for the validation
-    function updateLimits(uint32 entityId, address token, bool hasLimit, uint256 newLimit) public {
-        if (token == address(0)) {
-            revert ERC20NotAllowed(address(0));
-        }
-        limits[entityId][token][msg.sender] = SpendLimit({hasLimit: hasLimit, limit: newLimit});
-    }
-
-    /// @inheritdoc BaseModule
-    function supportsInterface(bytes4 interfaceId) public view override(BaseModule, IERC165) returns (bool) {
-        return interfaceId == type(IERC6900ExecutionHookModule).interfaceId || super.supportsInterface(interfaceId);
-    }
-
-    function _decrementLimitIfApplies(uint32 entityId, address token, bytes memory innerCalldata) internal {
-        SpendLimit storage spendLimit = limits[entityId][token][msg.sender];
-
-        if (!spendLimit.hasLimit) {
-            return;
-        }
-
-        if (innerCalldata.length < 68) {
-            revert InvalidCalldataLength();
-        }
-
-        bytes4 selector;
-        uint256 spend;
-        assembly ("memory-safe") {
-            selector := mload(add(innerCalldata, 32)) // 0:32 is arr len, 32:36 is selector
-            spend := mload(add(innerCalldata, 68)) // 36:68 is recipient, 68:100 is spend
-        }
-        if (_isAllowedERC20Function(selector)) {
-            uint256 limit = spendLimit.limit;
-            if (spend > limit) {
-                revert ExceededTokenLimit();
-            }
-            unchecked {
-                spendLimit.limit = limit - spend;
-            }
-        } else {
-            revert SelectorNotAllowed();
-        }
-    }
-
-    function _isAllowedERC20Function(bytes4 selector) internal pure returns (bool) {
-        return selector == IERC20.transfer.selector || selector == IERC20.approve.selector;
-    }
-}

package/src/modules/permissions/NativeTokenLimitModule.sol

@@ -1,154 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-import {UserOperationLib} from "@eth-infinitism/account-abstraction/core/UserOperationLib.sol";
-import {PackedUserOperation} from "@eth-infinitism/account-abstraction/interfaces/PackedUserOperation.sol";
-import {EnumerableSet} from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
-
-import {Call, IERC6900Account} from "../../interfaces/IERC6900Account.sol";
-
-import {IERC6900ExecutionHookModule} from "../../interfaces/IERC6900ExecutionHookModule.sol";
-import {IERC6900Module} from "../../interfaces/IERC6900Module.sol";
-import {IERC6900ValidationHookModule} from "../../interfaces/IERC6900ValidationHookModule.sol";
-import {BaseModule, IERC165} from "../BaseModule.sol";
-
-/// @title Native Token Limit Module
-/// @author ERC-6900 Authors
-/// @notice This module supports a single total native token spend limit.
-/// It tracks a total spend limit across UserOperation gas limits and native token transfers.
-/// If a non whitelisted paymaster is used, UO gas would not cause the limit to decrease.
-/// If a whitelisted paymaster is used, gas is still counted towards the limit
-contract NativeTokenLimitModule is BaseModule, IERC6900ExecutionHookModule, IERC6900ValidationHookModule {
-    using UserOperationLib for PackedUserOperation;
-    using EnumerableSet for EnumerableSet.Bytes32Set;
-
-    mapping(uint256 funcIds => mapping(address account => uint256 limit)) public limits;
-    // Accounts should add paymasters that still use the accounts tokens here
-    // E.g. ERC20 paymasters that pull funds from the account
-    mapping(address paymaster => mapping(address account => bool allowed)) public specialPaymasters;
-
-    error ExceededNativeTokenLimit();
-    error ExceededNumberOfEntities();
-
-    function updateLimits(uint32 entityId, uint256 newLimit) external {
-        limits[entityId][msg.sender] = newLimit;
-    }
-
-    function updateSpecialPaymaster(address paymaster, bool allowed) external {
-        specialPaymasters[paymaster][msg.sender] = allowed;
-    }
-
-    /// @inheritdoc IERC6900ValidationHookModule
-    function preUserOpValidationHook(uint32 entityId, PackedUserOperation calldata userOp, bytes32)
-        external
-        returns (uint256)
-    {
-        // Decrease limit only if no paymaster is used, or if its a special paymaster
-        if (
-            userOp.paymasterAndData.length == 0
-                || specialPaymasters[address(bytes20(userOp.paymasterAndData[:20]))][msg.sender]
-        ) {
-            uint256 vgl = UserOperationLib.unpackVerificationGasLimit(userOp);
-            uint256 cgl = UserOperationLib.unpackCallGasLimit(userOp);
-            uint256 pvgl;
-            uint256 ppogl;
-            if (userOp.paymasterAndData.length > 0) {
-                // Can skip the EP length check here since it would have reverted there if it was invalid
-                (, pvgl, ppogl) = UserOperationLib.unpackPaymasterStaticFields(userOp.paymasterAndData);
-            }
-            uint256 totalGas = userOp.preVerificationGas + vgl + cgl + pvgl + ppogl;
-            uint256 usage = totalGas * UserOperationLib.unpackMaxFeePerGas(userOp);
-
-            uint256 limit = limits[entityId][msg.sender];
-            if (usage > limit) {
-                revert ExceededNativeTokenLimit();
-            }
-            limits[entityId][msg.sender] = limit - usage;
-        }
-        return 0;
-    }
-
-    /// @inheritdoc IERC6900ExecutionHookModule
-    function preExecutionHook(uint32 entityId, address, uint256, bytes calldata data)
-        external
-        override
-        returns (bytes memory)
-    {
-        return _checkAndDecrementLimit(entityId, data);
-    }
-
-    /// @inheritdoc IERC6900Module
-    function onInstall(bytes calldata data) external override {
-        (uint32 startEntityId, uint256[] memory spendLimits) = abi.decode(data, (uint32, uint256[]));
-
-        if (startEntityId + spendLimits.length > type(uint32).max) {
-            revert ExceededNumberOfEntities();
-        }
-
-        for (uint256 i = 0; i < spendLimits.length; i++) {
-            limits[i + startEntityId][msg.sender] = spendLimits[i];
-        }
-    }
-
-    /// @inheritdoc IERC6900Module
-    function onUninstall(bytes calldata data) external override {
-        // This is the highest entityId that's being used by the account
-        uint32 entityId = abi.decode(data, (uint32));
-        for (uint256 i = 0; i < entityId; i++) {
-            delete limits[i][msg.sender];
-        }
-    }
-
-    /// @inheritdoc IERC6900ExecutionHookModule
-    function postExecutionHook(uint32, bytes calldata) external pure override {
-        revert NotImplemented();
-    }
-
-    // No implementation, no revert
-    // Runtime spends no account gas, and we check native token spend limits in exec hooks
-    function preRuntimeValidationHook(uint32, address, uint256, bytes calldata, bytes calldata)
-        external
-        pure
-        override
-    {} // solhint-disable-line no-empty-blocks
-
-    // solhint-disable-next-line no-empty-blocks
-    function preSignatureValidationHook(uint32, address, bytes32, bytes calldata) external pure override {}
-
-    /// @inheritdoc IERC6900Module
-    function moduleId() external pure returns (string memory) {
-        return "erc6900.native-token-limit-module.1.0.0";
-    }
-
-    // ┏━━━━━━━━━━━━━━━┓
-    // ┃    EIP-165    ┃
-    // ┗━━━━━━━━━━━━━━━┛
-
-    /// @inheritdoc BaseModule
-    function supportsInterface(bytes4 interfaceId) public view override(BaseModule, IERC165) returns (bool) {
-        return interfaceId == type(IERC6900ExecutionHookModule).interfaceId || super.supportsInterface(interfaceId);
-    }
-
-    function _checkAndDecrementLimit(uint32 entityId, bytes calldata data) internal returns (bytes memory) {
-        (bytes4 selector, bytes memory callData) = _getSelectorAndCalldata(data);
-
-        uint256 value;
-        // Get value being sent
-        if (selector == IERC6900Account.execute.selector) {
-            (, value) = abi.decode(callData, (address, uint256));
-        } else if (selector == IERC6900Account.executeBatch.selector) {
-            Call[] memory calls = abi.decode(callData, (Call[]));
-            for (uint256 i = 0; i < calls.length; i++) {
-                value += calls[i].value;
-            }
-        }
-
-        uint256 limit = limits[entityId][msg.sender];
-        if (value > limit) {
-            revert ExceededNativeTokenLimit();
-        }
-        limits[entityId][msg.sender] = limit - value;
-
-        return "";
-    }
-}

package/src/modules/validation/ISingleSignerValidationModule.sol

@@ -1,22 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-import {IERC6900ValidationModule} from "../../interfaces/IERC6900ValidationModule.sol";
-
-interface ISingleSignerValidationModule is IERC6900ValidationModule {
-    /// @notice This event is emitted when Signer of the account's validation changes.
-    /// @param account The account whose validation Signer changed.
-    /// @param entityId The entityId for the account and the signer.
-    /// @param newSigner The address of the new signer.
-    /// @param previousSigner The address of the previous signer.
-    event SignerTransferred(
-        address indexed account, uint32 indexed entityId, address indexed newSigner, address previousSigner
-    ) anonymous;
-
-    error NotAuthorized();
-
-    /// @notice Transfer Signer of the account's validation to `newSigner`.
-    /// @param entityId The entityId for the account and the signer.
-    /// @param newSigner The address of the new signer.
-    function transferSigner(uint32 entityId, address newSigner) external;
-}