rbdc 0.8.0

data/dyncall/dyncallback/dyncall_callback_x64.h

@@ -0,0 +1,44 @@
+/*
+
+ Package: dyncall
+ Library: dyncallback
+ File: dyncallback/dyncall_callback_x64.h
+ Description: Callback - Header for x64
+ License:
+
+   Copyright (c) 2007-2011 Daniel Adler <dadler@uni-goettingen.de>,
+                           Tassilo Philipp <tphilipp@potion-studios.com>
+
+   Permission to use, copy, modify, and distribute this software for any
+   purpose with or without fee is hereby granted, provided that the above
+   copyright notice and this permission notice appear in all copies.
+
+   THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+   WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+   MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+   ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+   WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+   ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+   OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+*/
+
+
+#ifndef DYNCALL_CALLBACK_X64_H_
+#define DYNCALL_CALLBACK_X64_H_
+
+#include "dyncall_callback.h"
+
+#include "dyncall_thunk.h"
+#include "dyncall_args_x64.h"
+
+
+struct DCCallback
+{
+  DCThunk  	         thunk;    // offset 0,  size 24
+  DCCallbackHandler* handler;  // offset 24
+  void*              userdata; // offset 32
+};
+
+#endif /* DYNCALL_CALLBACK_X64_H_ */
+

data/dyncall/dyncallback/dyncall_callback_x64_apple.s

@@ -0,0 +1,122 @@
+/*
+
+ Package: dyncall
+ Library: dyncallback
+ File: dyncallback/dyncall_callback_x64_apple.s
+ Description: Callback Thunk - Implementation for x64 (Apple as assembly)
+ License:
+
+   Copyright (c) 2007-2011 Daniel Adler <dadler@uni-goettingen.de>,
+                           Tassilo Philipp <tphilipp@potion-studios.com>
+
+   Permission to use, copy, modify, and distribute this software for any
+   purpose with or without fee is hereby granted, provided that the above
+   copyright notice and this permission notice appear in all copies.
+
+   THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+   WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+   MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+   ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+   WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+   ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+   OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+*/
+
+
+.intel_syntax
+.text
+
+/* sizes */
+
+.set DCThunk_size	,  24
+.set DCArgs_size	, 128
+.set DCValue_size	,   8
+
+/* frame local variable offsets relative to %rbp*/
+
+.set FRAME_arg0		,  16
+.set FRAME_return	,   8
+.set FRAME_parent	,   0
+.set FRAME_DCArgs	,-128
+.set FRAME_DCValue	,-136
+
+/* struct DCCallback */
+
+.set CTX_thunk		,   0
+.set CTX_handler	,  24
+.set CTX_userdata	,  32
+.set DCCallback_size	,  40
+
+.globl _dcCallbackThunkEntry
+_dcCallbackThunkEntry:
+
+	pushq %rbp
+	movq  %rbp, %rsp
+
+	// initialize DCArgs
+
+	// float parameters (8 registers spill to DCArgs)
+	sub %rsp, 8*8
+	movq [%rsp+8*7], %xmm7  # struct offset 120: float parameter 7
+	movq [%rsp+8*6], %xmm6  # struct offset 112: float parameter 6
+	movq [%rsp+8*5], %xmm5  # struct offset 104: float parameter 5
+	movq [%rsp+8*4], %xmm4  # struct offset  96: float parameter 4
+	movq [%rsp+8*3], %xmm3  # struct offset  88: float parameter 3
+	movq [%rsp+8*2], %xmm2  # struct offset  80: float parameter 2
+	movq [%rsp+8*1], %xmm1  # struct offset  72: float parameter 1
+	movq [%rsp+8*0], %xmm0	# struct offset  64: float parameter 0
+
+	// integer parameters (6 registers spill to DCArgs)
+	pushq %r9	# struct offset 56: parameter 5
+	pushq %r8	# struct offset 48: parameter 4
+	pushq %rcx	# struct offset 40: parameter 3
+	pushq %rdx	# struct offset 32: parameter 2
+	pushq %rsi	# struct offset 24: parameter 1
+	pushq %rdi	# struct offset 16: parameter 0
+
+	// register counts for integer/pointer and float regs
+			# struct offset 12: fcount
+	pushq 0		# struct offset 8:  icount
+
+	lea  %rdx, [%rbp+FRAME_arg0]	# struct offset 0: stack pointer
+	pushq %rdx
+
+	mov  %rsi, %rsp			# parameter 1 (RSI) = DCArgs*
+
+	// initialize DCValue
+
+	pushq 0				# structo offset 0: return value (max long long)
+
+	// call handler( *ctx, *args, *value, *userdata)
+
+	mov  %rdi, %rax			# parameter 0 (RDI) = DCCallback* (RAX)
+	mov  %rcx, [%rdi+CTX_userdata]	# arg3 = userdata*
+	mov  %rdx, %rsp 		# arg2 (RDX) = DCValue*
+
+	pushq 0				# align to 16 bytes
+
+	call [%rax+CTX_handler]
+
+	// pass return type via registers
+	// distinguish two basic classes 'integer' and 'float'
+	
+	mov  %dl, %al
+	movq %rax, [%rbp+FRAME_DCValue]
+
+ASCII_f	= 102
+ASCII_d = 100
+
+	cmpb	%dl, ASCII_f
+	je	.float
+	cmpb	%dl, ASCII_d
+	jne	.return
+.float:
+	movd %xmm0, %rax
+
+.return:
+	mov  %rsp, %rbp
+	pop  %rbp
+	ret
+
+

data/dyncall/dyncallback/dyncall_callback_x64_gas.s

@@ -0,0 +1,119 @@
+/*
+
+ Package: dyncall
+ Library: dyncallback
+ File: dyncallback/dyncall_callback_x64_gas.s
+ Description: Callback Thunk - Implementation for x64 (GNU as assembler)
+ License:
+
+   Copyright (c) 2007-2011 Daniel Adler <dadler@uni-goettingen.de>,
+                           Tassilo Philipp <tphilipp@potion-studios.com>
+
+   Permission to use, copy, modify, and distribute this software for any
+   purpose with or without fee is hereby granted, provided that the above
+   copyright notice and this permission notice appear in all copies.
+
+   THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+   WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+   MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+   ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+   WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+   ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+   OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+*/
+
+.intel_syntax
+.text
+.globl dcCallbackThunkEntry
+
+/* sizes */
+
+.set DCThunk_size	,  24
+.set DCArgs_size	, 128
+.set DCValue_size	,   8
+
+/* frame local variable offsets relative to %rbp*/
+
+.set FRAME_arg0		,  16
+.set FRAME_return	,   8
+.set FRAME_parent	,   0
+.set FRAME_DCArgs	,-128
+.set FRAME_DCValue	,-136
+
+/* struct DCCallback */
+
+.set CTX_thunk		,   0
+.set CTX_handler	,  24
+.set CTX_userdata	,  32
+.set DCCallback_size	,  40
+
+dcCallbackThunkEntry:
+
+	pushq %rbp
+	movq  %rbp, %rsp
+
+	// initialize DCArgs
+
+	// float parameters (8 registers spill to DCArgs)
+	sub %rsp, 8*8
+	movq [%rsp+8*7], %xmm7  # struct offset 120: float parameter 7
+	movq [%rsp+8*6], %xmm6  # struct offset 112: float parameter 6
+	movq [%rsp+8*5], %xmm5  # struct offset 104: float parameter 5
+	movq [%rsp+8*4], %xmm4  # struct offset  96: float parameter 4
+	movq [%rsp+8*3], %xmm3  # struct offset  88: float parameter 3
+	movq [%rsp+8*2], %xmm2  # struct offset  80: float parameter 2
+	movq [%rsp+8*1], %xmm1  # struct offset  72: float parameter 1
+	movq [%rsp+8*0], %xmm0	# struct offset  64: float parameter 0
+
+	// fill integer parameters (6 registers spill to DCArgs)
+	pushq 	%r9			# struct offset 56: parameter 5
+	pushq 	%r8			# struct offset 48: parameter 4
+	pushq 	%rcx			# struct offset 40: parameter 3
+	pushq 	%rdx			# struct offset 32: parameter 2
+	pushq 	%rsi			# struct offset 24: parameter 1
+	pushq 	%rdi			# struct offset 16: parameter 0
+
+	// fill register counts for integer/pointer and float regs
+	pushq	0			# struct offset 12: fcount
+					# struct offset 8:  icount
+
+	// fill argument stack pointer
+	lea  	%rdx, [%rbp+FRAME_arg0]
+	pushq	%rdx			# struct offset 0: stack pointer
+
+	mov 	%rsi, %rsp		# arg1 (RSI) = DCArgs*
+
+	// initialize DCValue:
+	pushq 	0			# structo offset 0: return value (max long long)
+
+	// call handler( *ctx, *args, *value, *userdata)
+
+	mov  %rdi, %rax			# arg0 (RDI) = DCCallback* (RAX)
+	mov  %rcx, [%rdi+CTX_userdata]	# arg3 = userdata*
+	mov  %rdx, %rsp 		# arg2 (RDX) = DCValue*
+
+	pushq 0				# align to 16 bytes
+
+	call [%rax+CTX_handler]
+
+	// pass return type via registers
+	// distinguish two basic classes 'integer' and 'float'
+
+	mov  %dl, %al
+	movq %rax, [%rbp+FRAME_DCValue]
+
+	cmp  %dl, 'f'
+	je   .float
+	cmp  %dl, 'd'
+	je   .float
+.int:
+	jmp  .return
+.float:
+	movd %xmm0, %rax
+
+.return:
+	mov  %rsp, %rbp
+	pop  %rbp
+	ret
+

data/dyncall/dyncallback/dyncall_callback_x64_gas_w64.s

@@ -0,0 +1,102 @@
+/*
+
+ Package: dyncall
+ Library: dyncallback
+ File: dyncallback/dyncall_callback_x64_gas_w64.s
+ Description: Callback Thunk - Implementation for x64 (GNU as assembler)
+ License:
+
+   Copyright (c) 2007-2011 Daniel Adler <dadler@uni-goettingen.de>,
+                           Tassilo Philipp <tphilipp@potion-studios.com>
+
+   Permission to use, copy, modify, and distribute this software for any
+   purpose with or without fee is hereby granted, provided that the above
+   copyright notice and this permission notice appear in all copies.
+
+   THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+   WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+   MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+   ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+   WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+   ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+   OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+*/
+
+.intel_syntax
+.text
+.globl dcCallbackThunkEntry
+
+/* sizes */
+
+.set DCThunk_size	,  24
+.set DCArgs_size	,  80 /* 128 */
+.set DCValue_size	,   8
+
+/* frame local variable offsets relative to %rbp*/
+
+.set FRAME_arg0		,  48 /* 16 */
+.set FRAME_return	,   8
+.set FRAME_parent	,   0
+.set FRAME_DCArgs	, -80  /* -128 */
+.set FRAME_DCValue	, -80  /* -136 */
+
+/* struct DCCallback */
+
+.set CTX_thunk		,   0
+.set CTX_handler	,  24
+.set CTX_userdata	,  32
+.set DCCallback_size	,  40
+
+dcCallbackThunkEntry:
+
+	pushq %rbp
+	movq  %rbp, %rsp
+
+	// initialize DCArgs
+
+	// float parameters (4 registers spill to DCArgs)
+	sub %rsp, 4*8
+	movq [%rsp+8*3], %xmm3  # struct offset  72: float parameter 3
+	movq [%rsp+8*2], %xmm2  # struct offset  64: float parameter 2
+	movq [%rsp+8*1], %xmm1  # struct offset  56: float parameter 1
+	movq [%rsp+8*0], %xmm0	# struct offset  48: float parameter 0
+
+	// fill integer parameters (4 registers spill to DCArgs)
+	pushq 	%r9			# struct offset 40: int parameter 3
+	pushq 	%r8			# struct offset 32: int parameter 2
+	pushq 	%rdx			# struct offset 24: int parameter 1
+	pushq 	%rcx			# struct offset 16: int parameter 0
+
+	// fill register counts for integer/pointer and float regs
+	pushq	0			# struct offset 8:  register count
+
+	// fill argument stack pointer
+	lea  	%rdx, [%rbp+FRAME_arg0]
+	pushq	%rdx			# struct offset 0: stack pointer
+
+	mov 	%rdx, %rsp		# arg1 (RDX) = DCArgs*
+
+	// initialize DCValue:
+	// pushq 	0			# structo offset 0: return value (max long long)
+
+	// call handler( *ctx, *args, *value, *userdata)
+
+	mov  %rcx, %rax			# arg0 (RCX) = DCCallback* (RAX)
+	mov  %r9,  [%rax+CTX_userdata]	# arg3 (R9)  = userdata*
+	mov  %r8, %rsp 			# arg2 (RDX) = DCValue*
+
+	sub  %rsp, 4*8			# make foom for spill area and call
+
+	call [%rax+CTX_handler]
+
+	// pass return type via registers
+	// distinguish two basic classes 'integer' and 'float'
+
+	movq %rax, [%rbp+FRAME_DCValue]
+	movd %xmm0, %rax
+
+	mov  %rsp, %rbp
+	pop  %rbp
+	ret
+

data/dyncall/dyncallback/dyncall_callback_x64_masm.asm

@@ -0,0 +1,89 @@
+; auto-generated by gen-masm.sh
+.CODE
+DCThunk_size = 24
+DCArgs_size_win64 = 80
+DCArgs_size_sysv = 128
+DCValue_size = 8
+FRAME_arg0_win64 = 48
+FRAME_arg0_sysv = 16
+FRAME_return = 8
+FRAME_parent = 0
+FRAME_DCArgs_sysv = -128
+FRAME_DCValue_sysv = -136
+FRAME_DCArgs_win64 = -80
+FRAME_DCValue_win64 = -80
+CTX_thunk = 0
+CTX_handler = 24
+CTX_userdata = 32
+DCCallback_size = 40
+dcCallback_x64_sysv PROC
+OPTION PROLOGUE:NONE, EPILOGUE:NONE
+ push RBP
+ mov RBP,RSP
+ sub RSP,8*8
+ movsd qword ptr [RSP+8*7],XMM7
+ movsd qword ptr [RSP+8*6],XMM6
+ movsd qword ptr [RSP+8*5],XMM5
+ movsd qword ptr [RSP+8*4],XMM4
+ movsd qword ptr [RSP+8*3],XMM3
+ movsd qword ptr [RSP+8*2],XMM2
+ movsd qword ptr [RSP+8*1],XMM1
+ movsd qword ptr [RSP+8*0],XMM0
+ push R9
+ push R8
+ push RCX
+ push RDX
+ push RSI
+ push RDI
+ push 0
+ lea RDX,qword ptr [RBP+FRAME_arg0_sysv]
+ push RDX
+ mov RSI,RSP
+ push 0
+ mov RDI,RAX
+ mov RCX,qword ptr [RDI+CTX_userdata]
+ mov RDX,RSP
+ push 0
+ call qword ptr [RAX+CTX_handler]
+ mov DL,AL
+ mov RAX,qword ptr [RBP+FRAME_DCValue_sysv]
+ cmp DL,102
+ je return_f64
+ cmp DL,100
+ jne return_i64
+return_f64:
+ movd XMM0,RAX
+return_i64:
+ mov RSP,RBP
+ pop RBP
+ ret
+dcCallback_x64_sysv ENDP
+dcCallback_x64_win64 PROC
+OPTION PROLOGUE:NONE, EPILOGUE:NONE
+ push RBP
+ mov RBP,RSP
+ sub RSP,4*8
+ movsd qword ptr [RSP+8*3],XMM3
+ movsd qword ptr [RSP+8*2],XMM2
+ movsd qword ptr [RSP+8*1],XMM1
+ movsd qword ptr [RSP+8*0],XMM0
+ push R9
+ push R8
+ push RDX
+ push RCX
+ push 0
+ lea RDX,qword ptr [RBP+FRAME_arg0_win64]
+ push RDX
+ mov RDX,RSP
+ mov RCX,RAX
+ mov R9,qword ptr [RAX+CTX_userdata]
+ mov R8,RSP
+ sub RSP,4*8
+ call qword ptr [RAX+CTX_handler]
+ mov RAX,qword ptr [RBP+FRAME_DCValue_win64]
+ movd XMM0,RAX
+ mov RSP,RBP
+ pop RBP
+ ret
+dcCallback_x64_win64 ENDP
+END