@erc6900/reference-implementation 0.8.1 → 1.0.0

package/src/account/SemiModularAccount.sol

@@ -1,214 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-import {ReferenceModularAccount} from "./ReferenceModularAccount.sol";
-import {IEntryPoint} from "@eth-infinitism/account-abstraction/interfaces/IEntryPoint.sol";
-import {PackedUserOperation} from "@eth-infinitism/account-abstraction/interfaces/PackedUserOperation.sol";
-
-import {ModuleEntityLib} from "../libraries/ModuleEntityLib.sol";
-
-import {IERC6900Account, ModuleEntity, ValidationConfig} from "../interfaces/IERC6900Account.sol";
-
-import {MessageHashUtils} from "@openzeppelin/contracts/utils/cryptography/MessageHashUtils.sol";
-import {SignatureChecker} from "@openzeppelin/contracts/utils/cryptography/SignatureChecker.sol";
-import {LibClone} from "solady/utils/LibClone.sol";
-
-contract SemiModularAccount is ReferenceModularAccount {
-    using MessageHashUtils for bytes32;
-    using ModuleEntityLib for ModuleEntity;
-
-    struct SemiModularAccountStorage {
-        address fallbackSigner;
-        bool fallbackSignerDisabled;
-    }
-
-    // keccak256("ERC6900.SemiModularAccount.Storage")
-    uint256 internal constant _SEMI_MODULAR_ACCOUNT_STORAGE_SLOT =
-        0x5b9dc9aa943f8fa2653ceceda5e3798f0686455280432166ba472eca0bc17a32;
-
-    // keccak256("EIP712Domain(uint256 chainId,address verifyingContract)")
-    bytes32 private constant _DOMAIN_SEPARATOR_TYPEHASH =
-        0x47e79534a245952e8b16893a336b85a3d9ea9fa8c573f3d803afb92a79469218;
-
-    // keccak256("ReplaySafeHash(bytes32 hash)")
-    bytes32 private constant _REPLAY_SAFE_HASH_TYPEHASH =
-        0x294a8735843d4afb4f017c76faf3b7731def145ed0025fc9b1d5ce30adf113ff;
-
-    ModuleEntity internal constant _FALLBACK_VALIDATION = ModuleEntity.wrap(bytes24(type(uint192).max));
-
-    uint256 internal constant _SIG_VALIDATION_PASSED = 0;
-    uint256 internal constant _SIG_VALIDATION_FAILED = 1;
-
-    event FallbackSignerSet(address indexed previousFallbackSigner, address indexed newFallbackSigner);
-    event FallbackSignerDisabledSet(bool prevDisabled, bool newDisabled);
-
-    error FallbackSignerMismatch();
-    error FallbackSignerDisabled();
-    error InitializerDisabled();
-
-    constructor(IEntryPoint anEntryPoint) ReferenceModularAccount(anEntryPoint) {}
-
-    /// @notice Updates the fallback signer address in storage.
-    /// @dev This function causes the fallback signer getter to ignore the bytecode signer if it is nonzero. It can
-    /// also be used to revert back to the bytecode signer by setting to zero.
-    /// @param fallbackSigner The new signer to set.
-    function updateFallbackSigner(address fallbackSigner) external wrapNativeFunction {
-        SemiModularAccountStorage storage _storage = _getSemiModularAccountStorage();
-        emit FallbackSignerSet(_storage.fallbackSigner, fallbackSigner);
-
-        _storage.fallbackSigner = fallbackSigner;
-    }
-
-    /// @notice Sets whether the fallback signer validation should be enabled or disabled.
-    /// @dev Due to being initially zero, we need to store "disabled" rather than "enabled" in storage.
-    /// @param isDisabled True to disable fallback signer validation, false to enable it.
-    function setFallbackSignerDisabled(bool isDisabled) external wrapNativeFunction {
-        SemiModularAccountStorage storage _storage = _getSemiModularAccountStorage();
-        emit FallbackSignerDisabledSet(_storage.fallbackSignerDisabled, isDisabled);
-
-        _storage.fallbackSignerDisabled = isDisabled;
-    }
-
-    /// @notice Returns whether the fallback signer validation is disabled.
-    /// @return True if the fallback signer validation is disabled, false if it is enabled.
-    function isFallbackSignerDisabled() external view returns (bool) {
-        return _getSemiModularAccountStorage().fallbackSignerDisabled;
-    }
-
-    /// @notice Returns the fallback signer associated with this account, regardless if the fallback signer
-    /// validation is enabled or not.
-    /// @return The fallback signer address, either overriden in storage, or read from bytecode.
-    function getFallbackSigner() external view returns (address) {
-        return _retrieveFallbackSignerUnchecked(_getSemiModularAccountStorage());
-    }
-
-    /// Override reverts on initialization, effectively disabling the initializer.
-    function initializeWithValidation(ValidationConfig, bytes4[] calldata, bytes calldata, bytes[] calldata)
-        external
-        pure
-        override
-    {
-        revert InitializerDisabled();
-    }
-
-    /// @inheritdoc IERC6900Account
-    function accountId() external pure virtual override returns (string memory) {
-        return "erc6900.reference-semi-modular-account.0.8.0";
-    }
-
-    function replaySafeHash(bytes32 hash) public view virtual returns (bytes32) {
-        return
-            MessageHashUtils.toTypedDataHash({domainSeparator: _domainSeparator(), structHash: _hashStruct(hash)});
-    }
-
-    function _execUserOpValidation(
-        ModuleEntity userOpValidationFunction,
-        PackedUserOperation memory userOp,
-        bytes32 userOpHash
-    ) internal override returns (uint256) {
-        if (userOpValidationFunction.eq(_FALLBACK_VALIDATION)) {
-            address fallbackSigner = _getFallbackSigner();
-
-            if (
-                SignatureChecker.isValidSignatureNow(
-                    fallbackSigner, userOpHash.toEthSignedMessageHash(), userOp.signature
-                )
-            ) {
-                return _SIG_VALIDATION_PASSED;
-            }
-            return _SIG_VALIDATION_FAILED;
-        }
-
-        return super._execUserOpValidation(userOpValidationFunction, userOp, userOpHash);
-    }
-
-    function _execRuntimeValidation(
-        ModuleEntity runtimeValidationFunction,
-        bytes calldata callData,
-        bytes calldata authorization
-    ) internal override {
-        if (runtimeValidationFunction.eq(_FALLBACK_VALIDATION)) {
-            address fallbackSigner = _getFallbackSigner();
-
-            if (msg.sender != fallbackSigner) {
-                revert FallbackSignerMismatch();
-            }
-        } else {
-            super._execRuntimeValidation(runtimeValidationFunction, callData, authorization);
-        }
-    }
-
-    function _exec1271Validation(ModuleEntity sigValidation, bytes32 hash, bytes calldata signature)
-        internal
-        view
-        override
-        returns (bytes4)
-    {
-        if (sigValidation.eq(_FALLBACK_VALIDATION)) {
-            address fallbackSigner = _getFallbackSigner();
-
-            if (SignatureChecker.isValidSignatureNow(fallbackSigner, replaySafeHash(hash), signature)) {
-                return _1271_MAGIC_VALUE;
-            }
-            return _1271_INVALID;
-        }
-        return super._exec1271Validation(sigValidation, hash, signature);
-    }
-
-    function _globalValidationAllowed(bytes4 selector) internal view override returns (bool) {
-        return selector == this.setFallbackSignerDisabled.selector
-            || selector == this.updateFallbackSigner.selector || super._globalValidationAllowed(selector);
-    }
-
-    function _isValidationGlobal(ModuleEntity validationFunction) internal view override returns (bool) {
-        return validationFunction.eq(_FALLBACK_VALIDATION) || super._isValidationGlobal(validationFunction);
-    }
-
-    function _getFallbackSigner() internal view returns (address) {
-        SemiModularAccountStorage storage _storage = _getSemiModularAccountStorage();
-
-        if (_storage.fallbackSignerDisabled) {
-            revert FallbackSignerDisabled();
-        }
-
-        return _retrieveFallbackSignerUnchecked(_storage);
-    }
-
-    function _retrieveFallbackSignerUnchecked(SemiModularAccountStorage storage _storage)
-        internal
-        view
-        virtual
-        returns (address)
-    {
-        address storageFallbackSigner = _storage.fallbackSigner;
-        if (storageFallbackSigner != address(0)) {
-            return storageFallbackSigner;
-        }
-
-        bytes memory appendedData = LibClone.argsOnERC1967(address(this), 0, 20);
-
-        return address(uint160(bytes20(appendedData)));
-    }
-
-    function _domainSeparator() internal view returns (bytes32) {
-        return keccak256(abi.encode(_DOMAIN_SEPARATOR_TYPEHASH, block.chainid, address(this)));
-    }
-
-    function _getSemiModularAccountStorage() internal pure returns (SemiModularAccountStorage storage) {
-        SemiModularAccountStorage storage _storage;
-        assembly ("memory-safe") {
-            _storage.slot := _SEMI_MODULAR_ACCOUNT_STORAGE_SLOT
-        }
-        return _storage;
-    }
-
-    function _hashStruct(bytes32 hash) internal pure virtual returns (bytes32) {
-        bytes32 res;
-        assembly ("memory-safe") {
-            mstore(0x00, _REPLAY_SAFE_HASH_TYPEHASH)
-            mstore(0x20, hash)
-            res := keccak256(0, 0x40)
-        }
-        return res;
-    }
-}

package/src/account/SemiModularAccount7702.sol

@@ -1,38 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-import {IERC6900Account} from "../interfaces/IERC6900Account.sol";
-import {SemiModularAccount} from "./SemiModularAccount.sol";
-import {IEntryPoint} from "@eth-infinitism/account-abstraction/interfaces/IEntryPoint.sol";
-
-contract SemiModularAccount7702 is SemiModularAccount {
-    error UpgradeNotAllowed();
-
-    constructor(IEntryPoint anEntryPoint) SemiModularAccount(anEntryPoint) {}
-
-    /// @inheritdoc IERC6900Account
-    function accountId() external pure virtual override returns (string memory) {
-        return "erc6900.reference-semi-modular-account-7702.0.8.0";
-    }
-
-    /// @dev To prevent accidental self-calls, upgrades are disabled in 7702 accounts.
-    function upgradeToAndCall(address, bytes memory) public payable override {
-        revert UpgradeNotAllowed();
-    }
-
-    /// @dev If the fallback signer is set in storage, ignore the 7702 signer.
-    function _retrieveFallbackSignerUnchecked(SemiModularAccountStorage storage _storage)
-        internal
-        view
-        override
-        returns (address)
-    {
-        address storageFallbackSigner = _storage.fallbackSigner;
-        if (storageFallbackSigner != address(0)) {
-            return storageFallbackSigner;
-        }
-
-        // To support 7702, we default to address(this) as the fallback signer.
-        return address(this);
-    }
-}

package/src/helpers/CollectReturnData.sol

@@ -1,14 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-function collectReturnData() pure returns (bytes memory returnData) {
-    assembly ("memory-safe") {
-        // Allocate a buffer of that size, advancing the memory pointer to the nearest word
-        returnData := mload(0x40)
-        mstore(returnData, returndatasize())
-        mstore(0x40, and(add(add(returnData, returndatasize()), 0x3f), not(0x1f)))
-
-        // Copy over the return data
-        returndatacopy(add(returnData, 0x20), 0, returndatasize())
-    }
-}

package/src/helpers/Constants.sol

@@ -1,11 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-// Index marking the start of the data for the validation function.
-uint8 constant RESERVED_VALIDATION_DATA_INDEX = type(uint8).max;
-
-// Maximum number of validation-associated hooks that can be registered.
-uint8 constant MAX_VALIDATION_ASSOC_HOOKS = type(uint8).max;
-
-// Magic value for the Entity ID of direct call validation.
-uint32 constant DIRECT_CALL_VALIDATION_ENTITY_ID = type(uint32).max;

package/src/helpers/EmptyCalldataSlice.sol

@@ -1,12 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-function getEmptyCalldataSlice() pure returns (bytes calldata) {
-    bytes calldata empty;
-
-    assembly ("memory-safe") {
-        empty.length := 0
-    }
-
-    return empty;
-}

package/src/helpers/ValidationResHelpers.sol

@@ -1,50 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.20;
-
-// solhint-disable-next-line private-vars-leading-underscore
-function _coalescePreValidation(uint256 validationRes1, uint256 validationRes2)
-    pure
-    returns (uint256 resValidationData)
-{
-    uint48 validUntil1 = uint48(validationRes1 >> 160);
-    if (validUntil1 == 0) {
-        validUntil1 = type(uint48).max;
-    }
-    uint48 validUntil2 = uint48(validationRes2 >> 160);
-    if (validUntil2 == 0) {
-        validUntil2 = type(uint48).max;
-    }
-    resValidationData = ((validUntil1 > validUntil2) ? uint256(validUntil2) << 160 : uint256(validUntil1) << 160);
-
-    uint48 validAfter1 = uint48(validationRes1 >> 208);
-    uint48 validAfter2 = uint48(validationRes2 >> 208);
-
-    resValidationData |= ((validAfter1 < validAfter2) ? uint256(validAfter2) << 208 : uint256(validAfter1) << 208);
-
-    // Once we know that the authorizer field is 0 or 1, we can safely bubble up SIG_FAIL with bitwise OR
-    resValidationData |= uint160(validationRes1) | uint160(validationRes2);
-}
-
-// solhint-disable-next-line private-vars-leading-underscore
-function _coalesceValidation(uint256 preValidationData, uint256 validationRes)
-    pure
-    returns (uint256 resValidationData)
-{
-    uint48 validUntil1 = uint48(preValidationData >> 160);
-    if (validUntil1 == 0) {
-        validUntil1 = type(uint48).max;
-    }
-    uint48 validUntil2 = uint48(validationRes >> 160);
-    if (validUntil2 == 0) {
-        validUntil2 = type(uint48).max;
-    }
-    resValidationData = ((validUntil1 > validUntil2) ? uint256(validUntil2) << 160 : uint256(validUntil1) << 160);
-
-    uint48 validAfter1 = uint48(preValidationData >> 208);
-    uint48 validAfter2 = uint48(validationRes >> 208);
-
-    resValidationData |= ((validAfter1 < validAfter2) ? uint256(validAfter2) << 208 : uint256(validAfter1) << 208);
-
-    // If prevalidation failed, bubble up failure
-    resValidationData |= uint160(preValidationData) == 1 ? 1 : uint160(validationRes);
-}

package/src/interfaces/IERC6900Account.sol

@@ -1,127 +0,0 @@
-// SPDX-License-Identifier: CC0-1.0
-pragma solidity ^0.8.20;
-
-import {ExecutionManifest} from "./IERC6900ExecutionModule.sol";
-
-type ModuleEntity is bytes24;
-// ModuleEntity is a packed representation of a module function
-// Layout:
-// 0xAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA________________________ // Address
-// 0x________________________________________BBBBBBBB________________ // Entity ID
-// 0x________________________________________________0000000000000000 // unused
-
-type ValidationConfig is bytes25;
-// ValidationConfig is a packed representation of a validation function and flags for its configuration.
-// Layout:
-// 0xAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA________________________ // Address
-// 0x________________________________________BBBBBBBB________________ // Entity ID
-// 0x________________________________________________CC______________ // ValidationFlags
-// 0x__________________________________________________00000000000000 // unused
-
-type ValidationFlags is uint8;
-// ValidationFlags layout:
-// 0b00000___ // unused
-// 0b_____A__ // isGlobal
-// 0b______B_ // isSignatureValidation
-// 0b_______C // isUserOpValidation
-
-type HookConfig is bytes25;
-// HookConfig is a packed representation of a hook function and flags for its configuration.
-// Layout:
-// 0xAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA________________________ // Address
-// 0x________________________________________BBBBBBBB________________ // Entity ID
-// 0x________________________________________________CC______________ // Hook Flags
-//
-// Hook flags layout:
-// 0b00000___ // unused
-// 0b_____A__ // hasPre (exec only)
-// 0b______B_ // hasPost (exec only)
-// 0b_______C // hook type (0 for exec, 1 for validation)
-
-struct Call {
-    // The target address for the account to call.
-    address target;
-    // The value to send with the call.
-    uint256 value;
-    // The calldata for the call.
-    bytes data;
-}
-
-interface IERC6900Account {
-    event ExecutionInstalled(address indexed module, ExecutionManifest manifest);
-    event ExecutionUninstalled(address indexed module, bool onUninstallSucceeded, ExecutionManifest manifest);
-    event ValidationInstalled(address indexed module, uint32 indexed entityId);
-    event ValidationUninstalled(address indexed module, uint32 indexed entityId, bool onUninstallSucceeded);
-
-    /// @notice Standard execute method.
-    /// @param target The target address for the account to call.
-    /// @param value The value to send with the call.
-    /// @param data The calldata for the call.
-    /// @return The return data from the call.
-    function execute(address target, uint256 value, bytes calldata data) external payable returns (bytes memory);
-
-    /// @notice Standard executeBatch method.
-    /// @dev If the target is a module, the call SHOULD revert. If any of the calls revert, the entire batch MUST
-    /// revert.
-    /// @param calls The array of calls.
-    /// @return An array containing the return data from the calls.
-    function executeBatch(Call[] calldata calls) external payable returns (bytes[] memory);
-
-    /// @notice Execute a call using the specified runtime validation.
-    /// @param data The calldata to send to the account.
-    /// @param authorization The authorization data to use for the call. The first 24 bytes is a ModuleEntity which
-    /// specifies which runtime validation to use, and the rest is sent as a parameter to runtime validation.
-    function executeWithRuntimeValidation(bytes calldata data, bytes calldata authorization)
-        external
-        payable
-        returns (bytes memory);
-
-    /// @notice Install a module to the modular account.
-    /// @param module The module to install.
-    /// @param manifest the manifest describing functions to install.
-    /// @param installData Optional data to be used by the account to handle the initial execution setup. Data
-    /// encoding is implementation-specific.
-    function installExecution(address module, ExecutionManifest calldata manifest, bytes calldata installData)
-        external;
-
-    /// @notice Uninstall a module from the modular account.
-    /// @param module The module to uninstall.
-    /// @param manifest The manifest describing functions to uninstall.
-    /// @param uninstallData Optional data to be used by the account to handle the execution uninstallation. Data
-    /// encoding is implementation-specific.
-    function uninstallExecution(address module, ExecutionManifest calldata manifest, bytes calldata uninstallData)
-        external;
-
-    /// @notice Installs a validation function across a set of execution selectors, and optionally mark it as a
-    /// global validation function.
-    /// @param validationConfig The validation function to install, along with configuration flags.
-    /// @param selectors The selectors to install the validation function for.
-    /// @param installData Optional data to be used by the account to handle the initial validation setup. Data
-    /// encoding is implementation-specific.
-    /// @param hooks Optional hooks to install and associate with the validation function. Data encoding is
-    /// implementation-specific.
-    function installValidation(
-        ValidationConfig validationConfig,
-        bytes4[] calldata selectors,
-        bytes calldata installData,
-        bytes[] calldata hooks
-    ) external;
-
-    /// @notice Uninstall a validation function from a set of execution selectors.
-    /// @param validationFunction The validation function to uninstall.
-    /// @param uninstallData Optional data to be used by the account to handle the validation uninstallation. Data
-    /// encoding is implementation-specific.
-    /// @param hookUninstallData Optional data to be used by the account to handle hook uninstallation. Data
-    /// encoding is implementation-specific.
-    function uninstallValidation(
-        ModuleEntity validationFunction,
-        bytes calldata uninstallData,
-        bytes[] calldata hookUninstallData
-    ) external;
-
-    /// @notice Return a unique identifier for the account implementation.
-    /// @dev This function MUST return a string in the format "vendor.account.semver". The vendor and account
-    /// names MUST NOT contain a period character.
-    /// @return The account ID.
-    function accountId() external view returns (string memory);
-}

package/src/interfaces/IERC6900AccountView.sol

@@ -1,52 +0,0 @@
-// SPDX-License-Identifier: CC0-1.0
-pragma solidity ^0.8.20;
-
-import {HookConfig, ModuleEntity, ValidationFlags} from "../interfaces/IERC6900Account.sol";
-
-/// @dev Represents data associated with a specific function selector.
-struct ExecutionDataView {
-    // The module that implements this execution function.
-    // If this is a native function, the address must be the address of the account.
-    address module;
-    // Whether or not the function needs runtime validation, or can be called by anyone. The function can still be
-    // state changing if this flag is set to true.
-    // Note that even if this is set to true, user op validation will still be required, otherwise anyone could
-    // drain the account of native tokens by wasting gas.
-    bool skipRuntimeValidation;
-    // Whether or not a global validation function may be used to validate this function.
-    bool allowGlobalValidation;
-    // The execution hooks for this function selector.
-    HookConfig[] executionHooks;
-}
-
-struct ValidationDataView {
-    // ValidationFlags layout:
-    // 0b00000___ // unused
-    // 0b_____A__ // isGlobal
-    // 0b______B_ // isSignatureValidation
-    // 0b_______C // isUserOpValidation
-    ValidationFlags validationFlags;
-    // The validation hooks for this validation function.
-    HookConfig[] validationHooks;
-    // Execution hooks to run with this validation function.
-    HookConfig[] executionHooks;
-    // The set of selectors that may be validated by this validation function.
-    bytes4[] selectors;
-}
-
-interface IERC6900AccountView {
-    /// @notice Get the execution data for a selector.
-    /// @dev If the selector is a native function, the module address will be the address of the account.
-    /// @param selector The selector to get the data for.
-    /// @return The execution data for this selector.
-    function getExecutionData(bytes4 selector) external view returns (ExecutionDataView memory);
-
-    /// @notice Get the validation data for a validation function.
-    /// @dev If the selector is a native function, the module address will be the address of the account.
-    /// @param validationFunction The validation function to get the data for.
-    /// @return The validation data for this validation function.
-    function getValidationData(ModuleEntity validationFunction)
-        external
-        view
-        returns (ValidationDataView memory);
-}

package/src/interfaces/IERC6900ExecutionHookModule.sol

@@ -1,26 +0,0 @@
-// SPDX-License-Identifier: CC0-1.0
-pragma solidity ^0.8.20;
-
-import {IERC6900Module} from "./IERC6900Module.sol";
-
-interface IERC6900ExecutionHookModule is IERC6900Module {
-    /// @notice Run the pre execution hook specified by the `entityId`.
-    /// @dev To indicate the entire call should revert, the function MUST revert.
-    /// @param entityId An identifier that routes the call to different internal implementations, should there
-    /// be more than one.
-    /// @param sender The caller address.
-    /// @param value The call value.
-    /// @param data The calldata sent. For `executeUserOp` calls of validation-associated hooks, hook modules
-    /// should receive the full calldata.
-    /// @return Context to pass to a post execution hook, if present. An empty bytes array MAY be returned.
-    function preExecutionHook(uint32 entityId, address sender, uint256 value, bytes calldata data)
-        external
-        returns (bytes memory);
-
-    /// @notice Run the post execution hook specified by the `entityId`.
-    /// @dev To indicate the entire call should revert, the function MUST revert.
-    /// @param entityId An identifier that routes the call to different internal implementations, should there
-    /// be more than one.
-    /// @param preExecHookData The context returned by its associated pre execution hook.
-    function postExecutionHook(uint32 entityId, bytes calldata preExecHookData) external;
-}

package/src/interfaces/IERC6900ExecutionModule.sol

@@ -1,37 +0,0 @@
-// SPDX-License-Identifier: CC0-1.0
-pragma solidity ^0.8.20;
-
-import {IERC6900Module} from "./IERC6900Module.sol";
-
-struct ManifestExecutionFunction {
-    // The selector to install.
-    bytes4 executionSelector;
-    // If true, the function won't need runtime validation, and can be called by anyone.
-    bool skipRuntimeValidation;
-    // If true, the function can be validated by a global validation function.
-    bool allowGlobalValidation;
-}
-
-struct ManifestExecutionHook {
-    bytes4 executionSelector;
-    uint32 entityId;
-    bool isPreHook;
-    bool isPostHook;
-}
-
-/// @dev A struct describing how the module should be installed on a modular account.
-struct ExecutionManifest {
-    // Execution functions defined in this module to be installed on the MSCA.
-    ManifestExecutionFunction[] executionFunctions;
-    ManifestExecutionHook[] executionHooks;
-    // List of ERC-165 interface IDs to add to account to support introspection checks. This MUST NOT include
-    // IERC6900Module's interface ID.
-    bytes4[] interfaceIds;
-}
-
-interface IERC6900ExecutionModule is IERC6900Module {
-    /// @notice Describe the contents and intended configuration of the module.
-    /// @dev This manifest MUST stay constant over time.
-    /// @return A manifest describing the contents and intended configuration of the module.
-    function executionManifest() external pure returns (ExecutionManifest memory);
-}

package/src/interfaces/IERC6900Module.sol

@@ -1,24 +0,0 @@
-// SPDX-License-Identifier: CC0-1.0
-pragma solidity ^0.8.20;
-
-import {IERC165} from "@openzeppelin/contracts/interfaces/IERC165.sol";
-
-interface IERC6900Module is IERC165 {
-    /// @notice Initialize module data for the modular account.
-    /// @dev Called by the modular account during `installExecution`.
-    /// @param data Optional bytes array to be decoded and used by the module to setup initial module data for the
-    /// modular account.
-    function onInstall(bytes calldata data) external;
-
-    /// @notice Clear module data for the modular account.
-    /// @dev Called by the modular account during `uninstallExecution`.
-    /// @param data Optional bytes array to be decoded and used by the module to clear module data for the modular
-    /// account.
-    function onUninstall(bytes calldata data) external;
-
-    /// @notice Return a unique identifier for the module.
-    /// @dev This function MUST return a string in the format "vendor.module.semver". The vendor and module
-    /// names MUST NOT contain a period character.
-    /// @return The module ID.
-    function moduleId() external view returns (string memory);
-}

package/src/interfaces/IERC6900ValidationHookModule.sol

@@ -1,46 +0,0 @@
-// SPDX-License-Identifier: CC0-1.0
-pragma solidity ^0.8.20;
-
-import {PackedUserOperation} from "@eth-infinitism/account-abstraction/interfaces/PackedUserOperation.sol";
-
-import {IERC6900Module} from "./IERC6900Module.sol";
-
-interface IERC6900ValidationHookModule is IERC6900Module {
-    /// @notice Run the pre user operation validation hook specified by the `entityId`.
-    /// @dev Pre user operation validation hooks MUST NOT return an authorizer value other than 0 or 1.
-    /// @param entityId An identifier that routes the call to different internal implementations, should there
-    /// be more than one.
-    /// @param userOp The user operation.
-    /// @param userOpHash The user operation hash.
-    /// @return Packed validation data for validAfter (6 bytes), validUntil (6 bytes), and authorizer (20 bytes).
-    function preUserOpValidationHook(uint32 entityId, PackedUserOperation calldata userOp, bytes32 userOpHash)
-        external
-        returns (uint256);
-
-    /// @notice Run the pre runtime validation hook specified by the `entityId`.
-    /// @dev To indicate the entire call should revert, the function MUST revert.
-    /// @param entityId An identifier that routes the call to different internal implementations, should there
-    /// be more than one.
-    /// @param sender The caller address.
-    /// @param value The call value.
-    /// @param data The calldata sent.
-    /// @param authorization Additional data for the hook to use.
-    function preRuntimeValidationHook(
-        uint32 entityId,
-        address sender,
-        uint256 value,
-        bytes calldata data,
-        bytes calldata authorization
-    ) external;
-
-    /// @notice Run the pre signature validation hook specified by the `entityId`.
-    /// @dev To indicate the call should revert, the function MUST revert.
-    /// @param entityId An identifier that routes the call to different internal implementations, should there
-    /// be more than one.
-    /// @param sender The caller address.
-    /// @param hash The hash of the message being signed.
-    /// @param signature The signature of the message.
-    function preSignatureValidationHook(uint32 entityId, address sender, bytes32 hash, bytes calldata signature)
-        external
-        view;
-}