spade-packager 0.1.0

data/packages/coffee-script/test/test_returns.coffee

@@ -0,0 +1,63 @@
+# Expression conversion under explicit returns.
+first = ->
+  return ('do' for x in [1,2,3])
+
+second = ->
+  return ['re' for x in [1,2,3]]
+
+third = ->
+  return ('mi' for x in [1,2,3])
+
+ok first().join(' ')     is 'do do do'
+ok second()[0].join(' ') is 're re re'
+ok third().join(' ')     is 'mi mi mi'
+
+
+# Testing returns with multiple branches.
+func = ->
+  if false
+    for a in b
+      return c if d
+  else
+    "word"
+
+ok func() is 'word'
+
+
+# And with switches.
+func = ->
+  switch 'a'
+    when 'a' then 42
+    else return 23
+
+eq func(), 42
+
+# Ensure that we don't wrap Nodes that are "pureStatement" in a closure.
+items = [1, 2, 3, "bacon", 4, 5]
+
+findit = (items) ->
+  for item in items
+    return item if item is "bacon"
+
+ok findit(items) is "bacon"
+
+
+# When a closure wrapper is generated for expression conversion, make sure
+# that references to "this" within the wrapper are safely converted as well.
+obj =
+  num: 5
+  func: ->
+    this.result = if false
+      10
+    else
+      "a"
+      "b"
+      this.num
+
+eq obj.num, obj.func()
+eq obj.num, obj.result
+
+
+# Multiple semicolon-separated statements in parentheticals.
+eq 3, (1; 2; 3)
+eq 3, (-> return (1; 2; 3))()

data/packages/coffee-script/test/test_splats.coffee

@@ -0,0 +1,102 @@
+# Splats
+# ------
+# note: splats in parameter lists of function definitions are tested in `arguments.coffee`
+
+# shared identity function
+id = (_) -> if arguments.length is 1 then _ else Array::slice.call(arguments)
+
+test "passing splats to functions", ->
+  arrayEq [0..4], id id [0..4]...
+
+  fn = (a, b, c..., d) -> [a, b, c, d]
+  [first, second, others, last] = fn [0..3]..., 4, [5...8]...
+  eq 0, first
+  eq 1, second
+  arrayEq [2..6], others
+  eq 7, last
+
+
+obj =
+  name: 'moe'
+  accessor: (args...) ->
+    [@name].concat(args).join(' ')
+  getNames: ->
+    args = ['jane', 'ted']
+    @accessor(args...)
+  index: 0
+  0: {method: -> this is obj[0]}
+
+ok obj.getNames() is 'moe jane ted'
+ok obj[obj.index++].method([]...), 'should cache base value'
+
+#crowd = [
+#  contenders...
+#  "Mighty Mouse"
+#]
+#
+#bests = [
+#  "Mighty Mouse"
+#  contenders.slice(0, 4)...
+#]
+#
+#ok crowd[0] is contenders[0]
+#ok crowd[10] is "Mighty Mouse"
+#
+#ok bests[1] is contenders[0]
+#ok bests[4] is contenders[3]
+
+
+# Finally, splats with super() within classes.
+
+class Parent
+  meth: (args...) ->
+    args
+
+class Child extends Parent
+  meth: ->
+    nums = [3, 2, 1]
+    super nums...
+
+ok (new Child).meth().join(' ') is '3 2 1'
+
+
+# Functions with splats being called with too few arguments.
+pen = null
+method = (first, variable..., penultimate, ultimate) ->
+  pen = penultimate
+
+method 1, 2, 3, 4, 5, 6, 7, 8, 9
+ok pen is 8
+
+method 1, 2, 3
+ok pen is 2
+
+method 1, 2
+ok pen is 2
+
+
+# Array splat expansions with assigns.
+nums = [1, 2, 3]
+list = [a = 0, nums..., b = 4]
+ok a is 0
+ok b is 4
+ok list.join(' ') is '0 1 2 3 4'
+
+
+# Splat on a line by itself is invalid.
+failed = true
+try
+  CoffeeScript.compile "x 'a'\n...\n"
+  failed = false
+catch err
+ok failed
+
+
+# multiple generated references
+(->
+  a = {b: []}
+  a.b[true] = -> this == a.b
+  c = 0
+  d = []
+  ok a.b[0<++c<2] d...
+)()

data/packages/coffee-script/test/test_strings.coffee

@@ -0,0 +1,118 @@
+eq '(((dollars)))', '\(\(\(dollars\)\)\)'
+eq 'one two three', "one
+ two
+ three"
+eq "four five", 'four
+
+ five'
+
+#647
+eq "''Hello, World\\''", '''
+'\'Hello, World\\\''
+'''
+eq '""Hello, World\\""', """
+"\"Hello, World\\\""
+"""
+eq 'Hello, World\n', '''
+Hello, World\
+
+'''
+
+
+hello = 'Hello'
+world = 'World'
+ok '#{hello} #{world}!' is '#{hello} #{world}!'
+ok "#{hello} #{world}!" is 'Hello World!'
+ok "[#{hello}#{world}]" is '[HelloWorld]'
+ok "#{hello}##{world}" is 'Hello#World'
+ok "Hello #{ 1 + 2 } World" is 'Hello 3 World'
+ok "#{hello} #{ 1 + 2 } #{world}" is "Hello 3 World"
+
+
+[s, t, r, i, n, g] = ['s', 't', 'r', 'i', 'n', 'g']
+ok "#{s}#{t}#{r}#{i}#{n}#{g}" is 'string'
+ok "\#{s}\#{t}\#{r}\#{i}\#{n}\#{g}" is '#{s}#{t}#{r}#{i}#{n}#{g}'
+ok "\#{string}" is '#{string}'
+
+
+ok "\#{Escaping} first" is '#{Escaping} first'
+ok "Escaping \#{in} middle" is 'Escaping #{in} middle'
+ok "Escaping \#{last}" is 'Escaping #{last}'
+
+
+ok "##" is '##'
+ok "#{}" is ''
+ok "#{}A#{} #{} #{}B#{}" is 'A  B'
+ok "\\\#{}" is '\\#{}'
+
+
+ok "I won ##{20} last night." is 'I won #20 last night.'
+ok "I won ##{'#20'} last night." is 'I won ##20 last night.'
+
+
+ok "#{hello + world}" is 'HelloWorld'
+ok "#{hello + ' ' + world + '!'}" is 'Hello World!'
+
+
+list = [0, 1, 2, 3, 4, 5, 6, 7, 8, 9]
+ok "values: #{list.join(', ')}, length: #{list.length}." is 'values: 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, length: 10.'
+ok "values: #{list.join ' '}" is 'values: 0 1 2 3 4 5 6 7 8 9'
+
+
+obj = {
+  name: 'Joe'
+  hi: -> "Hello #{@name}."
+  cya: -> "Hello #{@name}.".replace('Hello','Goodbye')
+}
+ok obj.hi() is "Hello Joe."
+ok obj.cya() is "Goodbye Joe."
+
+
+ok "With #{"quotes"}" is 'With quotes'
+ok 'With #{"quotes"}' is 'With #{"quotes"}'
+
+ok "Where is #{obj["name"] + '?'}" is 'Where is Joe?'
+
+ok "Where is #{"the nested #{obj["name"]}"}?" is 'Where is the nested Joe?'
+ok "Hello #{world ? "#{hello}"}" is 'Hello World'
+
+ok "Hello #{"#{"#{obj["name"]}" + '!'}"}" is 'Hello Joe!'
+
+
+a = """
+    Hello #{ "Joe" }
+    """
+ok a is "Hello Joe"
+
+
+a = 1
+b = 2
+c = 3
+ok "#{a}#{b}#{c}" is '123'
+
+
+result = null
+stash = (str) -> result = str
+stash "a #{ ('aa').replace /a/g, 'b' } c"
+ok result is 'a bb c'
+
+
+foo = "hello"
+ok "#{foo.replace("\"", "")}" is 'hello'
+
+
+eq 'multiline nested "interpolations" work', """multiline #{
+  "nested #{
+    ok true
+    "\"interpolations\""
+  }"
+} work"""
+
+
+# Issue #923: Tricky interpolation.
+eq "#{ "{" }", "{"
+
+eq "#{ '#{}}' } }", '#{}} }'
+
+eq "#{"'#{ ({a: "b#{1}"}['a']) }'"}", "'b1'"
+

data/packages/coffee-script/test/test_switch.coffee

@@ -0,0 +1,103 @@
+num = 10
+
+result = switch num
+  when 5 then false
+  when 'a'
+    true
+    true
+    false
+  when 10 then true
+
+
+  # Mid-switch comment with whitespace
+  # and multi line
+  when 11 then false
+  else false
+
+ok result
+
+
+func = (num) ->
+  switch num
+    when 2, 4, 6
+      true
+    when 1, 3, 5
+      false
+
+ok func(2)
+ok func(6)
+ok !func(3)
+eq func(8), undefined
+
+
+# Ensure that trailing switch elses don't get rewritten.
+result = false
+switch "word"
+  when "one thing"
+    doSomething()
+  else
+    result = true unless false
+
+ok result
+
+result = false
+switch "word"
+  when "one thing"
+    doSomething()
+  when "other thing"
+    doSomething()
+  else
+    result = true unless false
+
+ok result
+
+
+# Should be able to handle switches sans-condition.
+result = switch
+  when null                     then 0
+  when !1                       then 1
+  when '' not of {''}           then 2
+  when [] not instanceof Array  then 3
+  when true is false            then 4
+  when 'x' < 'y' > 'z'          then 5
+  when 'a' in ['b', 'c']        then 6
+  when 'd' in (['e', 'f'])      then 7
+  else ok
+
+eq result, ok
+
+
+# Should be able to use "@properties" within the switch clause.
+obj = {
+  num: 101
+  func: ->
+    switch @num
+      when 101 then '101!'
+      else 'other'
+}
+
+ok obj.func() is '101!'
+
+
+# Should be able to use "@properties" within the switch cases.
+obj = {
+  num: 101
+  func: (yesOrNo) ->
+    result = switch yesOrNo
+      when yes then @num
+      else 'other'
+    result
+}
+
+ok obj.func(yes) is 101
+
+
+# Switch with break as the return value of a loop.
+i = 10
+results = while i > 0
+  i--
+  switch i % 2
+    when 1 then i
+    when 0 then break
+
+eq results.join(', '), '9, , 7, , 5, , 3, , 1, '

data/packages/coffee-script/test/test_while.coffee

@@ -0,0 +1,71 @@
+i = 5
+list = while i -= 1
+  i * 2
+
+ok list.join(' ') is "8 6 4 2"
+
+
+i = 5
+list = (i * 3 while i -= 1)
+
+ok list.join(' ') is "12 9 6 3"
+
+
+i = 5
+func   = (num) -> i -= num
+assert = -> ok i < 5 > 0
+
+results = while func 1
+  assert()
+  i
+
+ok results.join(' ') is '4 3 2 1'
+
+
+i = 10
+results = while i -= 1 when i % 2 is 0
+  i * 2
+
+ok results.join(' ') is '16 12 8 4'
+
+
+value = false
+i = 0
+results = until value
+  value = true if i is 5
+  i += 1
+
+ok i is 6
+
+
+# And, the loop form of while.
+i = 5
+list = []
+loop
+  i -= 1
+  break if i is 0
+  list.push i * 2
+
+ok list.join(' ') is '8 6 4 2'
+
+
+#759: `if` within `while` condition
+2 while if 1 then 0
+
+
+# While over break.
+i = 0
+result = while i < 10
+  i++
+  break
+
+arrayEq result, []
+
+
+# While over continue.
+i = 0
+result = while i < 10
+  i++
+  continue
+
+arrayEq result, []