resin 0.2.2 → 0.2.3

data/amber/st/Helios-KeyBindings.st

@@ -0,0 +1,337 @@
+Smalltalk current createPackage: 'Helios-KeyBindings' properties: #{}!
+Object subclass: #HLBinding
+	instanceVariableNames: 'key label'
+	package: 'Helios-KeyBindings'!
+
+!HLBinding methodsFor: 'accessing'!
+
+key
+	^ key
+!
+
+key: anInteger
+	key := anInteger
+!
+
+label
+	^ label
+!
+
+label: aString
+	label := aString
+!
+
+shortcut
+	^ String fromCharCode: self key
+! !
+
+!HLBinding methodsFor: 'actions'!
+
+applyOn: aKeyBinder
+	self subclassResponsibility
+! !
+
+!HLBinding methodsFor: 'rendering'!
+
+renderOn: aBindingHelper html: html
+! !
+
+!HLBinding methodsFor: 'testing'!
+
+isBindingAction
+	^ false
+!
+
+isBindingGroup
+	^ false
+! !
+
+!HLBinding class methodsFor: 'instance creation'!
+
+on: anInteger labelled: aString
+	^ self new
+    	key: anInteger;
+        label: aString;
+        yourself
+! !
+
+HLBinding subclass: #HLBindingAction
+	instanceVariableNames: 'callback'
+	package: 'Helios-KeyBindings'!
+
+!HLBindingAction methodsFor: 'accessing'!
+
+callback
+	^ callback
+!
+
+callback: aBlock
+	callback := aBlock
+! !
+
+!HLBindingAction methodsFor: 'actions'!
+
+applyOn: aKeyBinder
+	aKeyBinder applyBindingAction: self
+! !
+
+!HLBindingAction methodsFor: 'testing'!
+
+isBindingAction
+	^ true
+! !
+
+HLBinding subclass: #HLBindingGroup
+	instanceVariableNames: 'bindings'
+	package: 'Helios-KeyBindings'!
+
+!HLBindingGroup methodsFor: 'accessing'!
+
+add: aBinding
+	^ self bindings add: aBinding
+!
+
+addActionKey: anInteger labelled: aString callback: aBlock
+	self add: ((HLBindingAction on: anInteger labelled: aString)
+    	callback: aBlock;
+        yourself)
+!
+
+addActionKey: anInteger labelled: aString command: aCommand
+	self add: ((HLBindingAction on: anInteger labelled: aString)
+    	command: aCommand;
+        yourself)
+!
+
+addGroupKey: anInteger labelled: aString
+	self add: (HLBindingGroup on: anInteger labelled: aString)
+!
+
+at: aString
+	^ self bindings 
+    	detect: [ :each | each label = aString ]
+      	ifNone: [ nil ]
+!
+
+atKey: anInteger
+	^ self bindings 
+    	detect: [ :each | each key = anInteger ]
+      	ifNone: [ nil ]
+!
+
+bindings
+	^ bindings ifNil: [ bindings := OrderedCollection new ]
+! !
+
+!HLBindingGroup methodsFor: 'actions'!
+
+applyOn: aKeyBinder
+	aKeyBinder applyBindingGroup: self
+! !
+
+!HLBindingGroup methodsFor: 'rendering'!
+
+renderOn: aBindingHelper html: html
+	aBindingHelper renderBindingGroup: self on: html
+! !
+
+!HLBindingGroup methodsFor: 'testing'!
+
+isBindingGroup
+	^ true
+! !
+
+Object subclass: #HLKeyBinder
+	instanceVariableNames: 'modifierKey active helper bindings selectedBinding'
+	package: 'Helios-KeyBindings'!
+
+!HLKeyBinder methodsFor: 'accessing'!
+
+activationKey
+	"SPACE"
+	^ 32
+!
+
+bindings
+	^ bindings ifNil: [ bindings := HLBindingGroup new ]
+!
+
+escapeKey
+	"ESC"
+	^ 27
+!
+
+helper
+	^ helper ifNil: [ helper := HLKeyBinderHelper on: self ]
+!
+
+selectedBinding
+	^ selectedBinding ifNil: [ self bindings ]
+! !
+
+!HLKeyBinder methodsFor: 'actions'!
+
+activate
+	active := true.
+	self helper show
+!
+
+applyBinding: aBinding
+    aBinding applyOn: self
+!
+
+applyBindingAction: aBinding
+    aBinding callback value.
+	self deactivate
+!
+
+applyBindingGroup: aBinding
+    selectedBinding := aBinding.
+    self helper refresh
+!
+
+deactivate
+	active := false.
+    selectedBinding := nil.
+	self helper hide
+!
+
+flushBindings
+	bindings := nil.
+    helper := nil
+! !
+
+!HLKeyBinder methodsFor: 'events'!
+
+handleActiveKeyDown: event
+
+	"ESC or ctrl+g deactivate the keyBinder"
+	(event which = self escapeKey or: [
+		event which = 71 and: [ event ctrlKey ] ])
+        	ifTrue: [ 
+            	self deactivate.
+				event preventDefault.
+				^ false ].
+            
+    "Handle the keybinding"
+    ^ self handleBindingFor: event
+!
+
+handleBindingFor: anEvent
+	| binding |
+    binding := self selectedBinding atKey: anEvent which.
+    
+    binding ifNotNil: [ 
+    	self applyBinding: binding.
+		anEvent preventDefault.
+		^ false ]
+!
+
+handleInactiveKeyDown: event
+      event which = self activationKey ifTrue: [
+      		event ctrlKey  ifTrue: [
+					self activate. 
+               		 event preventDefault. 
+                	^ false ] ]
+!
+
+handleKeyDown: event
+	^ self isActive
+    	ifTrue: [ self handleActiveKeyDown: event ]
+      	ifFalse: [ self handleInactiveKeyDown: event ]
+!
+
+setupEvents
+	(window jQuery: 'body') keydown: [ :event | self handleKeyDown: event ]
+! !
+
+!HLKeyBinder methodsFor: 'initialization'!
+
+initialize
+	super initialize.
+    active := false
+! !
+
+!HLKeyBinder methodsFor: 'testing'!
+
+isActive
+	^ active ifNil: [ false ]
+!
+
+systemIsMac
+	^ navigator platform match: 'Mac'
+! !
+
+HLWidget subclass: #HLKeyBinderHelper
+	instanceVariableNames: 'keyBinder'
+	package: 'Helios-KeyBindings'!
+
+!HLKeyBinderHelper methodsFor: 'accessing'!
+
+keyBinder
+	^ keyBinder
+!
+
+keyBinder: aKeyBinder
+	keyBinder := aKeyBinder
+!
+
+selectedBinding
+	^ self keyBinder selectedBinding
+! !
+
+!HLKeyBinderHelper methodsFor: 'actions'!
+
+hide
+	rootDiv asJQuery remove
+!
+
+show
+	self appendToJQuery: 'body' asJQuery
+! !
+
+!HLKeyBinderHelper methodsFor: 'keyBindings'!
+
+registerBindings
+	"Do nothing"
+! !
+
+!HLKeyBinderHelper methodsFor: 'rendering'!
+
+renderBindingGroup: aBindingGroup on: html
+	(aBindingGroup bindings 
+    	sorted: [ :a :b | a key < b key ])
+        do: [ :each |
+			html span class: 'command'; with: [
+				html span class: 'label'; with: each shortcut asLowercase.
+  				html a 
+                	class: 'action'; 
+                    with: each label;
+  					onClick: [ self keyBinder applyBinding: each ] ] ]
+!
+
+renderBindingOn: html
+	self selectedBinding renderOn: self html: html
+!
+
+renderContentOn: html
+	html div class: 'key_helper'; with: [
+      	self 
+        	renderSelectionOn:html;
+          	renderBindingOn: html ]
+!
+
+renderSelectionOn: html
+		html span 
+        	class: 'selected'; 
+            with: (self selectedBinding label ifNil: [ 'Action' ])
+! !
+
+!HLKeyBinderHelper class methodsFor: 'instance creation'!
+
+on: aKeyBinder
+	^ self new
+    	keyBinder: aKeyBinder;
+        yourself
+! !
+

data/amber/st/Helios-Layout.st

@@ -0,0 +1,199 @@
+Smalltalk current createPackage: 'Helios-Layout' properties: #{}!
+Widget subclass: #HLContainer
+	instanceVariableNames: 'splitter'
+	package: 'Helios-Layout'!
+
+!HLContainer methodsFor: 'accessing'!
+
+splitter
+	^ splitter
+!
+
+splitter: aSplitter
+	splitter := aSplitter
+! !
+
+!HLContainer methodsFor: 'rendering'!
+
+renderOn: html
+	html div 
+    	id: 'container'; 
+        with: self splitter.
+        
+   (window jQuery: window) bind: 'resize' do: [ self splitter resize ]
+! !
+
+!HLContainer class methodsFor: 'instance creation'!
+
+with: aSplitter
+	^ self new 
+    	splitter: aSplitter; 
+        yourself
+! !
+
+Widget subclass: #HLSplitter
+	instanceVariableNames: 'firstWidget secondWidget firstPane secondPane splitter'
+	package: 'Helios-Layout'!
+
+!HLSplitter methodsFor: 'accessing'!
+
+cssClass
+	^ 'splitter'
+!
+
+firstWidget
+	^ firstWidget
+!
+
+firstWidget: aWidget
+	firstWidget := aWidget
+!
+
+secondWidget
+	^ secondWidget
+!
+
+secondWidget: aWidget
+	secondWidget := aWidget
+! !
+
+!HLSplitter methodsFor: 'rendering'!
+
+panesCssClass
+	^ 'panes'
+!
+
+renderOn: html
+	html div class: self panesCssClass; with: [
+		firstPane := html div class: 'pane'; with: self firstWidget.
+    	splitter := html div class: self cssClass.
+    	secondPane := html div class: 'pane'; with: self secondWidget ].
+        
+	self 
+    	setupSplitter;
+        resize
+!
+
+resize
+	self firstWidget isHeliosSplitter ifTrue: [ self firstWidget resize ].
+    self secondWidget isHeliosSplitter ifTrue: [ self secondWidget resize ]
+!
+
+setupSplitter
+! !
+
+!HLSplitter methodsFor: 'testing'!
+
+isHeliosSplitter
+	^ true
+! !
+
+!HLSplitter class methodsFor: 'instance creation'!
+
+with: aWidget with: anotherWidget
+	^ self new
+    		firstWidget: aWidget;
+            secondWidget: anotherWidget;
+            yourself
+! !
+
+HLSplitter subclass: #HLHorizontalSplitter
+	instanceVariableNames: ''
+	package: 'Helios-Layout'!
+
+!HLHorizontalSplitter methodsFor: 'accessing'!
+
+cssClass
+	^ super cssClass, ' horizontal'
+!
+
+panesCssClass
+	^ super panesCssClass, ' horizontal'
+! !
+
+!HLHorizontalSplitter methodsFor: 'actions'!
+
+resize
+	self resize: splitter asJQuery offset top
+!
+
+resize: anInteger
+	| container position |
+    
+    container := firstPane asJQuery parent.
+    position := anInteger - container offset top.
+    
+	firstPane asJQuery height: ((position min: container height - 100) max: 100).
+    secondPane asJQuery height: (((container height - position) min: container height - 100) max: 100) - 6.
+    
+    super resize
+!
+
+startResizing: aSplitter
+	aSplitter width: splitter asJQuery width
+! !
+
+!HLHorizontalSplitter methodsFor: 'rendering'!
+
+setupSplitter
+	splitter asJQuery draggable: #{ 
+    	'axis' -> 'y'. 
+        'containment' -> splitter asJQuery parent.
+        'helper' -> 'clone'.
+        'start' -> [ :e :ui | self startResizing: ui helper ].
+        'drag' -> [ :e :ui | self resize: ui offset top ] }
+! !
+
+HLSplitter subclass: #HLVerticalSplitter
+	instanceVariableNames: ''
+	package: 'Helios-Layout'!
+
+!HLVerticalSplitter methodsFor: 'accessing'!
+
+cssClass
+	^ super cssClass, ' vertical'
+!
+
+panesCssClass
+	^ super panesCssClass, ' vertical'
+! !
+
+!HLVerticalSplitter methodsFor: 'actions'!
+
+resize
+	self resize: splitter asJQuery offset left
+!
+
+resize: anInteger
+	| container position |
+    
+    container := firstPane asJQuery parent.
+    position := anInteger - container offset left.
+    
+	firstPane asJQuery width: ((position min: container width - 100) max: 100).
+    secondPane asJQuery width: (((container width - position) min: container width - 100) max: 100) - 6.
+    
+    super resize
+!
+
+startResizing: aSplitter
+	aSplitter height: splitter asJQuery height
+! !
+
+!HLVerticalSplitter methodsFor: 'rendering'!
+
+setupSplitter
+	splitter asJQuery draggable: #{ 
+    	'axis' -> 'x'. 
+        'containment' -> splitter asJQuery parent.
+        'helper' -> 'clone'.
+        'start' -> [ :e :ui | self startResizing: ui helper ].
+        'drag' -> [ :e :ui | self resize: ui offset left ] }
+! !
+
+!Object methodsFor: '*Helios-Layout'!
+
+isHeliosSplitter
+	^ false
+! !
+