shank 0.0.1

data/lib/assets/javascripts/jquery.reverse_merge.coffee

@@ -0,0 +1,21 @@
+###*
+Merges properties from objects into target without overiding.
+First come, first served.
+
+@name reverseMerge
+@methodOf jQuery#
+
+@param {Object} target the object to merge the given properties onto
+@param {Object} objects... one or more objects whose properties are merged onto target
+
+@return {Object} target
+###
+jQuery.extend
+  reverseMerge: (target, objects...) ->
+    for object in objects
+      for name of object
+        unless target.hasOwnProperty(name)
+          target[name] = object[name]
+
+    return target
+

data/lib/assets/javascripts/keydown.coffee

@@ -0,0 +1,73 @@
+$ ->
+  ###*
+  The global keydown property lets your query the status of keys.
+
+  <code><pre>
+  if keydown.left
+    moveLeft()
+
+  if keydown.a or keydown.space
+    attack()
+
+  if keydown.return
+    confirm()
+
+  if keydown.esc
+    cancel()
+  </pre></code>
+
+  @name keydown
+  @namespace
+  ###
+
+  ###*
+  The global justPressed property lets your query the status of keys. However, 
+  unlike keydown it will only trigger once for each time the key is pressed.
+
+  <code><pre>
+  if justPressed.left
+    moveLeft()
+
+  if justPressed.a or justPressed.space
+    attack()
+
+  if justPressed.return
+    confirm()
+
+  if justPressed.esc
+    cancel()
+  </pre></code>
+
+  @name justPressed
+  @namespace
+  ###
+  window.keydown = {}
+  window.justPressed = {}
+
+  prevKeysDown = {}
+
+  keyName = (event) ->
+    jQuery.hotkeys.specialKeys[event.which] ||
+    String.fromCharCode(event.which).toLowerCase()
+
+  $(document).bind "keydown", (event) ->
+    key = keyName(event)
+    keydown[key] = true
+
+  $(document).bind "keyup", (event) ->
+    key = keyName(event)
+    keydown[key] = false
+
+  window.updateKeys = () ->
+    window.justPressed = {}
+    keydown.any = false
+
+    for key, value of keydown
+      justPressed[key] = value unless prevKeysDown[key]
+
+      justPressed.any = true if (justPressed[key] || mousePressed.left || mousePressed.right)
+      keydown.any = true if (value || mouseDown.left || mouseDown.right)
+
+    prevKeysDown = {}
+    for key, value of keydown
+      prevKeysDown[key] = value

data/lib/assets/javascripts/mouse.coffee

@@ -0,0 +1,66 @@
+$ ->
+  ###*
+  The global mouseDown property lets your query the status of mouse buttons.
+
+  <code><pre>
+  if mouseDown.left
+    moveLeft()
+
+  if mouseDown.right
+    attack()
+  </pre></code>
+
+  @name mouseDown
+  @namespace
+  ###
+
+  ###*
+  The global mousePressed property lets your query the status of mouse buttons.
+  However, unlike mouseDown it will only trigger the first time the button
+  pressed.
+
+  <code><pre>
+  if mousePressed.left
+    moveLeft()
+
+  if mousePressed.right
+    attack()
+  </pre></code>
+
+  @name mousePressed
+  @namespace
+  ###
+  window.mouseDown = {}
+  window.mousePressed = {}
+  window.mousePosition = Point(0, 0)
+
+  prevButtonsDown = {}
+
+  buttonNames =
+    1: "left"
+    2: "middle"
+    3: "right"
+
+  buttonName = (event) ->
+    buttonNames[event.which]
+
+  $(document).bind "mousemove", (event) ->
+    #TODO Position relative to canvas element
+    mousePosition.x = event.pageX
+    mousePosition.y = event.pageY
+
+  $(document).bind "mousedown", (event) ->
+    mouseDown[buttonName(event)] = true
+
+  $(document).bind "mouseup", (event) ->
+    mouseDown[buttonName(event)] = false
+
+  window.updateMouse = ->
+    window.mousePressed = {}
+
+    for button, value of mouseDown
+      mousePressed[button] = value unless prevButtonsDown[button]
+
+    prevButtonsDown = {}
+    for button, value of mouseDown
+      prevButtonsDown[button] = value

data/lib/assets/javascripts/music.coffee

@@ -0,0 +1,78 @@
+###*
+The Music object provides an easy API to play
+songs from your sounds project directory. By
+default, the track is looped.
+
+<code><pre>
+  Music.play('intro_theme')
+</pre></code>
+
+@name Music
+@namespace
+###
+
+Music = (->
+  # TODO: Load this from local storage of user preferences
+  globalMusicVolume = 1
+  trackVolume = 1
+
+  # TODO: Add format fallbacks
+  track = $ "<audio />",
+    loop: "loop"
+  .appendTo('body').get(0)
+
+  updateTrackVolume = ->
+    track.volume = globalMusicVolume * trackVolume
+
+  ###*
+  Set the global volume modifier for all music.
+
+  Any value set is clamped between 0 and 1. This is multiplied
+  into each individual track that plays.
+
+  If no argument is given return the current global music volume.
+
+  @name globalVolume
+  @methodOf Music
+  @param {Number} [newVolume] The volume to set
+  ###
+  globalVolume: (newVolume) ->
+    if newVolume?
+      globalMusicVolume = newVolume.clamp(0, 1)
+
+      updateTrackVolume()
+
+    return globalMusicVolume
+
+  ###*
+  Plays a music track.
+
+  @name play
+  @methodOf Music
+  @param {String} name The name of the track to play.
+  ###
+  play: (name) ->
+    updateTrackVolume()
+    # TODO: Format fallbacks
+    track.src = "#{BASE_URL}/sounds/#{name}.mp3"
+    track.play()
+
+  ###*
+  Get or set the current music volume. Any value passed is
+  clamped between 0 and 1. Use this to adjust the volume of
+  individual tracks or to increase or decrease volume during
+  gameplay.
+
+  @name volume
+  @methodOf Music
+  @param {Number} [newVolume] The volume to set to.
+  ###
+  volume: (newVolume) ->
+    if newVolume?
+      trackVolume = newVolume.clamp(0, 1)
+      updateTrackVolume()
+
+      return this
+    else
+      return trackVolume
+)()