safeguard-devise 0.0.2

data/puppet/modules/mysql/manifests/java.pp

@@ -0,0 +1,24 @@
+# Class: mysql::java
+#
+# This class installs the mysql-java-connector.
+#
+# Parameters:
+#   [*java_package_name*]  - The name of the mysql java package.
+#
+# Actions:
+#
+# Requires:
+#
+# Sample Usage:
+#
+class mysql::java (
+  $package_name   = $mysql::params::java_package_name,
+  $package_ensure = 'present'
+) inherits mysql::params {
+
+  package { 'mysql-connector-java':
+    ensure => $package_ensure,
+    name   => $package_name,
+  }
+
+}

data/puppet/modules/mysql/manifests/params.pp

@@ -0,0 +1,91 @@
+# Class: mysql::params
+#
+#   The mysql configuration settings.
+#
+# Parameters:
+#
+# Actions:
+#
+# Requires:
+#
+# Sample Usage:
+#
+class mysql::params {
+
+  $bind_address        = '127.0.0.1'
+  $port                = 3306
+  $etc_root_password   = false
+  $ssl                 = false
+
+  case $::operatingsystem {
+    "Ubuntu": {
+      $service_provider = upstart
+    }
+    default: {
+      $service_provider = undef
+    }
+  }
+
+  case $::osfamily {
+    'RedHat': {
+      $basedir               = '/usr'
+      $datadir               = '/var/lib/mysql'
+      $service_name          = 'mysqld'
+      $client_package_name   = 'mysql'
+      $server_package_name   = 'mysql-server'
+      $socket                = '/var/lib/mysql/mysql.sock'
+      $config_file           = '/etc/my.cnf'
+      $log_error             = '/var/log/mysqld.log'
+      $ruby_package_name     = 'ruby-mysql'
+      $ruby_package_provider = 'gem'
+      $python_package_name   = 'MySQL-python'
+      $java_package_name     = 'mysql-connector-java'
+      $root_group            = 'root'
+      $ssl_ca                = '/etc/mysql/cacert.pem'
+      $ssl_cert              = '/etc/mysql/server-cert.pem'
+      $ssl_key               = '/etc/mysql/server-key.pem'
+    }
+
+    'Debian': {
+      $basedir              = '/usr'
+      $datadir              = '/var/lib/mysql'
+      $service_name         = 'mysql'
+      $client_package_name  = 'mysql-client'
+      $server_package_name  = 'mysql-server'
+      $socket               = '/var/run/mysqld/mysqld.sock'
+      $config_file          = '/etc/mysql/my.cnf'
+      $log_error            = '/var/log/mysql/error.log'
+      $ruby_package_name    = 'libmysql-ruby'
+      $python_package_name  = 'python-mysqldb'
+      $java_package_name    = 'libmysql-java'
+      $root_group           = 'root'
+      $ssl_ca               = '/etc/mysql/cacert.pem'
+      $ssl_cert             = '/etc/mysql/server-cert.pem'
+      $ssl_key              = '/etc/mysql/server-key.pem'
+    }
+
+    'FreeBSD': {
+      $basedir               = '/usr/local'
+      $datadir               = '/var/db/mysql'
+      $service_name          = 'mysql-server'
+      $client_package_name   = 'databases/mysql55-client'
+      $server_package_name   = 'databases/mysql55-server'
+      $socket                = '/tmp/mysql.sock'
+      $config_file           = '/var/db/mysql/my.cnf'
+      $log_error             = "/var/db/mysql/${::hostname}.err"
+      $ruby_package_name     = 'ruby-mysql'
+      $ruby_package_provider = 'gem'
+      $python_package_name   = 'databases/py-MySQLdb'
+      $java_package_name     = 'databases/mysql-connector-java'
+      $root_group            = 'wheel'
+      $ssl_ca                = undef
+      $ssl_cert              = undef
+      $ssl_key               = undef
+    }
+
+    default: {
+      fail("Unsupported osfamily: ${::osfamily} operatingsystem: ${::operatingsystem}, module ${module_name} only support osfamily RedHat Debian and FreeBSD")
+    }
+  }
+
+}

data/puppet/modules/mysql/manifests/python.pp

@@ -0,0 +1,26 @@
+# Class: mysql::python
+#
+# This class installs the python libs for mysql.
+#
+# Parameters:
+#   [*ensure*]       - ensure state for package.
+#                        can be specified as version.
+#   [*package_name*] - name of package
+#
+# Actions:
+#
+# Requires:
+#
+# Sample Usage:
+#
+class mysql::python(
+  $package_name   = $mysql::params::python_package_name,
+  $package_ensure = 'present'
+) inherits mysql::params {
+
+  package { 'python-mysqldb':
+    name   => $package_name,
+    ensure => $package_ensure,
+  }
+
+}

data/puppet/modules/mysql/manifests/ruby.pp

@@ -0,0 +1,28 @@
+# Class: mysql::ruby
+#
+# installs the ruby bindings for mysql
+#
+# Parameters:
+#   [*ensure*]       - ensure state for package.
+#                        can be specified as version.
+#   [*package_name*] - name of package
+#
+# Actions:
+#
+# Requires:
+#
+# Sample Usage:
+#
+class mysql::ruby (
+  $package_name     = $mysql::params::ruby_package_name,
+  $package_provider = $mysql::params::ruby_package_provider,
+  $package_ensure   = 'present'
+) inherits mysql::params {
+
+  package{ 'ruby_mysql':
+    name     => $package_name,
+    ensure   => $package_ensure,
+    provider => $package_provider,
+  }
+
+}

data/puppet/modules/mysql/manifests/server/account_security.pp

@@ -0,0 +1,13 @@
+class mysql::server::account_security {
+  # Some installations have some default users which are not required.
+  # We remove them here. You can subclass this class to overwrite this behavior.
+  database_user { [ "root@${::fqdn}", "root@${::hostname}", 'root@127.0.0.1',
+                    "@${::fqdn}", "@${::hostname}", '@localhost', '@%' ]:
+    ensure  => 'absent',
+    require => Class['mysql::config'],
+  }
+  database { 'test':
+    ensure  => 'absent',
+    require => Class['mysql::config'],
+  }
+}

data/puppet/modules/mysql/manifests/server/monitor.pp

@@ -0,0 +1,19 @@
+class mysql::server::monitor (
+  $mysql_monitor_username,
+  $mysql_monitor_password,
+  $mysql_monitor_hostname
+) {
+
+  Class['mysql::server'] -> Class['mysql::server::monitor']
+
+  database_user{ "${mysql_monitor_username}@${mysql_monitor_hostname}":
+    password_hash => mysql_password($mysql_monitor_password),
+    ensure        => present,
+  }
+
+  database_grant { "${mysql_monitor_username}@${mysql_monitor_hostname}":
+    privileges => [ 'process_priv', 'super_priv' ],
+    require    => Mysql_user["${mysql_monitor_username}@${mysql_monitor_hostname}"],
+  }
+
+}

data/puppet/modules/mysql/manifests/server/mysqltuner.pp

@@ -0,0 +1,22 @@
+# Copyright 2009 Larry Ludwig (larrylud@gmail.com)
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may not
+# use this file except in compliance with the License. You may obtain a copy of
+# the License at:
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations under
+# the License.
+#
+class mysql::server::mysqltuner {
+  # mysql performance tester
+  file { '/usr/bin/mysqltuner':
+    ensure  => present,
+    mode    => '0550',
+    source  => 'puppet:///modules/mysql/mysqltuner.pl',
+  }
+}

data/puppet/modules/mysql/manifests/server.pp

@@ -0,0 +1,52 @@
+# Class: mysql::server
+#
+# manages the installation of the mysql server.  manages the package, service,
+# my.cnf
+#
+# Parameters:
+#   [*package_name*] - name of package
+#   [*service_name*] - name of service
+#   [*config_hash*]  - hash of config parameters that need to be set.
+#
+# Actions:
+#
+# Requires:
+#
+# Sample Usage:
+#
+class mysql::server (
+  $package_name     = $mysql::params::server_package_name,
+  $package_ensure   = 'present',
+  $service_name     = $mysql::params::service_name,
+  $service_provider = $mysql::params::service_provider,
+  $config_hash      = {},
+  $enabled          = true
+) inherits mysql::params {
+
+  Class['mysql::server'] -> Class['mysql::config']
+
+  $config_class = {}
+  $config_class['mysql::config'] = $config_hash
+
+  create_resources( 'class', $config_class )
+
+  package { 'mysql-server':
+    name   => $package_name,
+    ensure => $package_ensure,
+  }
+
+  if $enabled {
+    $service_ensure = 'running'
+  } else {
+    $service_ensure = 'stopped'
+  }
+
+  service { 'mysqld':
+    name     => $service_name,
+    ensure   => $service_ensure,
+    enable   => $enabled,
+    require  => Package['mysql-server'],
+    provider => $service_provider,
+  }
+
+}

data/puppet/modules/mysql/templates/my.cnf.erb

@@ -0,0 +1,42 @@
+[client]
+port    = <%= port %>
+socket    = <%= socket %>
+[mysqld_safe]
+socket    = <%= socket %>
+nice    = 0
+[mysqld]
+user    = mysql
+socket    = <%= socket %>
+port      = <%= port %>
+basedir   = <%= basedir %>
+datadir   = <%= datadir %>
+tmpdir    = /tmp
+skip-external-locking
+bind-address    = <%= bind_address %>
+key_buffer         = 16M
+max_allowed_packet = 16M
+thread_stack       = 192K
+thread_cache_size  = 8
+myisam-recover     = BACKUP
+query_cache_limit  = 1M
+query_cache_size   = 16M
+log_error          = <%= log_error %>
+expire_logs_days   = 10
+max_binlog_size    = 100M
+<% if default_engine != 'UNSET' %>
+default-storage-engine = <%= default_engine %>
+<% end %>
+<% if ssl == true %>
+ssl-ca    = <%= ssl_ca %>
+ssl-cert  = <%= ssl_cert %>
+ssl-key   = <%= ssl_key %>
+<% end %>
+
+[mysqldump]
+quick
+quote-names
+max_allowed_packet = 16M
+[mysql]
+[isamchk]
+key_buffer    = 16M
+!includedir /etc/mysql/conf.d/

data/puppet/modules/mysql/templates/my.cnf.pass.erb

@@ -0,0 +1,6 @@
+[client]
+user=root
+host=localhost
+<% unless root_password == 'UNSET' -%>
+password=<%= root_password %>
+<% end -%>

data/puppet/modules/mysql/templates/mysqlbackup.sh.erb

@@ -0,0 +1,23 @@
+#!/bin/sh
+#
+# MySQL Backup Script
+#  Dumps mysql databases to a file for another backup tool to pick up.
+#
+# MySQL code:
+# GRANT SELECT, RELOAD, LOCK TABLES ON *.* TO 'user'@'localhost'
+# IDENTIFIED BY 'password';
+# FLUSH PRIVILEGES;
+#
+##### START CONFIG ###################################################
+
+USER=<%= backupuser %>
+PASS=<%= backuppassword %>
+DIR=<%= backupdir %>
+
+##### STOP CONFIG ####################################################
+PATH=/usr/bin:/usr/sbin:/bin:/sbin
+
+find $DIR -mtime +30 -exec rm -f {} \;
+mysqldump -u${USER} -p${PASS} --opt --flush-logs --single-transaction \
+ --all-databases | bzcat -zc > ${DIR}/mysql_backup_`date +%Y%m%d-%H%M%S`.sql.bz2
+