@crossbind/port-gdal-wasm 2.0.0-beta.50

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindFileGDB.cmake

@@ -0,0 +1,93 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#.rst:
+# Find FGDB - ESRI File Geodatabaselibrary
+# ~~~~~~~~~
+#
+# Copyright (c) 2017,2018 Hiroshi Miura <miurahr@linux.com>
+#
+# ::
+#
+# If it's found it sets FileGDB_FOUND to TRUE
+# and following variables are set:
+#    FileGDB_INCLUDE_DIR
+#    FileGDB_LIBRARY
+#    FileGDB_VERSION
+#
+# Select a FGDB API to use, or disable driver.
+
+find_path(FileGDB_INCLUDE_DIR NAMES FileGDBAPI.h
+          PATHS /usr/local/filegdb/include "${FileGDB_ROOT}/include")
+mark_as_advanced(FileGDB_INCLUDE_DIR)
+
+if(FileGDB_INCLUDE_DIR)
+    if(WIN32)
+        if(NOT FileGDB_LIBRARY)
+          find_library(FileGDB_LIBRARY_RELEASE NAMES
+              FileGDBAPI
+              PATHS "${FileGDB_ROOT}/lib" "${FileGDB_ROOT}/lib64"
+          )
+          mark_as_advanced(FileGDB_LIBRARY_RELEASE)
+
+          find_library(FileGDB_LIBRARY_DEBUG NAMES
+              FileGDBAPID
+              PATHS "${FileGDB_ROOT}/lib" "${FileGDB_ROOT}/lib64"
+          )
+          mark_as_advanced(FileGDB_LIBRARY_DEBUG)
+
+          include(SelectLibraryConfigurations)
+          select_library_configurations(FileGDB)
+        endif()
+    else()
+        mark_as_advanced(FileGDB_LIBRARY)
+
+        find_library(FileGDB_LIBRARY NAMES FileGDBAPI PATHS "${FileGDB_ROOT}/lib" "${FileGDB_ROOT}/lib64")
+        include(CheckCXXSourceCompiles)
+        include(CMakePushCheckState)
+        cmake_push_check_state(RESET)
+        check_cxx_source_compiles("#include <FileGDBAPI.h>\nusing namespace FileGDBAPI;\n
+                int main() { Geodatabase oDB; std::wstring osStr; ::OpenGeodatabase(osStr, oDB); return 0; }" TEST_FileGDB_COMPILE)
+        cmake_pop_check_state()
+        if(NOT TEST_FileGDB_COMPILE)
+            set(FileGDB_FOUND FALSE)
+        endif()
+    endif()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(FileGDB
+                                  FOUND_VAR FileGDB_FOUND
+                                  REQUIRED_VARS FileGDB_LIBRARY FileGDB_INCLUDE_DIR)
+
+if(FileGDB_FOUND)
+    set(FileGDB_INCLUDE_DIRS ${FileGDB_INCLUDE_DIR})
+    set(FileGDB_LIBRARIES ${FileGDB_LIBRARY})
+    if(NOT TARGET FILEGDB::FileGDB)
+        add_library(FILEGDB::FileGDB UNKNOWN IMPORTED)
+        set_target_properties(FILEGDB::FileGDB PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${FileGDB_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C")
+
+        if(EXISTS "${FileGDB_LIBRARY}")
+          set_target_properties(FILEGDB::FileGDB PROPERTIES
+            IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+            IMPORTED_LOCATION "${FileGDB_LIBRARY}")
+        endif()
+        if(FileGDB_LIBRARY_RELEASE)
+          set_property(TARGET FILEGDB::FileGDB APPEND PROPERTY
+            IMPORTED_CONFIGURATIONS RELEASE)
+          set_target_properties(FILEGDB::FileGDB PROPERTIES
+            IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+            IMPORTED_LOCATION_RELEASE "${FileGDB_LIBRARY_RELEASE}")
+        endif()
+        if(FileGDB_LIBRARY_DEBUG)
+          set_property(TARGET FILEGDB::FileGDB APPEND PROPERTY
+            IMPORTED_CONFIGURATIONS DEBUG)
+          set_target_properties(FILEGDB::FileGDB PROPERTIES
+            IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+            IMPORTED_LOCATION_DEBUG "${FileGDB_LIBRARY_DEBUG}")
+        endif()
+
+    endif()
+endif()

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindFreeXL.cmake

@@ -0,0 +1,67 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindFreeXL
+----------
+
+Find the FreeXL includes and get all installed freexl library settings
+
+The following vars are set if freexl is found.
+
+.. variable:: FREEXL_FOUND
+
+  True if found, otherwise all other vars are undefined
+
+.. variable:: FREEXL_INCLUDE_DIR
+
+  The include dir for main *.h files
+
+.. variable:: FREEXL_VERSION_STRING
+
+  full version (e.g. 4.2.0)
+
+.. variable:: FREEXL_VERSION_MAJOR
+
+  major part of version (e.g. 4)
+
+.. variable:: FREEXL_VERSION_MINOR
+
+  minor part (e.g. 2)
+
+#]=======================================================================]
+
+
+include(FindPackageHandleStandardArgs)
+include(SelectLibraryConfigurations)
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_check_modules(PC_FREEXL QUIET freexl)
+endif()
+
+find_path(FREEXL_INCLUDE_DIR
+          NAMES freexl.h
+          HINTS ${PC_FREEXL_INCLUDE_DIRS})
+find_library(FREEXL_LIBRARY
+             NAMES freexl_i freexl
+             NAMES_PER_DIR
+             HINTS ${PC_FREEXL_LIBRARY_DIRS})
+
+mark_as_advanced(FREEXL_INCLUDE_DIR FREEXL_LIBRARY)
+find_package_handle_standard_args(FreeXL
+                                  FOUND_VAR FREEXL_FOUND
+                                  REQUIRED_VARS FREEXL_LIBRARY FREEXL_INCLUDE_DIR)
+
+if(FREEXL_FOUND)
+    set(FREEXL_LIBRARIES ${FREEXL_LIBRARY})
+    set(FREEXL_INCLUDE_DIRS ${FREEXL_INCLUDE_DIR})
+
+    if(NOT TARGET FREEXL::freexl)
+        add_library(FREEXL::freexl UNKNOWN IMPORTED)
+        set_target_properties(FREEXL::freexl PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${FREEXL_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${FREEXL_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindGEOS.cmake

@@ -0,0 +1,49 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#.rst:
+# FindGEOS
+# -----------
+#
+# CMake module to search for GEOS library
+#
+# Copyright (C) 2017-2018, Hiroshi Miura
+# Copyright (c) 2008, Mateusz Loskot <mateusz@loskot.net>
+# (based on FindGDAL.cmake by Magnus Homann)
+#
+# If it's found it sets GEOS_FOUND to TRUE
+# and following variables are set:
+#    GEOS_INCLUDE_DIR
+#    GEOS_LIBRARY
+#
+
+find_program(GEOS_CONFIG geos-config)
+if(GEOS_CONFIG)
+    execute_process(COMMAND "${GEOS_CONFIG}" --version OUTPUT_VARIABLE GEOS_VERSION)
+    execute_process(COMMAND "${GEOS_CONFIG}" --prefix OUTPUT_VARIABLE GEOS_PREFIX)
+endif()
+
+find_path(GEOS_INCLUDE_DIR NAMES geos_c.h
+          HINTS ${GEOS_PREFIX}/include)
+find_library(GEOS_LIBRARY NAMES geos_c
+             HINTS ${GEOS_PREFIX}/lib)
+mark_as_advanced(GEOS_INCLUDE_DIR GEOS_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(GEOS FOUND_VAR GEOS_FOUND
+                                  REQUIRED_VARS GEOS_LIBRARY GEOS_INCLUDE_DIR
+                                  VERSION_VAR GEOS_VERSION)
+
+if(GEOS_FOUND)
+    set(GEOS_LIBRARIES ${GEOS_LIBRARY})
+    set(GEOS_INCLUDE_DIRS ${GEOS_INCLUDE_DIR})
+    set(GEOS_TARGET GEOS::GEOS)
+
+    if(NOT TARGET ${GEOS_TARGET})
+        add_library(${GEOS_TARGET} UNKNOWN IMPORTED)
+        set_target_properties(${GEOS_TARGET} PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${GEOS_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${GEOS_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindGIF.cmake

@@ -0,0 +1,97 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#.rst:
+# FindGIF
+# -------
+#
+# This finds the GIF library (giflib)
+#
+# The module defines the following variables:
+#
+# ``GIF_FOUND``
+#   True if giflib was found
+# ``GIF_LIBRARIES``
+#   Libraries to link to in order to use giflib
+# ``GIF_INCLUDE_DIR``
+#   where to find the headers
+# ``GIF_VERSION``
+#   3, 4 or a full version string (eg 5.1.4) for versions >= 4.1.6
+#
+# The minimum required version of giflib can be specified using the
+# standard syntax, e.g.  find_package(GIF 4)
+#
+
+# Created by Eric Wing.
+# Modifications by Alexander Neundorf, Ben Campbell
+
+find_path(GIF_INCLUDE_DIR gif_lib.h
+  HINTS ${GIF_ROOT}
+  PATH_SUFFIXES include)
+
+# the gif library can have many names :-/
+set(POTENTIAL_GIF_LIBS gif libgif ungif libungif giflib giflib4)
+
+find_library(GIF_LIBRARY
+  NAMES ${POTENTIAL_GIF_LIBS}
+  NAMES_PER_DIR
+  HINTS ${GIF_ROOT}
+  PATH_SUFFIXES lib)
+
+# see readme.txt
+set(GIF_LIBRARIES ${GIF_LIBRARY})
+
+# Very basic version detection.
+# The GIF_LIB_VERSION string in gif_lib.h seems to be unreliable, since it seems
+# to be always " Version 2.0, " in versions 3.x of giflib.
+# In version 4 the member UserData was added to GifFileType, so we check for this
+# one.
+# Versions after 4.1.6 define GIFLIB_MAJOR, GIFLIB_MINOR, and GIFLIB_RELEASE
+# see http://giflib.sourceforge.net/gif_lib.html#compatibility
+if(GIF_INCLUDE_DIR)
+  include(CMakePushCheckState)
+  include(CheckStructHasMember)
+  CMAKE_PUSH_CHECK_STATE()
+  set(CMAKE_REQUIRED_QUIET ${GIF_FIND_QUIETLY})
+  set(CMAKE_REQUIRED_INCLUDES "${GIF_INCLUDE_DIR}")
+
+  # Check for the specific version defines (>=4.1.6 only)
+  file(STRINGS ${GIF_INCLUDE_DIR}/gif_lib.h _GIF_DEFS REGEX "^[ \t]*#define[ \t]+GIFLIB_(MAJOR|MINOR|RELEASE)")
+  if(_GIF_DEFS)
+    # yay - got exact version info
+    string(REGEX REPLACE ".*GIFLIB_MAJOR ([0-9]+).*" "\\1" _GIF_MAJ "${_GIF_DEFS}")
+    string(REGEX REPLACE ".*GIFLIB_MINOR ([0-9]+).*" "\\1" _GIF_MIN "${_GIF_DEFS}")
+    string(REGEX REPLACE ".*GIFLIB_RELEASE ([0-9]+).*" "\\1" _GIF_REL "${_GIF_DEFS}")
+    set(GIF_VERSION "${_GIF_MAJ}.${_GIF_MIN}.${_GIF_REL}")
+  else()
+    # use UserData field to sniff version instead
+    CHECK_STRUCT_HAS_MEMBER(GifFileType UserData gif_lib.h GIF_GifFileType_UserData )
+    if(GIF_GifFileType_UserData)
+      set(GIF_VERSION 4)
+    else()
+      set(GIF_VERSION 3)
+    endif()
+  endif()
+
+  unset(_GIF_MAJ)
+  unset(_GIF_MIN)
+  unset(_GIF_REL)
+  unset(_GIF_DEFS)
+  CMAKE_POP_CHECK_STATE()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(GIF  REQUIRED_VARS  GIF_LIBRARY  GIF_INCLUDE_DIR
+                                       VERSION_VAR GIF_VERSION )
+
+mark_as_advanced(GIF_INCLUDE_DIR GIF_LIBRARY)
+
+if(GIF_FOUND)
+  if(NOT TARGET GIF::GIF)
+    add_library(GIF::GIF UNKNOWN IMPORTED)
+    set_target_properties(GIF::GIF PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${GIF_INCLUDE_DIR}"
+                          IMPORTED_LINK_INTERFACE_LANGUAGES C
+                          IMPORTED_LOCATION "${GIF_LIBRARY}")
+  endif()
+endif()

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindGeoTIFF.cmake

@@ -0,0 +1,104 @@
+###############################################################################
+#
+# CMake module to search for GeoTIFF library
+#
+# On success, the macro sets the following variables:
+# GEOTIFF_FOUND       = if the library found
+# GEOTIFF_LIBRARIES   = full path to the library
+# GEOTIFF_INCLUDE_DIR = where to find the library headers
+# also defined, but not for general use are
+# GEOTIFF_LIBRARY
+#
+# Copyright (c) 2009 Mateusz Loskot <mateusz@loskot.net>
+# Copyright (c) 2016 NextGIS <info@nextgis.com>
+# Copyright (C) 2017,2018 Hiroshi Miura
+#
+# Origin from
+# https://svn.osgeo.org/metacrs/geotiff/trunk/libgeotiff/cmake/FindGeoTIFF.cmake
+# Module source: http://github.com/mloskot/workshop/tree/master/cmake/
+#
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+#
+###############################################################################
+
+find_path(GEOTIFF_INCLUDE_DIR geotiff.h PATH_SUFFIXES geotiff libgeotiff)
+
+set(GEOTIFF_NAMES ${GEOTIFF_NAMES} geotiff geotiff_i)
+set(GEOTIFF_NAMES_DEBUG ${GEOTIFF_NAMES_DEBUG} geotiffd geotiff_d geotiff_d_i)
+
+if(NOT GEOTIFF_LIBRARY)
+  find_library(GEOTIFF_LIBRARY_RELEASE NAMES ${GEOTIFF_NAMES} NAMES_PER_DIR)
+  find_library(GEOTIFF_LIBRARY_DEBUG NAMES ${GEOTIFF_NAMES_DEBUG} NAMES_PER_DIR)
+  include(SelectLibraryConfigurations)
+  select_library_configurations(GEOTIFF)
+  mark_as_advanced(GEOTIFF_LIBRARY_RELEASE GEOTIFF_LIBRARY_DEBUG)
+endif()
+
+unset(GEOTIFF_NAMES)
+unset(GEOTIFF_NAMES_DEBUG)
+
+
+if(GEOTIFF_INCLUDE_DIR)
+    set(GEOTIFF_MAJOR_VERSION 0)
+    set(GEOTIFF_MINOR_VERSION 0)
+    set(GEOTIFF_PATCH_VERSION 0)
+    set(GEOTIFF_REVISION_VERSION 0)
+
+    if(EXISTS "${GEOTIFF_INCLUDE_DIR}/geotiff.h")
+        file(READ "${GEOTIFF_INCLUDE_DIR}/geotiff.h" GEOTIFF_H_CONTENTS)
+        string(REGEX MATCH "LIBGEOTIFF_VERSION[ \t]+([0-9]+)"
+          LIBGEOTIFF_VERSION ${GEOTIFF_H_CONTENTS})
+        string (REGEX MATCH "([0-9]+)"
+          LIBGEOTIFF_VERSION ${LIBGEOTIFF_VERSION})
+
+        string(SUBSTRING ${LIBGEOTIFF_VERSION} 0 1 GEOTIFF_MAJOR_VERSION)
+        string(SUBSTRING ${LIBGEOTIFF_VERSION} 1 1 GEOTIFF_MINOR_VERSION)
+        string(SUBSTRING ${LIBGEOTIFF_VERSION} 2 1 GEOTIFF_PATCH_VERSION)
+        string(SUBSTRING ${LIBGEOTIFF_VERSION} 3 1 GEOTIFF_REVISION_VERSION)
+
+        unset(GEOTIFF_H_CONTENTS)
+    endif()
+
+    set(GEOTIFF_VERSION_STRING "${GEOTIFF_MAJOR_VERSION}.${GEOTIFF_MINOR_VERSION}.${GEOTIFF_PATCH_VERSION}.${GEOTIFF_REVISION_VERSION}")
+
+endif()
+mark_as_advanced(GEOTIFF_LIBRARY GEOTIFF_INCLUDE_DIR)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(GeoTIFF
+                                  FOUND_VAR GEOTIFF_FOUND
+                                  REQUIRED_VARS GEOTIFF_LIBRARY GEOTIFF_INCLUDE_DIR
+                                  VERSION_VAR GEOTIFF_VERSION_STRING)
+
+if(GEOTIFF_FOUND)
+    set(GEOTIFF_LIBRARIES "${GEOTIFF_LIBRARY}")
+    set(GEOTIFF_INCLUDE_DIRS "${GEOTIFF_INCLUDE_DIR}")
+    set(GeoTIFF_TARGET GEOTIFF::GEOTIFF)
+    if(NOT TARGET ${GeoTIFF_TARGET})
+        add_library(${GeoTIFF_TARGET} UNKNOWN IMPORTED)
+        set_target_properties(${GeoTIFF_TARGET} PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${GEOTIFF_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES C)
+        if(EXISTS "${GEOTIFF_LIBRARY}")
+          set_target_properties(${GeoTIFF_TARGET} PROPERTIES
+            IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+            IMPORTED_LOCATION "${GEOTIFF_LIBRARY}")
+        endif()
+        if(EXISTS "${GEOTIFF_LIBRARY_RELEASE}")
+          set_property(TARGET ${GeoTIFF_TARGET} APPEND PROPERTY
+            IMPORTED_CONFIGURATIONS RELEASE)
+          set_target_properties(${GeoTIFF_TARGET} PROPERTIES
+            IMPORTED_LINK_INTERFACE_LANGUAGES_RELEASE "C"
+            IMPORTED_LOCATION_RELEASE "${GEOTIFF_LIBRARY_RELEASE}")
+        endif()
+        if(EXISTS "${GEOTIFF_LIBRARY_DEBUG}")
+          set_property(TARGET ${GeoTIFF_TARGET} APPEND PROPERTY
+            IMPORTED_CONFIGURATIONS DEBUG)
+          set_target_properties(${GeoTIFF_TARGET} PROPERTIES
+            IMPORTED_LINK_INTERFACE_LANGUAGES_DEBUG "C"
+            IMPORTED_LOCATION_DEBUG "${GEOTIFF_LIBRARY_DEBUG}")
+        endif()
+    endif()
+endif()
+

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindHDF4.cmake

@@ -0,0 +1,133 @@
+#
+# To be used by projects that make use of CMakeified hdf-4.2
+#
+
+#[=======================================================================[.rst:
+FindHDF4
+---------
+
+Find the HDF4 includes and get all installed hdf4 library settings
+
+The following vars are set if hdf4 is found.
+
+.. variable:: HDF4_FOUND
+
+  True if found, otherwise all other vars are undefined
+
+IMPORTED targets
+^^^^^^^^^^^^^^^^
+This module defines the following :prop_tgt:`IMPORTED` target:
+``HDF4::HDF4``
+#
+#]=======================================================================]
+#
+
+
+include(SelectLibraryConfigurations)
+
+set(HDF4_PATHS
+    /usr/lib/hdf4
+    /usr/local/hdf4
+    )
+
+find_path(HDF4_INCLUDE_DIR hdf.h
+          PATHS ${HDF4_PATHS}
+          PATH_SUFFIXES
+          include
+          Include
+          hdf
+          hdf4
+          )
+mark_as_advanced(HDF4_INCLUDE_DIR)
+
+if(HDF4_INCLUDE_DIR AND EXISTS "${HDF4_INCLUDE_DIR}/hfile.h")
+    file(STRINGS "${HDF4_INCLUDE_DIR}/hfile.h" hdf4_version_string
+         REGEX "^#define[\t ]+LIBVER.*")
+    string(REGEX MATCH "LIBVER_MAJOR[ \t]+([0-9]+)" HDF4_VERSION_MAJOR "${hdf4_version_string}")
+    string(REGEX MATCH "([0-9]+)" HDF4_VERSION_MAJOR ${HDF4_VERSION_MAJOR})
+    string(REGEX MATCH "LIBVER_MINOR[ \t]+([0-9]+)" HDF4_VERSION_MINOR "${hdf4_version_string}")
+    string(REGEX MATCH "([0-9]+)" HDF4_VERSION_MINOR ${HDF4_VERSION_MINOR})
+    string(REGEX MATCH "LIBVER_RELEASE[ \t]+([0-9]+)" HDF4_VERSION_RELEASE "${hdf4_version_string}")
+    string(REGEX MATCH "([0-9]+)" HDF4_VERSION_RELEASE ${HDF4_VERSION_RELEASE})
+    string(REGEX MATCH "LIBVER_SUBRELEASE[ \t]+([0-9A-Za-z]+)" HDF4_VERSION_SUBRELEASE "${hdf4_version_string}")
+    unset(hdf4_version_string)
+    if(NOT HDF4_VERSION_SUBRELEASE STREQUAL "")
+        string(REGEX MATCH "([0-9A-Za-z]+)" LIBVER_SUBRELEASE ${LIBVER_SUBRELEASE})
+        set(HDF4_VERSION_STRING "${HDF4_VERSION_MAJOR}.${HDF4_VERSION_MINOR}.${HDF4_VERSION_RELEASE}_${HDF4_VERSION_SUBRELEASE}")
+    else()
+        set(HDF4_VERSION_STRING "${HDF4_VERSION_MAJOR}.${HDF4_VERSION_MINOR}.${HDF4_VERSION_RELEASE}")
+    endif()
+endif()
+
+if(NOT DEFINED HDF4_COMPONENTS)
+  set(HDF4_COMPONENTS df mfhdf xdr szip)
+endif()
+
+if(HDF4_INCLUDE_DIR)
+    # Debian supplies the HDF4 library which does not conflict with NetCDF.
+    # Test for Debian flavor first. Hint: install the libhdf4-alt-dev package.
+    foreach(tgt IN LISTS HDF4_COMPONENTS)
+        if(tgt STREQUAL "df")
+          # hdf.lib (dynamic) used by conda, but libhdf.lib (static) also present
+          set(_names_debug  ${tgt}altd ${tgt}d hdfd libhdfd)
+          set(_names_release ${tgt}alt ${tgt} hdf libhdf)
+        else()
+          set(_names_debug  ${tgt}altd ${tgt}d)
+          set(_names_release ${tgt}alt ${tgt} lib${tgt})
+        endif()
+        find_library(HDF4_${tgt}_LIBRARY_DEBUG
+                     NAMES ${_names_debug}
+                     NAMES_PER_DIR
+                     PATHS ${HDF4_PATHS}/lib)
+        find_library(HDF4_${tgt}_LIBRARY_RELEASE
+                     NAMES ${_names_release}
+                     NAMES_PER_DIR
+                     PATHS ${HDF4_PATHS}/lib)
+        select_library_configurations(HDF4_${tgt})
+        mark_as_advanced(HDF4_${tgt}_LIBRARY HDF4_${tgt}_LIBRARY_RELEASE HDF4_${tgt}_LIBRARY_DEBUG )
+    endforeach()
+
+    set(HDF4_LIBRARIES)
+    foreach(_comp IN LISTS HDF4_COMPONENTS)
+        if(HDF4_${_comp}_LIBRARY)
+            list(APPEND HDF4_LIBRARIES "${HDF4_${_comp}_LIBRARY}")
+        endif()
+    endforeach()
+
+    if(WIN32)
+        find_library(WS2_32_LIBRARY ws2_32)
+        if(WS2_32_LIBRARY)
+          list(APPEND HDF4_LIBRARIES ${WS2_32_LIBRARY})
+        endif()
+    endif()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(HDF4
+                                  FOUND_VAR HDF4_FOUND
+                                  REQUIRED_VARS HDF4_df_LIBRARY HDF4_mfhdf_LIBRARY HDF4_INCLUDE_DIR
+                                  VERSION_VAR HDF4_VERSION_STRING
+                                  HANDLE_COMPONENTS
+                                  )
+
+# set output variables
+if(HDF4_FOUND)
+  set(HDF4_INCLUDE_DIRS "${HDF4_INCLUDE_DIR}")
+  if(NOT TARGET HDF4::HDF4)
+      set(INCR 1)
+      set(HDF4_TARGETS)
+      foreach(_lib IN LISTS HDF4_LIBRARIES)
+          add_library(HDF4::HDF4_${INCR} UNKNOWN IMPORTED)
+          set_target_properties(HDF4::HDF4_${INCR} PROPERTIES
+                                IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                                IMPORTED_LOCATION "${_lib}")
+          list(APPEND HDF4_TARGETS HDF4::HDF4_${INCR})
+          math(EXPR INCR "${INCR}+1")
+      endforeach()
+
+      add_library(HDF4::HDF4 INTERFACE IMPORTED)
+      set_target_properties(HDF4::HDF4 PROPERTIES
+                            INTERFACE_INCLUDE_DIRECTORIES "${HDF4_INCLUDE_DIRS}"
+                            INTERFACE_LINK_LIBRARIES "${HDF4_TARGETS}")
+  endif()
+endif()

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindHDFS.cmake

@@ -0,0 +1,54 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindHDFS
+--------
+
+The following vars are set if HDFS (the native library provided with Hadoop) is found.
+
+.. variable:: HDFS_FOUND
+
+  True if found, otherwise all other vars are undefined
+
+.. variable:: HDFS_INCLUDE_DIR
+
+  The include dir for hdfs.h
+
+.. variable:: HDFS_LIBRARY
+
+  The library file
+
+#]=======================================================================]
+
+
+include(FindPackageHandleStandardArgs)
+
+find_package(JNI)
+if(JNI_FOUND)
+    add_library(HDFS::JVM UNKNOWN IMPORTED)
+    set_target_properties(HDFS::JVM PROPERTIES
+                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                          IMPORTED_LOCATION "${JAVA_JVM_LIBRARY}")
+endif()
+
+find_path(HDFS_INCLUDE_DIR NAMES hdfs.h)
+find_library(HDFS_LIBRARY NAMES hdfs PATH_SUFFIXES native)
+
+mark_as_advanced(HDFS_INCLUDE_DIR HDFS_LIBRARY)
+find_package_handle_standard_args(HDFS
+                                  FOUND_VAR HDFS_FOUND
+                                  REQUIRED_VARS HDFS_LIBRARY HDFS_INCLUDE_DIR)
+
+if(HDFS_FOUND)
+    set(HDFS_LIBRARIES ${HDFS_LIBRARY})
+    set(HDFS_INCLUDE_DIRS ${HDFS_INCLUDE_DIR})
+
+    if(NOT TARGET HDFS::HDFS)
+        add_library(HDFS::HDFS UNKNOWN IMPORTED)
+        set_target_properties(HDFS::HDFS PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${HDFS_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${HDFS_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindIDB.cmake

@@ -0,0 +1,45 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+find_path(IDB_INCLUDE_DIR c++/it.h PATHS ${IDB_ROOT} PATH_SUFFIXES incl)
+# following libs are what is needed with ibm.csdk.4.50.FC7.LNX.tar
+find_library(IDB_IFCPP_LIBRARY NAMES ifc++ PATHS ${IDB_ROOT} PATH_SUFFIXES lib/c++)
+find_library(IDB_IFDMI_LIBRARY NAMES ifdmi PATHS ${IDB_ROOT} PATH_SUFFIXES lib/dmi)
+find_library(IDB_IFSQL_LIBRARY NAMES ifsql PATHS ${IDB_ROOT} PATH_SUFFIXES lib/esql)
+find_library(IDB_IFCLI_LIBRARY NAMES ifcli PATHS ${IDB_ROOT} PATH_SUFFIXES lib/cli)
+mark_as_advanced(IDB_INCLUDE_DIR IDB_IFCPP_LIBRARY IDB_IFDMI_LIBRARY IDB_IFSQL_LIBRARY IDB_IFCLI_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(IDB
+                                  FOUND_VAR IDB_FOUND
+                                  REQUIRED_VARS IDB_INCLUDE_DIR
+                                                IDB_IFCPP_LIBRARY
+                                                IDB_IFDMI_LIBRARY
+                                                IDB_IFSQL_LIBRARY
+                                                IDB_IFCLI_LIBRARY)
+
+### Import targets ############################################################
+if(IDB_FOUND)
+  set(IDB_INCLUDE_DIRS "${IDB_INCLUDE_DIR}/dmi;${IDB_INCLUDE_DIR}/c++")
+  set(IDB_LIBRARIES "${IDB_IFCPP_LIBRARY};${IDB_IFDMI_LIBRARY};${IDB_IFSQL_LIBRARY};${IDB_IFCLI_LIBRARY}")
+  if(NOT TARGET IDB::IDB)
+    add_library(IDB::IDB UNKNOWN IMPORTED)
+                set_target_properties(IDB::IDB PROPERTIES
+                IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                IMPORTED_LOCATION "${IDB_IFCPP_LIBRARY}"
+                INTERFACE_INCLUDE_DIRECTORIES "${IDB_INCLUDE_DIRS}")
+
+    set(IDB_TARGETS)
+    set(IDB_LIBRARIES IDB_IFDMI_LIBRARY IDB_IFSQL_LIBRARY IDB_IFCLI_LIBRARY)
+    foreach(_IDB_LIBRARY_VARNAME IN LISTS IDB_LIBRARIES)
+        add_library(IDB::IDB_${_IDB_LIBRARY_VARNAME} UNKNOWN IMPORTED)
+        set_target_properties(IDB::IDB_${_IDB_LIBRARY_VARNAME} PROPERTIES
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${${_IDB_LIBRARY_VARNAME}}")
+        list(APPEND IDB_TARGETS IDB::IDB_${_IDB_LIBRARY_VARNAME})
+    endforeach()
+
+    set_property(TARGET IDB::IDB APPEND PROPERTY
+        INTERFACE_LINK_LIBRARIES "${IDB_TARGETS}")
+  endif()
+endif()