rbdc 0.8.0

data/dyncall/dyncall/dyncall_call_mips_eabi.h

@@ -0,0 +1,61 @@
+/*
+
+ Package: dyncall
+ Library: dyncall
+ File: dyncall/dyncall_call_mips_eabi.h
+ Description: mips "eabi" abi call kernel C interface.
+ License:
+
+   Copyright (c) 2007-2011 Daniel Adler <dadler@uni-goettingen.de>, 
+                           Tassilo Philipp <tphilipp@potion-studios.com>
+
+   Permission to use, copy, modify, and distribute this software for any
+   purpose with or without fee is hereby granted, provided that the above
+   copyright notice and this permission notice appear in all copies.
+
+   THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+   WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+   MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+   ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+   WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+   ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+   OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+*/
+
+
+#ifndef DYNCALL_CALL_MIPS_EABI_H
+#define DYNCALL_CALL_MIPS_EABI_H
+
+#include "dyncall_types.h"
+
+#ifdef __cplusplus
+extern "C" {
+#endif
+
+/* Call-kernel register data: 
+
+   Details:
+   Two register content buffers for the corresponding register types 
+   integer and float are filled from CallVM code and then later at
+   call-kernel loaded into the registers.
+ */
+
+struct DCRegData_mips_eabi
+{
+  DCint   mIntData[8];
+  DCfloat mSingleData[8];
+};
+
+
+/* Call kernel. */
+
+void dcCall_mips_eabi(DCpointer target, struct DCRegData_mips_eabi*  regdata, DCsize stksize, DCpointer stkdata);
+
+#ifdef __cplusplus
+}
+#endif
+
+
+#endif /* DYNCALL_CALL_MIPS_EABI_H */
+

data/dyncall/dyncall/dyncall_call_mips_eabi_gas.s

@@ -0,0 +1,115 @@
+/*
+
+ Package: dyncall
+ Library: dyncall
+ File: dyncall/dyncall_call_mips_eabi_gas.s
+ Description: 
+ License:
+
+   Copyright (c) 2007-2011 Daniel Adler <dadler@uni-goettingen.de>, 
+                           Tassilo Philipp <tphilipp@potion-studios.com>
+
+   Permission to use, copy, modify, and distribute this software for any
+   purpose with or without fee is hereby granted, provided that the above
+   copyright notice and this permission notice appear in all copies.
+
+   THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+   WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+   MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+   ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+   WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+   ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+   OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+*/
+
+
+/*//////////////////////////////////////////////////////////////////////
+
+	dyncall_call_mips_eabi_gas.s
+
+	MIPS 32bit family of processors.
+	2008-01-03
+
+//////////////////////////////////////////////////////////////////////*/
+.text
+.globl dcCall_mips_eabi
+
+dcCall_mips_eabi:
+	/* $4 target function */
+ 	/* $5 register data */
+	/* $6 stack size */
+	/* $7 stack data */
+	addiu	$sp,$sp,-16
+	sw	$16,8($sp)
+	sw	$31,4($sp)
+	sw	$fp,0($sp)
+
+	move	$fp,$sp
+	
+	move	$2, $0
+	add	$2, 8
+	neg	$2
+	and	$sp, $2
+	add	$6, 7
+	and	$6, $2
+
+	move	$12,$4		/* target function */
+	move	$13,$5		/* register data   */
+	move    $16,$6		/* stack size      */
+	
+	sub	$sp,$sp,$16	/* allocate stack frame */
+	
+	/* copy stack data */
+
+.next:
+	beq	$6,$0, .skip
+	nop
+	addiu	$6,$6, -4
+
+	lw	$2, 0($7)
+	sw	$2, 0($sp)
+	addiu	$7,$7, 4
+	addiu	$sp,$sp, 4
+	j	.next
+	nop
+	
+.skip:	
+
+	sub	$sp,$sp,$16
+
+	/* load integer parameter registers */
+
+	lw	$4 , 0($13)
+	lw	$5 , 4($13)
+	lw	$6 , 8($13)
+	lw	$7 ,12($13)
+	lw	$8 ,16($13)
+	lw	$9 ,20($13)
+	lw	$10,24($13)
+	lw	$11,28($13)
+
+	/* load single-precise floating pointer parameter registers */
+
+	lwc1	$f12, 32($13)
+	lwc1	$f13, 36($13)
+	lwc1	$f14, 40($13)
+	lwc1	$f15, 44($13)
+	lwc1	$f16, 48($13)
+	lwc1	$f17, 52($13)
+	lwc1	$f18, 56($13)
+	lwc1	$f19, 60($13)	
+
+	jal	$12
+	nop
+
+	/* add	$sp,$sp,$16  */
+	move	$sp,$fp 
+
+	lw	$16,8($sp)
+	lw	$31,4($sp)
+	lw	$fp,0($sp)
+	addiu	$sp,$sp,16
+	j	$31
+	nop
+

data/dyncall/dyncall/dyncall_call_mips_gas.S

@@ -0,0 +1,36 @@
+/*
+
+ Package: dyncall
+ Library: dyncall
+ File: dyncall/dyncall_call_mips_gas.S
+ Description: auto-select (via gnu c preprocessor) mips abi call kernel
+ License:
+
+   Copyright (c) 2007-2011 Daniel Adler <dadler@uni-goettingen.de>,
+                           Tassilo Philipp <tphilipp@potion-studios.com>
+
+   Permission to use, copy, modify, and distribute this software for any
+   purpose with or without fee is hereby granted, provided that the above
+   copyright notice and this permission notice appear in all copies.
+
+   THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+   WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+   MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+   ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+   WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+   ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+   OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+*/
+
+
+#if defined(DC__ABI_MIPS_O32)
+#include "dyncall_call_mips_o32_gas.s"
+#elif defined(DC__ABI_MIPS_N64)
+#include "dyncall_call_mips_n64_gas.s"
+#elif defined(DC__ABI_MIPS_N32)
+#include "dyncall_call_mips_n32_gas.s"
+#else
+#include "dyncall_call_mips_eabi_gas.s"
+#endif
+

data/dyncall/dyncall/dyncall_call_mips_n32.h

@@ -0,0 +1,67 @@
+/*
+
+ Package: dyncall
+ Library: dyncall
+ File: dyncall/dyncall_call_mips_n32.h
+ Description: mips "n32" ABI call-kernel C interface.
+ License:
+
+   Copyright (c) 2007-2011 Daniel Adler <dadler@uni-goettingen.de>, 
+                           Tassilo Philipp <tphilipp@potion-studios.com>
+
+   Permission to use, copy, modify, and distribute this software for any
+   purpose with or without fee is hereby granted, provided that the above
+   copyright notice and this permission notice appear in all copies.
+
+   THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+   WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+   MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+   ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+   WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+   ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+   OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+*/
+
+
+#ifndef DYNCALL_CALL_MIPS_N32_H
+#define DYNCALL_CALL_MIPS_N32_H
+
+#include "dyncall_types.h"
+
+#ifdef __cplusplus
+extern "C" {
+#endif
+
+/*
+  two register-files for integer (promoted to 64-bit) and float (not promoted!)
+  are used.
+
+  arguments are transfered in a free slot on the corresponding register file.
+  the other register-file will be skipped by one.
+
+  float arguments are either loaded from single or double -
+  a auto-conversion into double and then loaded as double precision
+  turned out to fail for several tests.
+
+  therefore a union for storage of float or double is used instead.
+  a bitmask (mUseDouble) records which type is used and will be
+  interpreted in the call-kernel.
+*/
+
+struct DCRegData_mips_n32
+{
+  DClonglong   mIntData[8];
+  union { DCfloat f; DCdouble d; } mFloatData[8];
+  DClonglong   mUseDouble; /* bitmask: lower 8 bits specifies to use float or double from union array. */
+};
+
+void dcCall_mips_n32(DCpointer target, struct DCRegData_mips_n32* regdata, DCsize stksize, DCpointer stkdata);
+
+#ifdef __cplusplus
+}
+#endif
+
+
+#endif /* DYNCALL_CALL_MIPS_N64_H */
+

data/dyncall/dyncall/dyncall_call_mips_n32_gas.s

@@ -0,0 +1,192 @@
+/*
+
+ Package: dyncall
+ Library: dyncall
+ File: dyncall/dyncall_call_mips_n32_gas.s
+ Description: mips "n32" abi call kernel implementation in GNU Assembler
+ License:
+
+   Copyright (c) 2007-2011 Daniel Adler <dadler@uni-goettingen.de>, 
+                           Tassilo Philipp <tphilipp@potion-studios.com>
+
+   Permission to use, copy, modify, and distribute this software for any
+   purpose with or without fee is hereby granted, provided that the above
+   copyright notice and this permission notice appear in all copies.
+
+   THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+   WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+   MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+   ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+   WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+   ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+   OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+*/
+
+	.section .mdebug.abiN32
+	.previous
+	.abicalls
+	.text
+	.align	2
+	.globl	dcCall_mips_n32
+	.ent	dcCall_mips_n32
+dcCall_mips_n32:
+
+	/* Stack-frame prolog */
+
+	.frame	$fp,64,$31		/* vars=16, regs=3/0, args=0, extra=16 */
+	.mask	0xd0000000,-8
+	.fmask	0x00000000,0
+	subu	$sp,$sp,64
+	sd	$31,48($sp)	/* save return address register (ra) */
+	sd	$30,40($sp)	/* save frame pointer register (fp) */
+	sd	$28,32($sp)	/* save global pointer register (gp) */
+	move	$fp,$sp
+
+
+	/* arguments: */
+		
+	/* $4 target function */
+ 	/* $5 register data */
+	/* $6 stack size */
+	/* $7 stack data */
+	
+
+	/* allocate argument stack space */
+
+	subu	$sp, $sp, $6
+	
+	/* copy stack data */
+
+	/* n64 abi call assumptions:
+           - stack data is 16-byte aligned.
+           - no extra-storage for arguments passed via registers.
+        */
+
+	/* $12  source pointer (parameter stack data) */
+	/* $14  destination (stack pointer) */
+	/* $6   byte count */
+
+	move	$12, $7
+	move	$14, $sp
+
+.next:
+	beq	$6, $0, .skip
+	nop
+	daddiu	$6, $6, -8
+	ld	$2, 0($12)
+	sd	$2, 0($14)
+	daddiu	$12,$12, 8
+	daddiu	$14,$14, 8
+	b	.next
+.skip:
+	move	$25, $4
+
+	/* load registers */
+
+	/* locals: */
+	/* $13 = register data */
+	/* $14 = useDouble flags */
+	move	$13, $5
+	ld	$14, 128($13)
+	
+	/* load integer parameter registers */
+
+	ld	$4 , 0($13)
+	ld	$5 , 8($13)
+	ld	$6 ,16($13)
+	ld	$7 ,24($13)
+	ld	$8 ,32($13)
+	ld	$9 ,40($13)
+	ld	$10,48($13)
+	ld	$11,56($13)
+
+	/* load float-or-double floating pointer parameter registers 
+           a 64-bit bitmask given at byte offset 128 of regdata indicates
+           if loading a float (bit cleared) or double (bit set), starting
+           at bit position 0 in bitmask.
+        */
+.t0:
+	and     $15, $14, 1
+	bgtz	$15, .d0
+.f0:
+	l.s	$f12, 64($13)
+	j	.t1
+.d0:
+	l.d	$f12, 64($13)
+
+.t1:
+	and	$15, $14, 2
+	bgtz	$15, .d1
+.f1:
+	l.s	$f13, 72($13)
+	j	.t2
+.d1:
+	l.d	$f13, 72($13)
+.t2:	
+	and	$15, $14, 4
+	bgtz	$15, .d2
+.f2:
+	l.s	$f14, 80($13)
+	j	.t3
+.d2:	
+	l.d	$f14, 80($13)
+.t3:
+	and	$15, $14, 8
+	bgtz	$15, .d3
+.f3:
+	l.s	$f15, 88($13)
+	j	.t4
+.d3:
+	l.d	$f15, 88($13)
+.t4:
+	and	$15, $14, 16
+	bgtz	$15, .d4
+.f4:
+	l.s	$f16, 96($13)
+	j	.t5
+.d4:
+	l.d	$f16, 96($13)
+.t5:
+	and	$15, $14, 32
+	bgtz	$15, .d5
+.f5:
+	l.s	$f17,104($13)
+	j	.t6
+.d5:
+	l.d	$f17,104($13)
+.t6:
+	and	$15, $14, 64
+	bgtz	$15, .d6
+.f6:
+	l.s	$f18,112($13)
+	j	.t7
+.d6:
+	l.d	$f18,112($13)
+.t7:
+	and	$15, $14, 128
+	bgtz	$15, .d7
+.f7:
+	l.s	$f19,120($13)
+	j	.fregend
+.d7:
+	l.d	$f19,120($13)
+
+.fregend:
+
+	/* jump-and-link to register $25 */
+
+	jal	$31, $25
+
+	/* no nop according to gcc assembly output */	
+
+	/* Stack-frame epilog */	
+	move	$sp,$fp 
+	ld	$31,48($sp)	/* restore ra register */
+	ld	$fp,40($sp)	/* restore fp register */
+	ld	$28,32($sp)	/* restore gp register */
+	daddu	$sp,$sp,64
+	j	$31
+	.end	dcCall_mips_n64
+	.size	dcCall_mips_n64, .-dcCall_mips_n64
+