shank 0.0.1

data/lib/assets/javascripts/request_animation_frame.coffee

@@ -0,0 +1,22 @@
+###*
+A browser polyfill so you can consistently 
+call requestAnimationFrame. Using 
+requestAnimationFrame is preferred to 
+setInterval for main game loops.
+
+http://paulirish.com/2011/requestanimationframe-for-smart-animating/
+
+@name requestAnimationFrame
+@namespace
+###
+
+window.requestAnimationFrame ||= 
+  window.webkitRequestAnimationFrame || 
+  window.mozRequestAnimationFrame    || 
+  window.oRequestAnimationFrame      || 
+  window.msRequestAnimationFrame     || 
+  (callback, element) ->
+    window.setTimeout( ->
+      callback(+new Date())
+    , 1000 / 60)
+

data/lib/assets/javascripts/shank.coffee

@@ -0,0 +1,18 @@
+#= require init
+
+#= require engine.gamepads
+#= require engine_stats
+#= require error_handler
+#= require game_keys
+#= require gamepads
+#= require gamepads.controller
+#= require joysticks
+#= require jquery.hotkeys
+#= require jquery.reverse_merge
+#= require keydown
+#= require mouse
+#= require music
+#= require pixie_canvas
+#= require request_animation_frame
+#= require sound
+#= require storage

data/lib/assets/javascripts/sound.coffee

@@ -0,0 +1,131 @@
+(($) ->
+  ###*
+  A simple interface for playing sounds in games.
+
+  @name Sound
+  @namespace
+  ###
+  directory = App?.directories?.sounds || "sounds"
+  format = "wav"
+  sounds = {}
+  globalVolume = 1
+
+  loadSoundChannel = (name) ->
+    url = "#{BASE_URL}/#{directory}/#{name}.#{format}"
+
+    sound = $('<audio />',
+      autobuffer: true
+      preload: 'auto'
+      src: url
+    ).get(0)
+
+  Sound = (id, maxChannels) ->
+    play: ->
+      Sound.play(id, maxChannels)
+
+    stop: ->
+      Sound.stop(id)
+
+  Object.extend Sound,
+    ###*
+    Set the global volume modifier for all sound effects.
+  
+    Any value set is clamped between 0 and 1. This is multiplied
+    into each individual effect that plays.
+  
+    If no argument is given return the current global sound effect volume.
+  
+    @name globalVolume
+    @methodOf Sound
+    @param {Number} [newVolume] The volume to set
+    ###
+    globalVolume: (newVolume) ->
+      if newVolume?
+        globalVolume = newVolume.clamp(0, 1)
+
+      return globalVolume
+
+    ###*
+    Play a sound from your sounds 
+    directory with the name of `id`.
+
+    <code><pre>
+    # plays a sound called explode from your sounds directory
+    Sound.play('explode')
+    </pre></code>
+
+    @name play
+    @methodOf Sound
+
+    @param {String} id id or name of the sound file to play
+    @param {String} maxChannels max number of sounds able to be played simultaneously
+    ###  
+    play: (id, maxChannels) ->
+      # TODO: Too many channels crash Chrome!!!1
+      maxChannels ||= 4
+
+      unless sounds[id]
+        sounds[id] = [loadSoundChannel(id)]
+
+      channels = sounds[id]
+
+      freeChannels = $.grep channels, (sound) ->
+        sound.currentTime == sound.duration || sound.currentTime == 0
+
+      if channel = freeChannels.first()
+        try
+          channel.currentTime = 0
+
+        channel.volume = globalVolume
+        channel.play()
+      else
+        if !maxChannels || channels.length < maxChannels
+          sound = loadSoundChannel(id)
+          channels.push(sound)
+          sound.play()
+          sound.volume = globalVolume
+
+    ###*
+    Play a sound from the given
+    url with the name of `id`.
+
+    <code><pre>
+    # plays the sound at the specified url
+    Sound.playFromUrl('http://YourSoundWebsite.com/explode.wav')
+    </pre></code>
+
+    @name playFromUrl
+    @methodOf Sound
+
+    @param {String} url location of sound file to play
+
+    @returns {Sound} this sound object
+    ### 
+    playFromUrl: (url) ->
+      sound = $('<audio />').get(0)
+      sound.src = url
+
+      sound.play()
+      sound.volume = globalVolume
+
+      return sound
+
+    ###*
+    Stop a sound while it is playing.
+
+    <code><pre>
+    # stops the sound 'explode' from 
+    # playing if it is currently playing 
+    Sound.stop('explode')
+    </pre></code>
+
+    @name stop
+    @methodOf Sound
+
+    @param {String} id id or name of sound to stop playing.
+    ### 
+    stop: (id) ->
+      sounds[id]?.stop()
+
+    (exports ? this)["Sound"] = Sound
+)(jQuery)

data/lib/assets/javascripts/storage.coffee

@@ -0,0 +1,88 @@
+( ->
+  ###*
+  A wrapper on the Local Storage API 
+
+  @name Local
+  @namespace
+  ###
+
+  ###*
+  Store an object in local storage.
+
+  <code><pre>
+  # you can store strings
+  Local.set('name', 'Matt')
+
+  # and numbers
+  Local.set('age', 26)
+
+  # and even objects
+  Local.set('person', {name: 'Matt', age: 26})
+  </pre></code>
+
+  @name set
+  @methodOf Local
+
+  @param {String} key string used to identify the object you are storing
+  @param {Object} value value of the object you are storing
+
+  @returns {Object} value
+  ###
+  store = (key, value) ->
+    localStorage[key] = JSON.stringify(value)
+
+    return value
+
+  ###*
+  Retrieve an object from local storage.
+
+  <code><pre>
+  Local.get('name')
+  # => 'Matt'
+
+  Local.get('age')
+  # => 26
+
+  Local.get('person')
+  # => { age: 26, name: 'Matt' }
+  </pre></code>
+
+  @name get
+  @methodOf Local
+
+  @param {String} key string that identifies the stored object
+
+  @returns {Object} The object that was stored or undefined if no object was stored.
+  ###
+  retrieve = (key) ->
+    value = localStorage[key]
+
+    if value?
+      JSON.parse(value)
+
+  # Export
+  (exports ? this)["Local"] =
+    get: retrieve
+    set: store
+    put: store
+    ###*
+    Access an instance of Local with a specified prefix.
+
+    @name new
+    @methodOf Local
+
+    @param {String} prefix 
+    @returns {Local} An interface to local storage with the given prefix applied.
+    ###
+    new: (prefix) ->
+      prefix ||= ""
+
+      get: (key) ->
+        retrieve("#{prefix}_#{key}")
+      set: (key, value) ->
+        store("#{prefix}_#{key}", value)
+      put: (key, value) ->
+        store("#{prefix}_#{key}", value)
+
+)()
+

data/lib/shank/version.rb

@@ -0,0 +1,3 @@
+module Shank
+  VERSION = "0.0.1"
+end

data/lib/shank.rb

@@ -0,0 +1,10 @@
+module Shank
+  if defined? ::Rails::Engine
+    class Rails < Rails::Engine
+    end
+  elsif defined? ::Sprockets
+    root_dir = File.expand_path(File.dirname(File.dirname(__FILE__)))
+
+    ::Sprockets.append_path File.join(root_dir, "lib", "assets", "javascripts")
+  end
+end

data/shank.gemspec

@@ -0,0 +1,17 @@
+# -*- encoding: utf-8 -*-
+require File.expand_path('../lib/shank/version', __FILE__)
+
+Gem::Specification.new do |gem|
+  gem.name          = "shank"
+  gem.version       = Shank::VERSION
+  gem.authors       = ["Matt Diebolt", "Daniel X. Moore"]
+  gem.email         = ["pixie@pixieengine.com"]
+  gem.homepage      = "https://github.com/PixieEngine/Shank"
+  gem.summary       = %q{Sometimes you gotta stab someone to make a game}
+  gem.description   = %q{Polyfills for making games in the browser}
+
+  gem.files         = `git ls-files`.split("\n")
+  gem.require_paths = ["lib"]
+
+  gem.add_development_dependency "rake"
+end

data/test/jquery.reverse_merge.coffee

@@ -0,0 +1,43 @@
+module "jQuery.reverseMerge"
+
+test "reverse merge", ->
+  o = {
+    exists: "cool"
+  }
+
+  $.reverseMerge o,
+    another: "also cool"
+    exists: "not cool"
+    u: undefined
+
+  equal o.exists, "cool"
+  equal o.another, "also cool"
+  equal o.u, undefined
+  ok "u" of o
+
+test "multiple arguments", ->
+   o = {
+     a: 0
+   }
+
+   $.reverseMerge o, {
+     a: 1
+     b: 1
+   }, {
+     a: 2
+     b: 2
+     c: 2
+   }, {
+     a: 3
+     b: 3
+     c: 3
+     d: 3
+   }
+
+   equal o.a, 0
+   equal o.b, 1
+   equal o.c, 2
+   equal o.d, 3
+
+module()
+

data/test/keydown.coffee

@@ -0,0 +1,19 @@
+module "keydown"
+
+test "keydown", ->
+  event = $.Event("keydown")
+  event.which = 32
+
+  $(document).trigger event
+
+  equal(keydown.space, true, "Space should be down after a keydown event")
+
+  event = $.Event("keyup")
+  event.which = 32
+
+  $(document).trigger event
+
+  equal(keydown.space, false, "Space should be up after a keyup event")
+
+module()
+

data/test/pixie_canvas.coffee

@@ -0,0 +1,18 @@
+module "PixieCanvas"
+
+test "exists", ->
+  ok $.fn.pixieCanvas
+
+test "#centerText font", ->
+  canvas = $("<canvas>").pixieCanvas()
+  
+  fontString = "normal normal normal 11px/16px Monaco, monospace"
+  
+  canvas.centerText
+    x: 50
+    y: 50
+    font: fontString
+    
+  equals canvas.font(), fontString
+
+module()

data/test/request_animation_frame.coffee

@@ -0,0 +1,7 @@
+module "window"
+
+test "requestAnimationFrame exists", ->
+  ok window.requestAnimationFrame
+
+module()
+

data/test/sound.coffee

@@ -0,0 +1,7 @@
+module "Sound"
+
+test ".play exists", ->
+  ok Sound.play
+
+module()
+

data/test/storage.coffee

@@ -0,0 +1,47 @@
+module "Storage"
+
+test "Local exists", ->
+  ok(Local)
+
+test "Local.set and Local.get", ->
+  object =
+    key: "test"
+    cool: true
+    num: 17
+    sub:
+      a: true
+      b: 14
+      c: "str"
+
+  Local.set("__TEST", object)
+  ret = Local.get("__TEST")
+  equal ret.key, object.key
+  equal ret.cool, object.cool
+  equal ret.num, object.num
+  equal ret.sub.a, object.sub.a
+  equal ret.sub.b, object.sub.b
+  equal ret.sub.c, object.sub.c
+
+  Local.set("__TEST", 0)
+  ret = Local.get("__TEST")
+  equal ret, 0
+
+  Local.set("__TEST", false)
+  ret = Local.get("__TEST")
+  equal ret, false
+
+  Local.set("__TEST", "")
+  ret = Local.get("__TEST")
+  equal ret, ""
+
+test "Local.new", ->
+  local = Local.new("TEST")
+  key = "a test value"
+  
+  local.set(key, true)
+  equal local.get(key), true
+  
+  equal Local.get(key), null
+
+module()
+

data/test/xstats.coffee

@@ -0,0 +1,7 @@
+module "Xstats"
+
+test "exists", ->
+  Engine.Stats()
+
+# Clear out the module
+module()