needy_debugger 1.4.0

data/emacs/rdebug-locring.el

@@ -0,0 +1,118 @@
+;;; rdebug-locring.el --- Ruby debugger location ring
+
+;; Copyright (C) 2008, 2009 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2008 Anders Lindgren
+
+;; $Id: rdebug-locring.el 917 2009-03-31 09:49:37Z rockyb $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+
+;; This file manages a ring of (recently stopped) positions to allow
+;; the programmer to move back and forth between them.
+
+;;; Code:
+
+(defvar rdebug-source-location-ring nil
+  "Ring of the last `rdebug-source-location-ring-size' positions we've stopped aft.")
+
+(defvar rdebug-source-location-ring-index -1
+  "Position in `rdebug-source-location-ring' of where we are.")
+
+(defun rdebug-locring-add (frame location-history-ring)
+  "Add FRAME to LOCATION-HISTORY-RING if we are on the top frame and have a frame to add."
+  ;; Switching frames shouldn't save a new ring
+  ;; position. Also make sure no position is different.
+  ;; Perhaps duplicates should be controlled by an option.
+  (unless (and (not (ring-empty-p location-history-ring))
+	       (equal (ring-ref location-history-ring
+				(ring-length location-history-ring)) frame))
+    (ring-insert-at-beginning location-history-ring frame)))
+
+(defun rdebug-locring-clear ()
+  "Clear out all source locations in `Go to the source location of the first stopping point."
+  (interactive)
+  (setq rdebug-source-location-ring-index -1)
+  (while (not (ring-empty-p rdebug-source-location-ring))
+    (ring-remove rdebug-source-location-ring)))
+
+(defun rdebug-locring-goto (ring-position)
+  "Go the source position RING-POSITION in the stopping history."
+  (interactive "NSource location ring position (0 is oldest): ")
+  (with-current-buffer gud-comint-buffer
+    (setq rdebug-source-location-ring-index ring-position)
+    (let* ((frame (ring-ref rdebug-source-location-ring ring-position))
+	   (file (car frame))
+	   (line (cdr frame)))
+      (when file
+	(rdebug-display-line file line)
+	(message (format "%d %s:%d" rdebug-source-location-ring-index
+			 file line))))))
+    
+(defun rdebug-locring-newer ()
+  "Cycle through source location stopping history to get the next newer (more recently visited) location."
+  (interactive)
+  (with-current-buffer gud-comint-buffer
+    (if (equal (+ 1 rdebug-source-location-ring-index)
+	       (ring-length rdebug-source-location-ring))
+	(progn
+	  (message "At newest - Will set to wrap to oldest.")
+	  (setq rdebug-source-location-ring-index -1))
+      ;; else
+      (rdebug-locring-goto
+       (if (> rdebug-source-location-ring-index
+	      (ring-length rdebug-source-location-ring))
+	   0
+	 ;; else
+	 (ring-plus1 rdebug-source-location-ring-index
+		     (ring-length rdebug-source-location-ring)))))))
+
+(defun rdebug-locring-newest ()
+  "Go to the source location of the first stopping point."
+  (interactive)
+  (rdebug-locring-goto (- (ring-length rdebug-source-location-ring) 1)))
+  
+(defun rdebug-locring-older ()
+  "Cycle through source location stopping history to get the next older (least recently visited) location."
+  (interactive)
+  (with-current-buffer gud-comint-buffer
+    (if (equal rdebug-source-location-ring-index 0)
+	(progn
+	  (message "At oldest - Will set to wrap to newest.")
+	  (setq rdebug-source-location-ring-index
+		(+ 1 (ring-length rdebug-source-location-ring))))
+      ;; else
+      (rdebug-locring-goto
+       (if (or (not rdebug-source-location-ring-index)
+	       (< rdebug-source-location-ring-index 0))
+	   0
+	 ;; else
+	 (ring-minus1 rdebug-source-location-ring-index
+		      (ring-length rdebug-source-location-ring)))))))
+
+(defun rdebug-locring-oldest ()
+  "Go to the oldest source position location."
+  (interactive)
+  (ring-ref rdebug-source-location-ring 0))
+
+(provide 'rdebug-locring)
+
+;;; Local variables:
+;;; eval:(put 'rdebug-debug-enter 'lisp-indent-hook 1)
+;;; End:
+
+;;; rdebug-locring.el ends here

data/emacs/rdebug-output.el

@@ -0,0 +1,106 @@
+;;; rdebug-output.el --- Ruby debugger output buffer
+
+;; Copyright (C) 2008 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2008 Anders Lindgren
+
+;; $Id: rdebug-output.el 711 2008-02-20 07:09:17Z andersl $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+
+;; See the manual and the file `rdebug.el' for more information.
+
+;; This file contains code dealing with the output secondary buffer.
+
+;;; Code:
+
+(require 'rdebug-dbg)
+(require 'rdebug-secondary)
+
+(defun rdebug-display-output-buffer ()
+  "Display the rdebug output buffer."
+  (interactive)
+  (rdebug-display-secondary-buffer "output"))
+
+;; FIXME add a macro to toggle read-only and run command.
+(defun rdebug-output-add-divider ()
+  (interactive "")
+  (save-excursion
+    (goto-char (point-max))
+    (setq buffer-read-only nil)
+    ;; FIXME Cooler would be to pick up stack position in stack line
+    ;; and prepend a buffer-local marker number
+    (insert (format "%d: ============================\n"
+		    rdebug-output-marker-number))
+    (setq rdebug-output-marker-number (+ rdebug-output-marker-number 1))
+    (setq buffer-read-only t)))
+
+(defun rdebug-output-delete-output ()
+  (interactive)
+  (setq buffer-read-only nil)
+  (delete-region (point-min) (point-max))
+  (setq buffer-read-only t))
+
+(defun rdebug-output-undo ()		;FIXME make more global?
+  (interactive "")
+  (setq buffer-read-only nil)
+  (undo)
+  (setq buffer-read-only t))
+
+(defvar rdebug-output-mode-map
+  (let ((map (make-sparse-keymap)))
+    (define-key map "d" 'rdebug-output-delete-output)
+    (define-key map "t" 'rdebug-goto-traceback-line)
+    (define-key map "!" 'rdebug-goto-dollarbang-traceback-line)
+    (define-key map "=" 'rdebug-output-add-divider)
+    (define-key map "\C-_" 'rdebug-output-undo) ; FIXME get from keymap
+    (define-key map "u"    'rdebug-output-undo)
+    (suppress-keymap map)
+    (rdebug-populate-secondary-buffer-map map)
+    map)
+  "Keymap used in the output buffer in the `rdebug' Ruby debugger.")
+
+(defun rdebug-output-mode ()
+  "Major mode for displaying the script output in the `rdebug' Ruby debugger.
+
+\\{rdebug-output-mode}"
+  (interactive)
+  (let ((old-marker-number rdebug-output-marker-number))
+    (kill-all-local-variables)
+    (setq major-mode 'rdebug-output-mode)
+    (setq mode-name "RDEBUG Output")
+    (setq buffer-read-only t)
+    (set (make-local-variable 'rdebug-secondary-buffer) t)
+    (setq mode-line-process 'rdebug-mode-line-process)
+    (set (make-local-variable 'rdebug-accumulative-buffer) t)
+    (use-local-map rdebug-output-mode-map)
+    (set (make-local-variable 'rdebug-output-marker-number) old-marker-number)
+    (run-mode-hooks 'rdebug-output-mode-hook)))
+
+(defun rdebug-setup-output-buffer (buf comint-buffer)
+  (rdebug-debug-enter "rdebug-setup-output-buffer"
+    (with-current-buffer buf
+      (rdebug-output-mode)
+      (set (make-local-variable 'gud-comint-buffer) comint-buffer))))
+
+(provide 'rdebug-output)
+
+;;; Local variables:
+;;; eval:(put 'rdebug-debug-enter 'lisp-indent-hook 1)
+;;; End:
+
+;;; rdebug-output.el ends here

data/emacs/rdebug-regexp.el

@@ -0,0 +1,118 @@
+;;; rdebug-regexp.el --- Ruby debugger regular expressions
+
+;; Copyright (C) 2007, 2008 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2007, 2008 Anders Lindgren
+
+;; $Id: rdebug-regexp.el 724 2008-02-24 16:14:52Z rockyb $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+
+;; See the manual and the file `rdebug.el' for more information.
+
+;; Here we have regular expressions and names for matched patterns
+;; of those regular expressions.
+
+;;; Code:
+
+;; -------------------------------------------------------------------
+;; Variables defining regular expressions (regexp:s).
+;;
+
+(defconst gud-rdebug-marker-regexp
+  "\\(?:source \\)?\\(\\(?:[a-zA-Z]:\\)?[^:\n]*\\):\\([0-9]*\\).*\n"
+  "Regular expression used to find a file location given by rdebug.
+
+Program-location lines look like this:
+   source /tmp/gcd.rb:29:  gcd
+   /tmp/gcd.rb:29:  gcd
+   source /tmp/gcd.rb:29
+   source C:/tmp/gcd.rb:29
+   source \\sources\\capfilterscanner\\capanalyzer.rb:3:  <module>")
+
+(defconst rdebug-annotation-end-regexp
+  "\n"
+  "Regular expression to match the end of an annotation.")
+
+;; Examples of annotations:
+;; ^Z^Z\n
+;; ^Z^Zfoo\n
+;; ^Z^Zpre-prompt\n
+;; ^Z^Zsource foo.rb:10\n
+
+(defconst rdebug-annotation-start-regexp
+  "\\(\\([a-z][-a-z]*\\)?\n\\|source \\)"
+  "Regular expression to match the start of an annotation.")
+
+(defconst rdebug-breakpoint-regexp
+  "^\\ +\\([0-9]+\\) \\([yn]\\) +at +\\(.+\\):\\([0-9]+\\)\\( if .*\\)?$"
+  "Regexp to recognize breakpoint lines in rdebug breakpoint buffers.")
+
+(defconst rdebug-marker-regexp-file-group 2
+  "Group position in `rdebug-position-regexp' that matches the file name.")
+
+(defconst rdebug-marker-regexp-line-group 3
+  "Group position in `rdebug-position-regexp' that matches the line number.")
+
+(defconst rdebug-position-regexp
+  "\\(\\)\\([-a-zA-Z0-9_/.]*\\):\\([0-9]+\\)"
+  "Regular expression for a rdebug position.")
+
+(defconst rdebug-traceback-line-re
+  "^[ \t]+from \\([^:]+\\):\\([0-9]+\\)\\( in `.*'\\)?"
+  "Regular expression that describes a Ruby traceback line.")
+
+(defconst rdebug-dollarbang-traceback-line-re
+  "^[ \t]+[[]?\\([^:]+\\):\\([0-9]+\\):in `.*'"
+  "Regular expression that describes a Ruby traceback line from $! list.")
+
+(defconst rdebug-stack-frame-1st-regexp
+  "^\\(-->\\|   \\) +#\\([0-9]+\\)\\(.*\\)"
+  "Regexp to match the first line of a stack frame in rdebug stack buffers.")
+
+(defconst rdebug-stack-frame-number-group 2
+  "The group position in `rdebug-stack-frame-1st-regexp' that matches the frame number.")
+
+(defconst rdebug-stack-frame-2nd-regexp
+  "\s+at line +\\([^:]+\\):\\([0-9]+\\)$"
+  "Regexp to match the second line of a stack frame in rdebug stack buffers.")
+
+(defconst rdebug-stack-frame-2nd-file-group 1
+  "Group position in `rdebug-stack-frame-2nd-regexp' that matches the file name.")
+
+(defconst rdebug-stack-frame-2nd-line-group 2
+  "Group position in `rdebug-stack-frame-2nd-regexp' that matches the line number.")
+(defconst rdebug-stack-frame-regexp
+  (concat rdebug-stack-frame-1st-regexp rdebug-stack-frame-2nd-regexp)
+  "Regexp to recognize a stack frame line in rdebug stack buffers.")
+
+(defconst rdebug-stack-frame-file-group 4
+  "Group position in `rdebug-stack-frame-regexp' that matches the file name.")
+
+(defconst rdebug-stack-frame-line-group 5
+  "Group position in `rdebug-stack-frame-regexp' that matches the line number.")
+
+(defconst rdebug-input-prompt-regexp "(+rdb:\\([0-9]+\\|post-mortem\\)) "
+  "Regular expression to recognize a rdebug prompt.  Some uses may prepend an anchor to the front.")
+
+(provide 'rdebug-regexp)
+
+;;; Local variables:
+;;; eval:(put 'rdebug-debug-enter 'lisp-indent-hook 1)
+;;; End:
+
+;;; rdebug-regexp.el ends here

data/emacs/rdebug-secondary.el

@@ -0,0 +1,260 @@
+;;; rdebug-secondary.el --- Rdebug support windows.
+
+;; Copyright (C) 2008 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2008 Anders Lindgren
+
+;; $Id: rdebug-secondary.el 733 2008-02-29 04:34:44Z rockyb $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+
+;; See the manual and the file `rdebug.el' for more information.
+
+;; Key bindings and menu for secondary buffers.
+
+;;; Code:
+
+(require 'rdebug)
+
+(defun rdebug-populate-secondary-buffer-map (map)
+  "Bind all common keys and menu used in the rdebug secondary buffers.
+This includes the keys bound to `gud-key-prefix' (typically C-x
+C-a)."
+  (rdebug-populate-secondary-buffer-map-plain map)
+  (rdebug-populate-common-keys map)
+  (rdebug-populate-debugger-menu map)
+  (let ((prefix-map (make-sparse-keymap)))
+    (rdebug-populate-secondary-buffer-map-plain prefix-map)
+    (define-key map gud-key-prefix prefix-map)))
+
+
+(defun rdebug-display-cmd-buffer ()
+  "Display the rdebug debugger command buffer."
+  (interactive)
+  (rdebug-display-secondary-buffer "cmd"))
+
+(defun rdebug-pick-secondary-window-categorize (win name orig-win)
+  "Return how suiteable this window is to display the a secondary buffer.
+The higher score the better."
+  (let ((buffer (window-buffer win)))
+    (save-current-buffer
+      (set-buffer buffer)
+      (cond (rdebug-secondary-buffer
+             (cond ((eq win orig-win)
+                    ;; If the user issued the command inside a
+                    ;; secondary window, use that window.
+                    5)
+                   ((and (member name '("variables" "watch"))
+                         (memq major-mode '(rdebug-variables-mode
+                                            rdebug-watch-mode)))
+                    ;; Let "Watch" and "Variables" switch content.
+                    4)
+                   (t
+                    ;; Any other secondary window.
+                    3)))
+            ((eq major-mode 'ruby-mode)
+             ;; Avoid source windows.
+             0)
+            ((eq major-mode 'gud-mode)
+             ;; Avoid the debugger shell window.
+             1)
+            (t
+             ;; Just any other window.
+             2)))))
+
+
+(defun rdebug-display-secondary-buffer (name)
+  "Display one of the rdebug secondary buffers.
+If the buffer doesn't exist, do nothing. If the buffer is already
+displayed, switch to it. Otherwise if the current buffer is a
+secondary buffer, bury it replacing with the requested
+buffer. Failing that, if there is secondary buffer visible, that
+is replaced instead.  And finally failing all of the preceding,
+we'll just pick a visible buffer to bury and replace."
+  (let* ((buf-name (rdebug-get-secondary-buffer-name name))
+         (buf (get-buffer buf-name))
+         (orig-win (selected-window)))
+    (if (null buf)
+        (message "Buffer %s not found" buf-name)
+      ;; Find a suitable window to display the buffer in.
+      (let ((win (get-buffer-window buf (selected-frame))))
+        (if win
+            ;; Buffer already displayed, switch to it.
+            (select-window win)
+          ;;
+          (let ((candidate nil)
+                (candidate-score -1))
+            (dolist (win (window-list (selected-frame)))
+              (let ((score (rdebug-pick-secondary-window-categorize
+                            win name orig-win)))
+                (if (> score candidate-score)
+                    (progn
+                      (setq candidate       win)
+                      (setq candidate-score score)))))
+            (select-window candidate)))))
+    (switch-to-buffer buf)))
+
+
+;; Note: The generic `gud' framework contains special code to handle
+;; this for GDB (see `gud-display-line') which we, unfortuately can't
+;; use. Instead, we call `rdebug-pick-source-window' from
+;; `gud-rdebug-marker-filter'. When gud becomes more generic we could
+;; hopefully solve this in another way.
+;;
+;; The machanism is that `rdebug-pick-source-window' displays the
+;; source file in the window of our choice, and gud kindly re-uses
+;; that window.
+
+
+(defun rdebug-display-source-window-categorize (win)
+  "Return how suitable this window WIN is to display the source buffer.
+The higher score the better."
+  (let ((buffer (window-buffer win)))
+    (cond ((eq buffer gud-comint-buffer)
+           0)
+          ((buffer-local-value 'rdebug-secondary-buffer buffer)
+           1)
+          ((eq (buffer-local-value 'major-mode buffer) 'ruby-mode)
+           3)                           ; Pick me! Pick me!
+          (t
+           2))))
+
+(defun rdebug-display-pick-source-window ()
+  "Return the window that should get replaced by the source window."
+  (rdebug-debug-enter "rdebug-display-pick-source-window"
+    (let ((candidate nil)
+          (candidate-score -1))
+      (dolist (win (window-list (selected-frame)))
+        (let ((score
+               (rdebug-display-source-window-categorize win)))
+          (if (> score candidate-score)
+              (progn
+                (setq candidate       win)
+                (setq candidate-score score)))))
+      candidate)))
+
+(defun rdebug-frame-source-buffer (frame)
+  "Return the buffer corresponding to the source file given in FRAME, or nil if none."
+  (and frame
+       gud-comint-buffer
+       (save-current-buffer
+         (set-buffer gud-comint-buffer)
+         (gud-find-file (car frame)))))
+
+
+(defun rdebug-current-source-buffer ()
+  "Return the latest source buffer, or nil."
+  (or (rdebug-frame-source-buffer gud-last-frame)
+      (rdebug-frame-source-buffer gud-last-last-frame)))
+
+
+(defun rdebug-display-source-buffer ()
+  "Display the current source buffer."
+  (interactive)
+  (rdebug-debug-enter "rdebug-display-source-buffer"
+    (let ((buffer (rdebug-current-source-buffer))
+          (last-buffer (rdebug-frame-source-buffer gud-last-last-frame)))
+      (if buffer
+          (let ((window
+                 (or
+                  ;; Buffer is already visible, re-use the window.
+                  (get-buffer-window buffer)
+                  ;; Re-use the last window
+                  (and last-buffer
+                       (get-buffer-window last-buffer))
+                  ;; Find a non-rdebug window.
+                  (rdebug-display-pick-source-window))))
+            (select-window window)
+            (switch-to-buffer buffer))))))
+
+
+(defun rdebug-pick-source-window ()
+  "Display the source file, but do not switch window."
+  (save-selected-window
+    (rdebug-display-source-buffer)))
+
+
+(defun rdebug-display-source-buffer-resync ()
+  "Resync output and display the source buffer."
+  (interactive)
+  (call-interactively 'gud-source-resync)
+  (rdebug-display-source-buffer))
+
+
+(defun rdebug-delete-frame-or-window ()
+  "Delete frame if there is only one window.  Otherwise delete the window."
+  (interactive)
+  (if (one-window-p) (delete-frame)
+    (delete-window)))
+
+(defun rdebug-goto-entry-try (str)
+  "See if thre is an entry with number STR.  If not return nil."
+  (goto-char (point-min))
+  (if (re-search-forward (concat "^[^0-9]*\\(" str "\\)[^0-9]") nil t)
+      (progn
+        (goto-char (match-end 1))
+        t)
+    nil))
+
+
+;; The following is split in two to facilitate debugging.
+(defun rdebug-goto-entry-n-internal (keys)
+  (if (and (stringp keys)
+           (= (length keys) 1))
+      (progn
+        (setq rdebug-goto-entry-acc (concat rdebug-goto-entry-acc keys))
+        ;; Try to find the longest suffix.
+        (let ((acc rdebug-goto-entry-acc)
+              (p (point)))
+          (while (not (string= acc ""))
+            (if (not (rdebug-goto-entry-try acc))
+                (setq acc (substring acc 1))
+              (setq p (point))
+              ;; Break loop.
+              (setq acc "")))
+          (goto-char p)))
+    (message "`rdebug-goto-entry-n' must be bound to a number key")))
+
+
+(defun rdebug-goto-entry-n ()
+  "Go to an entry number.
+
+Breakpoints, Display expressions and Stack Frames all have
+numbers associated with them which are distinct from line
+numbers.  In a secondary buffer, this function is usually bound to
+a numeric key which will position you at that entry number.  To
+go to an entry above 9, just keep entering the number.  For
+example, if you press 1 and then 9, you should jump to entry
+1 (if it exists) and then 19 (if that exists).  Entering any
+non-digit will start entry number from the beginning again."
+  (interactive)
+  (if (not (eq last-command 'rdebug-goto-entry-n))
+      (setq rdebug-goto-entry-acc ""))
+  (rdebug-goto-entry-n-internal (this-command-keys)))
+
+
+;; -------------------------------------------------------------------
+;; The end.
+;;
+
+(provide 'rdebug-secondary)
+
+;;; Local variables:
+;;; eval:(put 'rdebug-debug-enter 'lisp-indent-hook 1)
+;;; End:
+
+;;; rdebug-secondary.el ends here