resin 0.2.2 → 0.2.3

data/amber/st/Helios-Environments.st

@@ -0,0 +1,98 @@
+Smalltalk current createPackage: 'Helios-Environments' properties: #{}!
+Object subclass: #HLEnvironment
+	instanceVariableNames: ''
+	package: 'Helios-Environments'!
+!HLEnvironment commentStamp!
+Abstract class defining common behavior for local and remote environments!
+
+!HLEnvironment methodsFor: 'accessing'!
+
+packages
+
+	^ self subclassResponsibility
+! !
+
+!HLEnvironment methodsFor: 'actions'!
+
+eval: someCode on: aReceiver
+
+	^ self subclassResponsibility
+! !
+
+HLEnvironment subclass: #HLLocalEnvironment
+	instanceVariableNames: ''
+	package: 'Helios-Environments'!
+
+!HLLocalEnvironment methodsFor: 'accessing'!
+
+packages
+
+	^ Smalltalk current packages
+! !
+
+!HLLocalEnvironment methodsFor: 'actions'!
+
+eval: someCode on: aReceiver
+	| compiler  |
+	compiler := Compiler new.
+	[compiler parseExpression: someCode] on: Error do: [:ex |
+		^window alert: ex messageText].
+	^(compiler eval: (compiler compile: 'doIt ^[', someCode, '] value' forClass: DoIt)) fn applyTo: aReceiver arguments: #()
+! !
+
+HLEnvironment subclass: #HLRemoteEnvironment
+	instanceVariableNames: ''
+	package: 'Helios-Environments'!
+
+!HLRemoteEnvironment methodsFor: 'accessing'!
+
+packages
+	"Answer the remote environment's packages"
+  
+	"to-do"
+    
+    "Note for future self and friends:
+    the problem with remote stuff is that the answers shouldn't be expected to be
+    received in a syncrhonous fashion. Everything network is asyc, so you *are going to deal with callbacks* here"
+! !
+
+!HLRemoteEnvironment methodsFor: 'actions'!
+
+eval: someCode on: aReceiver
+
+	"Note for future self and friends:
+    whatever way this compilation happens on the other side, 
+    it should return a proxy to the remote resulting object"
+    
+    self notYetImplemented
+! !
+
+Object subclass: #HLRemoteObject
+	instanceVariableNames: ''
+	package: 'Helios-Environments'!
+!HLRemoteObject commentStamp!
+This is a local proxy to a remote object.
+Tipically useful for evaluating and inspecting and interacting with instances of a remote VM.!
+
+!HLRemoteObject methodsFor: 'actions'!
+
+doesNotUnderstand: aMessage
+
+	"to-do
+
+	aham, blah blah
+
+	super doesNotUnderstand: aMessage"
+!
+
+inspectOn: anInspector
+
+	"to-do"
+
+	"this is a source of so much fun..."
+!
+
+printString
+	^ 'this is a remote object'
+! !
+

data/amber/st/Helios-Inspector.st

@@ -0,0 +1,367 @@
+Smalltalk current createPackage: 'Helios-Inspector' properties: #{}!
+HLWidget subclass: #HLInspector
+	instanceVariableNames: 'model variablesWidget displayWidget codeWidget label'
+	package: 'Helios-Inspector'!
+
+!HLInspector methodsFor: 'accessing'!
+
+codeWidget
+	^ codeWidget ifNil: [
+		codeWidget := HLCodeWidget new
+    		model: model code;
+        	receiver: model inspectee;
+        	yourself ]
+!
+
+displayWidget
+	^ displayWidget ifNil: [
+		displayWidget := HLInspectorDisplayWidget new
+    		model: self model;
+        	yourself ]
+!
+
+inspectee
+	^ self model inspectee
+!
+
+inspectee: anObject
+	self model inspectee: anObject
+!
+
+label
+    ^ label ifNil: [ model inspectee printString ]
+!
+
+model
+	^ model ifNil: [ 
+    	self model: HLInspectorModel new.
+		model ]
+!
+
+model: aModel
+	model := aModel. 
+    self codeWidget model: aModel code.
+    
+    self 
+        observeCodeWidget;
+    	observeVariablesWidget;
+        observeModel
+!
+
+tabLabel
+    ^ self label
+!
+
+variablesWidget
+	^ variablesWidget ifNil: [
+		variablesWidget := HLInspectorVariablesWidget new
+    		model: self model;
+        	yourself ]
+! !
+
+!HLInspector methodsFor: 'actions'!
+
+inspect: anObject
+	self model inspect: anObject on: self.
+    
+	self 
+    	refreshVariablesWidget;
+		refreshDisplayWidget
+!
+
+observeCodeWidget
+	self codeWidget announcer 
+    	on: HLDoItExecuted 
+        do: [ self onDoneIt ]
+!
+
+observeModel
+	self model announcer
+        on: HLInstanceVariableSelected do: [ :ann | self onInstanceVariableSelected ]
+!
+
+observeVariablesWidget
+	self variablesWidget announcer 
+    	on: HLRefreshRequested do: [ :ann | self onRefresh ];
+        on: HLDiveRequested do:[ self onDive ]
+!
+
+open
+	HLManager current addTab: (HLTab on: self labelled: self tabLabel)
+!
+
+refresh
+	self inspect: self inspectee
+!
+
+refreshDisplayWidget
+	self displayWidget refresh
+!
+
+refreshVariablesWidget
+	self variablesWidget refresh
+!
+
+setLabel: aString
+	label := aString
+!
+
+setVariables: aDictionary
+	self model variables: aDictionary
+! !
+
+!HLInspector methodsFor: 'reactions'!
+
+onDive
+
+	self inspect: self model selectedInstVarObject
+!
+
+onDoneIt
+
+	self refresh
+!
+
+onInspectIt
+!
+
+onInstanceVariableSelected
+	self codeWidget receiver: self model selectedInstVarObject.
+	self refreshDisplayWidget
+!
+
+onPrintIt
+!
+
+onRefresh
+
+	self refresh
+! !
+
+!HLInspector methodsFor: 'rendering'!
+
+renderContentOn: html
+   	html with: (HLContainer with: (HLHorizontalSplitter
+    	with: (HLVerticalSplitter 
+            		with: self variablesWidget
+            	    with: self displayWidget)
+        with: self codeWidget))
+! !
+
+!HLInspector class methodsFor: 'accessing'!
+
+tabLabel
+	^ 'Inspector'
+!
+
+tabPriority
+	^ 10
+! !
+
+!HLInspector class methodsFor: 'testing'!
+
+canBeOpenAsTab
+	^ false
+! !
+
+HLNavigationListWidget subclass: #HLInspectorDisplayWidget
+	instanceVariableNames: 'model'
+	package: 'Helios-Inspector'!
+
+!HLInspectorDisplayWidget methodsFor: 'accessing'!
+
+model
+
+	^ model
+!
+
+model: aModel
+
+	model := aModel
+! !
+
+!HLInspectorDisplayWidget methodsFor: 'rendering'!
+
+renderContentOn: html
+	
+    html div with: self selectionDisplayString
+!
+
+selectionDisplayString
+	|selection|
+	selection := model selection.
+    ^ (model variables keys includes: selection)
+    	ifTrue:[(model instVarObjectAt: selection) printString]
+      	ifFalse:['']
+! !
+
+Object subclass: #HLInspectorModel
+	instanceVariableNames: 'announcer environment inspectee code variables selection'
+	package: 'Helios-Inspector'!
+
+!HLInspectorModel methodsFor: 'accessing'!
+
+announcer
+	^ announcer ifNil: [announcer := Announcer new ]
+!
+
+code
+	"Answers the code model working for this workspace model"
+	^ code ifNil:[ code := HLCodeModel on: self environment ]
+!
+
+environment
+	^ environment ifNil: [ HLManager current environment ]
+!
+
+environment: anEnvironment
+	environment := anEnvironment
+!
+
+inspectee 
+	^ inspectee
+!
+
+inspectee: anObject 
+	inspectee := anObject
+!
+
+selectedInstVarObject
+	^ self instVarObjectAt: self selection
+!
+
+selection
+	^ selection ifNil:[ '' ]
+!
+
+selection: anObject
+	selection := anObject.
+
+	self announcer announce: (HLInstanceVariableSelected on: selection)
+!
+
+variables
+	^ variables
+!
+
+variables: aCollection
+	variables := aCollection
+! !
+
+!HLInspectorModel methodsFor: 'actions'!
+
+inspect: anObject on: anInspector
+	inspectee := anObject.
+	variables := #().
+	inspectee inspectOn: anInspector
+!
+
+instVarObjectAt: anInstVarName
+	^ self variables at: anInstVarName
+!
+
+selectedInstVar: anInstVarName
+    self selection: anInstVarName
+!
+
+subscribe: aWidget
+	aWidget subscribeTo: self announcer
+! !
+
+!HLInspectorModel methodsFor: 'reactions'!
+
+onKeyDown: anEvent
+
+	<if(anEvent.ctrlKey) {
+		if(anEvent.keyCode === 80) { //ctrl+p
+			self._printIt();
+			anEvent.preventDefault();
+			return false;
+		}
+		if(anEvent.keyCode === 68) { //ctrl+d
+			self._doIt();
+			anEvent.preventDefault();
+			return false;
+		}
+		if(anEvent.keyCode === 73) { //ctrl+i
+			self._inspectIt();
+			anEvent.preventDefault();
+			return false;
+		}
+	}>
+! !
+
+!HLInspectorModel class methodsFor: 'actions'!
+
+on: anEnvironment
+
+	^ self new
+    	environment: anEnvironment;
+        yourself
+! !
+
+HLNavigationListWidget subclass: #HLInspectorVariablesWidget
+	instanceVariableNames: 'announcer model list diveButton'
+	package: 'Helios-Inspector'!
+
+!HLInspectorVariablesWidget methodsFor: 'accessing'!
+
+announcer
+	^ announcer ifNil:[ announcer := Announcer new ]
+!
+
+model
+    ^ model
+!
+
+model: aModel
+    model := aModel
+!
+
+selection
+	^ model selection
+!
+
+variables
+	^ model variables
+! !
+
+!HLInspectorVariablesWidget methodsFor: 'actions'!
+
+refresh
+	self resetItems.
+    super refresh
+!
+
+resetItems
+	items := nil
+! !
+
+!HLInspectorVariablesWidget methodsFor: 'defaults'!
+
+defaultItems
+	^ self model variables keys
+! !
+
+!HLInspectorVariablesWidget methodsFor: 'reactions'!
+
+selectItem: anObject
+	super selectItem: anObject.
+    self model selectedInstVar: anObject
+! !
+
+!HLInspectorVariablesWidget methodsFor: 'rendering'!
+
+renderButtonsOn: html
+
+	html button
+			class: 'btn';
+			with: 'Refresh';
+			onClick: [self announcer announce: HLRefreshRequested new].
+
+	diveButton := html button 
+				class: 'btn';
+				with: 'Dive'; 
+				onClick: [self announcer announce: HLDiveRequested new]
+! !
+