unpoly-rails 1.0.3 → 2.0.0.pre.rc2

data/lib/assets/javascripts/unpoly/browser.coffee.erb

@@ -1,240 +0,0 @@
-###**
-Browser support
-===============
-
-Unpoly supports all modern browsers.
-
-Chrome, Firefox, Edge, Safari
-: Full support
-
-Internet Explorer 11
-: Full support with a `Promise` polyfill like [es6-promise](https://github.com/stefanpenner/es6-promise) (2.4 KB).
-
-Internet Explorer 10 or lower
-: Unpoly prevents itself from booting itself, leaving you with a classic server-side application.
-
-@module up.browser
-###
-up.browser = do ->
-
-  u = up.util
-
-  ###**
-  @method up.browser.navigate
-  @param {string} url
-  @param {string} [options.method='get']
-  @param {object|Array|FormData|string} [options.params]
-  @internal
-  ###
-  navigate = (url, options) ->
-    requestOpts = u.merge(options, { url })
-    request = new up.Request(requestOpts)
-    request.navigate()
-
-  ###**
-  For mocking in specs.
-
-  @method submitForm
-  ###
-  submitForm = (form) ->
-    form.submit()
-
-  url = ->
-    location.href
-
-  isIE10OrWorse = u.memoize ->
-    !window.atob
-
-  isIE11 = u.memoize ->
-    'ActiveXObject' of window # this is undefined, but the key is set
-
-  ###**
-  Returns whether this browser supports manipulation of the current URL
-  via [`history.pushState`](https://developer.mozilla.org/en-US/docs/Web/API/History/pushState).
-
-  When `pushState`  (e.g. through [`up.follow()`](/up.follow)), it will gracefully
-  fall back to a full page load.
-
-  Note that Unpoly will not use `pushState` if the initial page was loaded with
-  a request method other than GET.
-
-  @function up.browser.canPushState
-  @return {boolean}
-  @experimental
-  ###
-  canPushState = ->
-    # We cannot use pushState if the initial request method is a POST for two reasons:
-    #
-    # 1. Unpoly replaces the initial state so it can handle the pop event when the
-    #    user goes back to the initial URL later. If the initial request was a POST,
-    #    Unpoly will wrongly assumed that it can restore the state by reloading with GET.
-    #
-    # 2. Some browsers have a bug where the initial request method is used for all
-    #    subsequently pushed states. That means if the user reloads the page on a later
-    #    GET state, the browser will wrongly attempt a POST request.
-    #    This issue affects Safari 9 and 10 (last tested in 2017-08).
-    #    Modern Firefoxes, Chromes and IE10+ don't have this behavior.
-    #
-    # The way that we work around this is that we don't support pushState if the
-    # initial request method was anything other than GET (but allow the rest of the
-    # Unpoly framework to work). This way Unpoly will fall back to full page loads until
-    # the framework was booted from a GET request.
-    u.isDefined(history.pushState) && up.protocol.initialRequestMethod() == 'get'
-
-  ###**
-  Returns whether this browser supports animation using
-  [CSS transitions](https://developer.mozilla.org/en-US/docs/Web/CSS/CSS_Transitions).
-
-  When Unpoly is asked to animate history on a browser that doesn't support
-  CSS transitions (e.g. through [`up.animate()`](/up.animate)), it will skip the
-  animation by instantly jumping to the last frame.
-
-  @function up.browser.canCssTransition
-  @return {boolean}
-  @internal
-  ###
-  canCssTransition = u.memoize ->
-    'transition' of document.documentElement.style
-
-  ###**
-  Returns whether this browser supports the DOM event [`input`](https://developer.mozilla.org/de/docs/Web/Events/input).
-
-  @function up.browser.canInputEvent
-  @return {boolean}
-  @internal
-  ###
-  canInputEvent = u.memoize ->
-    'oninput' of document.createElement('input')
-
-  ###**
-  Returns whether this browser supports promises.
-
-  @function up.browser.canPromise
-  @return {boolean}
-  @internal
-  ###
-  canPromise = u.memoize ->
-    !!window.Promise
-
-  ###**
-  Returns whether this browser supports the [`FormData`](https://developer.mozilla.org/en-US/docs/Web/API/FormData)
-  interface.
-
-  @function up.browser.canFormData
-  @return {boolean}
-  @experimental
-  ###
-  canFormData = u.memoize ->
-    !!window.FormData
-
-  ###**
-  @function up.browser.canInspectFormData
-  @return {boolean}
-  @internal
-  ###
-  canInspectFormData = u.memoize ->
-    canFormData() && !!FormData.prototype.entries
-
-  ###**
-  Returns whether this browser supports the [`DOMParser`](https://developer.mozilla.org/en-US/docs/Web/API/DOMParser)
-  interface.
-
-  @function up.browser.canDOMParser
-  @return {boolean}
-  @internal
-  ###
-  canDOMParser = u.memoize ->
-    !!window.DOMParser
-
-  ###**
-  Returns whether this browser supports the [`debugging console`](https://developer.mozilla.org/en-US/docs/Web/API/Console).
-
-  @function up.browser.canConsole
-  @return {boolean}
-  @internal
-  ###
-  canConsole = u.memoize ->
-    window.console &&
-      console.debug &&
-      console.info &&
-      console.warn &&
-      console.error &&
-      console.group &&
-      console.groupCollapsed &&
-      console.groupEnd
-
-  canCustomElements = u.memoize ->
-    !!window.customElements
-
-  canAnimationFrame = u.memoize ->
-    'requestAnimationFrame' of window
-
-  canControlScrollRestoration = u.memoize ->
-    'scrollRestoration' of history
-
-  # Don't memoize so a build may publish window.jQuery after Unpoly was loaded
-  canJQuery = ->
-    !!window.jQuery
-
-  popCookie = (name) ->
-    value = document.cookie.match(new RegExp(name+"=(\\w+)"))?[1]
-    if u.isPresent(value)
-      document.cookie = name + '=; expires=Thu, 01-Jan-70 00:00:01 GMT; path=/'
-    value
-
-  ###**
-  @function up,browser.whenConfirmed
-  @return {Promise}
-  @param {string} options.confirm
-  @param {boolean} options.preload
-  @internal
-  ###
-  whenConfirmed = (options) ->
-    if options.preload || u.isBlank(options.confirm) || window.confirm(options.confirm)
-      Promise.resolve()
-    else
-      Promise.reject(new Error('User canceled action'))
-
-  ###**
-  Returns whether Unpoly supports the current browser.
-
-  If this returns `false` Unpoly will prevent itself from [booting](/up.boot)
-  and ignores all registered [event handlers](/up.on) and [compilers](/up.compiler).
-  This leaves you with a classic server-side application.
-  This is usually a better fallback than loading incompatible Javascript and causing
-  many errors on load.
-
-  @function up.browser.isSupported
-  @stable
-  ###
-  isSupported = ->
-    !isIE10OrWorse() &&
-      canConsole() &&
-      # We don't require pushState in order to cater for Safari booting Unpoly with a non-GET method.
-      # canPushState() &&
-      canDOMParser() &&
-      canFormData() &&
-      canCssTransition() &&
-      canInputEvent() &&
-      canPromise() &&
-      canAnimationFrame()
-
-  callJQuery = (args...) ->
-    canJQuery() or up.fail("jQuery must be published as window.jQuery")
-    return jQuery(args...)
-
-  <% if ENV['JS_KNIFE'] %>knife: eval(Knife.point)<% end %>
-  url: url
-  navigate: navigate
-  submitForm: submitForm
-  canPushState: canPushState
-  canFormData: canFormData
-  canInspectFormData: canInspectFormData
-  canCustomElements: canCustomElements
-  canControlScrollRestoration: canControlScrollRestoration
-  canJQuery: canJQuery
-  whenConfirmed: whenConfirmed
-  isSupported: isSupported
-  popCookie: popCookie
-  jQuery: callJQuery
-  isIE11: isIE11

data/lib/assets/javascripts/unpoly/classes/body_shifter.coffee

@@ -1,45 +0,0 @@
-e = up.element
-
-# Gives `<body>` a right padding in the width of a scrollbar.
-# Also gives elements anchored to the right side of the screen
-# an increased `right`.
-#
-# This is to prevent the body and elements from jumping when we add the
-# modal overlay, which has its own scroll bar.
-# This is screwed up, but Bootstrap does the same.
-class up.BodyShifter
-
-  constructor: ->
-    @unshiftFns = []
-
-  shift: ->
-    # Remember whether the root viewport has a visible scrollbar at rest.
-    # It will disappear when we set overflow-y: hidden below.
-    rootHadVerticalScrollbar = up.viewport.rootHasVerticalScrollbar()
-
-    # Even if root viewport has no scroll bar, we still want to give overflow-y: hidden
-    # to the <body> element. Otherwise the user could scroll the underlying page by
-    # scrolling over the dimmed backdrop (observable with touch emulation in Chrome DevTools).
-    # Note that some devices don't show a vertical scrollbar at rest for a viewport, even
-    # when it can be scrolled.
-    overflowElement = up.viewport.rootOverflowElement()
-    @unshiftFns.push e.setTemporaryStyle(overflowElement, overflowY: 'hidden')
-
-    if rootHadVerticalScrollbar
-      body = document.body
-
-      scrollbarWidth = up.viewport.scrollbarWidth()
-
-      bodyRightPadding = e.styleNumber(body, 'paddingRight')
-      bodyRightShift = scrollbarWidth + bodyRightPadding
-
-      @unshiftFns.push e.setTemporaryStyle(body, paddingRight: bodyRightShift)
-
-      for anchor in up.viewport.anchoredRight()
-        elementRight = e.styleNumber(anchor, 'right')
-        elementRightShift = scrollbarWidth + elementRight
-        @unshiftFns.push e.setTemporaryStyle(anchor, right: elementRightShift)
-
-  unshift: ->
-    while unshiftFn = @unshiftFns.pop()
-      unshiftFn()

data/lib/assets/javascripts/unpoly/classes/cache.coffee

@@ -1,127 +0,0 @@
-u = up.util
-
-###**
-@class up.Cache
-@internal
-###
-class up.Cache
-
-  ###**
-  @constructor
-  @param {number|Function(): number} [config.size]
-    Maximum number of cache entries.
-    Set to `undefined` to not limit the cache size.
-  @param {number|Function(): number} [config.expiry]
-    The number of milliseconds after which a cache entry
-    will be discarded.
-  @param {string} [config.logPrefix]
-    A prefix for log entries printed by this cache object.
-  @param {Function(entry): string} [config.key]
-    A function that takes an argument and returns a string key
-    for storage. If omitted, `toString()` is called on the argument.
-  @param {Function(entry): boolean} [config.cachable]
-    A function that takes a potential cache entry and returns whether
-    this entry  can be stored in the hash. If omitted, all entries are considered
-    cachable.
-  ###
-  constructor: (@config = {}) ->
-    @store = @config.store || new up.store.Memory()
-
-  maxKeys: =>
-    u.evalOption(@config.size)
-
-  expiryMillis: =>
-    u.evalOption(@config.expiry)
-
-  normalizeStoreKey: (key) =>
-    if @config.key
-      @config.key(key)
-    else
-      key.toString()
-
-  isEnabled: =>
-    @maxKeys() isnt 0 && @expiryMillis() isnt 0
-
-  isCachable: (key) =>
-    if @config.cachable
-      @config.cachable(key)
-    else
-      true
-
-  clear: =>
-    @store.clear()
-
-  log: (args...) =>
-    if @config.logPrefix
-      args[0] = "[#{@config.logPrefix}] #{args[0]}"
-      up.puts(args...)
-
-  keys: =>
-    @store.keys()
-
-  makeRoomForAnotherKey: =>
-    storeKeys = u.copy(@keys())
-    max = @maxKeys()
-    if max && storeKeys.length >= max
-      oldestKey = undefined
-      oldestTimestamp = undefined
-      u.each storeKeys, (key) =>
-        entry = @store.get(key) # we don't need to call cacheKey here
-        timestamp = entry.timestamp
-        if !oldestTimestamp || oldestTimestamp > timestamp
-          oldestKey = key
-          oldestTimestamp = timestamp
-      @store.remove(oldestKey) if oldestKey
-
-  alias: (oldKey, newKey) =>
-    value = @get(oldKey, silent: true)
-    if u.isDefined(value)
-      @set(newKey, value)
-
-  timestamp: =>
-    (new Date()).valueOf()
-
-  set: (key, value) =>
-    if @isEnabled() && @isCachable(key)
-      @makeRoomForAnotherKey()
-      storeKey = @normalizeStoreKey(key)
-      @log("Setting entry %o to %o", storeKey, value)
-      timestampedValue =
-        timestamp: @timestamp()
-        value: value
-      @store.set(storeKey, timestampedValue)
-
-  remove: (key) =>
-    if @isCachable(key)
-      storeKey = @normalizeStoreKey(key)
-      @store.remove(storeKey)
-
-  isFresh: (entry) =>
-    millis = @expiryMillis()
-    if millis
-      timeSinceTouch = @timestamp() - entry.timestamp
-      timeSinceTouch < millis
-    else
-      true
-
-  get: (key, options = {}) =>
-    if @isCachable(key) && (entry = @store.get(@normalizeStoreKey(key)))
-      if @isFresh(entry)
-        @log("Cache hit for '%s'", key) unless options.silent
-        entry.value
-      else
-        @log("Discarding stale cache entry for '%s'", key) unless options.silent
-        @remove(key)
-        undefined
-    else
-      @log("Cache miss for '%s'", key) unless options.silent
-      undefined
-
-#  first: (keyOrKeys) =>
-#    @all(keyOrKeys)[0]
-#
-#  all: (keys = @keys()) =>
-#    keys = u.wrapArray(keys)
-#    matches = u.map keys, (key) =>
-#      @get(key)
-#    u.filter(matches, u.isPresent)

data/lib/assets/javascripts/unpoly/classes/compile_pass.coffee

@@ -1,93 +0,0 @@
-#= require ./record
-
-u = up.util
-e = up.element
-
-class up.CompilePass
-
-  constructor: (@root, @compilers, options = {}) ->
-    # Exclude all elements that are descendants of the subtrees we want to keep.
-    # The exclusion process is very expensive (in one case compiling 100 slements
-    # took 1.5s because of this). That's why we only do it if (1) options.skipSubtrees
-    # was given and (2) there is an [up-keep] element in root.
-    @skipSubtrees = options.skip
-    unless @skipSubtrees.length && @root.querySelector('[up-keep]')
-      @skipSubtrees = undefined
-
-  compile: ->
-    up.log.group "Compiling fragment %o", @root, =>
-      for compiler in @compilers
-        @runCompiler(compiler)
-
-  runCompiler: (compiler) ->
-    matches = @select(compiler.selector)
-    return unless matches.length
-
-    up.log.group ("Compiling '%s' on %d element(s)" unless compiler.isDefault), compiler.selector, matches.length, =>
-      if compiler.batch
-        @compileBatch(compiler, matches)
-      else
-        for match in matches
-          @compileOneElement(compiler, match)
-
-      # up.compiler() has a legacy { keep } option that will automatically
-      # set [up-keep] on the elements it compiles
-      if keepValue = compiler.keep
-        value = if u.isString(keepValue) then keepValue else ''
-        for match in matches
-          match.setAttribute('up-keep', value)
-
-  compileOneElement: (compiler, element) ->
-    elementArg = if compiler.jQuery then up.browser.jQuery(element) else element
-    compileArgs = [elementArg]
-    # Do not retrieve and parse [up-data] unless the compiler function
-    # expects a second argument. Note that we must pass data for an argument
-    # count of 0, since then the function might take varargs.
-    unless compiler.length == 1
-      data = up.syntax.data(element)
-      compileArgs.push(data)
-
-    result = compiler.apply(element, compileArgs)
-
-    if destructorOrDestructors = @destructorPresence(result)
-      up.destructor(element, destructorOrDestructors)
-
-  compileBatch: (compiler, elements) ->
-    elementsArgs = if compiler.jQuery then up.browser.jQuery(elements) else elements
-    compileArgs = [elementsArgs]
-    # Do not retrieve and parse [up-data] unless the compiler function
-    # expects a second argument. Note that we must pass data for an argument
-    # count of 0, since then the function might take varargs.
-    unless compiler.length == 1
-      dataList = u.map(elements, up.syntax.data)
-      compileArgs.push(dataList)
-
-    result = compiler.apply(elements, compileArgs)
-
-    if @destructorPresence(result)
-      up.fail('Compilers with { batch: true } cannot return destructors')
-
-  destructorPresence: (result) ->
-    # Check if the result value looks like a destructor to filter out
-    # unwanted implicit returns in CoffeeScript.
-    if u.isFunction(result) || u.isArray(result) && (u.every(result, u.isFunction))
-      result
-
-  select: (selector) ->
-    if u.isFunction(selector)
-      selector = selector()
-
-    matches = e.subtree(@root, selector)
-    if @skipSubtrees
-      matches = u.reject(matches, @isInSkippedSubtree)
-
-    matches
-
-  isInSkippedSubtree: (element) =>
-    if u.contains(@skipSubtrees, element)
-      true
-    else if parent = element.parentElement
-      @isInSkippedSubtree(parent)
-    else
-      false
-

data/lib/assets/javascripts/unpoly/classes/config.coffee

@@ -1,9 +0,0 @@
-u = up.util
-
-class up.Config
-
-  constructor: (@blueprint) ->
-    @reset()
-
-  reset: ->
-    u.assign(@, u.deepCopy(@blueprint))

data/lib/assets/javascripts/unpoly/classes/css_transition.coffee

@@ -1,118 +0,0 @@
-u = up.util
-e = up.element
-
-class up.CssTransition
-
-  constructor: (@element, @lastFrameKebab, options) ->
-    @lastFrameKeysKebab = Object.keys(@lastFrameKebab)
-    if u.some(@lastFrameKeysKebab, (key) -> key.match(/A-Z/))
-      up.fail('Animation keys must be kebab-case')
-    @finishEvent = options.finishEvent
-    @duration = options.duration
-    @delay = options.delay
-    @totalDuration = @delay + @duration
-    @easing = options.easing
-    @finished = false
-
-  start: =>
-    if @lastFrameKeysKebab.length == 0
-      @finished = true
-      # If we have nothing to animate, we will never get a transitionEnd event
-      # and the returned promise will never resolve.
-      return Promise.resolve()
-
-    @deferred = u.newDeferred()
-    @pauseOldTransition()
-    @startTime = new Date()
-    @startFallbackTimer()
-    @listenToFinishEvent()
-    @listenToTransitionEnd()
-
-    @startMotion()
-
-    return @deferred.promise()
-
-  listenToFinishEvent: =>
-    if @finishEvent
-      @stopListenToFinishEvent = @element.addEventListener(@finishEvent, @onFinishEvent)
-
-  onFinishEvent: (event) =>
-    # don't waste time letting the event bubble up the DOM
-    event.stopPropagation()
-    @finish()
-
-  startFallbackTimer: =>
-    timingTolerance = 100
-    @fallbackTimer = u.timer (@totalDuration + timingTolerance), =>
-      @finish()
-
-  stopFallbackTimer: =>
-    clearTimeout(@fallbackTimer)
-
-  listenToTransitionEnd: =>
-    @stopListenToTransitionEnd = up.on(@element, 'transitionend', @onTransitionEnd)
-
-  onTransitionEnd: (event) =>
-    # Check if the transitionend event was caused by our own transition,
-    # and not by some other transition that happens to affect this element.
-    return unless event.target == @element
-
-    # Check if we are receiving a late transitionEnd event
-    # from a previous CSS transition.
-    elapsed = new Date() - @startTime
-    return unless elapsed > 0.25 * @totalDuration
-
-    completedPropertyKebab = event.propertyName
-    return unless u.contains(@lastFrameKeysKebab, completedPropertyKebab)
-
-    @finish()
-
-  finish: =>
-    # Make sure that any queued events won't finish multiple times.
-    return if @finished
-    @finished = true
-
-    @stopFallbackTimer()
-    @stopListenToFinishEvent?()
-    @stopListenToTransitionEnd?()
-
-    # Cleanly finish our own transition so the old transition
-    # (or any other transition set right after that) will be able to take effect.
-    e.concludeCssTransition(@element)
-
-    @resumeOldTransition()
-
-    @deferred.resolve()
-
-  pauseOldTransition: =>
-    oldTransition = e.style(@element, [
-      'transitionProperty',
-      'transitionDuration',
-      'transitionDelay',
-      'transitionTimingFunction'
-    ])
-
-    if e.hasCssTransition(oldTransition)
-      # Freeze the previous transition at its current place, by setting the currently computed,
-      # animated CSS properties as inline styles. Transitions on all properties will not be frozen,
-      # since that would involve setting every single CSS property as an inline style.
-      unless oldTransition.transitionProperty == 'all'
-        oldTransitionProperties = oldTransition.transitionProperty.split(/\s*,\s*/)
-        oldTransitionFrameKebab = e.style(@element, oldTransitionProperties)
-        @setOldTransitionTargetFrame = e.setTemporaryStyle(@element, oldTransitionFrameKebab)
-
-      # Stop the existing CSS transition so it does not emit transitionEnd events
-      @setOldTransition = e.concludeCssTransition(@element)
-
-  resumeOldTransition: =>
-    @setOldTransitionTargetFrame?()
-    @setOldTransition?()
-
-  startMotion: =>
-    e.setStyle @element,
-      transitionProperty: Object.keys(@lastFrameKebab).join(', ')
-      transitionDuration: "#{@duration}ms"
-      transitionDelay: "#{@delay}ms"
-      transitionTimingFunction: @easing
-    e.setStyle(@element, @lastFrameKebab)
-

data/lib/assets/javascripts/unpoly/classes/divertible_chain.coffee

@@ -1,39 +0,0 @@
-u = up.util
-
-###**
-A linear task queue whose (2..n)th tasks can be changed at any time.
-
-@function up.DivertibleChain
-@internal
-###
-class up.DivertibleChain
-
-  constructor: ->
-    @reset()
-
-  reset: =>
-    @queue = []
-    @currentTask = undefined
-
-  promise: =>
-    lastTask = u.last(@allTasks())
-    lastTask?.promise || Promise.resolve()
-
-  allTasks: =>
-    tasks = []
-    tasks.push(@currentTask) if @currentTask
-    tasks = tasks.concat(@queue)
-    tasks
-
-  poke: =>
-    unless @currentTask # don't start a new task while we're still running one
-      if @currentTask = @queue.shift()
-        promise = @currentTask()
-        u.always promise, =>
-          @currentTask = undefined
-          @poke()
-
-  asap: (newTasks...) =>
-    @queue = u.map(newTasks, u.previewable)
-    @poke()
-    @promise()