trackler 2.2.1.33 → 2.2.1.34

data/tracks/coldfusion/exercises/sum-of-multiples/box.json

@@ -0,0 +1,8 @@
+{
+    "dependencies":{
+        "testbox":"^2.5.0+107"
+    },
+    "installPaths":{
+        "testbox":"testbox"
+    }
+}

data/tracks/coldfusion/exercises/sum-of-multiples/index.cfm

@@ -0,0 +1,37 @@
+<!--- 
+
+This file will only be used if you want to start up a web server in this directory.  You can do so by running:
+
+$> box
+CommandBox> install
+CommandBox> server start
+
+However, this is not necessary unless you really just want to use the HTML reporters on TestBox.  
+Ideally, you'll skip the need for this file entirely and just run the tests directly frm the CLI like this:
+
+CommandBox> task run TestRunner
+
+ --->
+<cfsetting showDebugOutput="false">
+<cfparam name="url.reporter" 		default="simple">
+<cfscript>
+	// get a list of all CFCs in this folder whose name looks like "XXXTest.cfc"
+	// And turn it into compnent path relative to the web root
+	url.bundles = directoryList(
+			path=expandPath( '/' ),
+			filter='*Test.cfc' )
+		.map( function( path ) {
+			return path
+					.replaceNoCase( expandPath( '/' ), '' )
+					.left( -4 )
+		} )
+		.toList();
+</cfscript>
+
+<!--- Ensure TestBox --->
+<cfif fileExists( "/testbox/system/runners/HTMLRunner.cfm" )>
+	<!--- Include the TestBox HTML Runner --->
+	<cfinclude template="/testbox/system/runners/HTMLRunner.cfm">
+<cfelse>
+	Oops, you don't have TestBox installed yet! Please run <b>box install</b> from the root of your excercise folder and refresh this page.	
+</cfif>

data/tracks/coldfusion/exercises/triangle/Solution.cfc

@@ -0,0 +1,53 @@
+/**
+* Here is an example solution for the Triangle exercise
+*/
+component {
+	
+	function equilateral( array sides ) {
+		// Is triangle and all 3 sides the same
+		return isTriangle( sides ) && countSides( sides ) == 1;
+	}
+	
+	function isosceles( array sides ) {
+		// Is triangle and at least two sides the same
+		return isTriangle( sides ) && countSides( sides ) < 3;
+	}
+	
+	function scalene( array sides ) {
+		// Is triangle and all 3 sides different
+		return isTriangle( sides ) && countSides( sides ) == 3;
+	}
+	
+	private function countSides( array sides ) {
+		var distinctSides = {};
+				
+		// Keep track of distinct sides
+		sides.each( function( side ){
+			distinctSides[ side ] = true;
+		} );
+		
+		// Count 'em up
+		return distinctSides.count();
+	}
+	
+	private function isTriangle( array sides ) {
+		// Any sides of 0 are invalid
+		if( sides[ 1 ] == 0 || sides[ 2 ] == 0 || sides[ 3 ] == 0 ) {
+			return false;
+		}
+		// sides 1 and 2 must be at least the size of side 3
+		if( sides[ 1 ] + sides[ 2 ] < sides[ 3 ] ) {
+			return false;
+		}
+		// sides 1 and 3 must be at least the size of side 2
+		if( sides[ 1 ] + sides[ 3 ] < sides[ 2 ] ) {
+			return false;
+		}
+		// sides 2 and 3 must be at least the size of side 1
+		if( sides[ 2 ] + sides[ 3 ] < sides[ 1 ] ) {
+			return false;
+		}
+		// If we made it here, it's a triangle!
+		return true;
+	}
+}

data/tracks/coldfusion/exercises/triangle/SolutionTest.cfc

@@ -0,0 +1,7 @@
+component extends="TriangleTest" {
+
+	function beforeAll(){
+	  SUT = createObject( 'Solution' );
+	}
+
+}

data/tracks/coldfusion/exercises/triangle/TestRunner.cfc

@@ -0,0 +1,103 @@
+/**
+* I am a CommandBox task runner which you can use to test your implementation of this exercise against the 
+* provided test suite.  To use me, open the CommandBox CLI and run this:
+* 
+* CommandBox> task run TestRunner
+*
+* To start up a test watcher that will automatically rerun the test suite every time you save a file change, run this:
+*
+* CommandBox> task run TestRunner --watcher
+*
+*/
+component {
+	
+	/**
+	* @solution Runs the tests against the solution
+	* @watcher Start up a file watch that re-runs the tests on file changes. Use Ctrl-C to stop
+	*/
+	function run( boolean solution=false, boolean watcher=false ) {
+		
+		ensureTestBox();
+
+		if( watcher ) {
+		
+			// Tabula rasa
+			command( 'cls' ).run();
+				
+			// Start watcher
+			watch()
+				.paths( '*.cfc' )
+				.inDirectory( getCWD() )
+				.withDelay( 500 )
+				.onChange( function() {
+	
+					// Clear the screen
+					command( 'cls' )
+						.run();
+
+					// This is neccessary so changes to tests get picked up right away.
+					pagePoolClear();	
+					
+					runTests( solution );
+	
+				} )
+				.start();
+					
+		} else {
+			runTests( solution );
+		}			
+
+	}
+
+	/**
+	* Make sure the TestBox framework is installed
+	*/
+	private function ensureTestBox() {
+		var excerciseRoot = getCWD();
+		var testBoxRoot = excerciseRoot & '/testbox';
+		
+		if( !directoryExists( testBoxRoot ) ) {
+			
+			print.boldYellowLine( 'Installing some missing dependencies for you!' ).toConsole();
+			command( 'install' )
+				.inWorkingDirectory( excerciseRoot )
+				.run();
+		}
+		
+		// Bootstrap TestBox framework
+		filesystemUtil.createMapping( '/testbox', testBoxRoot );
+	}
+
+	/**
+	* Invoke TestBox to run the test suite
+	*/
+	private function runTests( boolean solution=false ) {
+		
+		// Create TestBox and run the tests
+		testData = new testbox.system.TestBox()
+			.runRaw( directory = {
+				// Find all CFCs...
+				mapping = filesystemUtil.makePathRelative( getCWD() ),
+				// ... in this directory ...
+				recurse = false,
+				// ... whose name ends in "test"
+				filter = function( path ) {
+					return path.reFind( ( solution ? 'Solution' : '' ) & 'Test.cfc$' );
+				 }
+			} )
+			.getMemento();
+		
+		// Print out the results with ANSI formatting for the CLI
+		getInstance( 'CLIRenderer@testbox-commands' )
+			.render( print, testData, true );
+			
+		print.toConsole();
+		
+		// Set proper exit code
+		if( testData.totalFail || testData.totalError ) {
+			setExitCode( 1 );
+		}
+	}
+
+}
+

data/tracks/coldfusion/exercises/triangle/Triangle.cfc

@@ -0,0 +1,18 @@
+/**
+* Your implmentation of the Triangle exercise
+*/
+component {
+	
+	function equilateral( array sides ) {
+		// Implement me here
+	}
+	
+	function isosceles( array sides ) {
+		// Implement me here
+	}
+	
+	function scalene( array sides ) {
+		// Implement me here
+	}
+	
+}

data/tracks/coldfusion/exercises/triangle/TriangleTest.cfc

@@ -0,0 +1,95 @@
+component extends="testbox.system.BaseSpec" {
+
+	function beforeAll(){
+	  SUT = createObject( 'Triangle' );
+	}
+
+	function run(){
+	
+		describe( "My Triangle class", function(){			
+
+			describe( 'returns true if the triangle is equilateral', function(){
+
+				it( 'true if all sides are equal', function(){
+					expect( SUT.equilateral( sides=[2, 2, 2] ) ).toBeTrue();
+				});
+
+				it( 'false if any side is unequal', function(){
+					expect( SUT.equilateral( sides=[2, 3, 2] ) ).toBeFalse();
+				});
+
+				it( 'false if no sides are equal', function(){
+					expect( SUT.equilateral( sides=[5, 4, 6] ) ).toBeFalse();
+				});
+
+				it( 'All zero sides are illegal, so the triangle is not equilateral', function(){
+					expect( SUT.equilateral( sides=[0, 0, 0] ) ).toBeFalse();
+				});
+
+				it( 'sides may be floats', function(){
+					expect( SUT.equilateral( sides=[0.5, 0.5, 0.5] ) ).toBeTrue();
+				});
+
+			});
+
+			describe( 'returns true if the triangle is isosceles', function(){
+
+				it( 'true if last two sides are equal', function(){
+					expect( SUT.isosceles( sides=[3, 4, 4] ) ).toBeTrue();
+				});
+
+				it( 'true if first two sides are equal', function(){
+					expect( SUT.isosceles( sides=[4, 4, 3] ) ).toBeTrue();
+				});
+
+				it( 'true if first and last sides are equal', function(){
+					expect( SUT.isosceles( sides=[4, 3, 4] ) ).toBeTrue();
+				});
+
+				it( 'equilateral triangles are also isosceles', function(){
+					expect( SUT.isosceles( sides=[4, 4, 4] ) ).toBeTrue();
+				});
+
+				it( 'false if no sides are equal', function(){
+					expect( SUT.isosceles( sides=[2, 3, 4] ) ).toBeFalse();
+				});
+
+				it( 'Sides that violate triangle inequality are not isosceles, even if two are equal', function(){
+					expect( SUT.isosceles( sides=[1, 1, 3] ) ).toBeFalse();
+				});
+
+				it( 'sides may be floats', function(){
+					expect( SUT.isosceles( sides=[0.5, 0.4, 0.5] ) ).toBeTrue();
+				});
+
+			});
+
+			describe( 'returns true if the triangle is scalene', function(){
+
+				it( 'true if no sides are equal', function(){
+					expect( SUT.scalene( sides=[5, 4, 6] ) ).toBeTrue();
+				});
+
+				it( 'false if all sides are equal', function(){
+					expect( SUT.scalene( sides=[4, 4, 4] ) ).toBeFalse();
+				});
+
+				it( 'false if two sides are equal', function(){
+					expect( SUT.scalene( sides=[4, 4, 3] ) ).toBeFalse();
+				});
+
+				it( 'Sides that violate triangle inequality are not scalene, even if they are all different', function(){
+					expect( SUT.scalene( sides=[7, 3, 2] ) ).toBeFalse();
+				});
+
+				it( 'sides may be floats', function(){
+					expect( SUT.scalene( sides=[0.5, 0.4, 0.6] ) ).toBeTrue();
+				});
+
+			});
+
+		});
+		
+	}
+ 
+}

data/tracks/coldfusion/exercises/triangle/box.json

@@ -0,0 +1,8 @@
+{
+    "dependencies":{
+        "testbox":"^2.5.0+107"
+    },
+    "installPaths":{
+        "testbox":"testbox"
+    }
+}

data/tracks/coldfusion/exercises/triangle/index.cfm

@@ -0,0 +1,37 @@
+<!--- 
+
+This file will only be used if you want to start up a web server in this directory.  You can do so by running:
+
+$> box
+CommandBox> install
+CommandBox> server start
+
+However, this is not necessary unless you really just want to use the HTML reporters on TestBox.  
+Ideally, you'll skip the need for this file entirely and just run the tests directly frm the CLI like this:
+
+CommandBox> task run TestRunner
+
+ --->
+<cfsetting showDebugOutput="false">
+<cfparam name="url.reporter" 		default="simple">
+<cfscript>
+	// get a list of all CFCs in this folder whose name looks like "XXXTest.cfc"
+	// And turn it into compnent path relative to the web root
+	url.bundles = directoryList(
+			path=expandPath( '/' ),
+			filter='*Test.cfc' )
+		.map( function( path ) {
+			return path
+					.replaceNoCase( expandPath( '/' ), '' )
+					.left( -4 )
+		} )
+		.toList();
+</cfscript>
+
+<!--- Ensure TestBox --->
+<cfif fileExists( "/testbox/system/runners/HTMLRunner.cfm" )>
+	<!--- Include the TestBox HTML Runner --->
+	<cfinclude template="/testbox/system/runners/HTMLRunner.cfm">
+<cfelse>
+	Oops, you don't have TestBox installed yet! Please run <b>box install</b> from the root of your excercise folder and refresh this page.	
+</cfif>

data/tracks/coldfusion/tasks/GenerateTests.cfc

@@ -0,0 +1,179 @@
+/**
+* I scaffold a new exercise from the template.
+*/
+component {
+	
+	function run(
+		slug,
+		boolean all=false
+	) {
+		var repoRootPath = expandPath( getDirectoryFromPath( getCurrentTemplatePath() ) & '../' );
+		var problemSpecsPath = expandPath( getDirectoryFromPath( getCurrentTemplatePath() ) & '../../problem-specifications' );
+				
+		if( !directoryExists( problemSpecsPath ) ){
+			error( 'Cannot find [problem-specifications] repo.  It needs to be git cloned to [#problemSpecsPath#]' );
+		}
+		
+		if( all ) {
+			
+			// Get an array of all the excercise names
+			var exercises = directoryList( expandPath( getDirectoryFromPath( getCurrentTemplatePath() ) & '../exercises' ) )
+				.map( function( path ) {
+					return path.listLast( '/\' );
+				} );
+		
+		} else {
+		
+			// Acquire slug
+			if( isNull( arguments.slug ) ) {
+				arguments.slug = ask( 'Exercise slug as defined by Excercism. Ex: "hello-world": ' );
+			}
+			var exercises = [ slug ];
+			
+		}
+				
+		exercises.each( function( slug ) {
+			
+			try {
+				
+				// Slug of hello-world defaults to name of HelloWorld
+				var exerciseName = arguments.slug
+					.listToArray( '-' )
+					.map( function( i ){
+						return i.left( 1 ).uCase() & i.right( -1 ).lCase();
+					} )
+					.toList( '' );
+				
+				var exercisePath = problemSpecsPath & '/exercises/' & slug;
+				if( !directoryExists( exercisePath ) ){
+					error( 'Cannot find exercise [#slug#] in problem-specifications repo.  Tests not generated.' );
+				}
+				
+				var canonicalDataPath = exercisePath & '/canonical-data.json';
+				if( !fileExists( canonicalDataPath ) ){
+					error( 'Cannot find [canonical-data.json] for this slug.  No tests will be generated' );
+				}
+		
+				var canonicalData = deserializeJSON( fileRead( canonicalDataPath ) );
+				var testCases = generateCases( canonicalData.cases );
+				
+				var testStub = fileRead( repoRootPath & '/tasks/exercise_template/@@name@@Test.cfc' );
+				testStub = testStub.replace( '@@name@@', exerciseName, 'all' );
+				testStub = testStub.replace( '@@testCases@@', testCases, 'all' );
+				var targetExercisePath = repoRootPath & 'exercises/' & slug;
+				var newTestPath = targetExercisePath & '/' & exerciseName & 'Test.cfc';
+				
+				if( !directoryExists( targetExercisePath ) ) {
+					error( 'Target exercise does not exist! [#targetExercisePath#]' );
+				}
+				
+				fileWrite( newTestPath, testStub );
+				
+				print.greenLine( 'Test generated!' )
+					.indentedYellowLine( newTestPath )
+					.toConsole();
+			} catch( 'commandException' var e ) {
+				print.boldRedLine( e.message )
+					.line();
+			}
+			
+		} ); // End exercises.each()
+	}
+	
+	private function generateCases( cases, level=1 ) {
+		var CRLF = chr( 13 ) & chr( 10 );
+		var testCases = ''
+			
+		cases.each( function( case ) {
+				
+			// Nested spec
+			if( case.keyExists( 'cases' ) ) {
+				
+					testCases &=  "#CRLF##repeatString( chr( 9 ), level )#		describe( #generateDescription( case.description )#, function(){
+#generateCases( case.cases, level+1 )#
+#repeatString( chr( 9 ), level )#		});#CRLF#";
+					
+			} else {
+				case.expected = case.expected ?: '__NULL__';
+				// Don't adjust whitespace
+				testCases &=  "#CRLF##repeatString( chr( 9 ), level )#		it( #generateDescription( case.description )#, function(){#CRLF#";
+				// Special check for when error should be tested
+				if( isStruct( case.expected ) && case.expected.keyExists( 'error' ) ) {
+					testCases &=  "#repeatString( chr( 9 ), level )#			expect( function(){ SUT.#case.property#(#generateInput( case )#); } ).#generateExpectation( case.expected )#;#CRLF#";	
+				// "normal" expectation
+				} else {
+					testCases &=  "#repeatString( chr( 9 ), level )#			expect( SUT.#case.property#(#generateInput( case )#) ).#generateExpectation( case.expected )#;#CRLF#";
+				}
+				testCases &=  "#repeatString( chr( 9 ), level )#		});#CRLF#";
+			} 
+			
+		} );
+		
+		return testCases;
+	}
+	
+	private function generateDescription( description ) {
+		return escapeString( description );
+	}
+	
+	private function generateInput( case ) {
+		var thisInput = '';
+		for( var key in case ) {
+			if( !listFindNoCase( 'description,property,expected,cases,comments', key ) && !isNull( case[ key ] ) ) {
+				thisInput = thisInput.listAppend( "#key#=#escapeString( case[ key ] )#" );
+			}
+		}
+		if( thisInput.len() ) {
+			return ' ' & thisInput.listChangeDelims( ', ', ',' ) & ' ';				
+		} else {
+			return thisInput;				
+		}
+	}
+	
+	private function generateExpectation( expected ) {
+		if( isSimpleValue( expected ) && compareNoCase( expected, 'true' ) == 0 ) {
+			return 'toBeTrue()';
+		} else if( isSimpleValue( expected ) && compareNoCase( expected, 'false' ) == 0 ) {
+			return 'toBeFalse()';
+		} else if( isSimpleValue( expected) && expected == '__NULL__' ) {
+			return 'toBeNull()';
+		} else if( isStruct( expected ) && expected.keyExists( 'error' ) ) {
+			return 'toThrow( message=#escapeString( expected.error )# )';
+		} else {
+			return "toBe( #escapeString( expected )# )";
+		}
+		
+	}
+	
+	private function escapeString( myString ) {
+		if( isSimpleValue( myString ) ) {
+			myString = replace( myString, "'", "''", "all" );
+			myString = replace( myString, '##', '####', 'all' );
+			myString = replace( myString, chr( 13 ), '##chr( 13 )##', 'all' );
+			myString = replace( myString, chr( 10 ), '##chr( 10 )##', 'all' );
+			return "'" & myString & "'";
+		} else {
+			return convertJSONEscapesToCFML( serializeJSON( myString ) );			
+		}
+	}
+	
+	
+	// A complex value serialized as JSON differs from CFML struct literals in that
+	// double quotes are \" instead of "".  Any escaped double quotes must be converted
+	// to the CFML version to work as an object literal.
+	private function convertJSONEscapesToCFML( required string arg ) {
+		arguments.arg = replaceNoCase( arguments.arg, '\\', '__double_backslash_', 'all' );
+		arguments.arg = replaceNoCase( arguments.arg, '\/', '/', 'all' );
+		arguments.arg = replaceNoCase( arguments.arg, '\"', '""', 'all' );
+		arguments.arg = replaceNoCase( arguments.arg, '\t', '	', 'all' );
+		arguments.arg = replaceNoCase( arguments.arg, '\n', chr(13)&chr(10), 'all' );
+		arguments.arg = replaceNoCase( arguments.arg, '\r', chr(13), 'all' );
+		arguments.arg = replaceNoCase( arguments.arg, '\f', chr(12), 'all' );
+		arguments.arg = replaceNoCase( arguments.arg, '\b', chr(8), 'all' );
+		// This doesn't work-- I'd need to do it in a loop and replace each one individually.  Meh...
+		// arguments.arg = reReplaceNoCase( arguments.arg, '\\u([0-9a-f]{4})', chr( inputBaseN( '\1', 16 ) ), 'all' );
+		arguments.arg = replaceNoCase( arguments.arg, '__double_backslash_', '\', 'all' );
+		return arguments.arg;
+	}
+	
+}