@artblocks/contracts 1.3.2 → 1.4.0

package/contracts/AdminACLV0RoyaltyRegistry.sol

@@ -0,0 +1,142 @@
+// SPDX-License-Identifier: MIT
+
+pragma solidity 0.8.22;
+
+import "./interfaces/v0.8.x/IAdminACLV0.sol";
+import {IAdminACLV0_Extended} from "./interfaces/v0.8.x/IAdminACLV0_Extended.sol";
+import "@openzeppelin-4.7/contracts/access/Ownable.sol";
+import "@openzeppelin-4.7/contracts/utils/introspection/ERC165.sol";
+
+interface IRoyaltyRegistry {
+    function setRoyaltyLookupAddress(
+        address tokenAddress,
+        address royaltyLookupAddress
+    ) external returns (bool);
+}
+
+/**
+ * @title Admin ACL contract, V0, with Royalty Registry support.
+ * @author Art Blocks Inc.
+ * @notice Privileged Roles and Ownership:
+ * This contract has a single superAdmin that passes all ACL checks. All checks
+ * for any other address will return false.
+ * The superAdmin can be changed by the current superAdmin.
+ * Extends AdminACLV0 with a single additional function to call
+ * setRoyaltyLookupAddress on a Royalty Registry contract. This is needed
+ * because V3 core contracts return this AdminACL as admin(), and the
+ * Royalty Registry's overrideAllowed check requires msg.sender == admin().
+ * Care must be taken to ensure that the admin ACL contract is secure behind a
+ * multi-sig or other secure access control mechanism.
+ */
+contract AdminACLV0RoyaltyRegistry is
+    IAdminACLV0,
+    IAdminACLV0_Extended,
+    ERC165
+{
+    string public AdminACLType = "AdminACLV0RoyaltyRegistry";
+
+    /// superAdmin is the only address that passes any and all ACL checks
+    address public superAdmin;
+
+    constructor(address superAdmin_) {
+        superAdmin = superAdmin_;
+    }
+
+    /**
+     * @notice Allows superAdmin change the superAdmin address.
+     * @param _newSuperAdmin The new superAdmin address.
+     * @param _genArt721CoreAddressesToUpdate Array of genArt721Core
+     * addresses to update to the new superAdmin, for indexing purposes only.
+     * @dev this function is gated to only superAdmin address.
+     */
+    function changeSuperAdmin(
+        address _newSuperAdmin,
+        address[] calldata _genArt721CoreAddressesToUpdate
+    ) external {
+        require(msg.sender == superAdmin, "Only superAdmin");
+        address previousSuperAdmin = superAdmin;
+        superAdmin = _newSuperAdmin;
+        emit SuperAdminTransferred(
+            previousSuperAdmin,
+            _newSuperAdmin,
+            _genArt721CoreAddressesToUpdate
+        );
+    }
+
+    /**
+     * Calls transferOwnership on other contract from this contract.
+     * This is useful for updating to a new AdminACL contract.
+     * @dev this function is gated to only superAdmin address.
+     * @dev This implementation requires that the new AdminACL contract
+     * broadcasts support of IAdminACLV0 via ERC165 interface detection.
+     */
+    function transferOwnershipOn(
+        address _contract,
+        address _newAdminACL
+    ) external {
+        require(msg.sender == superAdmin, "Only superAdmin");
+        require(
+            ERC165(_newAdminACL).supportsInterface(
+                type(IAdminACLV0).interfaceId
+            ),
+            "AdminACLV0RoyaltyRegistry: new admin ACL does not support IAdminACLV0"
+        );
+        Ownable(_contract).transferOwnership(_newAdminACL);
+    }
+
+    /**
+     * @notice Calls renounceOwnership on other contract from this contract.
+     * @dev this function is gated to only superAdmin address.
+     */
+    function renounceOwnershipOn(address _contract) external {
+        require(msg.sender == superAdmin, "Only superAdmin");
+        Ownable(_contract).renounceOwnership();
+    }
+
+    /**
+     * @notice Checks if sender `_sender` is allowed to call function with selector
+     * `_selector` on contract `_contract`. Returns true if sender is superAdmin.
+     */
+    function allowed(
+        address _sender,
+        address /*_contract*/,
+        bytes4 /*_selector*/
+    ) external view returns (bool) {
+        return superAdmin == _sender;
+    }
+
+    /**
+     * @notice Calls setRoyaltyLookupAddress on a Royalty Registry contract.
+     * This is necessary because V3 core contracts return this AdminACL's
+     * address from admin(), and the Royalty Registry requires
+     * msg.sender == admin() for override authorization.
+     * @param _royaltyRegistry Address of the Royalty Registry contract.
+     * @param _tokenAddress Core contract address to configure.
+     * @param _royaltyLookupAddress Override address for royalty lookups
+     * (typically a royalty override shim). Set to address(0) to clear.
+     * @dev this function is gated to only superAdmin address.
+     */
+    function setRoyaltyLookupAddressOn(
+        address _royaltyRegistry,
+        address _tokenAddress,
+        address _royaltyLookupAddress
+    ) external {
+        require(msg.sender == superAdmin, "Only superAdmin");
+        IRoyaltyRegistry(_royaltyRegistry).setRoyaltyLookupAddress(
+            _tokenAddress,
+            _royaltyLookupAddress
+        );
+    }
+
+    /**
+     * @inheritdoc ERC165
+     */
+    function supportsInterface(
+        bytes4 interfaceId
+    ) public view virtual override(ERC165) returns (bool) {
+        return
+            interfaceId == type(IAdminACLV0).interfaceId ||
+            interfaceId == type(IAdminACLV0_Extended).interfaceId ||
+            super.supportsInterface(interfaceId);
+    }
+}

package/contracts/DependencyRegistryV0.sol

@@ -439,6 +439,98 @@ contract DependencyRegistryV0 is
         );
     }
 
+    /**
+     * @notice Updates the canvas tag requirement for dependency `dependencyNameAndVersion`.
+     * @param dependencyNameAndVersion Name and version of dependency (i.e. "name@version") used to identify dependency.
+     * @param canvasTagType Whether generated HTML requires a canvas tag, and where it belongs
+     * relative to the project script.
+     */
+    function updateDependencyCanvasTagType(
+        bytes32 dependencyNameAndVersion,
+        IDependencyRegistryV0.CanvasTagType canvasTagType
+    ) external {
+        _onlyAdminACL(this.updateDependencyCanvasTagType.selector);
+        _onlyExistingDependency(dependencyNameAndVersion);
+
+        DependencyRegistryStorageLib
+            .s()
+            .dependencyRecords[dependencyNameAndVersion]
+            .canvasTagType = canvasTagType;
+
+        emit DependencyCanvasTagTypeUpdated(
+            dependencyNameAndVersion,
+            canvasTagType
+        );
+    }
+
+    /**
+     * @notice Updates whether dependency `dependencyNameAndVersion` must be loaded as an ES module.
+     * @dev When true, the generator exposes the dependency to project scripts via an import map
+     * keyed on the dependency's name, rather than loading it with a plain `<script src>` tag.
+     * @param dependencyNameAndVersion Name and version of dependency (i.e. "name@version") used to identify dependency.
+     * @param loadAsModule Whether the dependency's script is an ES module.
+     */
+    function updateDependencyLoadAsModule(
+        bytes32 dependencyNameAndVersion,
+        bool loadAsModule
+    ) external {
+        _onlyAdminACL(this.updateDependencyLoadAsModule.selector);
+        _onlyExistingDependency(dependencyNameAndVersion);
+
+        DependencyRegistryStorageLib
+            .s()
+            .dependencyRecords[dependencyNameAndVersion]
+            .loadAsModule = loadAsModule;
+
+        emit DependencyLoadAsModuleUpdated(
+            dependencyNameAndVersion,
+            loadAsModule
+        );
+    }
+
+    /**
+     * @notice Updates how project scripts using `dependencyNameAndVersion` are injected into
+     * generated HTML.
+     * @param dependencyNameAndVersion Name and version of dependency (i.e. "name@version") used to identify dependency.
+     * @param projectScriptTagType How the project script must be wrapped.
+     * @param projectScriptSpecialType `type` attribute to use, required to be non-empty when
+     * `projectScriptTagType` is SpecialType and required to be empty otherwise.
+     */
+    function updateDependencyProjectScriptTagType(
+        bytes32 dependencyNameAndVersion,
+        IDependencyRegistryV0.ProjectScriptTagType projectScriptTagType,
+        string memory projectScriptSpecialType
+    ) external {
+        _onlyAdminACL(this.updateDependencyProjectScriptTagType.selector);
+        _onlyExistingDependency(dependencyNameAndVersion);
+        // @dev keeps the special type and the tag type from drifting out of sync, which would
+        // otherwise silently produce a script tag with a missing or ignored `type` attribute.
+        if (
+            projectScriptTagType ==
+            IDependencyRegistryV0.ProjectScriptTagType.SpecialType
+        ) {
+            _onlyNonEmptyString(projectScriptSpecialType);
+        } else {
+            require(
+                bytes(projectScriptSpecialType).length == 0,
+                "Special type only for SpecialType"
+            );
+        }
+
+        DependencyRegistryStorageLib.Dependency
+            storage dependency = DependencyRegistryStorageLib
+                .s()
+                .dependencyRecords[dependencyNameAndVersion];
+        dependency.projectScriptTagType = projectScriptTagType;
+        dependency.projectScriptSpecialType = projectScriptSpecialType;
+
+        emit DependencyProjectScriptTagTypeUpdated(
+            dependencyNameAndVersion,
+            projectScriptTagType,
+            projectScriptSpecialType
+        );
+    }
+
     /**
      * @notice Adds a new CDN url to `dependencyNameAndVersion`.
      * @param dependencyNameAndVersion Name and version of dependency (i.e. "name@version") used to identify dependency.
@@ -1377,6 +1469,46 @@ contract DependencyRegistryV0 is
     /**
      * @notice Returns details for a given dependency type `dependencyNameAndVersion`.
      * @param dependencyNameAndVersion Name and version of dependency (i.e. "name@version") used to identify dependency.
+     * @return dependencyDetails Details for the given dependency.
+     */
+    function getDependencyDetailsV2(
+        bytes32 dependencyNameAndVersion
+    )
+        public
+        view
+        returns (
+            IDependencyRegistryV0.DependencyDetails memory dependencyDetails
+        )
+    {
+        DependencyRegistryStorageLib.Dependency
+            storage dependency = DependencyRegistryStorageLib
+                .s()
+                .dependencyRecords[dependencyNameAndVersion];
+
+        return
+            IDependencyRegistryV0.DependencyDetails({
+                nameAndVersion: dependencyNameAndVersion.toString(),
+                licenseType: dependency.licenseType.toString(),
+                preferredCDN: dependency.preferredCDN,
+                additionalCDNCount: dependency.additionalCDNCount,
+                preferredRepository: dependency.preferredRepository,
+                additionalRepositoryCount: dependency.additionalRepositoryCount,
+                dependencyWebsite: dependency.website,
+                availableOnChain: dependency.scriptCount > 0,
+                scriptCount: dependency.scriptCount,
+                loadAsModule: dependency.loadAsModule,
+                canvasTagType: dependency.canvasTagType,
+                projectScriptTagType: dependency.projectScriptTagType,
+                projectScriptSpecialType: dependency.projectScriptSpecialType
+            });
+    }
+
+    /**
+     * @notice Returns details for a given dependency type `dependencyNameAndVersion`.
+     * @dev Superseded by `getDependencyDetailsV2`, which additionally returns the fields
+     * prescribing how the generator renders projects using this dependency. Retained with an
+     * unchanged signature so that existing off-chain consumers continue to decode correctly.
+     * @param dependencyNameAndVersion Name and version of dependency (i.e. "name@version") used to identify dependency.
      * @return nameAndVersion String representation of `dependencyNameAndVersion`.
      *                        (e.g. "p5js(atSymbol)1.0.0")
      * @return licenseType License type for dependency
@@ -1405,21 +1537,19 @@ contract DependencyRegistryV0 is
             uint24 scriptCount
         )
     {
-        DependencyRegistryStorageLib.Dependency
-            storage dependency = DependencyRegistryStorageLib
-                .s()
-                .dependencyRecords[dependencyNameAndVersion];
+        IDependencyRegistryV0.DependencyDetails
+            memory details = getDependencyDetailsV2(dependencyNameAndVersion);
 
         return (
-            dependencyNameAndVersion.toString(),
-            dependency.licenseType.toString(),
-            dependency.preferredCDN,
-            dependency.additionalCDNCount,
-            dependency.preferredRepository,
-            dependency.additionalRepositoryCount,
-            dependency.website,
-            dependency.scriptCount > 0,
-            dependency.scriptCount
+            details.nameAndVersion,
+            details.licenseType,
+            details.preferredCDN,
+            details.additionalCDNCount,
+            details.preferredRepository,
+            details.additionalRepositoryCount,
+            details.dependencyWebsite,
+            details.availableOnChain,
+            details.scriptCount
         );
     }
 

package/contracts/GenArt721CoreV3_Curated.sol

@@ -24,7 +24,7 @@ contract GenArt721CoreV3_Curated is GenArt721CoreV3_Engine {
 
     /// override patch version of this core contract
     // @dev this is a constant value that is used to override the inherited core version CORE_VERSION
-    bytes32 private constant _CORE_VERSION_OVERRIDE = "v3.2.6";
+    bytes32 private constant _CORE_VERSION_OVERRIDE = "v3.3.2";
 
     // @dev overridden core version is returned instead of the inherited core version
     function coreVersion() external pure override returns (string memory) {

package/contracts/GenArt721CoreV3_Curated_Flex.sol

@@ -0,0 +1,173 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+pragma solidity 0.8.22;
+
+// Created By: Art Blocks Inc.
+
+import {GenArt721CoreV3_Engine_Flex} from "./engine/V3/GenArt721CoreV3_Engine_Flex.sol";
+import {EngineConfiguration} from "./interfaces/v0.8.x/IGenArt721CoreContractV3_Engine.sol";
+
+import "./libs/v0.8.x/Bytes32Strings.sol";
+
+/**
+ * @title Art Blocks Curated ERC-721 core contract, V3.2 Flex (ONCHAIN only)
+ * @author Art Blocks Inc.
+ * @notice This contract derives from the Art Blocks Engine Flex contract and adds
+ * some functionality to support curation of projects by Art Blocks.
+ * It also performs initialization of the contract in the constructor, because
+ * the contract is not intended to use a clone proxy pattern, and is intended
+ * to be deployed without any required follow-on calls to initialize.
+ * Constraints are added to the contract to only allow ONCHAIN dependencies,
+ * ensuring that the Art Blocks Curated projects are only dependent on onchain
+ * data, consistent with previous Art Blocks Curated contracts.
+ * ----------------------------------------------------------------------------
+ * See the Art Blocks Engine Flex contract for additional applicable documentation.
+ */
+contract GenArt721CoreV3_Curated_Flex is GenArt721CoreV3_Engine_Flex {
+    using Bytes32Strings for bytes32;
+
+    /// override patch version of this core contract
+    // @dev this is a constant value that is used to override the inherited core version CORE_VERSION
+    bytes32 private constant _CORE_VERSION_OVERRIDE = "v3.3.3";
+
+    // @dev overridden core version is returned instead of the inherited core version
+    function coreVersion() external pure override returns (string memory) {
+        return _CORE_VERSION_OVERRIDE.toString();
+    }
+
+    /// metadata pointer to the previous associated Flagship Artblocks core contracts
+    // @dev not defined as constant because constant address arrays are not yet implemented in Solidity
+    address[] public PREVIOUS_ART_BLOCKS_CONTRACTS = [
+        0x059EDD72Cd353dF5106D2B9cC5ab83a52287aC3a,
+        0xa7d8d9ef8D8Ce8992Df33D8b8CF4Aebabd5bD270,
+        0x99a9B7c1116f9ceEB1652de04d5969CcE509B069,
+        0xAB0000000000aa06f89B268D604a9c1C41524Ac6
+    ];
+
+    /// Curation registry for Flagship projects, managed by Art Blocks
+    address public artblocksCurationRegistryAddress;
+
+    bool public constant IS_FLAGSHIP = true;
+
+    /**
+     * @notice Construct a new curated Art Blocks ERC-721 core contract.
+     * Performs all contract initialization in the constructor.
+     * @param engineConfiguration Configuration for the engine contract.
+     * note: parameter `engineConfiguration.newSuperAdminAddress` is not used or operated on in this contract.
+     * @param adminACLContract_ Address of the admin ACL contract.
+     * @param defaultBaseURIHost Default base URI host for token URIs, e.g. "https://token.artblocks.io/" for mainnet
+     * @param bytecodeStorageReaderContract_ Address of the bytecode storage reader contract to be used by this
+     * contract.
+     */
+    constructor(
+        EngineConfiguration memory engineConfiguration,
+        address adminACLContract_,
+        string memory defaultBaseURIHost,
+        address bytecodeStorageReaderContract_
+    ) GenArt721CoreV3_Engine_Flex() {
+        // input validation generally performed by the engine factory
+        _onlyNonZeroAddress(engineConfiguration.renderProviderAddress);
+        _onlyNonZeroAddress(engineConfiguration.randomizerContract);
+        _onlyNonZeroAddress(adminACLContract_);
+        _onlyNonZeroAddress(bytecodeStorageReaderContract_);
+        require(
+            bytes(defaultBaseURIHost).length > 0,
+            "GenArt721CoreV3_Curated_Flex: defaultBaseURIHost must be non-empty"
+        );
+
+        // input validation specific to the curated contract
+        require(
+            !engineConfiguration.autoApproveArtistSplitProposals,
+            "GenArt721CoreV3_Curated_Flex: autoApproveArtistSplitProposals must be false"
+        );
+        // @dev artblocks is listed as render provider, no party should be platform provider
+        require(
+            engineConfiguration.nullPlatformProvider,
+            "GenArt721CoreV3_Curated_Flex: nullPlatformProvider must be true"
+        );
+        require(
+            !engineConfiguration.allowArtistProjectActivation,
+            "GenArt721CoreV3_Curated_Flex: allowArtistProjectActivation must be false"
+        );
+        // @dev previous artblocks contracts exists, so only starting project ID > 0
+        require(
+            engineConfiguration.startingProjectId > 0,
+            "GenArt721CoreV3_Curated_Flex: startingProjectId must be greater than 0"
+        );
+
+        // initialize the contract
+        _initialize({
+            engineConfiguration: engineConfiguration,
+            adminACLContract_: adminACLContract_,
+            defaultBaseURIHost: defaultBaseURIHost,
+            bytecodeStorageReaderContract_: bytecodeStorageReaderContract_
+        });
+
+        // override default base URI to be curated format instead of Engine (no address required for curated)
+        _updateDefaultBaseURI(defaultBaseURIHost);
+    }
+
+    /**
+     * @notice Override of the Engine contract's initialize function.
+     * Immediately reverts, as initialization of this Curated contract is performed in the constructor.
+     */
+    function initialize(
+        EngineConfiguration memory /*engineConfiguration*/,
+        address /*adminACLContract_*/,
+        string memory /*defaultBaseURIHost*/,
+        address /*bytecodeStorageReaderContract_*/
+    ) external pure override {
+        // revert - initialization for this contract is performed in the constructor
+        // @dev note that the initialize function would revert without this override, but it is included for clarity
+        revert(
+            "GenArt721CoreV3_Curated_Flex: contract initialized in constructor"
+        );
+    }
+
+    /**
+     * @notice Updates reference to Art Blocks Curation Registry contract.
+     * @param _artblocksCurationRegistryAddress Address of Art Blocks Curation Registry contract.
+     */
+    function updateArtblocksCurationRegistryAddress(
+        address _artblocksCurationRegistryAddress
+    ) external {
+        _onlyAdminACL(this.updateArtblocksCurationRegistryAddress.selector);
+        artblocksCurationRegistryAddress = _artblocksCurationRegistryAddress;
+        emit ArtBlocksCurationRegistryContractUpdated(
+            _artblocksCurationRegistryAddress
+        );
+    }
+
+    function updateProjectExternalAssetDependency(
+        uint256 _projectId,
+        uint256 _index,
+        string memory _cidOrData,
+        ExternalAssetDependencyType _dependencyType
+    ) public override {
+        require(
+            _dependencyType == ExternalAssetDependencyType.ONCHAIN,
+            "GenArt721CoreV3_Curated_Flex: Curated dependency type must be ONCHAIN"
+        );
+        super.updateProjectExternalAssetDependency({
+            _projectId: _projectId,
+            _index: _index,
+            _cidOrData: _cidOrData,
+            _dependencyType: _dependencyType
+        });
+    }
+
+    function addProjectExternalAssetDependency(
+        uint256 _projectId,
+        string memory _cidOrData,
+        ExternalAssetDependencyType _dependencyType
+    ) public override {
+        require(
+            _dependencyType == ExternalAssetDependencyType.ONCHAIN,
+            "GenArt721CoreV3_Curated_Flex: Curated dependency type must be ONCHAIN"
+        );
+        super.addProjectExternalAssetDependency({
+            _projectId: _projectId,
+            _cidOrData: _cidOrData,
+            _dependencyType: _dependencyType
+        });
+    }
+}

package/contracts/GenArt721CoreV3_Explorations_Flex.sol

@@ -0,0 +1,159 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+pragma solidity 0.8.22;
+
+// Created By: Art Blocks Inc.
+
+import {GenArt721CoreV3_Engine_Flex} from "./engine/V3/GenArt721CoreV3_Engine_Flex.sol";
+import {EngineConfiguration} from "./interfaces/v0.8.x/IGenArt721CoreContractV3_Engine.sol";
+
+import "./libs/v0.8.x/Bytes32Strings.sol";
+
+/**
+ * @title Art Blocks Explorations ERC-721 core contract, V3.2 Flex (ONCHAIN only)
+ * @author Art Blocks Inc.
+ * @notice This contract derives from the Art Blocks Engine Flex contract and adds
+ * some functionality to support curation of projects by Art Blocks.
+ * It also performs initialization of the contract in the constructor, because
+ * the contract is not intended to use a clone proxy pattern, and is intended
+ * to be deployed without any required follow-on calls to initialize.
+ * Constraints are added to the contract to only allow ONCHAIN dependencies.
+ * ----------------------------------------------------------------------------
+ * See the Art Blocks Engine Flex contract for additional applicable documentation.
+ */
+contract GenArt721CoreV3_Explorations_Flex is GenArt721CoreV3_Engine_Flex {
+    using Bytes32Strings for bytes32;
+
+    /// override patch version of this core contract
+    // @dev this is a constant value that is used to override the inherited core version CORE_VERSION
+    bytes32 private constant _CORE_VERSION_OVERRIDE = "v3.3.4";
+
+    // @dev overridden core version is returned instead of the inherited core version
+    function coreVersion() external pure override returns (string memory) {
+        return _CORE_VERSION_OVERRIDE.toString();
+    }
+
+    /// metadata pointer to the previous associated Art Blocks Explorations core contracts
+    // @dev not defined as constant because constant address arrays are not yet implemented in Solidity
+    address[] public PREVIOUS_ART_BLOCKS_EXPLORATIONS_CONTRACTS = [
+        0x942BC2d3e7a589FE5bd4A5C6eF9727DFd82F5C8a
+    ];
+
+    /// Curation registry for Flagship projects, managed by Art Blocks
+    address public artblocksCurationRegistryAddress;
+
+    bool public constant IS_FLAGSHIP = true;
+
+    /**
+     * @notice Construct a new Explorations Art Blocks ERC-721 core contract.
+     * Performs all contract initialization in the constructor.
+     * @param engineConfiguration Configuration for the engine contract.
+     * note: parameter `engineConfiguration.newSuperAdminAddress` is not used or operated on in this contract.
+     * @param adminACLContract_ Address of the admin ACL contract.
+     * @param bytecodeStorageReaderContract_ Address of the bytecode storage reader contract to be used by this
+     * contract.
+     */
+    constructor(
+        EngineConfiguration memory engineConfiguration,
+        address adminACLContract_,
+        address bytecodeStorageReaderContract_
+    ) GenArt721CoreV3_Engine_Flex() {
+        // input validation generally performed by the engine factory
+        _onlyNonZeroAddress(engineConfiguration.renderProviderAddress);
+        _onlyNonZeroAddress(engineConfiguration.randomizerContract);
+        _onlyNonZeroAddress(adminACLContract_);
+        _onlyNonZeroAddress(bytecodeStorageReaderContract_);
+
+        // input validation specific to the Explorations contract
+        require(
+            !engineConfiguration.autoApproveArtistSplitProposals,
+            "GenArt721CoreV3_Explorations_Flex: autoApproveArtistSplitProposals must be false"
+        );
+        // @dev artblocks is listed as render provider, no party should be platform provider
+        require(
+            engineConfiguration.nullPlatformProvider,
+            "GenArt721CoreV3_Explorations_Flex: nullPlatformProvider must be true"
+        );
+        require(
+            !engineConfiguration.allowArtistProjectActivation,
+            "GenArt721CoreV3_Explorations_Flex: allowArtistProjectActivation must be false"
+        );
+        // @dev previous artblocks contracts exists, so only starting project ID > 0
+        require(
+            engineConfiguration.startingProjectId > 0,
+            "GenArt721CoreV3_Explorations_Flex: startingProjectId must be greater than 0"
+        );
+
+        // initialize the contract
+        _initialize({
+            engineConfiguration: engineConfiguration,
+            adminACLContract_: adminACLContract_,
+            defaultBaseURIHost: "https://token.artblocks.io/", // function will append contract address
+            bytecodeStorageReaderContract_: bytecodeStorageReaderContract_
+        });
+    }
+
+    /**
+     * @notice Override of the Engine contract's initialize function.
+     * Immediately reverts, as initialization of this Explorations contract is performed in the constructor.
+     */
+    function initialize(
+        EngineConfiguration memory /*engineConfiguration*/,
+        address /*adminACLContract_*/,
+        string memory /*defaultBaseURIHost*/,
+        address /*bytecodeStorageReaderContract_*/
+    ) external pure override {
+        // revert - initialization for this contract is performed in the constructor
+        // @dev note that the initialize function would revert without this override, but it is included for clarity
+        revert(
+            "GenArt721CoreV3_Explorations_Flex: contract initialized in constructor"
+        );
+    }
+
+    /**
+     * @notice Updates reference to Art Blocks Curation Registry contract.
+     * @param _artblocksCurationRegistryAddress Address of Art Blocks Curation Registry contract.
+     */
+    function updateArtblocksCurationRegistryAddress(
+        address _artblocksCurationRegistryAddress
+    ) external {
+        _onlyAdminACL(this.updateArtblocksCurationRegistryAddress.selector);
+        artblocksCurationRegistryAddress = _artblocksCurationRegistryAddress;
+        emit ArtBlocksCurationRegistryContractUpdated(
+            _artblocksCurationRegistryAddress
+        );
+    }
+
+    function updateProjectExternalAssetDependency(
+        uint256 _projectId,
+        uint256 _index,
+        string memory _cidOrData,
+        ExternalAssetDependencyType _dependencyType
+    ) public override {
+        require(
+            _dependencyType == ExternalAssetDependencyType.ONCHAIN,
+            "GenArt721CoreV3_Explorations_Flex: Dependency type must be ONCHAIN"
+        );
+        super.updateProjectExternalAssetDependency({
+            _projectId: _projectId,
+            _index: _index,
+            _cidOrData: _cidOrData,
+            _dependencyType: _dependencyType
+        });
+    }
+
+    function addProjectExternalAssetDependency(
+        uint256 _projectId,
+        string memory _cidOrData,
+        ExternalAssetDependencyType _dependencyType
+    ) public override {
+        require(
+            _dependencyType == ExternalAssetDependencyType.ONCHAIN,
+            "GenArt721CoreV3_Explorations_Flex: Dependency type must be ONCHAIN"
+        );
+        super.addProjectExternalAssetDependency({
+            _projectId: _projectId,
+            _cidOrData: _cidOrData,
+            _dependencyType: _dependencyType
+        });
+    }
+}