unpoly-rails 1.0.3 → 2.0.0.pre.rc2

data/lib/assets/javascripts/unpoly/classes/request.coffee

@@ -1,247 +0,0 @@
-#= require ./record
-
-u = up.util
-e = up.element
-
-###**
-Instances of `up.Request` normalizes properties of an [`AJAX request`](/up.request)
-such as the requested URL, form parameters and HTTP method.
-
-@class up.Request
-###
-class up.Request extends up.Record
-
-  ###**
-  The HTTP method for the request.
-
-  @property up.Request#method
-  @param {string} method
-  @stable
-  ###
-
-  ###**
-  The URL for the request.
-
-  @property up.Request#url
-  @param {string} url
-  @stable
-  ###
-
-  ###**
-  [Parameters](/up.Params) that should be sent as the request's payload.
-
-  @property up.Request#params
-  @param {Object|FormData|string|Array} params
-  @stable
-  ###
-
-  ###**
-  The CSS selector that will be sent as an [`X-Up-Target` header](/up.protocol#optimizing-responses).
-
-  @property up.Request#target
-  @param {string} target
-  @stable
-  ###
-
-  ###**
-  The CSS selector that will be sent as an [`X-Up-Fail-Target` header](/up.protocol#optimizing-responses).
-
-  @property up.Request#failTarget
-  @param {string} failTarget
-  @stable
-  ###
-
-  ###**
-  An object of additional HTTP headers.
-
-  @property up.Request#headers
-  @param {Object} headers
-  @stable
-  ###
-
-  ###**
-  A timeout in milliseconds.
-
-  If [`up.proxy.config.maxRequests`](/up.proxy.config#config.maxRequests) is set,
-  the timeout will not include the time spent waiting in the queue.
-
-  @property up.Request#timeout
-  @param {Object|undefined} timeout
-  @stable
-  ###
-  fields: ->
-    [
-      'method',
-      'url',
-      'params',
-      'target',
-      'failTarget',
-      'headers',
-      'timeout',
-      'preload' # since up.proxy.request() options are sometimes wrapped in this class
-      'cache'   # since up.proxy.request() options are sometimes wrapped in this class
-    ]
-
-  ###**
-  Creates a new `up.Request` object.
-
-  This will not actually send the request over the network. For that use `up.request()`.
-
-  @constructor up.Request
-  @param {string} attrs.url
-  @param {string} [attrs.method='get']
-  @param {up.Params|string|Object|Array} [attrs.params]
-  @param {string} [attrs.target]
-  @param {string} [attrs.failTarget]
-  @param {Object<string, string>} [attrs.headers]
-  @param {number} [attrs.timeout]
-  @internal
-  ###
-  constructor: (options) ->
-    up.legacy.fixKey(options, 'data', 'params')
-    super(options)
-    @normalize()
-
-  normalize: =>
-    @params = new up.Params(@params) # copies, which we want
-    @method = u.normalizeMethod(@method)
-    @headers ||= {}
-    @extractHashFromUrl()
-
-    unless u.methodAllowsPayload(@method)
-      @transferParamsToUrl()
-
-  extractHashFromUrl: =>
-    urlParts = u.parseUrl(@url)
-    # Remember the #hash for later revealing.
-    # It will be lost during normalization.
-    @hash = u.presence(urlParts.hash)
-    @url = u.normalizeUrl(urlParts, hash: false)
-
-  transferParamsToUrl: =>
-    unless u.isBlank(@params)
-      # GET methods are not allowed to have a payload, so we transfer { params } params to the URL.
-      @url = @params.toURL(@url)
-      # Now that we have transfered the params into the URL, we delete them from the { params } option.
-      @params.clear()
-
-  transferSearchToParams: =>
-    paramsFromQuery = up.Params.fromURL(@url)
-    unless u.isBlank(paramsFromQuery)
-      @params.addAll(paramsFromQuery)
-      @url = u.normalizeUrl(@url, search: false)
-
-  isSafe: =>
-    up.proxy.isSafeMethod(@method)
-
-  send: =>
-    # We will modify this request below.
-    # This would confuse API clients and cache key logic in up.proxy.
-    new Promise (resolve, reject) =>
-      xhr = new XMLHttpRequest()
-
-      xhrHeaders = u.copy(@headers)
-      xhrUrl = @url
-      xhrParams = u.copy(@params)
-      xhrMethod = up.proxy.wrapMethod(@method, xhrParams)
-
-      xhrPayload = null
-      unless u.isBlank(xhrParams)
-        delete xhrHeaders['Content-Type'] # let the browser set the content type
-        xhrPayload = xhrParams.toFormData()
-
-      pc = up.protocol.config
-      xhrHeaders[pc.versionHeader] = up.version
-      xhrHeaders[pc.targetHeader] = @target if @target
-      xhrHeaders[pc.failTargetHeader] = @failTarget if @failTarget
-      xhrHeaders['X-Requested-With'] ||= 'XMLHttpRequest' unless @isCrossDomain()
-      if csrfToken = @csrfToken()
-        xhrHeaders[pc.csrfHeader] = csrfToken
-
-      xhr.open(xhrMethod, xhrUrl)
-
-      for header, value of xhrHeaders
-        xhr.setRequestHeader(header, value)
-
-      resolveWithResponse = =>
-        response = @buildResponse(xhr)
-        if response.isSuccess()
-          resolve(response)
-        else
-          reject(response)
-
-      # Convert from XHR API to promise API
-      xhr.onload = resolveWithResponse
-      xhr.onerror = resolveWithResponse
-      xhr.ontimeout = resolveWithResponse
-
-      xhr.timeout = @timeout if @timeout
-
-      xhr.send(xhrPayload)
-
-  navigate: =>
-    # GET forms cannot have an URL with a query section in their [action] attribute.
-    # The query section would be overridden by the serialized input values on submission.
-    @transferSearchToParams()
-
-    form = e.affix(document.body, 'form.up-page-loader')
-
-    addField = (attrs) ->
-      e.affix(form, 'input[type=hidden]', attrs)
-
-    if @method == 'GET'
-      formMethod = 'GET'
-    else
-      # Browser forms can only have GET or POST methods.
-      # When we want to make a request with another method, most backend
-      # frameworks allow to pass the method as a param.
-      addField(name: up.protocol.config.methodParam, value: @method)
-      formMethod = 'POST'
-
-    e.setAttrs(form, method: formMethod, action: @url)
-
-    if (csrfParam = up.protocol.csrfParam()) && (csrfToken = @csrfToken())
-      addField(name: csrfParam, value: csrfToken)
-
-    # @params will be undefined for GET requests, since we have already
-    # transfered all params to the URL during normalize().
-    u.each(@params.toArray(), addField)
-
-    e.hide(form)
-
-    up.browser.submitForm(form)
-
-  # Returns a csrfToken if this request requires it
-  csrfToken: =>
-    if !@isSafe() && !@isCrossDomain()
-      up.protocol.csrfToken()
-
-  isCrossDomain: =>
-    u.isCrossDomain(@url)
-
-  buildResponse: (xhr) =>
-    responseAttrs =
-      method: @method
-      url: @url
-      text: xhr.responseText
-      status: xhr.status
-      request: @
-      xhr: xhr
-
-    if urlFromServer = up.protocol.locationFromXhr(xhr)
-      responseAttrs.url = urlFromServer
-      # If the server changes a URL, it is expected to signal a new method as well.
-      responseAttrs.method = up.protocol.methodFromXhr(xhr) ? 'GET'
-
-    responseAttrs.title = up.protocol.titleFromXhr(xhr)
-
-    new up.Response(responseAttrs)
-
-  isCachable: =>
-    @isSafe() && !u.isFormData(@params)
-
-  cacheKey: =>
-    [@url, @method, @params.toQuery(), @target].join('|')
-
-  @wrap: (value) ->
-    u.wrapValue(value, @)

data/lib/assets/javascripts/unpoly/classes/response.coffee

@@ -1,157 +0,0 @@
-#= require ./record
-
-u = up.util
-
-###**
-Instances of `up.Response` describe the server response to an [`AJAX request`](/up.request).
-
-\#\#\# Example
-
-    up.request('/foo').then(function(response) {
-      console.log(response.status) // 200
-      console.log(response.text)   // "<html><body>..."
-    })
-
-@class up.Response
-###
-class up.Response extends up.Record
-
-  ###**
-  The HTTP method used for the response.
-
-  This is usually the HTTP method used by the request.
-  However, after a redirect the server should signal a `GET` method using
-  an [`X-Up-Method: GET` header](/up.protocol#redirect-detection).
-
-  @property up.Response#method
-  @param {string} method
-  @stable
-  ###
-
-  ###**
-  The URL used for the response.
-
-  This is usually the requested URL.
-  However, after a redirect the server should signal a the new URL
-  using an [`X-Up-Location: /new-url` header](/up.protocol#redirect-detection).
-
-  @property up.Response#url
-  @param {string} method
-  @stable
-  ###
-
-  ###**
-  The response body as a `string`.
-
-  @property up.Response#text
-  @param {string} text
-  @stable
-  ###
-
-  ###**
-  The response's
-  [HTTP status code](https://en.wikipedia.org/wiki/List_of_HTTP_status_codes)
-  as a `number`.
-
-  A successful response will usually have a `200` or `201' status code.
-
-  @property up.Response#status
-  @param {number} status
-  @stable
-  ###
-
-  ###**
-  The [request](/up.Request) that triggered this response.
-
-  @property up.Response#request
-  @param {up.Request} request
-  @experimental
-  ###
-
-  ###**
-  The [`XMLHttpRequest`](https://developer.mozilla.org/en-US/docs/Web/API/XMLHttpRequest)
-  object that was used to create this response.
-
-  @property up.Response#xhr
-  @param {XMLHttpRequest} xhr
-  @experimental
-  ###
-
-  ###**
-  A [document title pushed by the server](/up.protocol#pushing-a-document-title-to-the-client).
-
-  If the server pushed no title via HTTP header, this will be `undefined`.
-
-  @property up.Response#title
-  @param {string} [title]
-  @stable
-  ###
-  fields: ->
-    [
-      'method',
-      'url',
-      'text',
-      'status',
-      'request',
-      'xhr',
-      'title',
-    ]
-
-  ###**
-  @constructor up.Response
-  @internal
-  ###
-  constructor: (options) ->
-    super(options)
-
-  ###**
-  Returns whether the server responded with a 2xx HTTP status.
-
-  @function up.Response#isSuccess
-  @return {boolean}
-  @experimental
-  ###
-  isSuccess: =>
-    @status && (@status >= 200 && @status <= 299)
-
-  ###**
-  Returns whether the response was not [successful](/up.Request.prototype.isSuccess).
-
-  This also returns `true` when the request encountered a [fatal error](/up.Request.prototype.isFatalError)
-  like a timeout or loss of network connectivity.
-
-  @function up.Response#isError
-  @return {boolean}
-  @experimental
-  ###
-  isError: =>
-    !@isSuccess()
-
-  ###**
-  Returns whether the request encountered a [fatal error](/up.Request.prototype.isFatalError)
-  like a timeout or loss of network connectivity.
-
-  When the server produces an error message with an HTTP status like `500`,
-  this is not considered a fatal error and `false` is returned.
-
-  @function up.Response#isFatalError
-  @return {boolean}
-  @experimental
-  ###
-  isFatalError: =>
-    @isError() && u.isBlank(@text)
-
-  ###**
-  Returns the HTTP header value with the given name.
-
-  The search for the header name is case-insensitive.
-
-  Returns `undefined` if the given header name was not included in the response.
-
-  @function up.Response#getHeader
-  @param {string} name
-  @return {string|undefined} value
-  @experimental
-  ###
-  getHeader: (name) =>
-    @xhr.getResponseHeader(name)

data/lib/assets/javascripts/unpoly/classes/reveal_motion.coffee

@@ -1,102 +0,0 @@
-e = up.element
-
-class up.RevealMotion
-
-  constructor: (@element, options = {}) ->
-    layoutConfig = up.viewport.config
-    @viewport = options.viewport ? up.viewport.closest(@element)
-    up.legacy.fixKey(layoutConfig, 'snap', 'revealSnap')
-    snapDefault = layoutConfig.revealSnap
-    @snap = options.snap ? options.revealSnap ? snapDefault
-    if @snap == false
-      @snap = 0
-    else if @snap == true
-      @snap = snapDefault
-    @padding = options.padding ? options.revealPadding ? layoutConfig.revealPadding
-    @top = options.top
-    @fixedTop = options.fixedTop ? layoutConfig.fixedTop
-    @fixedBottom = options.fixedBottom ? layoutConfig.fixedBottom
-
-    # Options for up.ScrollMotion
-    @speed = options.speed ? options.scrollSpeed ? layoutConfig.scrollSpeed
-    @behavior = options.behavior ? options.scrollBehavior
-
-  start: ->
-    elementRect = up.Rect.fromElement(@element)
-    viewportRect = @getViewportRect(@viewport)
-
-    @addPadding(elementRect)
-    @substractObstructions(viewportRect)
-
-    if viewportRect.height <= 0
-      return Promise.reject(new Error('Viewport has no visible area'))
-
-    originalScrollTop = @viewport.scrollTop
-    newScrollTop = originalScrollTop
-
-    if @top || elementRect.height > viewportRect.height
-      # Element is either larger than the viewport,
-      # or the user has explicitely requested for the element to align at top
-      # => Scroll the viewport so the first element row is the first viewport row
-      diff = elementRect.top - viewportRect.top
-      newScrollTop += diff
-    else if elementRect.top < viewportRect.top
-      # Element fits within viewport, but sits too high
-      # => Scroll up (reduce scrollY), so the element comes down
-      newScrollTop -= (viewportRect.top - elementRect.top)
-    else if elementRect.bottom > viewportRect.bottom
-      # Element fits within viewport, but sits too low
-      # => Scroll down (increase scrollY), so the element comes up
-      newScrollTop += (elementRect.bottom - viewportRect.bottom)
-    else
-      # Element is fully visible within viewport
-      # => Do nothing
-
-    if newScrollTop < @snap && elementRect.top < (0.5 * viewportRect.height)
-      newScrollTop = 0
-
-    if newScrollTop != originalScrollTop
-      @scrollTo(newScrollTop)
-    else
-      Promise.resolve()
-
-  scrollTo: (newScrollTop) ->
-    scrollOptions =
-      speed: @speed
-      behavior: @behavior
-    @scrollMotion = new up.ScrollMotion(@viewport, newScrollTop, scrollOptions)
-    @scrollMotion.start()
-
-  getViewportRect: ->
-    if up.viewport.isRoot(@viewport)
-      # Other than an element with overflow-y, the document viewport
-      # stretches to the full height of its contents. So we create a viewport
-      # sized to the usuable screen area.
-      new up.Rect
-        left: 0
-        top: 0
-        width: up.viewport.rootWidth()
-        height: up.viewport.rootHeight()
-    else
-      up.Rect.fromElement(@viewport)
-
-  addPadding: (elementRect) ->
-    elementRect.top -= @padding
-    elementRect.height += 2 * @padding
-
-  substractObstructions: (viewportRect) ->
-    for obstruction in e.list(@fixedTop...)
-      obstructionRect = up.Rect.fromElement(obstruction)
-      diff = obstructionRect.bottom - viewportRect.top
-      if diff > 0
-        viewportRect.top += diff
-        viewportRect.height -= diff
-
-    for obstruction in e.list(@fixedBottom...)
-      obstructionRect = up.Rect.fromElement(obstruction)
-      diff = viewportRect.bottom - obstructionRect.top
-      if diff > 0
-        viewportRect.height -= diff
-
-  finish: ->
-    @scrollMotion?.finish()

data/lib/assets/javascripts/unpoly/classes/scroll_motion.coffee

@@ -1,67 +0,0 @@
-u = up.util
-
-class up.ScrollMotion
-
-  # We want to make the default speed mimic Chrome's smooth scrolling behavior.
-  # We also want to keep the default value in up.viewport.config.scrollSpeed to be 1.
-  # For our calculation in #animationFrame() we need to multiply it with this factor.
-  SPEED_CALIBRATION = 0.065
-
-  constructor: (@scrollable, @targetTop, options = {}) ->
-    # The option for up.scroll() is { behavior }, but coming
-    # from up.replace() it's { scrollBehavior }.
-    @behavior = options.behavior ? options.scrollBehavior ? 'auto'
-
-    # The option for up.scroll() is { behavior }, but coming
-    # from up.replace() it's { scrollSpeed }.
-    @speed = (options.speed ? options.scrollSpeed ? up.viewport.config.scrollSpeed) * SPEED_CALIBRATION
-
-  start: =>
-    return new Promise (@resolve, @reject) =>
-      if @behavior == 'smooth' && up.motion.isEnabled()
-        @startAnimation()
-      else
-        @finish()
-
-  startAnimation: ->
-    @startTime = Date.now()
-    @startTop = @scrollable.scrollTop
-    @topDiff = @targetTop - @startTop
-    # We're applying a square root to become slower for small distances
-    # and faster for large distances.
-    @duration = Math.sqrt(Math.abs(@topDiff)) / @speed
-    requestAnimationFrame(@animationFrame)
-
-  animationFrame: =>
-    return if @settled
-
-    # When the scroll position is not the one we previously set, we assume
-    # that the user has tried scrolling on her own. We then cancel the scrolling animation.
-    if @frameTop && Math.abs(@frameTop - @scrollable.scrollTop) > 1.5
-      @cancel('Animation aborted due to user intervention')
-
-    currentTime = Date.now()
-    timeElapsed = currentTime - @startTime
-    timeFraction = Math.min(timeElapsed / @duration, 1)
-
-    @frameTop = @startTop + (u.simpleEase(timeFraction) * @topDiff)
-
-    # When we're very close to the target top, finish the animation
-    # directly to deal with rounding errors.
-    if Math.abs(@targetTop - @frameTop) < 0.3
-      @finish()
-    else
-      @scrollable.scrollTop = @frameTop
-      requestAnimationFrame(@animationFrame)
-
-  cancel: (reason) =>
-    @settled = true
-    @reject(new Error(reason))
-
-  finish: =>
-    # In case we're animating with emulation, cancel the next scheduled frame
-    @settled = true
-    # Setting the { scrollTop } prop will also finish a native scrolling
-    # animation in Firefox and Chrome.
-    @scrollable.scrollTop = @targetTop
-    @resolve()

data/lib/assets/javascripts/unpoly/classes/selector.coffee

@@ -1,60 +0,0 @@
-u = up.util
-
-class up.Selector
-
-  CSS_HAS_SUFFIX_PATTERN = new RegExp("\\:has\\(([^\\)]+)\\)$")
-  MATCH_FN_NAME = if up.browser.isIE11() then 'msMatchesSelector' else 'matches'
-
-  constructor: (@selector, @filterFn) ->
-
-  matches: (element) ->
-    doesMatch = element[MATCH_FN_NAME](@selector)
-    doesMatch &&= @filterFn(element) if @filterFn
-    doesMatch
-
-  descendants: (root) ->
-    matches = root.querySelectorAll(@selector)
-    if @filterFn
-      matches = u.filter(matches, @filterFn)
-    matches
-
-  descendant: (root) ->
-    if !@filterFn
-     root.querySelector(@selector)
-    else
-      candidates = root.querySelectorAll(@selector)
-      u.find(candidates, @filterFn)
-
-  subtree: (root) ->
-    matches = []
-    if @matches(root)
-      matches.push(root)
-    matches.push(@descendants(root)...)
-    matches
-
-  closest: (root) ->
-    if root.closest && !@filterFn
-      return root.closest(@selector)
-    else
-      return @closestPolyfill(root)
-
-  closestPolyfill: (root) ->
-    if @matches(root, @selector)
-      root
-    else
-      @ancestor(root)
-
-  ancestor: (element) ->
-    if parentElement = element.parentElement
-      if @matches(parentElement)
-        parentElement
-      else
-        @ancestor(parentElement)
-
-  @parse: (selector) ->
-    filter = null
-    selector = selector.replace CSS_HAS_SUFFIX_PATTERN, (match, descendantSelector) ->
-      filter = (element) ->
-        element.querySelector(descendantSelector)
-      return ''
-    new @(selector, filter)

data/lib/assets/javascripts/unpoly/classes/store/memory.coffee

@@ -1,26 +0,0 @@
-up.store ||= {}
-
-u = up.util
-
-class up.store.Memory
-
-  constructor: ->
-    @clear()
-
-  clear: =>
-    @data = {}
-
-  get: (key) =>
-    @data[key]
-
-  set: (key, value) =>
-    @data[key] = value
-
-  remove: (key) =>
-    delete @data[key]
-
-  keys: =>
-    Object.keys(@data)
-
-  values: =>
-    u.values(@data)