@artblocks/contracts 1.3.2 → 1.4.0

package/contracts/web3call/combined-hooks/LiftHooks.sol

@@ -0,0 +1,304 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity 0.8.22;
+
+import {AbstractPMPAugmentHook} from "../augment-hooks/AbstractPMPAugmentHook.sol";
+import {AbstractPMPConfigureHook} from "../configure-hooks/AbstractPMPConfigureHook.sol";
+
+import {IWeb3Call} from "../../interfaces/v0.8.x/IWeb3Call.sol";
+import {IPMPV0} from "../../interfaces/v0.8.x/IPMPV0.sol";
+import {Strings} from "@openzeppelin-5.0/contracts/utils/Strings.sol";
+import {IERC721} from "@openzeppelin-5.0/contracts/interfaces/IERC721.sol";
+import {IDelegationRegistry as IDelegationRegistryV1} from "../../interfaces/v0.8.x/IDelegationRegistry.sol";
+import {IDelegateRegistry as IDelegationRegistryV2} from "../../interfaces/v0.8.x/IDelegateRegistry.sol";
+import {IPMPConfigureHook} from "../../interfaces/v0.8.x/IPMPConfigureHook.sol";
+import {IPMPAugmentHook} from "../../interfaces/v0.8.x/IPMPAugmentHook.sol";
+
+interface IGenArt721V0_Minimal {
+    function showTokenHashes(
+        uint256 _tokenId
+    ) external view returns (bytes32[] memory);
+}
+
+interface IRelic {
+    // Query the inscription list by address; returning true/false for whether that address has inscribed,
+    // and the number of squiggles under ownership (directly or through delegation)
+    function inscriptionByAddress(
+        address a
+    ) external view returns (bool inscribed, uint256 squiggle_count);
+}
+
+/**
+ * @title LiftHooks
+ * @author Art Blocks Inc.
+ * @notice This hook verifies ownership of any custom squiggle PostParam setting,
+ * and injects the squiggle's token hash into the token's PMPs if configured.
+ * It supports delegate.xyz V1 and V2, and also allows squiggle #9998 for any address that
+ * inscribed the squiggle Relic contract on eth mainnet.
+ * It also allows resetting the squiggle token back to default #1981.
+ * This hook contract has logic for both the augment and configure hooks.
+ * It reverts if the squiggle token id doesn't pass relic or ownership checks during configuring.
+ * Ownership checks are performed during configuring, keeping provenance history indexable and preventing
+ * effects intuitive during transfers and delegation revocations.
+ * If the squiggle token id is configured to be default #1981, the squiggle PostParams will
+ * be stripped, allowing the owner to effectively "clear" the squiggle-related PostParams back to default.
+ */
+contract LiftHooks is AbstractPMPAugmentHook, AbstractPMPConfigureHook {
+    using Strings for uint256;
+
+    address public immutable SQUIGGLE_GENART_V0_ADDRESS;
+    address public immutable RELIC_CONTRACT_ADDRESS;
+
+    IDelegationRegistryV1 public constant DELEGATE_V1 =
+        IDelegationRegistryV1(0x00000000000076A84feF008CDAbe6409d2FE638B);
+    IDelegationRegistryV2 public constant DELEGATE_V2 =
+        IDelegationRegistryV2(0x00000000000000447e69651d841bD8D104Bed493);
+    bytes32 public constant DELEGATION_REGISTRY_TOKEN_OWNER_RIGHTS =
+        bytes32("postmintparameters");
+
+    uint256 public constant FINAL_SQUIGGLE_TOKEN_ID = 9998;
+    uint256 public constant DEFAULT_SQUIGGLE_TOKEN_ID = 1981;
+    bytes32 internal constant _HASHED_KEY_SPLASH_SCREEN_SQUIGGLE =
+        keccak256("Splash Screen Squiggle (ROM)");
+
+    /**
+     * @notice Constructor
+     * @param _squiggleGenArtV0Address The address of the squiggle GenArt V0 contract.
+     * For mainnet, use 0x059EDD72Cd353dF5106D2B9cC5ab83a52287aC3a.
+     * @param _relicContractAddress The address of the relic contract.
+     * For mainnet, use 0x9b917686DD68B68A780cB8Bf70aF46617A7b3f80.
+     */
+    constructor(
+        address _squiggleGenArtV0Address,
+        address _relicContractAddress
+    ) {
+        SQUIGGLE_GENART_V0_ADDRESS = _squiggleGenArtV0Address;
+        RELIC_CONTRACT_ADDRESS = _relicContractAddress;
+    }
+
+    /**
+     * @notice Execution logic to be executed when a token's PMP is configured.
+     * Reverts if the squiggle token id is invalid or the liftOwner does not have access to the squiggle token id.
+     * @dev This hook is executed after the PMP is configured.
+     * @param coreContract The address of the core contract that was configured.
+     * @param tokenId The tokenId of the token that was configured.
+     * @param pmpInput The PMP input that was used to successfully configure the token.
+     */
+    function onTokenPMPConfigure(
+        address coreContract,
+        uint256 tokenId,
+        IPMPV0.PMPInput calldata pmpInput
+    ) external view override {
+        // only verify ownership if the squiggle token id is being configured
+        if (
+            keccak256(bytes(pmpInput.key)) == _HASHED_KEY_SPLASH_SCREEN_SQUIGGLE
+        ) {
+            // @dev can assume squiggle token id is configured as a uint256, so will show up as configuredValue
+            uint256 squiggleTokenId = uint256(pmpInput.configuredValue);
+
+            // @dev only allow squiggle token ids up to FINAL_SQUIGGLE_TOKEN_ID
+            // @dev no coverage - redundant check due to operationally enforced range check in PMPV0.sol
+            require(
+                squiggleTokenId <= FINAL_SQUIGGLE_TOKEN_ID,
+                "Invalid squiggle token id"
+            );
+
+            // perform ownership checks if not default squiggle
+            if (squiggleTokenId != DEFAULT_SQUIGGLE_TOKEN_ID) {
+                address liftOwner = IERC721(coreContract).ownerOf(tokenId);
+
+                require(
+                    passesSquiggleAccessCheck({
+                        squiggleTokenId: squiggleTokenId,
+                        liftOwner: liftOwner
+                    }),
+                    "Failed squiggle access check"
+                );
+            }
+        }
+    }
+
+    /**
+     * @notice Augment the token parameters for a given token.
+     * Augments the token parameters as described in the contract natspec doc.
+     * @dev This hook is called when a token's PMPs are read.
+     * @dev This must return all desired tokenParams, not just additional data.
+     * @param tokenParams The token parameters for the queried token.
+     * @return augmentedTokenParams The augmented token parameters.
+     */
+    function onTokenPMPReadAugmentation(
+        address /* coreContract */,
+        uint256 /* tokenId */,
+        IWeb3Call.TokenParam[] calldata tokenParams
+    )
+        external
+        view
+        override
+        returns (IWeb3Call.TokenParam[] memory augmentedTokenParams)
+    {
+        // create a new augmentedTokenParams array with maximum length of
+        // input tokenParams + 1 extra element for the squiggle's token hash
+        uint256 originalLength = tokenParams.length;
+        uint256 augmentedMaxLength = originalLength + 1;
+        augmentedTokenParams = new IWeb3Call.TokenParam[](augmentedMaxLength);
+
+        // allocate squiggle token id to a variable (may or may not be configured)
+        uint256 squiggleTokenId = DEFAULT_SQUIGGLE_TOKEN_ID; // default squiggle
+
+        // copy the original tokenParams into the new array, skipping the squiggle token id
+        uint256 j = 0;
+        for (uint256 i = 0; i < originalLength; i++) {
+            if (
+                keccak256(bytes(tokenParams[i].key)) ==
+                _HASHED_KEY_SPLASH_SCREEN_SQUIGGLE
+            ) {
+                squiggleTokenId = parseUint(tokenParams[i].value);
+                // skip the squiggle token id and assign later if appropriate
+                continue;
+            } else {
+                augmentedTokenParams[j++] = tokenParams[i];
+            }
+        }
+
+        // if the squiggle token id is default squiggle token id, return the stripped tokenParams
+        if (squiggleTokenId == DEFAULT_SQUIGGLE_TOKEN_ID) {
+            // shorten the new array to length of j
+            assembly {
+                mstore(augmentedTokenParams, j)
+            }
+            return augmentedTokenParams;
+        }
+
+        // @dev intentionally do not perform ownership checks during read augmentation
+        // this keeps provenance history indexable, and prevents effects intuitive during transfers and delegation revocations
+
+        // ownership was passed, so we can inject the squiggle's token hash into the new array
+        // @dev okay to assume squiggle exists since all squiggles are minted, passed previous checks
+        bytes32 squiggleTokenHash = IGenArt721V0_Minimal(
+            SQUIGGLE_GENART_V0_ADDRESS
+        ).showTokenHashes(squiggleTokenId)[0];
+
+        // inject the squiggles ID and hash into the new array
+        augmentedTokenParams[j++] = IWeb3Call.TokenParam({
+            key: "Splash Screen Squiggle (ROM)",
+            value: squiggleTokenId.toString()
+        });
+        augmentedTokenParams[j] = IWeb3Call.TokenParam({
+            key: "Splash Screen Squiggle Hash",
+            value: uint256(squiggleTokenHash).toHexString()
+        });
+
+        // @dev no need to reduce the array length, since we guaranteed to be max length in this case
+
+        // return the augmented tokenParams
+        return augmentedTokenParams;
+    }
+
+    function supportsInterface(
+        bytes4 interfaceId
+    )
+        public
+        view
+        override(AbstractPMPAugmentHook, AbstractPMPConfigureHook)
+        returns (bool)
+    {
+        return
+            interfaceId == type(IPMPAugmentHook).interfaceId ||
+            interfaceId == type(IPMPConfigureHook).interfaceId ||
+            super.supportsInterface(interfaceId);
+    }
+
+    /**
+     * @notice Checks if the liftOwner has access to the squiggle token id.
+     * @dev This function is used to check if the liftOwner has access to the squiggle token id.
+     * @param squiggleTokenId The token id of the squiggle to check access for.
+     * @param liftOwner The address of the lift owner to check access for.
+     * @return bool True if the liftOwner has access to the squiggle token id, false otherwise.
+     */
+    function passesSquiggleAccessCheck(
+        uint256 squiggleTokenId,
+        address liftOwner
+    ) internal view returns (bool) {
+        return
+            passesRelicCheck(squiggleTokenId, liftOwner) ||
+            isOwnerOrDelegate(squiggleTokenId, liftOwner);
+    }
+
+    /**
+     * @notice Checks if the liftOwner is configuring squiggle 9998.
+     * If so, it verifies that the liftOwner is inscribed in the relic contract.
+     * @param squiggleTokenId The token id of the squiggle to check access for.
+     * @param liftOwner The address of the lift owner to check access for.
+     * @return bool True if the liftOwner is configuring squiggle 9998 and is
+     * inscribed in the relic contract, false otherwise.
+     */
+    function passesRelicCheck(
+        uint256 squiggleTokenId,
+        address liftOwner
+    ) internal view returns (bool) {
+        if (squiggleTokenId == FINAL_SQUIGGLE_TOKEN_ID) {
+            // verify token owner inscribed relic contract
+            (bool inscribed, ) = IRelic(RELIC_CONTRACT_ADDRESS)
+                .inscriptionByAddress(liftOwner);
+            return inscribed;
+        }
+        return false;
+    }
+
+    /**
+     * @notice Checks if the liftOwner is the owner of the squiggle token id or
+     * a delegate of the vault that owns the squiggle token id.
+     * Supports delegate.xyz V1 and V2.
+     * @param squiggleTokenId The token id of the squiggle to check access for.
+     * @param liftOwner The address of the lift owner to check access for.
+     * @return bool True if the liftOwner is the owner of the squiggle token id or
+     * a delegate of the squiggle token id, false otherwise.
+     */
+    function isOwnerOrDelegate(
+        uint256 squiggleTokenId,
+        address liftOwner
+    ) internal view returns (bool) {
+        address squiggleOwner = IERC721(SQUIGGLE_GENART_V0_ADDRESS).ownerOf(
+            squiggleTokenId
+        );
+
+        // if the owner is the same, return true
+        if (squiggleOwner == liftOwner) {
+            return true;
+        }
+
+        // if the liftOwner is delegate of vault that owns squiggle(delegate.xyz V1 or V2), return true
+        // @dev on v2, allow subdelegation rights consistent with PMPV0.sol
+        return
+            DELEGATE_V1.checkDelegateForToken({
+                delegate: liftOwner,
+                vault: squiggleOwner,
+                contract_: SQUIGGLE_GENART_V0_ADDRESS,
+                tokenId: squiggleTokenId
+            }) ||
+            DELEGATE_V2.checkDelegateForERC721({
+                to: liftOwner,
+                from: squiggleOwner,
+                contract_: SQUIGGLE_GENART_V0_ADDRESS,
+                tokenId: squiggleTokenId,
+                rights: DELEGATION_REGISTRY_TOKEN_OWNER_RIGHTS
+            });
+    }
+
+    /**
+     * @notice Parses a string into a uint256.
+     * @dev This function is used to parse a string into a uint256.
+     * @param s The string to parse.
+     * @return result The parsed uint256.
+     */
+    function parseUint(string memory s) internal pure returns (uint256 result) {
+        bytes memory b = bytes(s);
+        for (uint i = 0; i < b.length; i++) {
+            // Require each character to be 0-9
+            // @dev no coverage - operationally redundant check due to operationally enforced range check in PMPV0.sol
+            require(b[i] >= 0x30 && b[i] <= 0x39, "Invalid character");
+            result = result * 10 + (uint8(b[i]) - 48);
+        }
+    }
+}

package/contracts/web3call/configure-hooks/{abstractPMPConfigureHook.sol → AbstractPMPConfigureHook.sol}

@@ -33,7 +33,7 @@ abstract contract AbstractPMPConfigureHook is IPMPConfigureHook, ERC165 {
 
     function supportsInterface(
         bytes4 interfaceId
-    ) public view override(ERC165, IERC165) returns (bool) {
+    ) public view virtual override(ERC165, IERC165) returns (bool) {
         return
             interfaceId == type(IPMPConfigureHook).interfaceId ||
             super.supportsInterface(interfaceId);

package/contracts/web3call/configure-hooks/PMPConfigureLockHook.sol

@@ -0,0 +1,107 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity 0.8.22;
+
+import {AbstractPMPConfigureHook} from "./AbstractPMPConfigureHook.sol";
+
+import {IPMPV0} from "../../interfaces/v0.8.x/IPMPV0.sol";
+
+/**
+ * @title PMPConfigureLockHook
+ * @author Art Blocks Inc.
+ * @notice A generic post-configuration hook that enforces per-parameter value locks on a
+ * PMPV0 project. For each configured key, an artist-chosen lock timestamp may be set; once
+ * that timestamp has passed, any attempt to configure that parameter's value on any token
+ * reverts, rolling back the collector's (or artist's) entire configureTokenParams()
+ * transaction.
+ *
+ * ── Why this exists ──────────────────────────────────────────────────────────
+ * PMPV0 interprets `pmpLockedAfterTimestamp` only as a *configuration* lock (it prevents
+ * the artist from re-configuring the parameter definition after the timestamp). It does NOT
+ * prevent token owners from continuing to write *values* after the timestamp. The Art Blocks
+ * Creator Dashboard advertises the Lock Date as cementing values permanently, so this hook
+ * patches the gap for existing PMPV0 projects by reverting value writes after the lock date.
+ * PMPV1 enforces this natively; this hook is intended for projects already deployed on PMPV0.
+ *
+ * ── Scope ────────────────────────────────────────────────────────────────────
+ * This hook is stateless after construction and has no side effects — it only reverts. It is
+ * intended to be registered for a single project via PMPV0.configureProjectHooks(). Keys not
+ * present in the lock table are always allowed (the hook is a no-op for them). A lock
+ * timestamp is matched to the same instant PMPV0 uses for its config lock: a value write is
+ * allowed while `block.timestamp < lockedAfter`, and reverts once `block.timestamp >=
+ * lockedAfter`. The lock timestamps supplied at construction should exactly match each key's
+ * `pmpLockedAfterTimestamp` in the project's PMPV0 configuration.
+ *
+ * ── Residual trust ───────────────────────────────────────────────────────────
+ * A hook-based lock only holds while this hook remains registered. PMPV0.configureProjectHooks()
+ * is not itself gated by `pmpLockedAfterTimestamp`, so the project artist could later unregister
+ * this hook and re-enable value writes. This is acceptable for the artist's own project but is
+ * a weaker guarantee than PMPV1's native value lock.
+ */
+contract PMPConfigureLockHook is AbstractPMPConfigureHook {
+    /// @notice Per-key lock timestamp. keccak256(bytes(key)) => unix timestamp after which
+    /// (inclusive) the key's value is locked. A value of 0 means the key is not locked by
+    /// this hook.
+    mapping(bytes32 keyHash => uint256 lockedAfterTimestamp) public lockedAfter;
+
+    /// @notice The keys locked by this hook, in construction order (for introspection).
+    string[] public lockedKeys;
+
+    error ParamLocked(string key, uint256 lockedAfterTimestamp);
+    error EmptyConfig();
+    error LengthMismatch();
+    error ZeroTimestamp(string key);
+    error DuplicateKey(string key);
+
+    /**
+     * @notice Constructor.
+     * @param keys The parameter keys to lock. Should match the project's PMPV0 param keys.
+     * @param timestamps The unix timestamp for each key, aligned by index, after which
+     * (inclusive) the key's value is locked. Each must be non-zero and should match the
+     * corresponding key's `pmpLockedAfterTimestamp` in the project's PMPV0 configuration.
+     */
+    constructor(string[] memory keys, uint256[] memory timestamps) {
+        uint256 keysLength = keys.length;
+        if (keysLength == 0) revert EmptyConfig();
+        if (keysLength != timestamps.length) revert LengthMismatch();
+        for (uint256 i = 0; i < keysLength; i++) {
+            if (timestamps[i] == 0) revert ZeroTimestamp(keys[i]);
+            bytes32 keyHash = keccak256(bytes(keys[i]));
+            // @dev reject duplicate keys to avoid silent override of a lock timestamp
+            if (lockedAfter[keyHash] != 0) revert DuplicateKey(keys[i]);
+            lockedAfter[keyHash] = timestamps[i];
+            lockedKeys.push(keys[i]);
+        }
+    }
+
+    /**
+     * @notice Post-configuration hook executed by PMPV0 after a token's PMP is configured.
+     * Reverts if the configured key is locked and its lock timestamp has passed, which rolls
+     * back the entire configureTokenParams() transaction.
+     * @dev Stateless and side-effect free; safe to be called by any address.
+     * @param pmpInput The PMP input that was used to configure the token.
+     */
+    function onTokenPMPConfigure(
+        address /* coreContract */,
+        uint256 /* tokenId */,
+        IPMPV0.PMPInput calldata pmpInput
+    ) external view override {
+        uint256 lockedAfterTimestamp = lockedAfter[
+            keccak256(bytes(pmpInput.key))
+        ];
+        // @dev keys not in the lock table (lockedAfterTimestamp == 0) are always allowed
+        if (
+            lockedAfterTimestamp != 0 && block.timestamp >= lockedAfterTimestamp
+        ) {
+            revert ParamLocked(pmpInput.key, lockedAfterTimestamp);
+        }
+    }
+
+    /**
+     * @notice Returns the number of keys locked by this hook.
+     */
+    function lockedKeysLength() external view returns (uint256) {
+        return lockedKeys.length;
+    }
+}

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "@artblocks/contracts",
-  "version": "1.3.2",
+  "version": "1.4.0",
   "description": "Smart contracts used by Art Blocks",
   "files": [
     "/contracts/**/*.sol",
@@ -21,58 +21,63 @@
     "remix": "remixd -s ./ --remix-ide https://remix.ethereum.org",
     "codegen": "yarn --cwd=\"../..\" codegen:project contracts",
     "get-init-code": "yarn hardhat run --network sepolia scripts/get-init-code.ts",
+    "create2-deploy": "hardhat compile && hardhat run scripts/create2-deploy/index.ts",
     "verify": "yarn hardhat run scripts/verify.ts --network",
     "deploy:v3-engine:dev": "yarn codegen && yarn require-low-gas sepolia && NODE_ENV=dev yarn hardhat run --network sepolia scripts/engine/V3/batch-create-engine-contracts.ts",
-    "deploy:v3-engine:dev-arbitrum": "yarn codegen && yarn require-low-gas arbitrum-sepolia && NODE_ENV=arbitrum-dev yarn hardhat run --network arbitrum-sepolia scripts/engine/V3/batch-create-engine-contracts.ts",
-    "deploy:v3-engine:staging-arbitrum": "yarn codegen && yarn require-low-gas arbitrum-sepolia && NODE_ENV=arbitrum-staging yarn hardhat run --network arbitrum-sepolia scripts/engine/V3/batch-create-engine-contracts.ts",
-    "deploy:v3-engine:arbitrum": "yarn codegen && yarn require-low-gas arbitrum && NODE_ENV=arbitrum yarn hardhat run --network arbitrum scripts/engine/V3/batch-create-engine-contracts.ts",
-    "deploy:v3-engine:base": "yarn codegen && yarn require-low-gas base && NODE_ENV=base yarn hardhat run --network base scripts/engine/V3/batch-create-engine-contracts.ts",
+    "deploy:v3-engine:dev:txbuilder": "yarn codegen && yarn require-low-gas sepolia && NODE_ENV=dev EXPORT_TX_BUILDER=true yarn hardhat run --network sepolia scripts/engine/V3/batch-create-engine-contracts.ts",
     "deploy:v3-engine:staging": "yarn codegen && yarn require-low-gas sepolia && NODE_ENV=staging yarn hardhat run --network sepolia scripts/engine/V3/batch-create-engine-contracts.ts",
-    "deploy:v3-engine:mainnet": "yarn codegen && yarn require-low-gas mainnet && NODE_ENV=mainnet yarn hardhat run --network mainnet scripts/engine/V3/batch-create-engine-contracts.ts",
+    "deploy:v3-engine:staging:txbuilder": "yarn codegen && yarn require-low-gas sepolia && NODE_ENV=staging EXPORT_TX_BUILDER=true yarn hardhat run --network sepolia scripts/engine/V3/batch-create-engine-contracts.ts",
+    "deploy:v3-engine:mainnet": "yarn codegen && yarn require-low-gas mainnet && NODE_ENV=prod yarn hardhat run --network mainnet scripts/engine/V3/batch-create-engine-contracts.ts",
+    "deploy:v3-engine:mainnet:txbuilder": "yarn require-low-gas mainnet && NODE_ENV=prod EXPORT_TX_BUILDER=true yarn hardhat run --network mainnet scripts/engine/V3/batch-create-engine-contracts.ts",
+    "deploy:v3-engine:arbitrum": "yarn codegen && yarn require-low-gas arbitrum && NODE_ENV=prod yarn hardhat run --network arbitrum scripts/engine/V3/batch-create-engine-contracts.ts",
+    "deploy:v3-engine:arbitrum:txbuilder": "yarn codegen && yarn require-low-gas arbitrum && NODE_ENV=prod EXPORT_TX_BUILDER=true yarn hardhat run --network arbitrum scripts/engine/V3/batch-create-engine-contracts.ts",
+    "deploy:v3-engine:base": "yarn codegen && yarn require-low-gas base && NODE_ENV=prod yarn hardhat run --network base scripts/engine/V3/batch-create-engine-contracts.ts",
+    "deploy:v3-engine:base:txbuilder": "yarn codegen && yarn require-low-gas base && NODE_ENV=prod EXPORT_TX_BUILDER=true yarn hardhat run --network base scripts/engine/V3/batch-create-engine-contracts.ts",
+    "deploy:v3-engine:shape:txbuilder": "yarn codegen && yarn require-low-gas shape && NODE_ENV=prod EXPORT_TX_BUILDER=true yarn hardhat run --network shape scripts/engine/V3/batch-create-engine-contracts.ts",
     "post-deploy:v3-engine:dev": "yarn codegen && yarn require-low-gas sepolia && NODE_ENV=dev yarn hardhat run --network sepolia scripts/engine/V3/post-batch-create-engine-contracts.ts",
-    "post-deploy:v3-engine:dev-arbitrum": "yarn codegen && yarn require-low-gas arbitrum-sepolia && NODE_ENV=arbitrum-dev yarn hardhat run --network arbitrum-sepolia scripts/engine/V3/post-batch-create-engine-contracts.ts",
-    "post-deploy:v3-engine:staging-arbitrum": "yarn codegen && yarn require-low-gas arbitrum-sepolia && NODE_ENV=arbitrum-staging yarn hardhat run --network arbitrum-sepolia scripts/engine/V3/post-batch-create-engine-contracts.ts",
-    "post-deploy:v3-engine:arbitrum": "yarn codegen && yarn require-low-gas arbitrum && NODE_ENV=arbitrum yarn hardhat run --network arbitrum scripts/engine/V3/post-batch-create-engine-contracts.ts",
-    "post-deploy:v3-engine:base": "yarn codegen && yarn require-low-gas base && NODE_ENV=base yarn hardhat run --network base scripts/engine/V3/post-batch-create-engine-contracts.ts",
     "post-deploy:v3-engine:staging": "yarn codegen && yarn require-low-gas sepolia && NODE_ENV=staging yarn hardhat run --network sepolia scripts/engine/V3/post-batch-create-engine-contracts.ts",
-    "post-deploy:v3-engine:mainnet": "yarn codegen && yarn require-low-gas mainnet && NODE_ENV=mainnet yarn hardhat run --network mainnet scripts/engine/V3/post-batch-create-engine-contracts.ts",
+    "post-deploy:v3-engine:mainnet": "yarn codegen && yarn require-low-gas mainnet && NODE_ENV=prod yarn hardhat run --network mainnet scripts/engine/V3/post-batch-create-engine-contracts.ts",
+    "post-deploy:v3-engine:arbitrum": "yarn codegen && yarn require-low-gas arbitrum && NODE_ENV=prod yarn hardhat run --network arbitrum scripts/engine/V3/post-batch-create-engine-contracts.ts",
+    "post-deploy:v3-engine:base": "yarn codegen && yarn require-low-gas base && NODE_ENV=prod yarn hardhat run --network base scripts/engine/V3/post-batch-create-engine-contracts.ts",
+    "post-deploy:v3-engine:shape": "yarn codegen && yarn require-low-gas shape && NODE_ENV=prod yarn hardhat run --network shape scripts/engine/V3/post-batch-create-engine-contracts.ts",
     "deploy:shared-randomizer:goerli": "yarn require-low-gas goerli && yarn hardhat run --network goerli scripts/randomizer-deployments/shared-randomizer-deployer.ts",
     "deploy:shared-randomizer:dev-sepolia": "yarn require-low-gas sepolia && NODE_ENV=dev yarn hardhat run --network sepolia scripts/randomizer-deployments/shared-randomizer-deployer.ts",
     "deploy:shared-randomizer:mainnet": "yarn require-low-gas mainnet && yarn hardhat run --network mainnet scripts/randomizer-deployments/shared-randomizer-deployer.ts",
     "deploy:shared-randomizer:arbitrum-goerli": "yarn require-low-gas arbitrum-goerli && yarn hardhat run --network arbitrum-goerli scripts/randomizer-deployments/shared-randomizer-deployer.ts",
     "deploy:shared-randomizer:arbitrum": "yarn require-low-gas arbitrum && yarn hardhat run --network arbitrum scripts/randomizer-deployments/shared-randomizer-deployer.ts",
     "deploy:shared-randomizer:base": "yarn require-low-gas base && yarn hardhat run --network base scripts/randomizer-deployments/shared-randomizer-deployer.ts",
+    "deploy:shared-randomizer:shape": "yarn require-low-gas shape && yarn hardhat run --network shape scripts/randomizer-deployments/shared-randomizer-deployer.ts",
     "deploy:shared-minter-filter:goerli": "yarn require-low-gas goerli && yarn hardhat run --network goerli scripts/minter-filter-deployments/shared-minter-filter-deployer.ts",
     "deploy:shared-minter-filter:dev-sepolia": "yarn require-low-gas sepolia && NODE_ENV=dev yarn hardhat run --network sepolia scripts/minter-filter-deployments/shared-minter-filter-deployer.ts",
     "deploy:shared-minter-filter:mainnet": "yarn require-low-gas mainnet && yarn hardhat run --network mainnet scripts/minter-filter-deployments/shared-minter-filter-deployer.ts",
     "deploy:shared-minter-filter:arbitrum-goerli": "yarn require-low-gas arbitrum-goerli && yarn hardhat run --network arbitrum-goerli scripts/minter-filter-deployments/shared-minter-filter-deployer.ts",
     "deploy:shared-minter-filter:arbitrum": "yarn require-low-gas arbitrum && yarn hardhat run --network arbitrum scripts/minter-filter-deployments/shared-minter-filter-deployer.ts",
     "deploy:shared-minter-filter:base": "yarn require-low-gas base && yarn hardhat run --network base scripts/minter-filter-deployments/shared-minter-filter-deployer.ts",
+    "deploy:shared-minter-filter:shape": "yarn require-low-gas shape && yarn hardhat run --network shape scripts/minter-filter-deployments/shared-minter-filter-deployer.ts",
     "deploy:shared-minters:goerli": "yarn require-low-gas goerli && yarn hardhat run --network goerli scripts/minter-deployments/shared-minters-deployer.ts",
     "deploy:shared-minters:sepolia": "yarn require-low-gas sepolia && yarn hardhat run --network sepolia scripts/minter-deployments/shared-minters-deployer.ts",
     "deploy:shared-minters:mainnet": "yarn require-low-gas mainnet && yarn hardhat run --network mainnet scripts/minter-deployments/shared-minters-deployer.ts",
     "deploy:shared-minters:arbitrum-goerli": "yarn require-low-gas arbitrum-goerli && yarn hardhat run --network arbitrum-goerli scripts/minter-deployments/shared-minters-deployer.ts",
     "deploy:shared-minters:arbitrum": "yarn require-low-gas arbitrum && yarn hardhat run --network arbitrum scripts/minter-deployments/shared-minters-deployer.ts",
     "deploy:shared-minters:base": "yarn require-low-gas base && yarn hardhat run --network base scripts/minter-deployments/shared-minters-deployer.ts",
+    "deploy:shared-minters:shape": "yarn require-low-gas shape && yarn hardhat run --network shape scripts/minter-deployments/shared-minters-deployer.ts",
     "deploy:splits-factory:dev": "yarn require-low-gas sepolia && NODE_ENV=dev yarn hardhat run --network sepolia scripts/splits/splits-factory-deployer.ts",
     "deploy:splits-factory:staging": "yarn require-low-gas sepolia && NODE_ENV=staging yarn hardhat run --network sepolia scripts/splits/splits-factory-deployer.ts",
-    "deploy:splits-factory:mainnet": "yarn require-low-gas mainnet && NODE_ENV=mainnet yarn hardhat run --network mainnet scripts/splits/splits-factory-deployer.ts",
+    "deploy:splits-factory:mainnet": "yarn require-low-gas mainnet && NODE_ENV=prod yarn hardhat run --network mainnet scripts/splits/splits-factory-deployer.ts",
     "deploy:core-registry:dev-sepolia": "yarn require-low-gas sepolia && NODE_ENV=dev yarn hardhat run --network sepolia scripts/core-registry-deployments/core-registry-deployer.ts",
-    "dependency-registry:upload-script:mainnet": "NODE_ENV=mainnet yarn hardhat run --network mainnet ./scripts/propose-add-dependency-script-transactions.ts",
+    "dependency-registry:upload-script:mainnet": "NODE_ENV=prod yarn hardhat run --network mainnet ./scripts/propose-add-dependency-script-transactions.ts",
     "require-low-gas": "yarn hardhat run scripts/require-low-gas.ts --network",
     "pre-commit": "yarn lint",
-    "deploy:deprecated:mainnet:v3-engine-shared": "yarn codegen && yarn require-low-gas mainnet && NODE_ENV=mainnet yarn hardhat run --network mainnet scripts/engine/V3/generic-engine-shared-suite-deployer.ts",
+    "deploy:deprecated:mainnet:v3-engine-shared": "yarn codegen && yarn require-low-gas mainnet && NODE_ENV=prod yarn hardhat run --network mainnet scripts/engine/V3/generic-engine-shared-suite-deployer.ts",
     "deploy:deprecated:dev:v3-engine": "yarn codegen && yarn require-low-gas goerli && NODE_ENV=dev yarn hardhat run --network goerli scripts/engine/V3/deprecated/generic-engine-deployer.ts",
     "deploy:deprecated:staging:v3-engine": "yarn codegen && yarn require-low-gas goerli && NODE_ENV=staging yarn hardhat run --network goerli scripts/engine/V3/deprecated/generic-engine-deployer.ts",
-    "deploy:deprecated:dev-arbitrum:v3-engine": "yarn codegen && yarn require-low-gas arbitrum-goerli && NODE_ENV=arbitrum-dev yarn hardhat run --network arbitrum-goerli scripts/engine/V3/deprecated/generic-engine-deployer.ts",
-    "deploy:deprecated:staging-arbitrum:v3-engine": "yarn codegen && yarn require-low-gas arbitrum-goerli && NODE_ENV=arbitrum-staging yarn hardhat run --network arbitrum-goerli scripts/engine/V3/deprecated/generic-engine-deployer.ts",
-    "deploy:deprecated:arbitrum:v3-engine": "yarn codegen && yarn require-low-gas arbitrum && NODE_ENV=arbitrum yarn hardhat run --network arbitrum scripts/engine/V3/deprecated/generic-engine-deployer.ts",
-    "deploy:deprecated:mainnet:v3-engine": "yarn codegen && yarn require-low-gas mainnet && NODE_ENV=mainnet yarn hardhat run --network mainnet scripts/engine/V3/deprecated/generic-engine-deployer.ts",
+    "deploy:deprecated:arbitrum:v3-engine": "yarn codegen && yarn require-low-gas arbitrum && NODE_ENV=prod yarn hardhat run --network arbitrum scripts/engine/V3/deprecated/generic-engine-deployer.ts",
+    "deploy:deprecated:mainnet:v3-engine": "yarn codegen && yarn require-low-gas mainnet && NODE_ENV=prod yarn hardhat run --network mainnet scripts/engine/V3/deprecated/generic-engine-deployer.ts",
     "deploy:deprecated:goerli:non-shared-minter": "yarn require-low-gas goerli && yarn hardhat run --network goerli scripts/minter-deployments/V3/generic-minter-deployer-v3core.ts",
     "deploy:deprecated:mainnet:non-shared-minter": "yarn require-low-gas mainnet && yarn hardhat run --network mainnet scripts/minter-deployments/V3/generic-minter-deployer-v3core.ts"
   },
   "devDependencies": {
-    "@aws-sdk/client-s3": "^3.596.0",
+    "@aws-sdk/client-s3": "^3.943.0",
     "@aws-sdk/credential-providers": "^3.651.1",
     "@defi-wonderland/smock": "^2.4.0",
     "@gnosis.pm/safe-contracts": "^1.3.0",
@@ -101,16 +106,16 @@
     "@types/prompt": "^1.1.8",
     "@typescript-eslint/eslint-plugin": "^7.13.0",
     "@typescript-eslint/parser": "^8.17.0",
-    "aws-sdk-client-mock": "^4.0.1",
+    "aws-sdk-client-mock": "^4.1.0",
     "chai": "^4.3.10",
     "coveralls": "^3.1.1",
-    "dotenv": "^16.4.5",
+    "dotenv": "^17.2.3",
     "eslint": "^8.57.0",
     "eslint-config-custom": "*",
     "eslint-plugin-mocha": "^10.4.3",
     "ethers": "^5.7.2",
     "hardhat": "^2.22.14",
-    "hardhat-contract-sizer": "^2.10.0",
+    "hardhat-contract-sizer": "^2.10.1",
     "hardhat-docgen": "^1.3.0",
     "hardhat-gas-reporter": "^2.2.1",
     "husky": "^9.0.11",
@@ -130,17 +135,27 @@
   },
   "author": "Art Blocks, Inc",
   "license": "LGPL-3.0-only",
+  "repository": {
+    "type": "git",
+    "url": "https://github.com/ArtBlocks/artblocks-contracts.git"
+  },
   "dependencies": {
-    "@nomicfoundation/hardhat-verify": "^2.0.5",
+    "@ethersproject/signing-key": "^5.8.0",
+    "@nomicfoundation/hardhat-verify": "^2.0.14",
     "@openzeppelin-0.5/contracts": "npm:@openzeppelin/contracts@2.5.1",
     "@openzeppelin-4.5/contracts": "npm:@openzeppelin/contracts@4.5.0",
     "@openzeppelin-4.7/contracts": "npm:@openzeppelin/contracts@4.7.1",
     "@openzeppelin-4.8/contracts-upgradeable": "npm:@openzeppelin/contracts-upgradeable@4.8.0",
     "@openzeppelin-5.0/contracts": "npm:@openzeppelin/contracts@5.0.1",
+    "@openzeppelin-5.0/contracts-upgradeable": "npm:@openzeppelin/contracts-upgradeable@5.0.1",
+    "@openzeppelin/contracts": "5.0.1",
     "@urql/exchange-retry": "^1.3.0",
     "graphql": "^16.8.2",
     "scripty.sol": "2.1.1",
-    "solady": "^0.0.181",
+    "solady": "^0.1.26",
     "urql": "^4.2.1"
+  },
+  "resolutions": {
+    "@openzeppelin-5.0/contracts-upgradeable/@openzeppelin/contracts": "5.0.1"
   }
 }