@agent-webui/ai-desk-python-darwin-x64 1.0.29-beta1

package/python/lib/tk9.0/demos/README

@@ -0,0 +1,44 @@
+This directory contains a collection of programs to demonstrate
+the features of the Tk toolkit.  The programs are all scripts for
+"wish", a windowing shell.  If wish has been installed on your path
+then you can invoke any of the programs in this directory just
+by typing its file name to your command shell under Unix.  Otherwise
+invoke wish with the file as its first argument, e.g., "wish hello".
+The rest of this file contains a brief description of each program.
+Files with names ending in ".tcl" are procedure packages used by one
+or more of the demo programs;  they can't be used as programs by
+themselves so they aren't described below.
+
+hello -		Creates a single button;  if you click on it, a message
+		is typed and the application terminates.
+
+widget -	Contains a collection of demonstrations of the widgets
+		currently available in the Tk library.  Most of the .tcl
+		files are scripts for individual demos available through
+		the "widget" program.
+
+ixset -		A simple Tk-based wrapper for the "xset" program, which
+		allows you to interactively query and set various X options
+		such as mouse acceleration and bell volume.  Thanks to
+		Pierre David for contributing this example.
+
+rolodex -	A mock-up of a simple rolodex application.  It has much of
+		the user interface for such an application but no back-end
+		database.  This program was written in response to Tom
+		LaStrange's toolkit benchmark challenge.
+
+tcolor -	A color editor.  Allows you to edit colors in several
+		different ways, and will also perform automatic updates
+		using "send".
+
+rmt -		Allows you to "hook-up" remotely to any Tk application
+		on the display.  Select an application with the menu,
+		then just type commands:  they'll go to that application.
+
+timer -		Displays a seconds timer with start and stop buttons.
+		Control-c and control-q cause it to exit.
+
+browse -	A simple directory browser.  Invoke it with and argument
+		giving the name of the directory you'd like to browse.
+		Double-click on files or subdirectories to browse them.
+		Control-c and control-q cause the program to exit.

package/python/lib/tk9.0/demos/anilabel.tcl

@@ -0,0 +1,168 @@
+# anilabel.tcl --
+#
+# This demonstration script creates a toplevel window containing
+# several animated label widgets.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require tk
+
+set w .anilabel
+catch {destroy $w}
+toplevel $w
+wm title $w "Animated Label Demonstration"
+wm iconname $w "anilabel"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "Four animated labels are displayed below; each of the labels on the left is animated by making the text message inside it appear to scroll, and the label on the right is animated by animating the image that it displays."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+# Ensure that this this is an array
+array set animationCallbacks {}
+
+## This callback is the core of how to do animation in Tcl/Tk; all
+## animations work in basically the same way, with a procedure that
+## uses the [after] command to reschedule itself at some point in the
+## future. Of course, the details of how to update the state will vary
+## according to what is being animated.
+proc RotateLabelText {w interval} {
+    global animationCallbacks
+
+    # Schedule the calling of this procedure again in the future
+    set animationCallbacks($w) [after $interval RotateLabelText $w $interval]
+
+    # We do marquee-like scrolling text by chopping characters off the
+    # front of the text and sticking them on the end.
+    set text [$w cget -text]
+    set newText [string range $text 1 end][string index $text 0]
+    $w configure -text $newText
+}
+
+## A helper procedure to start the animation happening.
+proc animateLabelText {w text interval} {
+    global animationCallbacks
+
+    # Install the text into the widget
+    $w configure -text $text
+
+    # Schedule the start of the animation loop
+    set animationCallbacks($w) [after $interval RotateLabelText $w $interval]
+
+    # Make sure that the animation stops and is cleaned up after itself
+    # when the animated label is destroyed.  Note that at this point we
+    # cannot manipulate the widget itself, as that has already died.
+    bind $w <Destroy> {
+	after cancel $animationCallbacks(%W)
+	unset animationCallbacks(%W)
+    }
+}
+
+## Next, a similar pair of procedures to animate a GIF loaded into a
+## photo image.
+proc SelectNextImageFrame {w interval} {
+    global animationCallbacks image zoomFactor
+    set animationCallbacks($w) \
+	    [after $interval SelectNextImageFrame $w $interval]
+    set image2 [$w cget -image]
+
+    # The easy way to animate a GIF!
+    set idx -1
+    scan [$image cget -format] "GIF -index %d" idx
+    if {[catch {
+	# Note that we get an error if the index is out of range
+	$image configure -format "GIF -index [incr idx]"
+    }]} then {
+	$image configure -format "GIF -index 0"
+    }
+    $image2 copy $image -zoom $zoomFactor
+}
+proc animateLabelImage {w imageData interval} {
+    global animationCallbacks image zoomFactor
+
+    # Create a multi-frame GIF from base-64-encoded data
+    set image [image create photo -format GIF -data $imageData]
+
+    # Create a copy of the image just created, magnified according to the
+    # display's DPI scaling level.  Since the zooom factor must be an integer,
+    # the copy will only be effectively magnified if $tk::scalingPct >= 200.
+    set image2 [image create photo]
+    set zoomFactor [expr {$tk::scalingPct / 100}]
+    $image2 copy $image -zoom $zoomFactor
+
+    # Install the image copy into the widget
+    $w configure -image $image2
+
+    # Schedule the start of the animation loop
+    set animationCallbacks($w) \
+	    [after $interval SelectNextImageFrame $w $interval]
+
+    # Make sure that the animation stops and is cleaned up after itself
+    # when the animated label is destroyed.  Note that at this point we
+    # cannot manipulate the widget itself, as that has already died.
+    # Also note that this script is in double-quotes; this is always OK
+    # because image names are chosen automatically to be simple words.
+    bind $w <Destroy> "
+	after cancel \$animationCallbacks(%W)
+	unset animationCallbacks(%W)
+	rename $image {}
+    "
+}
+
+# Make some widgets to contain the animations
+labelframe $w.left -text "Scrolling Texts"
+labelframe $w.right -text "GIF Image"
+pack $w.left $w.right -side left -padx 7.5p -pady 7.5p -expand yes
+
+# This method of scrolling text looks far better with a fixed-width font
+label $w.left.l1 -bd 3p -relief ridge -font fixedFont
+label $w.left.l2 -bd 3p -relief groove -font fixedFont
+label $w.left.l3 -bd 3p -relief flat -font fixedFont -width 18
+pack $w.left.l1 $w.left.l2 $w.left.l3 -side top -expand yes -padx 7.5p -pady 7.5p -anchor w
+# Don't need to do very much with this label except turn off the border
+label $w.right.l -bd 0
+pack $w.right.l -side top -expand yes -padx 7.5p -pady 7.5p
+
+# This is a base-64-encoded animated GIF file.
+set tclPoweredData {
+    R0lGODlhKgBAAPQAAP//////zP//AP/MzP/Mmf/MAP+Zmf+ZZv+ZAMz//8zM
+    zMyZmcyZZsxmZsxmAMwzAJnMzJmZzJmZmZlmmZlmZplmM5kzM2aZzGZmzGZm
+    mWZmZmYzZmYzMzNmzDMzZgAzmSH+IE1hZGUgd2l0aCBHSU1QIGJ5IExARGVt
+    YWlsbHkuY29tACH5BAVkAAEALAAAAAAqAEAAAAX+YCCOZEkyTKM2jOm66yPP
+    dF03bx7YcuHIDkGBR7SZeIyhTID4FZ+4Es8nQyCe2EeUNJ0peY2s9mi7PhAM
+    ngEAMGRbUpvzSxskLh1J+Hkg134OdDIDEB+GHxtYMEQMTjMGEYeGFoomezaC
+    DZGSHFmLXTQKkh8eNQVpZ2afmDQGHaOYSoEyhhcklzVmMpuHnaZmDqiGJbg0
+    qFqvh6UNAwB7VA+OwydEjgujkgrPNhbTI8dFvNgEYcHcHx0lB1kX2IYeA2G6
+    NN0YfkXJ2BsAMuAzHB9cZMk3qoEbRzUACsRCUBK5JxsC3iMiKd8GN088SIyT
+    0RAFSROyeEg38caDiB/+JEgqxsODrZJ1BkT0oHKSmI0ceQxo94HDpg0qsuDk
+    UmRAMgu8OgwQ+uIJgUMVeGXA+IQkzEeHGvD8cIGlDXsLiRjQ+EHroQhea7xY
+    8IQBSgYYDi1IS+OFBCgaDMGVS3fGi5BPJpBaENdQ0EomKGD56IHwO39EXiSC
+    Ysgxor5+Xfgq0qByYUpiXmwuoredB2aYH4gWWda0B7SeNENpEJHC1ghi+pS4
+    AJpIAwWvKPBi+8YEht5EriEqpFfMlhEdkBNpx0HUhwypx5T4IB1MBg/Ws2sn
+    wV3MSQOkzI8fUd48Aw3dOZto71x85hHtHijYv18Gf/3GqCdDCXHNoICBobSo
+    IqBqJLyCoH8JPrLgdh88CKCFD0CGmAiGYPgffwceZh6FC2ohIIklnkhehTNY
+    4CIHHGzgwYw01ujBBhvAqKOLLq5AAk9kuSPkkKO40NB+h1gnypJIIvkBf09a
+    N5QIRz5p5ZJXJpmlIVhOGQA2TmIJZZhKKmmll2BqyWSXWUrZpQtpatlmk1c2
+    KaWRHeTZEJF8SqLDn/hhsOeQgBbqAh6DGqronxeARUIIACH5BAUeAAAALAUA
+    LgAFAAUAAAUM4CeKz/OV5YmqaRkCACH5BAUeAAEALAUALgAKAAUAAAUUICCK
+    z/OdJVCaa7p+7aOWcDvTZwgAIfkEBR4AAQAsCwAuAAkABQAABRPgA4zP95zA
+    eZqoWqqpyqLkZ38hACH5BAUKAAEALAcALgANAA4AAAU7ICA+jwiUJEqeKau+
+    r+vGaTmac63v/GP9HM7GQyx+jsgkkoRUHJ3Qx0cK/VQVTKtWwbVKn9suNunc
+    WkMAIfkEBQoAAAAsBwA3AAcABQAABRGgIHzk842j+Yjlt5KuO8JmCAAh+QQF
+    CgAAACwLADcABwAFAAAFEeAnfN9TjqP5oOWziq05lmUIACH5BAUKAAAALA8A
+    NwAHAAUAAAUPoPCJTymS3yiQj4qOcPmEACH5BAUKAAAALBMANwAHAAUAAAUR
+    oCB+z/MJX2o+I2miKimiawgAIfkEBQoAAAAsFwA3AAcABQAABRGgIHzfY47j
+    Q4qk+aHl+pZmCAAh+QQFCgAAACwbADcABwAFAAAFEaAgfs/zCV9qPiNJouo7
+    ll8IACH5BAUKAAAALB8ANwADAAUAAAUIoCB8o0iWZggAOw==
+}
+
+# Finally, set up the text scrolling animation
+animateLabelText $w.left.l1 "* Slow Animation *" 300
+animateLabelText $w.left.l2 "* Fast Animation *" 80
+animateLabelText $w.left.l3 "This is a longer scrolling text in a widget that will not show the whole message at once. " 150
+animateLabelImage $w.right.l $tclPoweredData 100

package/python/lib/tk9.0/demos/aniwave.tcl

@@ -0,0 +1,107 @@
+# aniwave.tcl --
+#
+# This demonstration script illustrates how to adjust canvas item
+# coordinates in a way that does something fairly similar to waveform
+# display.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require tk
+
+set w .aniwave
+catch {destroy $w}
+toplevel $w
+wm title $w "Animated Wave Demonstration"
+wm iconname $w "aniwave"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "This demonstration contains a canvas widget with a line item inside it. The animation routines work by adjusting the coordinates list of the line; a trace on a variable is used so updates to the variable result in a change of position of the line."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+# Create a canvas large enough to hold the wave. In fact, the wave
+# sticks off both sides of the canvas to prevent visual glitches.
+pack [canvas $w.c -width 225p -height 150p -background black] -padx 7.5p -pady 7.5p -expand yes
+
+# Ensure that this this is an array
+array set animationCallbacks {}
+
+# Creates a coordinates list of a wave. This code does a very sketchy
+# job and relies on Tk's line smoothing to make things look better.
+set waveCoords {}
+for {set x -10} {$x<=300} {incr x 5} {
+    lappend waveCoords $x 100
+}
+lappend waveCoords $x 0 [incr x 5] 200
+
+# Create a smoothed line and arrange for its coordinates to be the
+# contents of the variable waveCoords.
+$w.c create line $waveCoords -tags wave -width 0.75p -fill green -smooth 1
+proc waveCoordsTracer {w args} {
+    global waveCoords
+    # Actual visual update will wait until we have finished
+    # processing; Tk does that for us automatically.
+    $w.c coords wave $waveCoords
+
+    set scaleFactor [expr {$tk::scalingPct / 100.0}]
+    $w.c scale wave 0 0 $scaleFactor $scaleFactor
+}
+trace add variable waveCoords write [list waveCoordsTracer $w]
+
+# Basic motion handler. Given what direction the wave is travelling
+# in, it advances the y coordinates in the coordinate-list one step in
+# that direction.
+proc basicMotion {} {
+    global waveCoords direction
+    set oc $waveCoords
+    for {set i 1} {$i<[llength $oc]} {incr i 2} {
+	if {$direction eq "left"} {
+	    lset waveCoords $i [lindex $oc \
+		    [expr {$i+2>[llength $oc] ? 1 : $i+2}]]
+	} else {
+	    lset waveCoords $i \
+		    [lindex $oc [expr {$i-2<0 ? "end" : $i-2}]]
+	}
+    }
+}
+
+# Oscillation handler. This detects whether to reverse the direction
+# of the wave by checking to see if the peak of the wave has moved off
+# the screen (whose size we know already.)
+proc reverser {} {
+    global waveCoords direction
+    if {[lindex $waveCoords 1] < 10} {
+	set direction "right"
+    } elseif {[lindex $waveCoords end] < 10} {
+	set direction "left"
+    }
+}
+
+# Main animation "loop". This calls the two procedures that handle the
+# movement repeatedly by scheduling asynchronous calls back to itself
+# using the [after] command. This procedure is the fundamental basis
+# for all animated effect handling in Tk.
+proc move {} {
+    basicMotion
+    reverser
+
+    # Theoretically 100 frames-per-second (==10ms between frames)
+    global animationCallbacks
+    set animationCallbacks(simpleWave) [after 10 move]
+}
+
+# Initialise our remaining animation variables
+set direction "left"
+set animateAfterCallback {}
+# Arrange for the animation loop to stop when the canvas is deleted
+bind $w.c <Destroy> {
+    after cancel $animationCallbacks(simpleWave)
+    unset animationCallbacks(simpleWave)
+}
+# Start the animation processing
+move

package/python/lib/tk9.0/demos/arrow.tcl

@@ -0,0 +1,260 @@
+# arrow.tcl --
+#
+# This demonstration script creates a canvas widget that displays a
+# large line with an arrowhead whose shape can be edited interactively.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require tk
+
+# scl --
+# Scales an integer according to the display's current scaling percentage.
+#
+# Arguments:
+#   num -	An integer.
+
+proc scl num {
+    return [expr {round($num*$tk::scalingPct/100.0)}]
+}
+
+# arrowSetup --
+# This procedure regenerates all the text and graphics in the canvas
+# window.  It's called when the canvas is initially created, and also
+# whenever any of the parameters of the arrow head are changed
+# interactively.
+#
+# Arguments:
+# c -		Name of the canvas widget.
+
+proc arrowSetup c {
+    upvar #0 demo_arrowInfo v
+
+    # Remember the current box, if there is one.
+
+    set tags [$c gettags current]
+    if {$tags != ""} {
+	set cur [lindex $tags [lsearch -glob $tags box?]]
+    } else {
+	set cur ""
+    }
+
+    # Create the arrow and outline.
+
+    $c delete all
+    $c create line $v(x1) $v(y) $v(x2) $v(y) -arrow last \
+	    -width [expr {10*$v(width)}] -arrowshape [list \
+	    [expr {10*$v(a)}] [expr {10*$v(b)}] [expr {10*$v(c)}]] \
+	    {*}$v(bigLineStyle)
+    set xtip [expr {$v(x2)-10*$v(b)}]
+    set deltaY [expr {10*$v(c)+5*$v(width)}]
+    $c create line $v(x2) $v(y) $xtip [expr {$v(y)+$deltaY}] \
+	    [expr {$v(x2)-10*$v(a)}] $v(y) $xtip [expr {$v(y)-$deltaY}] \
+	    $v(x2) $v(y) -width 1.5p -capstyle round -joinstyle round
+
+    # Create the boxes for reshaping the line and arrowhead.
+
+    set _5 [scl 5]
+    $c create rect [expr {$v(x2)-10*$v(a)-$_5}] [expr {$v(y)-$_5}] \
+	    [expr {$v(x2)-10*$v(a)+$_5}] [expr {$v(y)+$_5}] \
+	    -tags {box1 box} {*}$v(boxStyle)
+    $c create rect [expr {$xtip-$_5}] [expr {$v(y)-$deltaY-$_5}] \
+	    [expr {$xtip+$_5}] [expr {$v(y)-$deltaY+$_5}] \
+	    -tags {box2 box} {*}$v(boxStyle)
+    $c create rect [expr {$v(x1)-$_5}] [expr {$v(y)-5*$v(width)-$_5}] \
+	    [expr {$v(x1)+$_5}] [expr {$v(y)-5*$v(width)+$_5}] \
+	    -tags {box3 box} {*}$v(boxStyle)
+    if {$cur != ""} {
+	$c itemconfigure $cur {*}$v(activeStyle)
+    }
+
+    # Create three arrows in actual size with the same parameters.
+
+    set _10  [scl 10]
+    set _15  [scl 15]
+    set _25  [scl 25]
+    set _50  [scl 50]
+    set _75  [scl 75]
+    set _125 [scl 125]
+    $c create line [expr {$v(x2)+$_50}] 0 [expr {$v(x2)+$_50}] 750p -width 1.5p
+    set tmp [expr {$v(x2)+[scl 100]}]
+    $c create line $tmp [expr {$v(y)-$_125}] $tmp [expr {$v(y)-$_75}] \
+	    -width $v(width) -arrow both -arrowshape "$v(a) $v(b) $v(c)"
+    $c create line [expr {$tmp-$_25}] $v(y) [expr {$tmp+$_25}] $v(y) \
+	    -width $v(width) -arrow both -arrowshape "$v(a) $v(b) $v(c)"
+    $c create line [expr {$tmp-$_25}] [expr {$v(y)+$_75}] \
+	    [expr {$tmp+$_25}] [expr {$v(y)+$_125}] \
+	    -width $v(width) -arrow both -arrowshape "$v(a) $v(b) $v(c)"
+
+    # Create a bunch of other arrows and text items showing the
+    # current dimensions.
+
+    set tmp [expr {$v(x2)+$_10}]
+    $c create line $tmp [expr {$v(y)-5*$v(width)}] \
+	    $tmp [expr {$v(y)-$deltaY}] \
+	    -arrow both -arrowshape $v(smallTips)
+    $c create text [expr {$v(x2)+$_15}] [expr {$v(y)-$deltaY+5*$v(c)}] \
+	    -text $v(c) -anchor w
+    set tmp [expr {$v(x1)-$_10}]
+    $c create line $tmp [expr {$v(y)-5*$v(width)}] \
+	    $tmp [expr {$v(y)+5*$v(width)}] \
+	    -arrow both -arrowshape $v(smallTips)
+    $c create text [expr {$v(x1)-$_15}] $v(y) -text $v(width) -anchor e
+    set tmp [expr {$v(y)+5*$v(width)+10*$v(c)+$_10}]
+    $c create line [expr {$v(x2)-10*$v(a)}] $tmp $v(x2) $tmp \
+	    -arrow both -arrowshape $v(smallTips)
+    $c create text [expr {$v(x2)-5*$v(a)}] [expr {$tmp+$_5}] \
+	    -text $v(a) -anchor n
+    set tmp [expr {$tmp+$_25}]
+    $c create line [expr {$v(x2)-10*$v(b)}] $tmp $v(x2) $tmp \
+	    -arrow both -arrowshape $v(smallTips)
+    $c create text [expr {$v(x2)-5*$v(b)}] [expr {$tmp+$_5}] \
+	    -text $v(b) -anchor n
+
+    $c create text $v(x1) 232.5p -text "-width  $v(width)" \
+	    -anchor w -font {Helvetica 18}
+    $c create text $v(x1) 247.5p -text "-arrowshape  {$v(a)  $v(b)  $v(c)}" \
+	    -anchor w -font {Helvetica 18}
+
+    incr v(count)
+}
+
+set w .arrow
+catch {destroy $w}
+toplevel $w
+wm title $w "Arrowhead Editor Demonstration"
+wm iconname $w "arrow"
+positionWindow $w
+set c $w.c
+
+label $w.msg -font $font -wraplength 5i -justify left -text "This widget allows you to experiment with different widths and arrowhead shapes for lines in canvases.  To change the line width or the shape of the arrowhead, drag any of the three boxes attached to the oversized arrow.  The arrows on the right give examples at normal scale.  The text at the bottom shows the configuration options as you'd enter them for a canvas line item."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+canvas $c -width 375p -height 262.5p -relief sunken -borderwidth 2
+pack $c -expand yes -fill both
+
+set demo_arrowInfo(a)	  [scl 8]
+set demo_arrowInfo(b)	  [scl 10]
+set demo_arrowInfo(c)	  [scl 3]
+set demo_arrowInfo(width) [scl 2]
+set demo_arrowInfo(motionProc) arrowMoveNull
+set demo_arrowInfo(x1)	  [scl 40]
+set demo_arrowInfo(x2)	  [scl 350]
+set demo_arrowInfo(y)	  [scl 150]
+set demo_arrowInfo(smallTips) {3.75p 3.75p 1.5p}
+set demo_arrowInfo(count) 0
+if {[winfo depth $c] > 1} {
+    if {[tk windowingsystem] eq "aqua"} {
+	set demo_arrowInfo(bigLineStyle) "-fill systemSelectedTextBackgroundColor"
+    } else {
+	set demo_arrowInfo(bigLineStyle) "-fill LightSeaGreen"
+    }
+    set demo_arrowInfo(boxStyle) "-fill {} -width 0.75p"
+    set demo_arrowInfo(activeStyle) "-fill red -width 0.75p"
+} else {
+    # Main widget program sets variable tk_demoDirectory
+    set demo_arrowInfo(bigLineStyle) "-fill black \
+	-stipple @[file join $tk_demoDirectory images grey.25]"
+    set demo_arrowInfo(boxStyle) "-fill {} -outline black -width 0.75p"
+    set demo_arrowInfo(activeStyle) "-fill black -outline black -width 0.75p"
+}
+arrowSetup $c
+$c bind box <Enter> "$c itemconfigure current $demo_arrowInfo(activeStyle)"
+$c bind box <Leave> "$c itemconfigure current $demo_arrowInfo(boxStyle)"
+$c bind box <B1-Enter> " "
+$c bind box <B1-Leave> " "
+$c bind box1 <Button-1> {set demo_arrowInfo(motionProc) arrowMove1}
+$c bind box2 <Button-1> {set demo_arrowInfo(motionProc) arrowMove2}
+$c bind box3 <Button-1> {set demo_arrowInfo(motionProc) arrowMove3}
+$c bind box <B1-Motion> "\$demo_arrowInfo(motionProc) $c %x %y"
+bind $c <ButtonRelease-1> "arrowSetup $c"
+
+# arrowMove1 --
+# This procedure is called for each mouse motion event on box1 (the
+# one at the vertex of the arrow).  It updates the controlling parameters
+# for the line and arrowhead.
+#
+# Arguments:
+# c -		The name of the canvas window.
+# x, y -	The coordinates of the mouse.
+
+proc arrowMove1 {c x y} {
+    upvar #0 demo_arrowInfo v
+    set newA [expr {($v(x2)+[scl 5]-round([$c canvasx $x]))/10}]
+    if {$newA < 0} {
+	set newA 0
+    }
+    set _25 [scl 25]
+    if {$newA > $_25} {
+	set newA $_25
+    }
+    if {$newA != $v(a)} {
+	$c move box1 [expr {10*($v(a)-$newA)}] 0
+	set v(a) $newA
+    }
+}
+
+# arrowMove2 --
+# This procedure is called for each mouse motion event on box2 (the
+# one at the trailing tip of the arrowhead).  It updates the controlling
+# parameters for the line and arrowhead.
+#
+# Arguments:
+# c -		The name of the canvas window.
+# x, y -	The coordinates of the mouse.
+
+proc arrowMove2 {c x y} {
+    upvar #0 demo_arrowInfo v
+    set _5 [scl 5]
+    set newB [expr {($v(x2)+$_5-round([$c canvasx $x]))/10}]
+    if {$newB < 0} {
+	set newB 0
+    }
+    set _25 [scl 25]
+    if {$newB > $_25} {
+	set newB $_25
+    }
+    set newC [expr {($v(y)+$_5-round([$c canvasy $y])-5*$v(width))/10}]
+    if {$newC < 0} {
+	set newC 0
+    }
+    set _20 [scl 20]
+    if {$newC > $_20} {
+	set newC $_20
+    }
+    if {($newB != $v(b)) || ($newC != $v(c))} {
+	$c move box2 [expr {10*($v(b)-$newB)}] [expr {10*($v(c)-$newC)}]
+	set v(b) $newB
+	set v(c) $newC
+    }
+}
+
+# arrowMove3 --
+# This procedure is called for each mouse motion event on box3 (the
+# one that controls the thickness of the line).  It updates the
+# controlling parameters for the line and arrowhead.
+#
+# Arguments:
+# c -		The name of the canvas window.
+# x, y -	The coordinates of the mouse.
+
+proc arrowMove3 {c x y} {
+    upvar #0 demo_arrowInfo v
+    set newWidth [expr {($v(y)+[scl 2]-round([$c canvasy $y]))/5}]
+    if {$newWidth < 0} {
+	set newWidth 0
+    }
+    set _20 [scl 20]
+    if {$newWidth > $_20} {
+	set newWidth $_20
+    }
+    if {$newWidth != $v(width)} {
+	$c move box3 0 [expr {5*($v(width)-$newWidth)}]
+	set v(width) $newWidth
+    }
+}

package/python/lib/tk9.0/demos/bind.tcl

@@ -0,0 +1,78 @@
+# bind.tcl --
+#
+# This demonstration script creates a text widget with bindings set
+# up for hypertext-like effects.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require tk
+
+set w .bind
+catch {destroy $w}
+toplevel $w
+wm title $w "Text Demonstration - Tag Bindings"
+wm iconname $w "bind"
+positionWindow $w
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+text $w.text -yscrollcommand "$w.scroll set" -setgrid 1 \
+	-width 60 -height 24 -font $font -wrap word
+ttk::scrollbar $w.scroll -command "$w.text yview"
+pack $w.scroll -side right -fill y
+pack $w.text -expand yes -fill both
+
+# Set up display styles.
+
+if {[winfo depth $w] > 1} {
+    set bold "-background #43ce80 -relief raised -borderwidth 1"
+    set normal "-background {} -relief flat"
+} else {
+    set bold "-foreground white -background black"
+    set normal "-foreground {} -background {}"
+}
+
+# Add text to widget.
+
+$w.text insert 0.0 {\
+The same tag mechanism that controls display styles in text widgets can also be used to associate Tcl commands with regions of text, so that mouse or keyboard actions on the text cause particular Tcl commands to be invoked.  For example, in the text below the descriptions of the canvas demonstrations have been tagged.  When you move the mouse over a demo description the description lights up, and when you press button 1 over a description then that particular demonstration is invoked.
+
+}
+$w.text insert end \
+{1. Samples of all the different types of items that can be created in canvas widgets.} d1
+$w.text insert end \n\n
+$w.text insert end \
+{2. A simple two-dimensional plot that allows you to adjust the positions of the data points.} d2
+$w.text insert end \n\n
+$w.text insert end \
+{3. Anchoring and justification modes for text items.} d3
+$w.text insert end \n\n
+$w.text insert end \
+{4. An editor for arrow-head shapes for line items.} d4
+$w.text insert end \n\n
+$w.text insert end \
+{5. A ruler with facilities for editing tab stops.} d5
+$w.text insert end \n\n
+$w.text insert end \
+{6. A grid that demonstrates how canvases can be scrolled.} d6
+
+# Create bindings for tags.
+
+foreach tag {d1 d2 d3 d4 d5 d6} {
+    $w.text tag bind $tag <Enter> "$w.text tag configure $tag $bold"
+    $w.text tag bind $tag <Leave> "$w.text tag configure $tag $normal"
+}
+# Main widget program sets variable tk_demoDirectory
+$w.text tag bind d1 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory items.tcl]}
+$w.text tag bind d2 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory plot.tcl]}
+$w.text tag bind d3 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory ctext.tcl]}
+$w.text tag bind d4 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory arrow.tcl]}
+$w.text tag bind d5 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory ruler.tcl]}
+$w.text tag bind d6 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory cscroll.tcl]}
+
+$w.text mark set insert 0.0
+$w.text configure -state disabled