@agent-webui/ai-desk-python-darwin-x64 1.0.29-beta1

package/python/lib/tk9.0/demos/ctext.tcl

@@ -0,0 +1,172 @@
+# ctext.tcl --
+#
+# This demonstration script creates a canvas widget with a text
+# item that can be edited and reconfigured in various ways.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require tk
+
+set w .ctext
+catch {destroy $w}
+toplevel $w
+wm title $w "Canvas Text Demonstration"
+wm iconname $w "Text"
+positionWindow $w
+set c $w.c
+
+label $w.msg -font $font -wraplength 5i -justify left -text "This window displays a string of text to demonstrate the text facilities of canvas widgets.  You can click in the boxes to adjust the position of the text relative to its positioning point or change its justification, and on a pie slice to change its angle.  The text also supports the following simple bindings for editing:
+  1. You can point, click, and type.
+  2. You can also select with button 1.
+  3. You can copy the selection to the mouse position with button 2.
+  4. Backspace and Control+h delete the selection if there is one;
+     otherwise they delete the character just before the insertion cursor.
+  5. Delete deletes the selection if there is one; otherwise it deletes
+     the character just after the insertion cursor."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+canvas $c -relief flat -borderwidth 0 -width 375p -height 262.5p
+pack $w.c -side top -expand yes -fill both
+
+set textFont {Helvetica 24}
+
+$c create rectangle 183.75p 122.25p 191.25p 129.75p -outline black -fill red
+
+# First, create the text item and give it bindings so it can be edited.
+
+$c addtag text withtag [$c create text 187.5p 126p -text "This is just a string of text to demonstrate the text facilities of canvas widgets. Bindings have been defined to support editing (see above)." -width 330p -anchor n -font $textFont -justify left]
+$c bind text <Button-1> "textB1Press $c %x %y"
+$c bind text <B1-Motion> "textB1Move $c %x %y"
+$c bind text <Shift-Button-1> "$c select adjust current @%x,%y"
+$c bind text <Shift-B1-Motion> "textB1Move $c %x %y"
+$c bind text <Key> "textInsert $c %A"
+$c bind text <Return> "textInsert $c \\n"
+$c bind text <Control-h> "textBs $c"
+$c bind text <BackSpace> "textBs $c"
+$c bind text <Delete> "textDel $c"
+$c bind text <Button-2> "textPaste $c @%x,%y"
+
+# Next, create some items that allow the text's anchor position
+# to be edited.
+
+proc mkTextConfigBox {w x y option value color} {	;# x, y are in points
+    set item [$w create rect ${x}p ${y}p [expr {$x+22.5}]p [expr {$y+22.5}]p \
+	    -outline black -fill $color -width 0.75p]
+    $w bind $item <Button-1> "$w itemconf text $option $value"
+    $w addtag config withtag $item
+}
+proc mkTextConfigPie {w x y a option value color} {	;# x, y are in points
+    set item [$w create arc ${x}p ${y}p [expr {$x+67.5}]p [expr {$y+67.5}]p \
+	    -start [expr {$a-15}] -extent 30 -outline black -fill $color \
+	    -width 0.75p]
+    $w bind $item <Button-1> "$w itemconf text $option $value"
+    $w addtag config withtag $item
+}
+
+set x 37.5	;# in points
+set y 37.5	;# in points
+set color LightSkyBlue1
+mkTextConfigBox $c $x $y -anchor se $color
+mkTextConfigBox $c [expr {$x+22.5}] [expr {$y     }] -anchor s      $color
+mkTextConfigBox $c [expr {$x+45  }] [expr {$y     }] -anchor sw     $color
+mkTextConfigBox $c [expr {$x     }] [expr {$y+22.5}] -anchor e      $color
+mkTextConfigBox $c [expr {$x+22.5}] [expr {$y+22.5}] -anchor center $color
+mkTextConfigBox $c [expr {$x+45  }] [expr {$y+22.5}] -anchor w      $color
+mkTextConfigBox $c [expr {$x     }] [expr {$y+45  }] -anchor ne     $color
+mkTextConfigBox $c [expr {$x+22.5}] [expr {$y+45  }] -anchor n      $color
+mkTextConfigBox $c [expr {$x+45  }] [expr {$y+45  }] -anchor nw     $color
+set item [$c create rect \
+	[expr {$x+30}]p [expr {$y+30}]p [expr {$x+37.5}]p [expr {$y+37.5}]p \
+	-outline black -fill red]
+$c bind $item <Button-1> "$c itemconf text -anchor center"
+$c create text [expr {$x+33.75}]p [expr {$y-3.75}]p \
+	-text {Text Position}  -anchor s  -font {Times 20}  -fill brown
+
+# Now create some items that allow the text's angle to be changed.
+
+set x 153.75	;# in points
+set y 37.5	;# in points
+set color Yellow
+mkTextConfigPie $c $x $y   0 -angle  90 $color
+mkTextConfigPie $c $x $y  30 -angle 120 $color
+mkTextConfigPie $c $x $y  60 -angle 150 $color
+mkTextConfigPie $c $x $y  90 -angle 180 $color
+mkTextConfigPie $c $x $y 120 -angle 210 $color
+mkTextConfigPie $c $x $y 150 -angle 240 $color
+mkTextConfigPie $c $x $y 180 -angle 270 $color
+mkTextConfigPie $c $x $y 210 -angle 300 $color
+mkTextConfigPie $c $x $y 240 -angle 330 $color
+mkTextConfigPie $c $x $y 270 -angle   0 $color
+mkTextConfigPie $c $x $y 300 -angle  30 $color
+mkTextConfigPie $c $x $y 330 -angle  60 $color
+$c create text [expr {$x+33.75}]p [expr {$y-3.75}]p \
+	-text {Text Angle}     -anchor s  -font {Times 20}  -fill brown
+
+# Lastly, create some items that allow the text's justification to be
+# changed.
+
+set x 262.5	;# in points
+set y 37.5	;# in points
+set color SeaGreen2
+mkTextConfigBox $c $x $y -justify left $color
+mkTextConfigBox $c [expr {$x+22.5}] $y -justify center $color
+mkTextConfigBox $c [expr {$x+45}] $y -justify right $color
+$c create text [expr {$x+33.75}]p [expr {$y-3.75}]p \
+	-text {Justification}  -anchor s  -font {Times 20}  -fill brown
+
+$c bind config <Enter> "textEnter $c"
+$c bind config <Leave> "$c itemconf current -fill \$textConfigFill"
+
+set textConfigFill {}
+
+proc textEnter {w} {
+    global textConfigFill
+    set textConfigFill [lindex [$w itemconfig current -fill] 4]
+    $w itemconfig current -fill black
+}
+
+proc textInsert {w string} {
+    if {$string == ""} {
+	return
+    }
+    catch {$w dchars text sel.first sel.last}
+    $w insert text insert $string
+}
+
+proc textPaste {w pos} {
+    catch {
+	$w insert text $pos [selection get]
+    }
+}
+
+proc textB1Press {w x y} {
+    $w icursor current @$x,$y
+    $w focus current
+    focus $w
+    $w select from current @$x,$y
+}
+
+proc textB1Move {w x y} {
+    $w select to current @$x,$y
+}
+
+proc textBs {w} {
+    if {![catch {$w dchars text sel.first sel.last}]} {
+	return
+    }
+    set char [expr {[$w index text insert] - 1}]
+    if {$char >= 0} {$w dchar text $char}
+}
+
+proc textDel {w} {
+    if {![catch {$w dchars text sel.first sel.last}]} {
+	return
+    }
+    $w dchars text insert
+}

package/python/lib/tk9.0/demos/dialog1.tcl

@@ -0,0 +1,25 @@
+# dialog1.tcl --
+#
+# This demonstration script creates a dialog box with a local grab.
+
+interp create child
+load {} Tk child
+child eval {
+    wm title . child
+    wm geometry . +700+30
+    pack [text .t -width 30 -height 10]
+}
+
+after idle {.dialog1.msg configure -wraplength 4i}
+set i [tk_dialog .dialog1 "Dialog with local grab" {This is a modal dialog box.  It uses Tk's "grab" command to create a "local grab" on the dialog box.  The grab prevents any mouse or keyboard events from getting to any other windows in the application until you have answered the dialog by invoking one of the buttons below.  However, you can still interact with other applications.  For example, you should be able to edit text in the window named "child" which was created by a child interpreter.} \
+info 0 OK Cancel {Show Code}]
+
+switch $i {
+    0 {puts "You pressed OK"}
+    1 {puts "You pressed Cancel"}
+    2 {showCode .dialog1}
+}
+
+if {[interp exists child]} {
+    interp delete child
+}

package/python/lib/tk9.0/demos/dialog2.tcl

@@ -0,0 +1,18 @@
+# dialog2.tcl --
+#
+# This demonstration script creates a dialog box with a global grab.
+
+after idle {
+    .dialog2.msg configure -wraplength 4i
+}
+after 100 {
+    grab -global .dialog2
+}
+set i [tk_dialog .dialog2 "Dialog with global grab" {This dialog box uses a global grab. If you are using an X11 window manager you will be prevented from interacting with anything on your display until you invoke one of the buttons below.  This is almost always a bad idea; don't use global grabs with X11 unless you're truly desperate.  On macOS systems you will not be able to interact with any window belonging to this process, but interaction with other macOS Applications will still be possible.}\
+warning 0 OK Cancel {Show Code}]
+
+switch $i {
+    0 {puts "You pressed OK"}
+    1 {puts "You pressed Cancel"}
+    2 {showCode .dialog2}
+}

package/python/lib/tk9.0/demos/en.msg

@@ -0,0 +1,103 @@
+::msgcat::mcset en "Widget Demonstration"
+::msgcat::mcset en "tkWidgetDemo"
+::msgcat::mcset en "&File"
+::msgcat::mcset en "About..."
+::msgcat::mcset en "&About..."
+::msgcat::mcset en "<F1>"
+::msgcat::mcset en "&Quit"
+::msgcat::mcset en "Meta+Q"		;# Displayed hotkey
+::msgcat::mcset en "Meta-q"		;# Actual binding sequence
+::msgcat::mcset en "Ctrl+Q"		;# Displayed hotkey
+::msgcat::mcset en "Control-q"		;# Actual binding sequence
+::msgcat::mcset en "See Variables"
+::msgcat::mcset en "Variable values"
+::msgcat::mcset en "Variable values:"
+::msgcat::mcset en "OK"
+::msgcat::mcset en "Run the \"%s\" sample program"
+::msgcat::mcset en "Dismiss"
+::msgcat::mcset en "Rerun Demo"
+::msgcat::mcset en "Print Code"
+::msgcat::mcset en "Demo code: %s"
+::msgcat::mcset en "About Widget Demo"
+::msgcat::mcset en "Tk widget demonstration"
+::msgcat::mcset en "Copyright © %s"
+
+::msgcat::mcset en "Tk Widget Demonstrations"
+::msgcat::mcset en "This application provides a front end for several short scripts"
+::msgcat::mcset en "that demonstrate what you can do with Tk widgets.  Each of the"
+::msgcat::mcset en "numbered lines below describes a demonstration;  you can click on"
+::msgcat::mcset en "it to invoke the demonstration.  Once the demonstration window"
+::msgcat::mcset en "appears, you can click the"
+::msgcat::mcset en "See Code"  "See Code"	;# This is also button text!
+::msgcat::mcset en "button to see the Tcl/Tk code that created the demonstration.  If"
+::msgcat::mcset en "you wish, you can edit the code and click the"
+::msgcat::mcset en "button in the code window to reinvoke the demonstration with the"
+::msgcat::mcset en "modified code."
+
+::msgcat::mcset en "Labels, buttons, checkbuttons, and radiobuttons"
+::msgcat::mcset en "Labels (text and bitmaps)"
+::msgcat::mcset en "Labels and UNICODE text"
+::msgcat::mcset en "Buttons"
+::msgcat::mcset en "Check-buttons (select any of a group)"
+::msgcat::mcset en "Radio-buttons (select one of a group)"
+::msgcat::mcset en "A 15-puzzle game made out of buttons"
+::msgcat::mcset en "Iconic buttons that use bitmaps"
+::msgcat::mcset en "Two labels displaying images"
+::msgcat::mcset en "A simple user interface for viewing images"
+::msgcat::mcset en "Labelled frames"
+
+::msgcat::mcset en "Listboxes"
+::msgcat::mcset en "The 50 states"
+::msgcat::mcset en "Colors: change the color scheme for the application"
+::msgcat::mcset en "A collection of famous and infamous sayings"
+
+::msgcat::mcset en "Entries and Spin-boxes"
+::msgcat::mcset en "Entries without scrollbars"
+::msgcat::mcset en "Entries with scrollbars"
+::msgcat::mcset en "Validated entries and password fields"
+::msgcat::mcset en "Spin-boxes"
+::msgcat::mcset en "Simple Rolodex-like form"
+
+::msgcat::mcset en "Text"
+::msgcat::mcset en "Basic editable text"
+::msgcat::mcset en "Text display styles"
+::msgcat::mcset en "Hypertext (tag bindings)"
+::msgcat::mcset en "A text widget with embedded windows"
+::msgcat::mcset en "A search tool built with a text widget"
+
+::msgcat::mcset en "Canvases"
+::msgcat::mcset en "The canvas item types"
+::msgcat::mcset en "A simple 2-D plot"
+::msgcat::mcset en "Text items in canvases"
+::msgcat::mcset en "An editor for arrowheads on canvas lines"
+::msgcat::mcset en "A ruler with adjustable tab stops"
+::msgcat::mcset en "A building floor plan"
+::msgcat::mcset en "A simple scrollable canvas"
+
+::msgcat::mcset en "Scales"
+::msgcat::mcset en "Horizontal scale"
+::msgcat::mcset en "Vertical scale"
+
+::msgcat::mcset en "Paned Windows"
+::msgcat::mcset en "Horizontal paned window"
+::msgcat::mcset en "Vertical paned window"
+::msgcat::mcset en "Menus"
+::msgcat::mcset en "Menus and cascades (sub-menus)"
+::msgcat::mcset en "Menu-buttons"
+::msgcat::mcset en "Common Dialogs"
+::msgcat::mcset en "Message boxes"
+::msgcat::mcset en "File selection dialog"
+::msgcat::mcset en "Color picker"
+::msgcat::mcset en "Font selection dialog"
+::msgcat::mcset en "System tray icon and notification"
+::msgcat::mcset en "Printing from canvas and text widgets"
+::msgcat::mcset en "Animation"
+::msgcat::mcset en "Animated labels"
+::msgcat::mcset en "Animated wave"
+::msgcat::mcset en "Pendulum simulation"
+::msgcat::mcset en "A celebration of Rube Goldberg"
+::msgcat::mcset en "Miscellaneous"
+::msgcat::mcset en "The built-in bitmaps"
+::msgcat::mcset en "A dialog box with a local grab"
+::msgcat::mcset en "A dialog box with a global grab"
+::msgcat::mcset en "Window icons and badges"

package/python/lib/tk9.0/demos/entry1.tcl

@@ -0,0 +1,34 @@
+# entry1.tcl --
+#
+# This demonstration script creates several entry widgets without
+# scrollbars.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require tk
+
+set w .entry1
+catch {destroy $w}
+toplevel $w
+wm title $w "Entry Demonstration (no scrollbars)"
+wm iconname $w "entry1"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 5i -justify left -text "Three different entries are displayed below.  You can add characters by pointing, clicking and typing.  The normal Motif editing characters are supported, along with many Emacs bindings.  For example, Backspace and Control-h delete the character to the left of the insertion cursor and Delete and Control-d delete the chararacter to the right of the insertion cursor.  For entries that are too large to fit in the window all at once, you can scan through the entries by dragging with mouse the middle mouse button pressed."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+entry $w.e1
+entry $w.e2
+entry $w.e3 -placeholder {Enter text here} -placeholderforeground gray75
+pack $w.e1 $w.e2 $w.e3 -side top -pady 3p -padx 7.5p -fill x
+
+$w.e1 insert 0 "Initial value"
+$w.e2 insert end "This entry contains a long value, much too long "
+$w.e2 insert end "to fit in the window at one time, so long in fact "
+$w.e2 insert end "that you'll have to scan or scroll to see the end."

package/python/lib/tk9.0/demos/entry2.tcl

@@ -0,0 +1,47 @@
+# entry2.tcl --
+#
+# This demonstration script is the same as the entry1.tcl script
+# except that it creates scrollbars for the entries.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require tk
+
+set w .entry2
+catch {destroy $w}
+toplevel $w
+wm title $w "Entry Demonstration (with scrollbars)"
+wm iconname $w "entry2"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 5i -justify left -text "Three different entries are displayed below, with a scrollbar for each entry.  You can add characters by pointing, clicking and typing.  The normal Motif editing characters are supported, along with many Emacs bindings.  For example, Backspace and Control-h delete the character to the left of the insertion cursor and Delete and Control-d delete the chararacter to the right of the insertion cursor.  For entries that are too large to fit in the window all at once, you can scan through the entries with the scrollbars, or by dragging with the middle mouse button pressed."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+frame $w.frame -borderwidth 7.5p
+pack $w.frame -side top -fill x -expand 1
+
+entry $w.frame.e1 -xscrollcommand "$w.frame.s1 set"
+ttk::scrollbar $w.frame.s1 -orient horizontal -command \
+	"$w.frame.e1 xview"
+frame $w.frame.spacer1 -width 15p -height 7.5p
+entry $w.frame.e2 -xscrollcommand "$w.frame.s2 set"
+ttk::scrollbar $w.frame.s2 -orient horizontal -command \
+	"$w.frame.e2 xview"
+frame $w.frame.spacer2 -width 15p -height 7.5p
+entry $w.frame.e3 -xscrollcommand "$w.frame.s3 set"
+ttk::scrollbar $w.frame.s3 -orient horizontal -command \
+	"$w.frame.e3 xview"
+pack $w.frame.e1 $w.frame.s1 $w.frame.spacer1 $w.frame.e2 $w.frame.s2 \
+	$w.frame.spacer2 $w.frame.e3 $w.frame.s3 -side top -fill x
+
+$w.frame.e1 insert 0 "Initial value"
+$w.frame.e2 insert end "This entry contains a long value, much too long "
+$w.frame.e2 insert end "to fit in the window at one time, so long in fact "
+$w.frame.e2 insert end "that you'll have to scan or scroll to see the end."
+$w.frame.e3 configure -placeholder {Enter text here} -placeholderforeground gray75

package/python/lib/tk9.0/demos/entry3.tcl

@@ -0,0 +1,185 @@
+# entry3.tcl --
+#
+# This demonstration script creates several entry widgets whose
+# permitted input is constrained in some way.  It also shows off a
+# password entry.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require tk
+
+set w .entry3
+catch {destroy $w}
+toplevel $w
+wm title $w "Constrained Entry Demonstration"
+wm iconname $w "entry3"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 5i -justify left -text "Four different\
+	entries are displayed below.  You can add characters by pointing,\
+	clicking and typing, though each is constrained in what it will\
+	accept.  The first only accepts 32-bit integers or the empty string\
+	(checking when focus leaves it) and will flash to indicate any\
+	problem.  The second only accepts strings with fewer than ten\
+	characters and sounds the bell when an attempt to go over the limit\
+	is made.  The third accepts US phone numbers, mapping letters to\
+	their digit equivalent and sounding the bell on encountering an\
+	illegal character or if trying to type over a character that is not\
+	a digit.  The fourth is a password field that accepts up to eight\
+	characters (silently ignoring further ones), and displaying them as\
+	asterisk characters."
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+# focusAndFlash --
+# Error handler for entry widgets that forces the focus onto the
+# widget and makes the widget flash by exchanging the foreground and
+# background colours at intervals of 200ms (i.e. at approximately
+# 2.5Hz).
+#
+# Arguments:
+# W -		Name of entry widget to flash
+# fg -		Initial foreground colour
+# bg -		Initial background colour
+# count -	Counter to control the number of times flashed
+
+proc focusAndFlash {W fg bg {count 9}} {
+    focus -force $W
+    if {$count<1} {
+	$W configure -foreground $fg -background $bg
+    } else {
+	if {$count%2} {
+	    $W configure -foreground $bg -background $fg
+	} else {
+	    $W configure -foreground $fg -background $bg
+	}
+	after 200 [list focusAndFlash $W $fg $bg [expr {$count-1}]]
+    }
+}
+
+labelframe $w.l1 -text "Integer Entry"
+# Alternatively try using {string is digit} for arbitrary length numbers,
+# and not just 32-bit ones.
+entry $w.l1.e -validate focus -validatecommand {string is integer %P}
+$w.l1.e configure -invalidcommand \
+	"focusAndFlash %W [$w.l1.e cget -fg] [$w.l1.e cget -bg]"
+pack $w.l1.e -fill x -expand 1 -padx 1m -pady 1m
+
+labelframe $w.l2 -text "Length-Constrained Entry"
+entry $w.l2.e -validate key -invcmd bell -validatecommand {expr {[string length %P]<10}}
+pack $w.l2.e -fill x -expand 1 -padx 1m -pady 1m
+
+### PHONE NUMBER ENTRY ###
+# Note that the source to this is quite a bit longer as the behaviour
+# demonstrated is a lot more ambitious than with the others.
+
+# Initial content for the third entry widget
+set entry3content "1-(000)-000-0000"
+# Mapping from alphabetic characters to numbers.  This is probably
+# wrong, but it is the only mapping I have; the UK doesn't really go
+# for associating letters with digits for some reason.
+set phoneNumberMap {}
+foreach {chars digit} {abc 2 def 3 ghi 4 jkl 5 mno 6 pqrs 7 tuv 8 wxyz 9} {
+    foreach char [split $chars ""] {
+	lappend phoneNumberMap $char $digit [string toupper $char] $digit
+    }
+}
+
+# validatePhoneChange --
+# Checks that the replacement (mapped to a digit) of the given
+# character in an entry widget at the given position will leave a
+# valid phone number in the widget.
+#
+# W -	  The entry widget to validate
+# vmode - The widget's validation mode
+# idx -	  The index where replacement is to occur
+# char -  The character (or string, though that will always be
+#	  refused) to be overwritten at that point.
+
+proc validatePhoneChange {W vmode idx char} {
+    global phoneNumberMap entry3content
+    if {$idx < 0} {return 1}
+    after idle [list $W configure -validate $vmode -invcmd bell]
+    if {
+	!($idx<3 || $idx==6 || $idx==7 || $idx==11 || $idx>15) &&
+	[string match {[0-9A-Za-z]} $char]
+    } then {
+	$W delete $idx
+	$W insert $idx [string map $phoneNumberMap $char]
+	after idle [list phoneSkipRight $W -1]
+	return 1
+    }
+    return 0
+}
+
+# phoneSkipLeft --
+# Skip over fixed characters in a phone-number string when moving left.
+#
+# Arguments:
+# W -	The entry widget containing the phone-number.
+
+proc phoneSkipLeft {W} {
+    set idx [$W index insert]
+    if {$idx == 8} {
+	# Skip back two extra characters
+	$W icursor [incr idx -2]
+    } elseif {$idx == 7 || $idx == 12} {
+	# Skip back one extra character
+	$W icursor [incr idx -1]
+    } elseif {$idx <= 3} {
+	# Can't move any further
+	bell
+	return -code break
+    }
+}
+
+# phoneSkipRight --
+# Skip over fixed characters in a phone-number string when moving right.
+#
+# Arguments:
+# W -	The entry widget containing the phone-number.
+# add - Offset to add to index before calculation (used by validation.)
+
+proc phoneSkipRight {W {add 0}} {
+    set idx [$W index insert]
+    if {$idx+$add == 5} {
+	# Skip forward two extra characters
+	$W icursor [incr idx 2]
+    } elseif {$idx+$add == 6 || $idx+$add == 10} {
+	# Skip forward one extra character
+	$W icursor [incr idx]
+    } elseif {$idx+$add == 15 && !$add} {
+	# Can't move any further
+	bell
+	return -code break
+    }
+}
+
+labelframe $w.l3 -text "US Phone-Number Entry"
+entry $w.l3.e -validate key  -invcmd bell  -textvariable entry3content \
+	-validatecommand {validatePhoneChange %W %v %i %S}
+# Click to focus goes to the first editable character...
+bind $w.l3.e <FocusIn> {
+    if {"%d" ne "NotifyAncestor"} {
+	%W icursor 3
+	after idle {%W selection clear}
+    }
+}
+bind $w.l3.e <<PrevChar>> {phoneSkipLeft  %W}
+bind $w.l3.e <<NextChar>> {phoneSkipRight %W}
+pack $w.l3.e -fill x -expand 1 -padx 1m -pady 1m
+
+labelframe $w.l4 -text "Password Entry"
+entry $w.l4.e -validate key -show "*" -validatecommand {expr {[string length %P]<=8}}
+pack $w.l4.e -fill x -expand 1 -padx 1m -pady 1m
+
+lower [frame $w.mid]
+grid $w.l1 $w.l2 -in $w.mid -padx 3m -pady 1m -sticky ew
+grid $w.l3 $w.l4 -in $w.mid -padx 3m -pady 1m -sticky ew
+grid columnconfigure $w.mid {0 1} -uniform 1
+pack $w.msg -side top
+pack $w.mid -fill both -expand 1

package/python/lib/tk9.0/demos/filebox.tcl

@@ -0,0 +1,82 @@
+# filebox.tcl --
+#
+# This demonstration script prompts the user to select a file.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require tk
+
+set w .filebox
+catch {destroy $w}
+toplevel $w
+wm title $w "File Selection Dialogs"
+wm iconname $w "filebox"
+positionWindow $w
+
+ttk::frame $w._bg
+place $w._bg -x 0 -y 0 -relwidth 1 -relheight 1
+
+ttk::label $w.msg -font $font -wraplength 4i -justify left -text "Enter a file name in the entry box or click on the \"Browse\" buttons to select a file name using the file selection dialog."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+set f [ttk::frame $w.f]
+foreach i {open save} {
+    ttk::label $f.lab_$i -text "Select a file to $i:"
+    ttk::entry $f.ent_$i -width 20
+    ttk::button $f.but_$i -text "Browse ..." -command \
+	    "fileDialog $w $f.ent_$i $i"
+    grid $f.lab_$i $f.ent_$i $f.but_$i -pady 3p -sticky w
+    grid configure $f.ent_$i -padx 3p -sticky ew
+}
+grid columnconfigure $f 1 -weight 1
+pack $f -fill x -padx 1c
+
+if {[tk windowingsystem] eq "x11"} {
+    ttk::checkbutton $w.strict -text "Use Motif Style Dialog" \
+	-variable tk_strictMotif -onvalue 1 -offvalue 0
+    pack $w.strict -anchor c
+
+    # This binding ensures that we don't run the rest of the demos
+    # with motif style interactions
+    bind $w.strict <Destroy> {set tk_strictMotif 0}
+}
+
+proc fileDialog {w ent operation} {
+    #   Type names		Extension(s)	Mac File Type(s)
+    #
+    #---------------------------------------------------------
+    set types {
+	{"Text files"		{.txt .doc}	}
+	{"Text files"		{}		TEXT}
+	{"Tcl Scripts"		{.tcl}		TEXT}
+	{"C Source Files"	{.c .h}		}
+	{"All Source Files"	{.tcl .c .h}	}
+	{"Image Files"		{.gif}		}
+	{"Image Files"		{.jpeg .jpg}	}
+	{"Image Files"		""		{GIFF JPEG}}
+	{"All files"		*}
+    }
+    if {$operation == "open"} {
+	global selected_type
+	if {![info exists selected_type]} {
+	    set selected_type "Tcl Scripts"
+	}
+	set file [tk_getOpenFile -filetypes $types -parent $w \
+		-typevariable selected_type]
+	puts "You selected filetype \"$selected_type\""
+    } else {
+	set file [tk_getSaveFile -filetypes $types -parent $w \
+		-initialfile Untitled -defaultextension .txt]
+    }
+    if {[string compare $file ""]} {
+	$ent delete 0 end
+	$ent insert 0 $file
+	$ent xview end
+    }
+}