@andespindola/crow-term-linux-x64 0.0.0-bootstrap.1 → 0.1.0-alpha.5

package/bin/shell/vendor/fisher/functions/fisher.fish

@@ -0,0 +1,251 @@
+function fisher --argument-names cmd --description "A plugin manager for Fish"
+    set --query fisher_path || set --local fisher_path $__fish_config_dir
+    set --local fisher_version 4.4.8
+    set --local fish_plugins $__fish_config_dir/fish_plugins
+
+    switch "$cmd"
+        case -v --version
+            echo "fisher, version $fisher_version"
+        case "" -h --help
+            echo "Usage: fisher install   <plugins...>  Install plugins"
+            echo "       fisher remove    <plugins...>  Remove installed plugins" 
+            echo "       fisher uninstall <plugins...>  Remove installed plugins (alias)" 
+            echo "       fisher update    <plugins...>  Update installed plugins"
+            echo "       fisher update                  Update all installed plugins"
+            echo "       fisher list    [<regex>]       List installed plugins matching regex"
+            echo "Options:"
+            echo "       -v, --version  Print version"
+            echo "       -h, --help     Print this help message"
+            echo "Variables:"
+            echo "       \$fisher_path  Plugin installation path. Default: $__fish_config_dir" | string replace --regex -- $HOME \~
+        case ls list
+            string match --entire --regex -- "$argv[2]" $_fisher_plugins
+        case install update remove uninstall
+            isatty || read --local --null --array stdin && set --append argv $stdin
+
+            test "$cmd" = uninstall && set cmd remove
+
+            set --local install_plugins
+            set --local update_plugins
+            set --local remove_plugins
+            set --local arg_plugins $argv[2..-1]
+            set --local old_plugins $_fisher_plugins
+            set --local new_plugins
+
+            test -e $fish_plugins && set --local file_plugins (string match --regex -- '^[^\s]+$' <$fish_plugins | string replace -- \~ ~)
+
+            if ! set --query argv[2]
+                if test "$cmd" != update
+                    echo "fisher: Not enough arguments for command: \"$cmd\"" >&2 && return 1
+                else if ! set --query file_plugins
+                    echo "fisher: \"$fish_plugins\" file not found: \"$cmd\"" >&2 && return 1
+                end
+                set arg_plugins $file_plugins
+            else if test "$cmd" = install && ! set --query old_plugins[1] 
+                set --append arg_plugins $file_plugins
+            end
+
+            for plugin in $arg_plugins
+                set plugin (test -e "$plugin" && realpath $plugin || string lower -- $plugin)
+                contains -- "$plugin" $new_plugins || set --append new_plugins $plugin
+            end
+
+            if set --query argv[2]
+                for plugin in $new_plugins
+                    if contains -- "$plugin" $old_plugins
+                        test "$cmd" = remove &&
+                            set --append remove_plugins $plugin ||
+                            set --append update_plugins $plugin
+                    else if test "$cmd" = install
+                        set --append install_plugins $plugin
+                    else
+                        echo "fisher: Plugin not installed: \"$plugin\"" >&2 && return 1
+                    end
+                end
+            else
+                for plugin in $new_plugins
+                    contains -- "$plugin" $old_plugins &&
+                        set --append update_plugins $plugin ||
+                        set --append install_plugins $plugin
+                end
+
+                for plugin in $old_plugins
+                    contains -- "$plugin" $new_plugins || set --append remove_plugins $plugin
+                end
+            end
+
+            set --local pid_list
+            set --local source_plugins
+            set --local fetch_plugins $update_plugins $install_plugins
+            set --local fish_path (status fish-path)
+
+            echo (set_color --bold)fisher $cmd version $fisher_version(set_color normal)
+
+            for plugin in $fetch_plugins
+                set --local source (command mktemp -d)
+                set --append source_plugins $source
+
+                command mkdir -p $source/{completions,conf.d,themes,functions}
+
+                $fish_path --command "
+                    if test -e $plugin
+                        command cp -Rf $plugin/* $source
+                    else
+                        set resp (command mktemp)
+                        set temp (command mktemp -d)
+                        set repo (string split -- \@ $plugin) || set repo[2] HEAD
+
+                        if set path (string replace --regex -- '^(https://)?gitlab.com/' '' \$repo[1])
+                            set name (string split -- / \$path)[-1]
+                            set url https://gitlab.com/\$path/-/archive/\$repo[2]/\$name-\$repo[2].tar.gz
+                        else
+                            set url https://api.github.com/repos/\$repo[1]/tarball/\$repo[2]
+                        end
+
+                        echo Fetching (set_color --underline)\$url(set_color normal)
+
+                        set http (command curl -q --silent -L -o \$resp -w %{http_code} \$url)
+
+                        if test \"\$http\" = 200 && command tar -xzC \$temp -f \$resp 2>/dev/null
+                            command cp -Rf \$temp/*/* $source
+                        else if test \"\$http\" = 403
+                            echo fisher: GitHub API rate limit exceeded \(HTTP 403\) >&2
+                            command rm -rf $source
+                        else
+                            echo fisher: Invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
+                            command rm -rf $source
+                        end
+
+                        command rm -rf \$temp
+                    end
+
+                    set files $source/* && string match --quiet --regex -- .+\.fish\\\$ \$files
+                " &
+
+                set --append pid_list (jobs --last --pid)
+            end
+
+            wait $pid_list 2>/dev/null
+
+            for plugin in $fetch_plugins
+                if set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
+                    if set --local index (contains --index -- "$plugin" $install_plugins)
+                        set --erase install_plugins[$index]
+                    else
+                        set --erase update_plugins[(contains --index -- "$plugin" $update_plugins)]
+                    end
+                end
+            end
+
+            for plugin in $update_plugins $remove_plugins
+                if set --local index (contains --index -- "$plugin" $_fisher_plugins)
+                    set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                    if contains -- "$plugin" $remove_plugins
+                        for name in (string replace --filter --regex -- '.+/conf\.d/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                            emit {$name}_uninstall
+                        end
+                        printf "%s\n" Removing\ (set_color red --bold)$plugin(set_color normal) "         "$$plugin_files_var | string replace -- \~ ~
+                        set --erase _fisher_plugins[$index]
+                    end
+
+                    command rm -rf (string replace -- \~ ~ $$plugin_files_var)
+
+                    functions --erase (string replace --filter --regex -- '.+/functions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+
+                    for name in (string replace --filter --regex -- '.+/completions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                        complete --erase --command $name
+                    end
+
+                    set --erase $plugin_files_var
+                end
+            end
+
+            if set --query update_plugins[1] || set --query install_plugins[1]
+                command mkdir -p $fisher_path/{functions,themes,conf.d,completions}
+            end
+
+            for plugin in $update_plugins $install_plugins
+                set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
+                set --local files $source/{functions,themes,conf.d,completions}/*
+
+                if set --local index (contains --index -- $plugin $install_plugins)
+                    set --local user_files $fisher_path/{functions,themes,conf.d,completions}/*
+                    set --local conflict_files
+
+                    for file in (string replace -- $source/ $fisher_path/ $files)
+                        contains -- $file $user_files && set --append conflict_files $file
+                    end
+
+                    if set --query conflict_files[1] && set --erase install_plugins[$index]
+                        echo -s "fisher: Cannot install \"$plugin\": please remove or move conflicting files first:" \n"        "$conflict_files >&2
+                        continue
+                    end
+                end
+
+                for file in (string replace -- $source/ "" $files)
+                    command cp -RLf $source/$file $fisher_path/$file
+                end
+
+                set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                set --query files[1] && set --universal $plugin_files_var (string replace -- $source $fisher_path $files | string replace -- ~ \~)
+
+                contains -- $plugin $_fisher_plugins || set --universal --append _fisher_plugins $plugin
+                contains -- $plugin $install_plugins && set --local event install || set --local event update
+
+                printf "%s\n" Installing\ (set_color --bold)$plugin(set_color normal) "           "$$plugin_files_var | string replace -- \~ ~
+
+                for file in (string match --regex -- '.+/[^/]+\.fish$' $$plugin_files_var | string replace -- \~ ~)
+                    source $file
+                    if set --local name (string replace --regex -- '.+conf\.d/([^/]+)\.fish$' '$1' $file)
+                        emit {$name}_$event
+                    end
+                end
+            end
+
+            command rm -rf $source_plugins
+
+            if set --query _fisher_plugins[1]
+                set --local commit_plugins
+
+                for plugin in $file_plugins
+                    contains -- (string lower -- $plugin) (string lower -- $_fisher_plugins) && set --append commit_plugins $plugin
+                end
+
+                for plugin in $_fisher_plugins
+                    contains -- (string lower -- $plugin) (string lower -- $commit_plugins) || set --append commit_plugins $plugin
+                end
+
+                string replace --regex -- $HOME \~ $commit_plugins >$fish_plugins
+            else
+                set --erase _fisher_plugins
+                command rm -f $fish_plugins
+            end
+
+            set --local total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
+
+            test "$total" != "0 0 0" && echo (string join ", " (
+                test $total[1] = 0 || echo "Installed $total[1]") (
+                test $total[2] = 0 || echo "Updated $total[2]") (
+                test $total[3] = 0 || echo "Removed $total[3]")
+            ) plugin/s
+        case \*
+            echo "fisher: Unknown command: \"$cmd\"" >&2 && return 1
+    end
+end
+
+if ! set --query _fisher_upgraded_to_4_4
+    set --universal _fisher_upgraded_to_4_4
+    if functions --query _fisher_list
+        set --query XDG_DATA_HOME[1] || set --local XDG_DATA_HOME ~/.local/share
+        command rm -rf $XDG_DATA_HOME/fisher
+        functions --erase _fisher_{list,plugin_parse}
+        fisher update >/dev/null 2>/dev/null
+    else
+        for var in (set --names | string match --entire --regex '^_fisher_.+_files$')
+            set $var (string replace -- ~ \~ $$var)
+        end
+        functions --erase _fisher_fish_postexec
+    end
+end

package/bin/shell/vendor/z/LICENSE

@@ -0,0 +1,21 @@
+The MIT License (MIT)
+
+Copyright (C) 2016 Jethro Kuan
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

package/bin/shell/vendor/z/conf.d/z.fish

@@ -0,0 +1,63 @@
+if test -z "$Z_DATA"
+    if test -z "$XDG_DATA_HOME"
+        set -U Z_DATA_DIR "$HOME/.local/share/z"
+    else
+        set -U Z_DATA_DIR "$XDG_DATA_HOME/z"
+    end
+    set -U Z_DATA "$Z_DATA_DIR/data"
+end
+
+if test ! -e "$Z_DATA"
+    if test ! -e "$Z_DATA_DIR"
+        mkdir -p -m 700 "$Z_DATA_DIR"
+    end
+    touch "$Z_DATA"
+end
+
+if test -z "$Z_CMD"
+    set -U Z_CMD z
+end
+
+set -U ZO_CMD "$Z_CMD"o
+
+if test ! -z $Z_CMD
+    function $Z_CMD -d "jump around"
+        __z $argv
+    end
+end
+
+if test ! -z $ZO_CMD
+    function $ZO_CMD -d "open target dir"
+        __z -d $argv
+    end
+end
+
+if not set -q Z_EXCLUDE
+    set -U Z_EXCLUDE "^$HOME\$"
+else if contains $HOME $Z_EXCLUDE
+    # Workaround: migrate old default values to a regex (see #90).
+    set Z_EXCLUDE (string replace -r -- "^$HOME\$" '^'$HOME'$$' $Z_EXCLUDE)
+end
+
+# Setup completions once first
+__z_complete
+
+function __z_on_variable_pwd --on-variable PWD
+    __z_add
+end
+
+function __z_uninstall --on-event z_uninstall
+    functions -e __z_on_variable_pwd
+    functions -e $Z_CMD
+    functions -e $ZO_CMD
+
+    if test ! -z "$Z_DATA"
+        printf "To completely erase z's data, remove:\n" >/dev/stderr
+        printf "%s\n" "$Z_DATA" >/dev/stderr
+    end
+
+    set -e Z_CMD
+    set -e ZO_CMD
+    set -e Z_DATA
+    set -e Z_EXCLUDE
+end

package/bin/shell/vendor/z/functions/__z.fish

@@ -0,0 +1,178 @@
+function __z -d "Jump to a recent directory."
+    function __print_help -d "Print z help."
+        printf "Usage: $Z_CMD  [-celrth] string1 string2...\n\n"
+        printf "         -c --clean    Removes directories that no longer exist from $Z_DATA\n"
+        printf "         -d --dir      Opens matching directory using system file manager.\n"
+        printf "         -e --echo     Prints best match, no cd\n"
+        printf "         -l --list     List matches and scores, no cd\n"
+        printf "         -p --purge    Delete all entries from $Z_DATA\n"
+        printf "         -r --rank     Search by rank\n"
+        printf "         -t --recent   Search by recency\n"
+        printf "         -x --delete   Removes the current directory from $Z_DATA\n"
+        printf "         -h --help     Print this help\n\n"
+    end
+    function __z_legacy_escape_regex
+        # taken from escape_string_pcre2 in fish
+        # used to provide compatibility with fish 2
+        for c in (string split -- '' $argv)
+            if contains $c (string split '' '.^$*+()?[{}\\|-]')
+                printf \\
+            end
+            printf '%s' $c
+        end
+    end
+
+    set -l options h/help c/clean e/echo l/list p/purge r/rank t/recent d/directory x/delete
+
+    argparse $options -- $argv
+
+    if set -q _flag_help
+        __print_help
+        return 0
+    else if set -q _flag_clean
+        __z_clean
+        printf "%s cleaned!\n" $Z_DATA
+        return 0
+    else if set -q _flag_purge
+        echo >$Z_DATA
+        printf "%s purged!\n" $Z_DATA
+        return 0
+    else if set -q _flag_delete
+        sed -i -e "\:^$PWD|.*:d" $Z_DATA
+        return 0
+    end
+
+    set -l typ
+
+    if set -q _flag_rank
+        set typ rank
+    else if set -q _flag_recent
+        set typ recent
+    end
+
+    set -l z_script '
+        function frecent(rank, time) {
+            dx = t-time
+            if( dx < 3600 ) return rank*4
+            if( dx < 86400 ) return rank*2
+            if( dx < 604800 ) return rank/2
+            return rank/4
+        }
+
+        function output(matches, best_match, common) {
+            # list or return the desired directory
+            if( list ) {
+                cmd = "sort -nr"
+                for( x in matches ) {
+                    if( matches[x] ) {
+                        printf "%-10s %s\n", matches[x], x | cmd
+                    }
+                }
+            } else {
+                if( common ) best_match = common
+                print best_match
+            }
+        }
+
+        function common(matches) {
+            # find the common root of a list of matches, if it exists
+            for( x in matches ) {
+                if( matches[x] && (!short || length(x) < length(short)) ) {
+                    short = x
+                }
+            }
+            if( short == "/" ) return
+            for( x in matches ) if( matches[x] && index(x, short) != 1 ) {
+                    return
+                }
+            return short
+        }
+
+        BEGIN {
+            hi_rank = ihi_rank = -9999999999
+        }
+        {
+            if( typ == "rank" ) {
+                rank = $2
+            } else if( typ == "recent" ) {
+                rank = $3 - t
+            } else rank = frecent($2, $3)
+            if( $1 ~ q ) {
+                matches[$1] = rank
+            } else if( tolower($1) ~ tolower(q) ) imatches[$1] = rank
+            if( matches[$1] && matches[$1] > hi_rank ) {
+                best_match = $1
+                hi_rank = matches[$1]
+            } else if( imatches[$1] && imatches[$1] > ihi_rank ) {
+                ibest_match = $1
+                ihi_rank = imatches[$1]
+            }
+        }
+
+        END {
+        # prefer case sensitive
+            if( best_match ) {
+                output(matches, best_match, common(matches))
+            } else if( ibest_match ) {
+                output(imatches, ibest_match, common(imatches))
+            }
+        }
+    '
+
+    set -l qs
+    for arg in $argv
+        set -l escaped $arg
+        if string escape --style=regex '' >/dev/null 2>&1 # use builtin escape if available
+            set escaped (string escape --style=regex -- $escaped)
+        else
+            set escaped (__z_legacy_escape_regex $escaped)
+        end
+        # Need to escape twice, see https://www.math.utah.edu/docs/info/gawk_5.html#SEC32
+        set escaped (string replace --all -- \\ \\\\ $escaped)
+        set qs $qs $escaped
+    end
+    set -l q (string join -- '.*' $qs)
+
+    if set -q _flag_list
+        # Handle list separately as it can print common path information to stderr
+        # which cannot be captured from a subcommand.
+        command awk -v t=(date +%s) -v list="list" -v typ="$typ" -v q="$q" -F "|" $z_script "$Z_DATA"
+        return
+    end
+
+    if set -q q[1]
+        set target (command awk -v t=(date +%s) -v typ="$typ" -v q="$q" -F "|" $z_script "$Z_DATA")
+    else
+        set target $HOME
+    end
+
+    if test "$status" -gt 0
+        return
+    end
+
+    if test -z "$target"
+        printf "'%s' did not match any results\n" "$argv"
+        return 1
+    end
+
+    if set -q _flag_echo
+        printf "%s\n" "$target"
+    else if set -q _flag_directory
+        if test -n "$ZO_METHOD"
+            type -q "$ZO_METHOD"; and "$ZO_METHOD" "$target"; and return $status
+            echo "Cannot open with ZO_METHOD set to $ZO_METHOD"; and return 1
+        else if test "$OS" = Windows_NT
+            # Be careful, in msys2, explorer always return 1
+            type -q explorer; and explorer "$target"
+            return 0
+            echo "Cannot open file explorer"
+            return 1
+        else
+            type -q xdg-open; and xdg-open "$target"; and return $status
+            type -q open; and open "$target"; and return $status
+            echo "Not sure how to open file manager"; and return 1
+        end
+    else
+        cd "$target"
+    end
+end

package/bin/shell/vendor/z/functions/__z_add.fish

@@ -0,0 +1,49 @@
+function __z_add -d "Add PATH to .z file"
+    test -n "$fish_private_mode"; and return 0
+
+    for i in $Z_EXCLUDE
+        if string match -r $i $PWD >/dev/null
+            return 0 #Path excluded
+        end
+    end
+
+    set -l tmpfile (mktemp $Z_DATA.XXXXXX)
+
+    if test -f $tmpfile
+        set -l path (string replace --all \\ \\\\ $PWD)
+        command awk -v path=$path -v now=(date +%s) -F "|" '
+      BEGIN {
+          rank[path] = 1
+          time[path] = now
+      }
+      $2 >= 1 {
+          if( $1 == path ) {
+              rank[$1] = $2 + 1
+              time[$1] = now
+          }
+          else {
+              rank[$1] = $2
+              time[$1] = $3
+          }
+          count += $2
+      }
+      END {
+          if( count > 1000 ) {
+              for( i in rank ) print i "|" 0.9*rank[i] "|" time[i] # aging
+          }
+          else for( i in rank ) print i "|" rank[i] "|" time[i]
+      }
+    ' $Z_DATA 2>/dev/null >$tmpfile
+
+        if test ! -z "$Z_OWNER"
+            chown $Z_OWNER:(id -ng $Z_OWNER) $tmpfile
+        end
+        #
+        # Don't use redirection here as it can lead to a race condition where $Z_DATA is clobbered.
+        # Note: There is a still a possible race condition where an old version of $Z_DATA is
+        #       read by one instance of Fish before another instance of Fish writes its copy.
+        #
+        command mv $tmpfile $Z_DATA
+        or command rm $tmpfile
+    end
+end

package/bin/shell/vendor/z/functions/__z_clean.fish

@@ -0,0 +1,11 @@
+function __z_clean -d "Clean up .z file to remove paths no longer valid"
+    set -l tmpfile (mktemp $Z_DATA.XXXXXX)
+
+    if test -f $tmpfile
+        while read line
+            set -l path (string split '|' $line)[1]
+            test -d $path; and echo $line
+        end <$Z_DATA >$tmpfile
+        command mv -f $tmpfile $Z_DATA
+    end
+end

package/bin/shell/vendor/z/functions/__z_complete.fish

@@ -0,0 +1,13 @@
+function __z_complete -d "add completions"
+    complete -c $Z_CMD -a "(__z -l | string replace -r '^\\S*\\s*' '')" -f -k
+    complete -c $ZO_CMD -a "(__z -l | string replace -r '^\\S*\\s*' '')" -f -k
+
+    complete -c $Z_CMD -s c -l clean -d "Cleans out $Z_DATA"
+    complete -c $Z_CMD -s e -l echo -d "Prints best match, no cd"
+    complete -c $Z_CMD -s l -l list -d "List matches, no cd"
+    complete -c $Z_CMD -s p -l purge -d "Purges $Z_DATA"
+    complete -c $Z_CMD -s r -l rank -d "Searches by rank, cd"
+    complete -c $Z_CMD -s t -l recent -d "Searches by recency, cd"
+    complete -c $Z_CMD -s h -l help -d "Print help"
+    complete -c $Z_CMD -s x -l delete -d "Removes the current directory from $Z_DATA"
+end

package/bin/shell/vendor/zsh-autosuggestions/LICENSE

@@ -0,0 +1,23 @@
+Copyright (c) 2013 Thiago de Arruda
+Copyright (c) 2016-2021 Eric Freese
+
+Permission is hereby granted, free of charge, to any person
+obtaining a copy of this software and associated documentation
+files (the "Software"), to deal in the Software without
+restriction, including without limitation the rights to use,
+copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the
+Software is furnished to do so, subject to the following
+conditions:
+
+The above copyright notice and this permission notice shall be
+included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
+OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
+HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
+WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
+OTHER DEALINGS IN THE SOFTWARE.