@crossbind/port-gdal-wasm 2.0.0-beta.50

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindCryptoPP.cmake

@@ -0,0 +1,91 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#.rst:
+# FindCryptoPP
+# --------
+#
+# Find Crypto++ library
+#
+# ::
+#
+#  Following variables are set.
+#
+#   CRYPTOPP_FOUND
+#     Indicates whether the library has been found.
+#
+#   CRYPTOPP_INCLUDE_DIRS
+#     Points to the CryptoPP include directory.
+#
+#   CRYPTOPP_LIBRARIES
+#     Points to the CryptoPP libraries that should be passed to
+#     target_link_libararies.
+#
+
+find_path(CRYPTOPP_INCLUDE_DIR NAMES cryptopp/aes.h HINTS ${CRYPTOPP_HINTPATH}/include)
+
+if(CRYPTOPP_INCLUDE_DIR)
+    if(BUILD_SHARED_LIBS)
+        find_library(CRYPTOPP_LIBRARY_RELEASE NAMES cryptolib cryptopp NAMES_PER_DIR HINTS ${CRYPTOPP_HINTPATH}/lib)
+        find_library(CRYPTOPP_LIBRARY_DEBUG NAMES cryptolibd cryptoppd NAMES_PER_DIR HINTS ${CRYPTOPP_HINTPATH}/debug)
+    else()
+        find_library(CRYPTOPP_LIBRARY_RELEASE NAMES cryptopp NAMES_PER_DIR HINTS ${CRYPTOPP_HINTPATH}/lib)
+        find_library(CRYPTOPP_LIBRARY_DEBUG NAMES cryptoppd NAMES_PER_DIR HINTS ${CRYPTOPP_HINTPATH}/debug)
+    endif()
+    mark_as_advanced(CRYPTOPP_LIBRARY_RELEASE CRYPTOPP_LIBRARY_DEBUG)
+    include(SelectLibraryConfigurations)
+    select_library_configurations(CRYPTOPP)
+
+    if(EXISTS ${_CRYPTOPP_VERSION_HEADER})
+        file(STRINGS "${CRYPTOPP_INCLUDE_DIR}/cryptopp/config.h" cryptopp_version_str REGEX "^#define CRYPTOPP_VERSION[ \t]+[0-9]+$")
+        string(REGEX REPLACE "^#define CRYPTOPP_VERSION[ \t]+([0-9]+)" "\\1" CRYPTOPP_VERSION_STRING "${cryptopp_version_str}")
+        unset(cryptopp_version_str)
+    endif()
+endif()
+
+if(NOT CMAKE_CXX_COMPILER_LOADED)
+    message(AUTHOR_WARNING "CXX language not enabled: Skipping detection of issue with clang++.")
+    set(CRYPTOPP_TEST_KNOWNBUG TRUE)
+elseif(CRYPTOPP_INCLUDE_DIR AND CRYPTOPP_LIBRARY)
+    include(CMakePushCheckState)
+    include(CheckCXXSourceCompiles)
+    cmake_push_check_state(RESET)
+    set(CMAKE_REQUIRED_LIBRARIES ${CRYPTOPP_LIBRARY})
+    set(CMAKE_REQUIRED_INCLUDES ${CRYPTOPP_INCLUDE_DIR})
+    # Catch issue with clang++ (https://groups.google.com/forum/#!topic/cryptopp-users/DfWHy3bT0KI)
+    check_cxx_source_compiles("#include <cryptopp/osrng.h>
+        int main(int argc, char** argv) { CryptoPP::AES::Encryption oEnc; return 0; }" CRYPTOPP_TEST_KNOWNBUG)
+    cmake_pop_check_state()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(CryptoPP
+                                  FOUND_VAR CRYPTOPP_FOUND
+                                  REQUIRED_VARS CRYPTOPP_LIBRARY CRYPTOPP_TEST_KNOWNBUG CRYPTOPP_INCLUDE_DIR
+                                  VERSION_VAR CRYPTOPP_VERSION_STRING)
+mark_as_advanced(CRYPTOPP_LIBRARY CRYPTOPP_INCLUDE_DIR)
+
+if(CRYPTOPP_FOUND)
+    set(CRYPTOPP_LIBRARIES "${CRYPTOPP_LIBRARY}")
+    set(CRYPTOPP_INCLUDE_DIRS "${CRYPTOPP_INCLUDE_DIR}")
+    if(NOT TARGET CRYPTOPP::CRYPTOPP)
+        add_library(CRYPTOPP::CRYPTOPP UNKNOWN IMPORTED)
+        set_target_properties(CRYPTOPP::CRYPTOPP PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${CRYPTOPP_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "CXX")
+
+        if(CRYPTOPP_LIBRARY_RELEASE)
+            set_property(TARGET CRYPTOPP::CRYPTOPP APPEND PROPERTY
+                    IMPORTED_CONFIGURATIONS RELEASE)
+            set_target_properties(CRYPTOPP::CRYPTOPP PROPERTIES
+                    IMPORTED_LOCATION_RELEASE "${CRYPTOPP_LIBRARY_RELEASE}")
+        endif()
+
+        if(CRYPTOPP_LIBRARY_DEBUG)
+            set_property(TARGET CRYPTOPP::CRYPTOPP APPEND PROPERTY
+                    IMPORTED_CONFIGURATIONS DEBUG)
+            set_target_properties(CRYPTOPP::CRYPTOPP PROPERTIES
+                    IMPORTED_LOCATION_DEBUG "${CRYPTOPP_LIBRARY_DEBUG}")
+        endif()
+   endif()
+endif()

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindDeflate.cmake

@@ -0,0 +1,113 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindDeflate
+--------
+
+Find the native Deflate includes and library.
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``Deflate::Deflate``, if
+Deflate has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+::
+
+  Deflate_INCLUDE_DIRS   - where to find deflate.h, etc.
+  Deflate_LIBRARIES      - List of libraries when using deflate.
+  Deflate_FOUND          - True if deflate found.
+
+::
+
+  Deflate_VERSION_STRING - The version of deflate found (x.y.z)
+  Deflate_VERSION_MAJOR  - The major version of deflate
+  Deflate_VERSION_MINOR  - The minor version of deflate
+
+  Debug and Release variants are found separately.
+#]=======================================================================]
+
+# Standard names to search for
+set(Deflate_NAMES deflate deflatestatic)
+set(Deflate_NAMES_DEBUG deflated deflatestaticd)
+
+find_path(Deflate_INCLUDE_DIR
+          NAMES libdeflate.h
+          PATH_SUFFIXES include)
+
+set(Deflate_OLD_FIND_LIBRARY_PREFIXES "${CMAKE_FIND_LIBRARY_PREFIXES}")
+# Library has a "lib" prefix even on Windows.
+set(CMAKE_FIND_LIBRARY_PREFIXES "lib" "")
+
+# Allow Deflate_LIBRARY to be set manually, as the location of the deflate library
+if(NOT Deflate_LIBRARY)
+  find_library(Deflate_LIBRARY_RELEASE
+               NAMES ${Deflate_NAMES}
+               NAMES_PER_DIR
+               PATH_SUFFIXES lib)
+  find_library(Deflate_LIBRARY_DEBUG
+               NAMES ${Deflate_NAMES_DEBUG}
+               NAMES_PER_DIR
+               PATH_SUFFIXES lib)
+
+  include(SelectLibraryConfigurations)
+  select_library_configurations(Deflate)
+endif()
+
+set(CMAKE_FIND_LIBRARY_PREFIXES "${Deflate_OLD_FIND_LIBRARY_PREFIXES}")
+
+unset(Deflate_NAMES)
+unset(Deflate_NAMES_DEBUG)
+unset(Deflate_OLD_FIND_LIBRARY_PREFIXES)
+
+mark_as_advanced(Deflate_INCLUDE_DIR)
+
+if(Deflate_INCLUDE_DIR AND EXISTS "${Deflate_INCLUDE_DIR}/deflate.h")
+    file(STRINGS "${Deflate_INCLUDE_DIR}/libdeflate.h" Deflate_H REGEX "^#define LIBDEFLATE_VERSION_STRING\s+\"[^\"]*\"$")
+
+    string(REGEX REPLACE "^.*Deflate_VERSION \"([0-9]+).*$" "\\1" Deflate_MAJOR_VERSION "${Deflate_H}")
+    string(REGEX REPLACE "^.*Deflate_VERSION \"[0-9]+\\.([0-9]+).*$" "\\1" Deflate_MINOR_VERSION  "${Deflate_H}")
+    set(Deflate_VERSION_STRING "${Deflate_MAJOR_VERSION}.${Deflate_MINOR_VERSION}")
+
+    set(Deflate_MAJOR_VERSION "${Deflate_VERSION_MAJOR}")
+    set(Deflate_MINOR_VERSION "${Deflate_VERSION_MINOR}")
+endif()
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(Deflate
+        REQUIRED_VARS Deflate_LIBRARY Deflate_INCLUDE_DIR
+        VERSION_VAR Deflate_VERSION_STRING)
+
+if(Deflate_FOUND)
+    set(Deflate_INCLUDE_DIRS ${Deflate_INCLUDE_DIR})
+
+    if(NOT Deflate_LIBRARIES)
+        set(Deflate_LIBRARIES ${Deflate_LIBRARY})
+    endif()
+
+    if(NOT TARGET Deflate::Deflate)
+        add_library(Deflate::Deflate UNKNOWN IMPORTED)
+        set_target_properties(Deflate::Deflate PROPERTIES
+                INTERFACE_INCLUDE_DIRECTORIES "${Deflate_INCLUDE_DIRS}")
+
+        if(Deflate_LIBRARY_RELEASE)
+            set_property(TARGET Deflate::Deflate APPEND PROPERTY
+                    IMPORTED_CONFIGURATIONS RELEASE)
+            set_target_properties(Deflate::Deflate PROPERTIES
+                    IMPORTED_LOCATION_RELEASE "${Deflate_LIBRARY_RELEASE}")
+        endif()
+
+        if(Deflate_LIBRARY_DEBUG)
+            set_property(TARGET Deflate::Deflate APPEND PROPERTY
+                    IMPORTED_CONFIGURATIONS DEBUG)
+            set_target_properties(Deflate::Deflate PROPERTIES
+                    IMPORTED_LOCATION_DEBUG "${Deflate_LIBRARY_DEBUG}")
+        endif()
+    endif()
+endif()

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindECW.cmake

@@ -0,0 +1,172 @@
+###############################################################################
+# CMake module to search for ECW library - Enhanced Compression Wavelets for JPEG2000.
+#
+# Sets
+#   ECW_FOUND.  If false, don't try to use ecw
+#   ECW_INCLUDE_DIR
+#   ECW_LIBRARY
+#   ECW_VERSION
+#
+#   Imported target
+#   ECW::ECW_ALL
+#
+# Author:   Alexander Lisovenko, alexander.lisovenko@gmail.com
+# Author:   Dmitry Baryshnikov, bishop.dev@gmail.com, Hiroshi Miura
+# Copyright (C) 2016, NextGIS <info@nextgis.com>
+# Copyright (C) 2017,2018 Hiroshi Miura
+################################################################################
+
+if(NOT ECW_ROOT AND DEFINED ENV{ECW_ROOT})
+  set(ECW_ROOT "$ENV{ECW_ROOT}")
+endif()
+
+find_path(ECW_INCLUDE_DIR NCSECWClient.h)
+mark_as_advanced(ECW_INCLUDE_DIR)
+
+if (ECW_INCLUDE_DIR)
+    set(MAJOR_VERSION 0)
+    set(MINOR_VERSION 0)
+    set(SRV_VERSION 0)
+    set(BLD_VERSION 0)
+
+    if (EXISTS "${ECW_INCLUDE_DIR}/ECWJP2BuildNumber.h")
+        file(READ "${ECW_INCLUDE_DIR}/ECWJP2BuildNumber.h" VERSION_H_CONTENTS)
+        string(REGEX MATCH "_VER_MAJOR[ \t]+([0-9]+)" MAJOR_VERSION ${VERSION_H_CONTENTS})
+        string(REGEX MATCH "([0-9]+)" MAJOR_VERSION ${MAJOR_VERSION})
+        string(REGEX MATCH "_VER_MINOR[ \t]+([0-9]+)" MINOR_VERSION ${VERSION_H_CONTENTS})
+        string(REGEX MATCH "([0-9]+)" MINOR_VERSION ${MINOR_VERSION})
+        string(REGEX MATCH "_VER_SERVICE[ \t]+([0-9]+)" SRV_VERSION ${VERSION_H_CONTENTS})
+        string(REGEX MATCH "([0-9]+)" SRV_VERSION ${SRV_VERSION})
+        string(REGEX MATCH "_VER_SERVICE[ \t]+([0-9]+)" BLD_VERSION ${VERSION_H_CONTENTS})
+        string(REGEX MATCH "([0-9]+)" BLD_VERSION ${BLD_VERSION})
+        set(ECW_VERSION_STRING "${MAJOR_VERSION}.${MINOR_VERSION}")
+        unset(VERSION_H_CONTENTS)
+    endif()
+
+    if(EXISTS "${ECW_INCLUDE_DIR}/NCSBuildNumber.h")
+        file(READ "${ECW_INCLUDE_DIR}/NCSBuildNumber.h" VERSION_H_CONTENTS)
+        string(REGEX MATCH "NCS_VERSION_NUMBER[ \t]+([0-9,]+)" ECW_VERSION_NUMBER ${VERSION_H_CONTENTS})
+        string(REGEX MATCH "([0-9]+),[0-9]+,[0-9]+,[0-9]+" MAJOR_VERSION ${ECW_VERSION_NUMBER})
+        string(REGEX MATCH "[0-9]+,([0-9]+),[0-9]+,[0-9]+" MINOR_VERSION ${ECW_VERSION_NUMBER})
+        string(REGEX MATCH "[0-9]+,[0-9]+,([0-9]+),[0-9]+" SRV_VERSION ${ECW_VERSION_NUMBER})
+        string(REGEX MATCH "[0-9]+,[0-9]+,[0-9]+,([0-9]+)" BLD_VERSION ${ECW_VERSION_NUMBER})
+        string(REGEX REPLACE "," "." ECW_VERSION_STRING ${ECW_VERSION_NUMBER})
+        string(REGEX MATCH "NCS_ECWSDK_VERSION_NUMBER[ \t]+([0-9.]+)" ECWSDK_VERSION_NUMBER ${VERSION_H_CONTENTS})
+        unset(VERSION_H_CONTENTS)
+    endif()
+endif()
+
+include(FindPackageHandleStandardArgs)
+
+if (ECW_VERSION_STRING VERSION_GREATER_EQUAL 5.5)
+    if (WIN32)
+        if (CMAKE_SIZEOF_VOID_P EQUAL 4)
+            set(ECW_ARCH Win32)
+        else()
+            set(ECW_ARCH x64)
+        endif()
+    else()
+        if (CMAKE_SIZEOF_VOID_P EQUAL 4)
+            set(ECW_ARCH x86)
+        else()
+            set(ECW_ARCH x64)
+        endif()
+    endif()
+
+    find_library(ECW_LIBRARY NCSEcw
+                 HINTS ${ECW_ROOT}/lib/cpp11abi/${ECW_ARCH}/release
+                       ${ECW_ROOT}/lib/vc141/${ECW_ARCH})
+    mark_as_advanced(ECW_LIBRARY)
+    find_package_handle_standard_args(ECW
+                                      REQUIRED_VARS ECW_LIBRARY ECW_INCLUDE_DIR
+                                      VERSION_VAR ECW_VERSION_STRING)
+    if(ECW_FOUND)
+        set(ECW_LIBRARIES ${ECW_LIBRARY})
+        set(ECW_INCLUDE_DIRS ${ECW_INCLUDE_DIR})
+        if(NOT TARGET ECW::ECW_ALL)
+            add_library(ECW::ECW_ALL UNKNOWN IMPORTED)
+            set(ECW_INTERFACE_COMPILE_DEFINITIONS "HAVE_COMPRESS")
+            if( "${ECW_LIBRARY}" MATCHES "NCSEcwS" )
+                set(ECW_INTERFACE_COMPILE_DEFINITIONS "${ECW_INTERFACE_COMPILE_DEFINITIONS};NCSECW_STATIC_LIBS")
+            endif()
+            if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
+                list(APPEND ECW_EXTRA_LINK_LIBRARIES "-framework Foundation")
+            endif()
+            set_target_properties(ECW::ECW_ALL PROPERTIES
+                                INTERFACE_INCLUDE_DIRECTORIES "${ECW_INCLUDE_DIRS}"
+                                INTERFACE_COMPILE_DEFINITIONS "${ECW_INTERFACE_COMPILE_DEFINITIONS}"
+                                IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                                IMPORTED_LOCATION "${ECW_LIBRARY}"
+                                INTERFACE_LINK_LIBRARIES "${ECW_EXTRA_LINK_LIBRARIES}")
+        endif()
+    endif()
+elseif(ECW_VERSION_STRING VERSION_GREATER_EQUAL 4.0)
+    # We could likely handle other versions, but not done currently
+    message(FATAL_ERROR "Only ECW SDK 3.3 and >= 5.5 are supported")
+else()
+    find_library(ECWJ_LIBRARY libecwj2)
+    if(ECWJ_LIBRARY)
+        # ECW SDK 3.3 built by gisinternals
+        mark_as_advanced(ECWJ_LIBRARY)
+        find_package_handle_standard_args(ECW
+                                          REQUIRED_VARS ECWJ_LIBRARY ECW_INCLUDE_DIR
+                                          VERSION_VAR ECW_VERSION_STRING)
+        if(ECW_FOUND)
+            set(ECW_LIBRARIES ${ECWJ_LIBRARY})
+            set(ECW_INCLUDE_DIRS ${ECW_INCLUDE_DIR})
+            if(NOT TARGET ECW::ECW_ALL)
+                add_library(ECW::ECW_ALL UNKNOWN IMPORTED)
+                set_target_properties(ECW::ECW_ALL PROPERTIES
+                                    INTERFACE_INCLUDE_DIRECTORIES "${ECW_INCLUDE_DIRS}"
+                                    IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                                    INTERFACE_COMPILE_DEFINITIONS "${ECW_INTERFACE_COMPILE_DEFINITIONS}"
+                                    IMPORTED_LOCATION "${ECWJ_LIBRARY}")
+            endif()
+        endif()
+    else()
+        # Case of ECW SDK 3.3. We need to find extra libraries than the base NCSEcw.
+        find_library(ECW_LIBRARY NCSEcw)
+        find_library(ECWnet_LIBRARY NCSCnet)
+        find_library(ECWC_LIBRARY NCSEcwC)
+        find_library(NCSUtil_LIBRARY NCSUtil)
+        mark_as_advanced(ECW_LIBRARY ECWnet_LIBRARY ECWC_LIBRARY NCSUtil_LIBRARY)
+        find_package_handle_standard_args(ECW
+                                          REQUIRED_VARS ECW_LIBRARY ECWnet_LIBRARY ECWC_LIBRARY NCSUtil_LIBRARY ECW_INCLUDE_DIR
+                                          VERSION_VAR ECW_VERSION_STRING)
+        if(ECW_FOUND)
+            set(ECW_LIBRARIES ${ECW_LIBRARY} ${ECWnet_LIBRARY} ${ECWC_LIBRARY} ${NCSUtil_LIBRARY})
+            set(ECW_INCLUDE_DIRS ${ECW_INCLUDE_DIR})
+            if(NOT TARGET ECW::ECW)
+                add_library(ECW::ECW UNKNOWN IMPORTED)
+                set_target_properties(ECW::ECW PROPERTIES
+                                    INTERFACE_INCLUDE_DIRECTORIES "${ECW_INCLUDE_DIRS}"
+                                    IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                                    IMPORTED_LOCATION "${ECW_LIBRARY}")
+            endif()
+            if(NOT TARGET ECW::ECWC)
+                add_library(ECW::ECWC UNKNOWN IMPORTED)
+                set_target_properties(ECW::ECWC PROPERTIES
+                                      IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                                      IMPORTED_LOCATION "${ECWC_LIBRARY}")
+            endif()
+            if(NOT TARGET ECW::ECWnet)
+                add_library(ECW::ECWnet UNKNOWN IMPORTED)
+                set_target_properties(ECW::ECWnet PROPERTIES
+                                      IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                                      IMPORTED_LOCATION "${ECWnet_LIBRARY}")
+            endif()
+            if(NOT TARGET ECW::NCSUtil)
+                add_library(ECW::NCSUtil UNKNOWN IMPORTED)
+                set_target_properties(ECW::NCSUtil PROPERTIES
+                                      IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                                      IMPORTED_LOCATION "${NCSUtil_LIBRARY}")
+            endif()
+            if(NOT TARGET ECW::ECW_ALL)
+                add_library(ECW::ECW_ALL INTERFACE IMPORTED)
+                set_target_properties(ECW::ECW_ALL PROPERTIES
+                             INTERFACE_INCLUDE_DIRECTORIES "${ECW_INCLUDE_DIRS}"
+                             INTERFACE_LINK_LIBRARIES "ECW::ECW;ECW::ECWC;ECW::ECWnet;ECW::NCSUtil")
+            endif()
+        endif()
+    endif()
+endif()

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindEXPAT.cmake

@@ -0,0 +1,156 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindEXPAT
+---------
+
+Find the native Expat headers and library.
+Expat is a stream-oriented XML parser library written in C.
+
+Imported Targets
+^^^^^^^^^^^^^^^^
+
+.. versionadded:: 3.10
+
+This module defines the following :prop_tgt:`IMPORTED` targets:
+
+``EXPAT::EXPAT``
+  The Expat ``expat`` library, if found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module will set the following variables in your project:
+
+``EXPAT_INCLUDE_DIRS``
+  where to find expat.h, etc.
+``EXPAT_LIBRARIES``
+  the libraries to link against to use Expat.
+``EXPAT_FOUND``
+  true if the Expat headers and libraries were found.
+
+Hints
+^^^^^
+
+Set ``EXPAT_USE_STATIC_LIBS`` to ``TRUE`` to use static libraries.
+
+#]=======================================================================]
+
+find_package(PkgConfig QUIET)
+
+pkg_check_modules(PC_EXPAT QUIET expat)
+
+# Look for the header file.
+find_path(EXPAT_INCLUDE_DIR NAMES expat.h HINTS ${PC_EXPAT_INCLUDE_DIRS})
+
+set(EXPAT_NAMES expat expatw)
+set(EXPAT_NAMES_DEBUG expatd expatwd)
+
+if(WIN32)
+  if(EXPAT_USE_STATIC_LIBS)
+    list(APPEND EXPAT_NAMES expatMT expatwMT)
+    list(APPEND EXPAT_NAMES_DEBUG expatdMT expatwdMT)
+  else()
+    list(APPEND EXPAT_NAMES expatMT expatMD expatwMT expatwMD)
+    list(APPEND EXPAT_NAMES_DEBUG expatdMT expatdMD expatwdMT expatwdMD)
+  endif()
+endif()
+
+# Allow EXPAT_LIBRARY to be set manually, as the location of the expat library
+if(NOT EXPAT_LIBRARY)
+  if(DEFINED CMAKE_FIND_LIBRARY_PREFIXES)
+    set(_expat_ORIG_CMAKE_FIND_LIBRARY_PREFIXES "${CMAKE_FIND_LIBRARY_PREFIXES}")
+  else()
+    set(_expat_ORIG_CMAKE_FIND_LIBRARY_PREFIXES)
+  endif()
+
+  if(WIN32)
+    list(APPEND CMAKE_FIND_LIBRARY_PREFIXES "" "lib")
+  endif()
+
+  # Look for the library.
+  find_library(EXPAT_LIBRARY_RELEASE NAMES ${EXPAT_NAMES} NAMES_PER_DIR HINTS ${PC_EXPAT_LIBRARY_DIRS} PATH_SUFFIXES lib)
+  find_library(EXPAT_LIBRARY_DEBUG NAMES ${EXPAT_NAMES_DEBUG} NAMES_PER_DIR HINTS ${PC_EXPAT_LIBRARY_DIRS} PATH_SUFFIXES lib)
+
+  # Restore the original find library ordering
+  if(DEFINED _expat_ORIG_CMAKE_FIND_LIBRARY_PREFIXES)
+    set(CMAKE_FIND_LIBRARY_PREFIXES "${_expat_ORIG_CMAKE_FIND_LIBRARY_PREFIXES}")
+  else()
+    set(CMAKE_FIND_LIBRARY_PREFIXES)
+  endif()
+
+  #include(${CMAKE_CURRENT_LIST_DIR}/SelectLibraryConfigurations.cmake)
+  include(SelectLibraryConfigurations)
+  select_library_configurations(EXPAT)
+endif()
+
+unset(EXPAT_NAMES)
+unset(EXPAT_NAMES_DEBUG)
+
+if(EXPAT_INCLUDE_DIR AND EXISTS "${EXPAT_INCLUDE_DIR}/expat.h")
+  file(STRINGS "${EXPAT_INCLUDE_DIR}/expat.h" expat_version_str
+    REGEX "^#[\t ]*define[\t ]+XML_(MAJOR|MINOR|MICRO)_VERSION[\t ]+[0-9]+$")
+
+  unset(EXPAT_VERSION_STRING)
+  foreach(VPART MAJOR MINOR MICRO)
+    foreach(VLINE ${expat_version_str})
+      if(VLINE MATCHES "^#[\t ]*define[\t ]+XML_${VPART}_VERSION[\t ]+([0-9]+)$")
+        set(EXPAT_VERSION_PART "${CMAKE_MATCH_1}")
+        if(EXPAT_VERSION_STRING)
+          string(APPEND EXPAT_VERSION_STRING ".${EXPAT_VERSION_PART}")
+        else()
+          set(EXPAT_VERSION_STRING "${EXPAT_VERSION_PART}")
+        endif()
+      endif()
+    endforeach()
+  endforeach()
+endif()
+
+#include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(EXPAT
+                                  REQUIRED_VARS EXPAT_LIBRARY EXPAT_INCLUDE_DIR
+                                  VERSION_VAR EXPAT_VERSION_STRING)
+
+# Copy the results to the output variables and target.
+if(EXPAT_FOUND)
+  set(EXPAT_INCLUDE_DIRS ${EXPAT_INCLUDE_DIR})
+
+  if(NOT EXPAT_LIBRARIES)
+    set(EXPAT_LIBRARIES ${EXPAT_LIBRARY})
+  endif()
+
+  if(NOT TARGET EXPAT::EXPAT)
+    add_library(EXPAT::EXPAT UNKNOWN IMPORTED)
+    set_target_properties(EXPAT::EXPAT PROPERTIES
+      IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+      INTERFACE_INCLUDE_DIRECTORIES "${EXPAT_INCLUDE_DIRS}")
+
+    if(EXPAT_USE_STATIC_LIBS)
+      set_property(TARGET EXPAT::EXPAT APPEND PROPERTY
+                   INTERFACE_COMPILE_DEFINITIONS "XML_STATIC")
+    endif()
+
+    if(EXPAT_LIBRARY_RELEASE)
+      set_property(TARGET EXPAT::EXPAT APPEND PROPERTY
+        IMPORTED_CONFIGURATIONS RELEASE)
+      set_target_properties(EXPAT::EXPAT PROPERTIES
+        IMPORTED_LOCATION_RELEASE "${EXPAT_LIBRARY_RELEASE}")
+    endif()
+
+    if(EXPAT_LIBRARY_DEBUG)
+      set_property(TARGET EXPAT::EXPAT APPEND PROPERTY
+        IMPORTED_CONFIGURATIONS DEBUG)
+      set_target_properties(EXPAT::EXPAT PROPERTIES
+        IMPORTED_LOCATION_DEBUG "${EXPAT_LIBRARY_DEBUG}")
+    endif()
+
+    if(NOT EXPAT_LIBRARY_RELEASE AND NOT EXPAT_LIBRARY_DEBUG)
+      set_property(TARGET EXPAT::EXPAT APPEND PROPERTY
+        IMPORTED_LOCATION "${EXPAT_LIBRARY}")
+    endif()
+  endif()
+endif()
+
+mark_as_advanced(EXPAT_INCLUDE_DIR EXPAT_LIBRARY)

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindExprTk.cmake

@@ -0,0 +1,93 @@
+# /*=========================================================================
+#
+#   Program:   Visualization Toolkit
+#   Module:    Copyright.txt
+#
+# Copyright (c) 1993-2015 Ken Martin, Will Schroeder, Bill Lorensen
+# All rights reserved.
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions are met:
+#
+#  * Redistributions of source code must retain the above copyright notice,
+#    this list of conditions and the following disclaimer.
+#
+#  * Redistributions in binary form must reproduce the above copyright notice,
+#    this list of conditions and the following disclaimer in the documentation
+#    and/or other materials provided with the distribution.
+#
+#  * Neither name of Ken Martin, Will Schroeder, or Bill Lorensen nor the names
+#    of any contributors may be used to endorse or promote products derived
+#    from this software without specific prior written permission.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS ``AS IS''
+# AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+# IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+# ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHORS OR CONTRIBUTORS BE LIABLE FOR
+# ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+# DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
+# SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+# CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
+# OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+#
+# =========================================================================*/
+
+# - Try to find ExprTk lib
+#
+# This module supports requiring a minimum version, e.g. you can do
+#   find_package(ExprTk 2.7)
+# to require version 2.7 or newer of ExprTk.
+#
+# Once done this will define
+#
+#  ExprTk_FOUND - system has exprtk with correct version
+#  ExprTk_INCLUDE_DIRS - the exprtk include directory
+#  ExprTk_VERSION - exprtk version
+#
+# And the following imported target:
+#
+#  ExprTk::ExprTk
+
+find_path(ExprTk_INCLUDE_DIR
+  NAMES exprtk.hpp
+  DOC "Path to ExprTk header")
+mark_as_advanced(ExprTk_INCLUDE_DIR)
+
+if (ExprTk_INCLUDE_DIR)
+  file(STRINGS "${ExprTk_INCLUDE_DIR}/exprtk.hpp" _exprtk_version_header REGEX "\"[0-9.]+\"")
+  set(ExprTk_VERSION)
+  foreach (_exprtk_version_line IN LISTS _exprtk_version_header)
+    if ("${ExprTk_VERSION}" STREQUAL "")
+      string(REGEX MATCH [[version = "(2\.7[0-9.]+)".*$]] _exprtk_version_match "${_exprtk_version_line}")
+      set(ExprTk_VERSION "${CMAKE_MATCH_1}")
+    else ()
+      string(REGEX MATCH "\"([0-9.]+)\".*$" _exprtk_version_match "${_exprtk_version_line}")
+      set(ExprTk_VERSION "${ExprTk_VERSION}${CMAKE_MATCH_1}")
+    endif ()
+    if (_exprtk_version_match MATCHES "\;")
+      break()
+    endif ()
+  endforeach ()
+  if (NOT ExprTk_VERSION)
+    # fallback: version in exprtk.hpp has always started with 2.7
+    set(ExprTk_VERSION "2.7")
+  endif ()
+  unset(_exprtk_version_header)
+  unset(_exprtk_version_line)
+  unset(_exprtk_version_match)
+endif ()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(ExprTk
+  REQUIRED_VARS ExprTk_INCLUDE_DIR
+  VERSION_VAR ExprTk_VERSION)
+
+if (ExprTk_FOUND)
+  set(ExprTk_INCLUDE_DIRS "${ExprTk_INCLUDE_DIR}")
+  if (NOT TARGET ExprTk::ExprTk)
+    add_library(ExprTk::ExprTk INTERFACE IMPORTED)
+    set_target_properties(ExprTk::ExprTk PROPERTIES
+      INTERFACE_INCLUDE_DIRECTORIES "${ExprTk_INCLUDE_DIR}")
+  endif ()
+endif ()

package/dist/prebuilt/wasm-wasm32-st-release/lib/cmake/gdal/packages/FindFYBA.cmake

@@ -0,0 +1,38 @@
+# - Try to find the FYBA library
+#
+# Once done this will define
+#
+#  FYBA_FOUND - System has libgta
+#  FYBA_INCLUDE_DIR - The libgta include directory
+#  FYBA_LIBRARIES - The libraries needed to use libgta
+
+find_path(FYBA_INCLUDE_DIR
+          NAMES fyba.h
+          PATH_SUFFIXES fyba)
+find_library(FYBA_FYBA_LIBRARY NAMES fyba)
+find_library(FYBA_FYGM_LIBRARY NAMES fygm)
+find_library(FYBA_FYUT_LIBRARY NAMES fyut)
+mark_as_advanced(FYBA_INCLUDE_DIR FYBA_FYBA_LIBRARY FYBA_FYGM_LIBRARY FYBA_FYUT_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(FYBA
+                                  REQUIRED_VARS FYBA_FYBA_LIBRARY FYBA_FYGM_LIBRARY FYBA_FYUT_LIBRARY FYBA_INCLUDE_DIR)
+if(FYBA_FOUND)
+    set(FYBA_LIBRARIES "${FYBA_FYBA_LIBRARY}" "${FYBA_FYGM_LIBRARY}" "${FYBA_FYUT_LIBRARY}")
+    set(FYBA_INCLUDE_DIRS "${FYBA_INCLUDE_DIR}")
+    if(NOT TARGET FYBA::FYBA)
+        add_library(FYBA::FYBA UNKNOWN IMPORTED)
+        set_target_properties(FYBA::FYBA PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${FYBA_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES C
+                              IMPORTED_LOCATION "${FYBA_FYBA_LIBRARY}")
+        add_library(FYBA::FYGM UNKNOWN IMPORTED)
+        set_target_properties(FYBA::FYGM PROPERTIES
+                              IMPORTED_LINK_INTERFACE_LANGUAGES C
+                              IMPORTED_LOCATION "${FYBA_FYGM_LIBRARY}")
+        add_library(FYBA::FYUT UNKNOWN IMPORTED)
+        set_target_properties(FYBA::FYUT PROPERTIES
+                              IMPORTED_LINK_INTERFACE_LANGUAGES C
+                              IMPORTED_LOCATION "${FYBA_FYUT_LIBRARY}")
+    endif()
+endif()