safeguard-devise 0.0.2

data/puppet/modules/elasticsearch/manifests/java.pp

@@ -0,0 +1,50 @@
+# == Class: elasticsearch::java
+#
+# This class exists to install java if its not managed from an other module
+#
+#
+# === Parameters
+#
+# This class does not provide any parameters.
+#
+#
+# === Examples
+#
+# This class may be imported by other classes to use its functionality:
+#   class { 'elasticsearch::java': }
+#
+# It is not intended to be used directly by external resources like node
+# definitions or other modules.
+#
+#
+# === Authors
+#
+# * Richard Pijnenburg <mailto:richard@ispavailability.com>
+#
+class elasticsearch::java {
+
+  if $elasticsearch::java_package == undef {
+    # Default Java package
+    case $::operatingsystem {
+      'CentOS', 'Fedora', 'Scientific', 'RedHat', 'Amazon', 'OracleLinux': {
+        $package = 'java-1.6.0-openjdk'
+      }
+      'Debian', 'Ubuntu': {
+        $package = 'openjdk-6-jre-headless'
+      }
+      default: {
+        fail("\"${module_name}\" provides no java package
+              for \"${::operatingsystem}\"")
+      }
+    }
+  } else {
+    $package = $elasticsearch::java_package
+  }
+
+  ## Install the java package unless already specified somewhere else
+  if !defined(Package[$package]) {
+    package { $package:
+      ensure => present
+    }
+  }
+}

data/puppet/modules/elasticsearch/manifests/package.pp

@@ -0,0 +1,84 @@
+# == Class: elasticsearch::package
+#
+# This class exists to coordinate all software package management related
+# actions, functionality and logical units in a central place.
+#
+#
+# === Parameters
+#
+# This class does not provide any parameters.
+#
+#
+# === Examples
+#
+# This class may be imported by other classes to use its functionality:
+#   class { 'elasticsearch::package': }
+#
+# It is not intended to be used directly by external resources like node
+# definitions or other modules.
+#
+#
+# === Authors
+#
+# * Richard Pijnenburg <mailto:richard@ispavailability.com>
+#
+class elasticsearch::package {
+
+  #### Package management
+
+  # set params: in operation
+  if $elasticsearch::ensure == 'present' {
+
+    if $elasticsearch::version == false {
+
+      $package_ensure = $elasticsearch::autoupgrade ? {
+        true    => 'latest',
+        default => 'present',
+      }
+
+    }  else {
+
+      $package_ensure = $elasticsearch::version
+
+    }
+
+  # set params: removal
+  } else {
+    $package_ensure = 'purged'
+  }
+
+  if $elasticsearch::pkg_source {
+
+    $filenameArray = split($elasticsearch::pkg_source, '/')
+    $basefilename = $filenameArray[-1]
+
+    $extArray = split($basefilename, '\.')
+    $ext = $extArray[-1]
+
+    $tmpSource = "/tmp/${basefilename}"
+
+    file { $tmpSource:
+      source => $elasticsearch::pkg_source,
+      owner  => 'root',
+      group  => 'root',
+      backup => false
+    }
+
+    case $ext {
+      'deb':   { $pkg_provider = 'dpkg' }
+      'rpm':   { $pkg_provider = 'rpm'  }
+      default: { fail("Unknown file extention \"${ext}\"") }
+    }
+  } else {
+    $tmpSource = undef
+    $pkg_provider = undef
+  }
+
+  # action
+  package { $elasticsearch::params::package:
+    ensure   => $package_ensure,
+    source   => $tmpSource,
+    provider => $pkg_provider
+  }
+
+}

data/puppet/modules/elasticsearch/manifests/params.pp

@@ -0,0 +1,103 @@
+# == Class: elasticsearch::params
+#
+# This class exists to
+# 1. Declutter the default value assignment for class parameters.
+# 2. Manage internally used module variables in a central place.
+#
+# Therefore, many operating system dependent differences (names, paths, ...)
+# are addressed in here.
+#
+#
+# === Parameters
+#
+# This class does not provide any parameters.
+#
+#
+# === Examples
+#
+# This class is not intended to be used directly.
+#
+#
+# === Links
+#
+# * {Puppet Docs: Using Parameterized Classes}[http://j.mp/nVpyWY]
+#
+#
+# === Authors
+#
+# * Richard Pijnenburg <mailto:richard@ispavailability.com>
+#
+class elasticsearch::params {
+
+  #### Default values for the parameters of the main module class, init.pp
+
+  # ensure
+  $ensure = 'present'
+
+  # autoupgrade
+  $autoupgrade = false
+
+  # restart on configuration change?
+  $restart_on_change = true
+
+  # service status
+  $status = 'enabled'
+
+  # configuration directory
+  $confdir = '/etc/elasticsearch'
+
+  # plugins directory
+  $plugindir = '/usr/share/elasticsearch/plugins'
+
+  # plugins helper binary
+  $plugintool = '/usr/share/elasticsearch/bin/plugin'
+
+  # default service settings
+  $service_settings = {
+    'ES_USER'      => 'elasticsearch',
+    'ES_GROUP'     => 'elasticsearch',
+  }
+
+  #### Internal module values
+
+  # packages
+  case $::operatingsystem {
+    'CentOS', 'Fedora', 'Scientific', 'RedHat', 'Amazon', 'OracleLinux': {
+      # main application
+      $package = [ 'elasticsearch' ]
+    }
+    'Debian', 'Ubuntu': {
+      # main application
+      $package = [ 'elasticsearch' ]
+    }
+    default: {
+      fail("\"${module_name}\" provides no package default value
+            for \"${::operatingsystem}\"")
+    }
+  }
+
+  # service parameters
+  case $::operatingsystem {
+    'CentOS', 'Fedora', 'Scientific', 'RedHat', 'Amazon', 'OracleLinux': {
+      $service_name          = 'elasticsearch'
+      $service_hasrestart    = true
+      $service_hasstatus     = true
+      $service_pattern       = $service_name
+      $service_provider      = 'redhat'
+      $service_settings_path = "/etc/sysconfig/${service_name}"
+    }
+    'Debian', 'Ubuntu': {
+      $service_name          = 'elasticsearch'
+      $service_hasrestart    = true
+      $service_hasstatus     = true
+      $service_pattern       = $service_name
+      $service_provider      = 'debian'
+      $service_settings_path = "/etc/default/${service_name}"
+    }
+    default: {
+      fail("\"${module_name}\" provides no service parameters
+            for \"${::operatingsystem}\"")
+    }
+  }
+
+}

data/puppet/modules/elasticsearch/manifests/plugin.pp

@@ -0,0 +1,97 @@
+# == Define: elasticsearch::plugin
+#
+# This define allows you to install arbitrary Elasticsearch plugins
+# either by using the default repositories or by specifying an URL
+#
+# All default values are defined in the elasticsearch::params class.
+#
+#
+# === Parameters
+#
+# [*module_dir*]
+#   Directory name where the module will be installed
+#   Value type is string
+#   Default value: None
+#   This variable is required
+#
+# [*ensure*]
+#   Whether the plugin will be installed or removed.
+#   Set to 'absent' to ensure a plugin is not installed
+#   Value type is string
+#   Default value: present
+#   This variable is optional
+#
+# [*url*]
+#   Specify an URL where to download the plugin from.
+#   Value type is string
+#   Default value: None
+#   This variable is optional
+#
+#
+# === Examples
+#
+# # From official repository
+# elasticsearch::plugin{'mobz/elasticsearch-head': module_dir => 'head'}
+#
+# # From custom url
+# elasticsearch::plugin{ 'elasticsearch-jetty':
+#  module_dir => 'elasticsearch-jetty',
+#  url        => 'https://oss-es-plugins.s3.amazonaws.com/elasticsearch-jetty/elasticsearch-jetty-0.90.0.zip',
+# }
+#
+# === Authors
+#
+# * Matteo Sessa <mailto:matteo.sessa@catchoftheday.com.au>
+# * Dennis Konert <mailto:dkonert@gmail.com>
+#
+define elasticsearch::plugin(
+    $module_dir,
+    $ensure      = 'present',
+    $url         = ''
+) {
+
+  require elasticsearch::params
+
+  Exec {
+    path => [ '/bin', '/usr/bin', '/usr/local/bin' ],
+    cwd  => '/',
+  }
+
+  $notify_elasticsearch = $elasticsearch::restart_on_change ? {
+    false   => undef,
+    default => Class['elasticsearch::service'],
+  }
+
+  if ($module_dir != '') {
+      validate_string($module_dir)
+  } else {
+      fail("module_dir undefined for plugin ${name}")
+  }
+
+  if ($url != '') {
+    validate_string($url)
+    $install_cmd = "${elasticsearch::plugintool} -install ${name} -url ${url}"
+    $exec_rets = [0,1]
+  } else {
+    $install_cmd = "${elasticsearch::plugintool} -install ${name}"
+    $exec_rets = [0,]
+  }
+
+  case $ensure {
+    'installed', 'present': {
+      exec {"install-plugin-${name}":
+        command  => $install_cmd,
+        creates  => "${elasticsearch::plugindir}/${module_dir}",
+        returns  => $exec_rets,
+        notify   => $notify_elasticsearch,
+      }
+    }
+    default: {
+      exec {"remove-plugin-${name}":
+        command => "${elasticsearch::plugintool} --remove ${module_dir}",
+        onlyif  => "test -d ${elasticsearch::plugindir}/${module_dir}",
+        notify  => $notify_elasticsearch,
+      }
+    }
+  }
+}

data/puppet/modules/elasticsearch/manifests/python.pp

@@ -0,0 +1,34 @@
+# there are many python bindings for elasticsearch. This provides all
+# the ones we know about http://www.elasticsearch.org/guide/clients/
+define elasticsearch::python (
+  $ensure   = 'installed',
+) {
+
+  # make sure the package name is valid and setup the provider as
+  # necessary
+  case $name {
+    'pyes': {
+      $provider = 'pip'
+    }
+    'rawes': {
+      $provider = 'pip'
+    }
+    'pyelasticsearch': {
+      $provider = 'pip'
+    }
+    'ESClient': {
+      $provider = 'pip'
+    }
+    'elasticutils': {
+      $provider = 'pip'
+    }
+    default: {
+      fail("unknown python binding package '${name}'")
+    }
+  }
+
+  package { $name:
+    ensure   => $ensure,
+    provider => $provider,
+  }
+}

data/puppet/modules/elasticsearch/manifests/service.pp

@@ -0,0 +1,114 @@
+# == Class: elasticsearch::service
+#
+# This class exists to coordinate all service management related actions,
+# functionality and logical units in a central place.
+#
+# <b>Note:</b> "service" is the Puppet term and type for background processes
+# in general and is used in a platform-independent way. E.g. "service" means
+# "daemon" in relation to Unix-like systems.
+#
+#
+# === Parameters
+#
+# This class does not provide any parameters.
+#
+#
+# === Examples
+#
+# This class may be imported by other classes to use its functionality:
+#   class { 'elasticsearch::service': }
+#
+# It is not intended to be used directly by external resources like node
+# definitions or other modules.
+#
+#
+# === Authors
+#
+# * Richard Pijnenburg <mailto:richard@ispavailability.com>
+#
+class elasticsearch::service {
+
+  include elasticsearch
+
+  $notify_elasticsearch = $elasticsearch::restart_on_change ? {
+    false   => undef,
+    default => Service['elasticsearch'],
+  }
+
+  #### Service management
+
+  # set params: in operation
+  if $elasticsearch::ensure == 'present' {
+
+    case $elasticsearch::status {
+      # make sure service is currently running, start it on boot
+      'enabled': {
+        $service_ensure = 'running'
+        $service_enable = true
+      }
+      # make sure service is currently stopped, do not start it on boot
+      'disabled': {
+        $service_ensure = 'stopped'
+        $service_enable = false
+      }
+      # make sure service is currently running, do not start it on boot
+      'running': {
+        $service_ensure = 'running'
+        $service_enable = false
+      }
+      # do not start service on boot, do not care whether currently running or not
+      'unmanaged': {
+        $service_ensure = undef
+        $service_enable = false
+      }
+      # unknown status
+      # note: don't forget to update the parameter check in init.pp if you
+      #       add a new or change an existing status.
+      default: {
+        fail("\"${elasticsearch::status}\" is an unknown service status value")
+      }
+    }
+
+  # set params: removal
+  } else {
+
+    # make sure the service is stopped and disabled (the removal itself will be
+    # done by package.pp)
+    $service_ensure = 'stopped'
+    $service_enable = false
+
+  }
+
+  file {$elasticsearch::params::service_settings_path:
+    ensure  => file,
+    content => template("${module_name}/etc/default/elasticsearch.erb"),
+    owner   => 'root',
+    group   => 'root',
+    mode    => '0644',
+    notify  => $notify_elasticsearch,
+  }
+
+  if $elasticsearch::status != 'unmanaged' and $elasticsearch::initfile != undef {
+    # Write service file
+    file { '/etc/init.d/elasticsearch':
+      ensure  => present,
+      source  => $elasticsearch::initfile,
+      owner   => 'root',
+      group   => 'root',
+      mode    => '0555',
+      before  => Service[ 'elasticsearch' ]
+    }
+  }
+
+  # action
+  service { 'elasticsearch':
+    ensure     => $service_ensure,
+    enable     => $service_enable,
+    name       => $elasticsearch::params::service_name,
+    hasstatus  => $elasticsearch::params::service_hasstatus,
+    hasrestart => $elasticsearch::params::service_hasrestart,
+    pattern    => $elasticsearch::params::service_pattern,
+    provider   => $elasticsearch::params::service_provider,
+  }
+
+}

data/puppet/modules/elasticsearch/manifests/template.pp

@@ -0,0 +1,118 @@
+# == Define: elasticsearch::template
+#
+#  This define allows you to insert, update or delete templates that are used within Elasticsearch for the indexes
+#
+# === Parameters
+#
+# [*file*]
+#   File path of the template ( json file )
+#   Value type is string
+#   Default value: undef
+#   This variable is optional
+#
+# [*replace*]
+#   Set to 'true' if you intend to replace the existing template
+#   Value type is boolean
+#   Default value: false
+#   This variable is optional
+#
+# [*delete*]
+#   Set to 'true' if you intend to delete the existing template
+#   Value type is boolean
+#   Default value: false
+#   This variable is optional
+#
+# [*host*]
+#   Host name or IP address of the ES instance to connect to
+#   Value type is string
+#   Default value: localhost
+#   This variable is optional
+#
+# [*port*]
+#   Port number of the ES instance to connect to
+#   Value type is number
+#   Default value: 9200
+#   This variable is optional
+#
+# === Authors
+#
+# * Richard Pijnenburg <mailto:richard@ispavailability.com>
+#
+define elasticsearch::template(
+  $file    = undef,
+  $replace = false,
+  $delete  = false,
+  $host    = 'localhost',
+  $port    = 9200
+) {
+
+  require elasticsearch
+
+  Exec {
+    path => [ '/bin', '/usr/bin', '/usr/local/bin' ],
+    cwd  => '/',
+  }
+
+  # Build up the url
+  $es_url = "http://${host}:${port}/_template/${name}"
+
+  # Can't do a replace and delete at the same time
+  if $replace == true and $delete == true {
+    fail('Replace and Delete cant be used together')
+  }
+
+  if $delete == false {
+    # Fail when no file is supplied
+    if $file == undef {
+      fail('The variable "file" cannot be empty when inserting or updating a template')
+    }
+  }
+
+  $file_ensure = $delete ? {
+    true    => 'absent',
+    default => 'present'
+  }
+
+  $file_notify = $delete ? {
+    true    => undef,
+    default => Exec[ "insert_template ${name}" ]
+  }
+
+  # place the template file
+  file { "${elasticsearch::confdir}/templates_import/elasticsearch-template-${name}.json":
+    ensure  => $file_ensure,
+    source  => $file,
+    notify  => $file_notify,
+    require => Exec[ 'mkdir_templates' ],
+  }
+
+  if $replace == true or $delete == true {
+
+    # Only notify the insert_template call when we do a replace.
+    $exec_notify = $replace ? {
+      true    => Exec[ "insert_template ${name}" ],
+      default => undef
+    }
+
+    # Delete the existing template
+    # First check if it exists of course
+    exec { "delete_template ${name}":
+      command => "curl -s -XDELETE ${es_url}",
+      onlyif  => "test $(curl -s '${es_url}?pretty=true' | wc -l) -gt 1",
+      notify  => $exec_notify
+    }
+
+  }
+
+  # Insert the template if we don't delete an existing one
+  # Before inserting we check if a template exists with that same name
+  if $delete == false {
+    exec { "insert_template ${name}":
+      command     => "curl -s -XPUT ${es_url} -d @${elasticsearch::confdir}/templates_import/elasticsearch-template-${name}.json",
+      unless      => "test $(curl -s '${es_url}?pretty=true' | wc -l) -gt 1",
+      refreshonly => true,
+      tries       => 3,
+      try_sleep   => 10
+    }
+  }
+}

data/puppet/modules/elasticsearch/metadata.json

@@ -0,0 +1,41 @@
+{
+  "project_page": "https://github.com/elasticsearch/puppet-elasticsearch",
+  "license": "Apache License, Version 2.0",
+  "source": "https://github.com/elasticsearch/puppet-elasticsearch",
+  "checksums": {
+    "spec/spec_helper.rb": "3ea886dd135e120afa31e0aab12e85b0",
+    "LICENSE": "1fc7fa7c411594f07888338b1865e9d7",
+    "templates/etc/elasticsearch/elasticsearch.yml.erb": "7960bf7708776396cf094e6bd5ee9e97",
+    "manifests/init.pp": "0a2ee898e72bc85b7f91b12b22072a04",
+    "manifests/package.pp": "f888a269dffc8ba1358b3fe558f7ddb9",
+    "manifests/template.pp": "a362fdf5c9e26510048fa9e730ed49bf",
+    "templates/etc/default/elasticsearch.erb": "496bf6f670c8a68653f2b9256c1539e0",
+    "spec/classes/elasticsearch_init_spec.rb": "d876ee65fe9cbabfc4f04de48a17c7a4",
+    "manifests/params.pp": "01a422c1a84ee073e0ebafc2585ff7ed",
+    "CHANGELOG": "6fa25a87d60ed7311403992eec4081c8",
+    "manifests/config.pp": "0463f24a00e0472996c0b18d5e976e5b",
+    "manifests/python.pp": "c3a546ce1eba575c209175867494f599",
+    "manifests/service.pp": "50709f07a8bea21172d59eeb15e589f1",
+    "Modulefile": "beaacf02407cbdcc878b0df8bef3b514",
+    "README.md": "a75ebe5b4562b12eda4cf4fa3f696931",
+    "Rakefile": "d9fad069cf2dfdc0541548e278e39bbb",
+    "manifests/java.pp": "94ecd1ef0bdccf492657c39a04d9d09e",
+    "manifests/plugin.pp": "b02c99cbd74aa0b20f547e942b854cf3",
+    "spec/defines/template_spec.rb": "a3bc69d8e679bdef1a4ff4957a2c68e8",
+    "CONTRIBUTORS": "14df2fd27cf7b6ca9833527f2ba93442"
+  },
+  "types": [
+
+  ],
+  "description": "Module for managing and configuring Elasticsearch nodes",
+  "version": "0.1.3",
+  "summary": "Module for managing and configuring Elasticsearch nodes",
+  "name": "ispavailability-elasticsearch",
+  "author": "ispavailability",
+  "dependencies": [
+    {
+      "version_requirement": ">= 3.0.0",
+      "name": "puppetlabs/stdlib"
+    }
+  ]
+}