torqml 0.1.1

data/qml/TorQML/Shapes/qmldir

@@ -0,0 +1,10 @@
+module TorQML.Shapes
+TQAxis 0.1 TQAxis.qml
+TQBox 0.1 TQBox.qml
+TQCone 0.1 TQCone.qml
+TQCoordinate 0.1 TQCoordinate.qml
+TQCylinder 0.1 TQCylinder.qml
+TQGrid 0.1 TQGrid.qml
+TQPrimitive 0.1 TQPrimitive.qml
+TQSphere 0.1 TQSphere.qml
+TQTorus 0.1 TQTorus.qml

data/qml/TorQML/TQModel.qml

@@ -0,0 +1,9 @@
+import QtQuick 2.0
+
+// root component for user-defined models
+Item {
+    id: objroot
+    property var dataSource: null
+}
+
+// vim:set ts=4 sw=4 et:

data/qml/TorQML/Views/Dialogs/TQCaptureDialog.qml

@@ -0,0 +1,197 @@
+import QtQuick 2.0
+import QtQuick.Controls 1.1
+import QtQuick.Window 2.1
+import QtQuick.Layouts 1.1
+import QtQuick.Dialogs 1.1
+
+Window {
+    id: _captureDialog
+    title: "Capture frames"
+    width: 500
+    height: 450
+    flags: Qt.Dialog
+    modality: Qt.WindowModal
+    property real maxFrame: 1
+    property string returnValue: ""
+    property alias frameWidth: _frameWidth.value
+    property alias frameHeight: _frameHeight.value
+
+    SystemPalette{ id: _palette }
+    color: _palette.window
+
+    ColumnLayout {
+        anchors.fill: parent
+        anchors.margins: 10
+        GroupBox {
+            Layout.fillWidth: true
+            title: "Format"
+            RowLayout {
+                anchors.fill: parent
+                ExclusiveGroup{ id: _formatGroup }
+                RadioButton {
+                    id: _formatPng
+                    text: "png"
+                    checked: true
+                    exclusiveGroup: _formatGroup
+                }
+                RadioButton {
+                    id: _formatMp4
+                    text: "mp4"
+                    exclusiveGroup: _formatGroup
+                    enabled: false
+                }
+            }
+        }
+        GroupBox {
+            Layout.fillWidth: true
+            title: "Dimension"
+            RowLayout {
+                SpinBox {
+                    id: _frameWidth
+                    minimumValue: 1
+                    maximumValue: 2048
+                }
+                Label { text: " x " }
+                SpinBox {
+                    id: _frameHeight
+                    minimumValue: 1
+                    maximumValue: 2048
+                }
+                Label { text: " px" }
+            }
+        }
+        GroupBox {
+            Layout.fillWidth: true
+            title: "Frame Range"
+            ColumnLayout {
+                anchors.fill: parent
+                ExclusiveGroup{ id: _rangeGroup }
+                RadioButton {
+                    id: _rangeCurrent
+                    text: "Current frame"
+                    exclusiveGroup: _rangeGroup
+                }
+                RadioButton {
+                    id: _rangeAll
+                    text: "All frames"
+                    checked: true
+                    exclusiveGroup: _rangeGroup
+                }
+                RowLayout {
+                    RadioButton {
+                        id: _rangeCustom
+                        text: "Custom range : "
+                        exclusiveGroup: _rangeGroup
+                        onCheckedChanged: { _rangeFrom.enabled = checked; _rangeTo.enabled = checked; }
+                    }
+                    SpinBox {
+                        id: _rangeFrom
+                        minimumValue: 1
+                        maximumValue: maxFrame
+                        enabled: false
+                        value: 1
+                    }
+                    Label { text: "-" }
+                    SpinBox {
+                        id: _rangeTo
+                        minimumValue: 1
+                        maximumValue: maxFrame
+                        enabled: false
+                        value: maxFrame
+                    }
+                }
+                RowLayout {
+                    Label { text: "Frame skip : " }
+                    SpinBox {
+                        id: _rangeFrameSkip
+                        minimumValue: 0
+                        maximumValue: maxFrame
+                        value: 0
+                    }
+                }
+            }
+        }
+        GroupBox {
+            Layout.fillWidth: true
+            title: "Directory"
+            RowLayout {
+                anchors.fill: parent
+                TextField {
+                    id: _pathDir
+                    Layout.fillWidth: true
+                }
+                Button {
+                    text: "..."
+                    FileDialog {
+                        id: _pathDialog
+                        title: "Select a directory"
+                        folder: ""
+                        selectFolder: true
+                        selectExisting: true
+                        // FIXME: QImage::save does not accept canonical urls
+                        onAccepted: { _pathDir.text = _pathDialog.fileUrls.toString().replace("file://", ""); }
+                    }
+                    onClicked: { _pathDialog.open(); }
+                    // FIXME: QImage::save does not accept canonical urls
+                    Component.onCompleted: { _pathDir.text = _pathDialog.folder.toString().replace("file://", ""); }
+                }
+            }
+        }
+        GroupBox {
+            Layout.fillWidth: true
+            title: "Prefix"
+            TextField {
+                id: _prefix
+                anchors.fill: parent
+                Layout.fillWidth: true
+                text: "frame_"
+            }
+        }
+        RowLayout {
+            Layout.alignment: Qt.AlignRight
+            Button {
+                text: "Ok"
+                onClicked: {
+                    if(_rangeCustom.checked && _rangeFrom.value > _rangeTo.value) {
+                        _alertDialog.text = "Invalid frame range!";
+                        _alertDialog.open();
+                        return;
+                    }
+                    var returnObject = {
+                        "format": (_formatPng.checked ? "png" : "") + (_formatMp4.checked ? "mp4" : ""),
+                        "dimension": {
+                            "width": _frameWidth.value,
+                            "height": _frameHeight.value
+                        },
+                        "range": {
+                            "mode": (_rangeCurrent.checked ? "current" : "") + (_rangeAll.checked ? "all" : "") + (_rangeCustom.checked ? "custom" : ""),
+                            "from": _rangeFrom.value,
+                            "to": _rangeTo.value,
+                            "frameSkip": _rangeFrameSkip.value
+                        },
+                        "path": {
+                            "directory": _pathDir.text,
+                            "prefix": _prefix.text
+                        }
+                    };
+                    returnValue = JSON.stringify(returnObject);
+                    _captureDialog.close();
+                }
+            }
+            Button {
+                text: "Cancel"
+                onClicked: {
+                    returnValue = "";
+                    _captureDialog.close();
+                }
+            }
+        }
+        MessageDialog {
+            id: _alertDialog;
+            title: "Warning"
+            icon: StandardIcon.Warning
+        }
+    }
+}
+
+// vim:set ts=4 sw=4 et:

data/qml/TorQML/Views/Dialogs/TQProgressDialog.qml

@@ -0,0 +1,36 @@
+import QtQuick 2.0
+import QtQuick.Controls 1.1
+import QtQuick.Window 2.1
+import QtQuick.Layouts 1.1
+import QtQuick.Dialogs 1.1
+
+Window {
+    id: _progressDialog
+    title: "Exporting..."
+    width: 300
+    height: 80
+    flags: Qt.Dialog
+    modality: Qt.WindowModal
+    property alias minimumValue: _progress.minimumValue
+    property alias maximumValue: _progress.maximumValue
+    property alias value: _progress.value
+
+    SystemPalette{ id: _palette }
+    color: _palette.window
+
+    ColumnLayout {
+        anchors.fill: parent
+        anchors.margins: 5
+        ProgressBar {
+            Layout.fillWidth: true
+            id: _progress
+        }
+        Button {
+            Layout.fillWidth: true
+            text: "Abort"
+            onClicked: { _progressDialog.close(); }
+        }
+    }
+}
+
+// vim:set ts=4 sw=4 et:

data/qml/TorQML/Views/Dialogs/qmldir

@@ -0,0 +1,3 @@
+module TorQML.Views.Dialogs
+TQCaptureDialog 0.1 TQCaptureDialog.qml
+TQProgressDialog 0.1 TQProgressDialog.qml

data/qml/TorQML/Views/TQBasicView.qml

@@ -0,0 +1,148 @@
+import QtQuick 2.0
+import QtQuick.Controls 1.1
+import QtQuick.Window 2.1
+import QtQuick.Layouts 1.1
+import QtQuick.Dialogs 1.1
+import Qt3D 2.0
+import TorQML.DataSources 0.1
+import TorQML.FrameGrabber 0.1
+import TorQML.Views.Dialogs 0.1
+import "basicview.js" as BasicViewLogic
+
+ApplicationWindow {
+    property alias models: _viewport.children
+    property alias numberOfFrames: _slider.maximumValue
+    property alias msPerFrame: _timePerFrame.value
+    property alias light: _viewport.light
+    property alias camera: _viewport.camera
+    id: _window
+    flags: Qt.Dialog
+
+    visible: true
+    width: 640
+    height: 480
+    color: "black"
+
+    title: "TorQML Viewer"
+
+    menuBar: MenuBar {
+        id: _menuBar
+        Menu {
+            title: "File"
+            MenuItem { text: "Open..." }
+            MenuItem { text: "Close" }
+        }
+        Menu {
+            title: "Tool"
+            MenuItem{ text: "hogehoge" }
+        }
+    }
+
+    toolBar: ToolBar {
+        id: _toolBar
+
+        RowLayout {
+            height: 34
+            spacing: 5
+
+            ToolButton {
+                id: _playButton
+                iconSource: "../../../assets/images/play.png"
+
+                onClicked: {
+                    if(_slider.value == numberOfFrames) _slider.value = 1;
+                    _sliderTransition.start();
+                }
+            }
+            ToolButton {
+                id: _stopButton
+                iconSource: "../../../assets/images/stop.png"
+
+                onClicked: _sliderTransition.stop();
+            }
+
+            Slider {
+                id: _slider
+                property real from: 0
+                property real to: numberOfFrames
+                minimumValue: 1
+                maximumValue: numberOfFrames
+
+                onValueChanged: BasicViewLogic.updateFrame(value);
+                onMaximumValueChanged: _maxFrameText.text = "/" + numberOfFrames;
+                Keys.onPressed: BasicViewLogic.onKeyPressed(event);
+
+                NumberAnimation on value {
+                    id: _sliderTransition; from: _slider.from; to: _slider.to;
+                    duration: _timePerFrame.value * (_slider.to - _slider.from); running:false
+                }
+            }
+            Label {
+                id: _frameText
+                text: Math.floor(_slider.value)
+            }
+            Label { id: _maxFrameText; text: "/" + numberOfFrames }
+
+            SpinBox {
+                id: _timePerFrame
+                minimumValue: 1
+                value: 1
+
+                onValueChanged: BasicViewLogic.restartTransition(value);
+            }
+            Label { text: "ms/f" }
+
+            ToolButton {
+                id: _reloadButton
+                iconSource: "../../../assets/images/reload.png"
+
+                onClicked: BasicViewLogic.reloadData();
+            }
+            ToolButton {
+                id: _captureButton
+                iconSource: "../../../assets/images/capture.png"
+
+                onClicked: BasicViewLogic.showCaptureDialog();
+            }
+        }
+    }
+
+    statusBar: StatusBar { id: _statusBar }
+
+    TQViewport {
+        id: _viewport;
+        Keys.forwardTo: [_slider]
+    }
+
+    FrameGrabber { id: _frameGrabber }
+
+    TQProgressDialog { id: _progressDialog }
+    TQCaptureDialog {
+        id: _captureDialog;
+        Component.onCompleted: _captureConnection.target = _captureDialog;
+    }
+    Connections {
+        id: _captureConnection
+        onVisibleChanged: BasicViewLogic.onCaptureDialogClosed();
+    }
+
+    Timer {
+        id: _frameGrabberStarter;
+        interval: 200;
+        repeat: false;
+        onTriggered: _frameGrabberTimer.start();
+    }
+
+    Timer {
+        id: _frameGrabberTimer
+        property variant config
+        property real currentFrame
+        interval: 1
+        repeat: true
+        onTriggered: BasicViewLogic.captureFrame();
+    }
+
+    Component.onCompleted: BasicViewLogic.initialize();
+}
+
+// vim:set ts=4 sw=4 et:

data/qml/TorQML/Views/TQCamera.qml

@@ -0,0 +1,11 @@
+import QtQuick 2.0
+import Qt3D 2.0
+
+Camera {
+    center: "0,0,0"
+    eye: "8,5,5"
+    nearPlane: 0.01
+    fieldOfView: 30
+}
+
+// vim:set ts=4 sw=4 et:

data/qml/TorQML/Views/TQViewport.qml

@@ -0,0 +1,41 @@
+import QtQuick 2.0
+import Qt3D 2.0
+import "mouseEventHandler.js" as MouseEventHandler
+
+Viewport {
+    id: _viewport
+    width: parent.width; height: parent.height
+    light: Light {
+        position: "50,80,50"
+        ambientColor: "white"
+    }
+    fovzoom: true
+    focus: true
+    anchors.fill: parent
+    camera: TQCamera {}
+    MouseArea {
+        id: _mouseArea
+        property bool rotating: false
+        property bool translating: false
+        property int startX: 0
+        property int startY: 0
+        property variant startEye
+        property variant startCenter
+        property variant startUpVector
+        anchors.fill: parent
+        onPressed: {
+            MouseEventHandler.onPressed(mouse);
+        }
+        onReleased: {
+            MouseEventHandler.onReleased(mouse);
+        }
+        onPositionChanged: {
+            MouseEventHandler.onPositionChanged(mouse);
+        }
+        onWheel: {
+            MouseEventHandler.onWheel(wheel);
+        }
+    }
+}
+
+// vim:set ts=4 sw=4 et: