needy_debugger 1.4.0

data/emacs/rdebug-gud.el

@@ -0,0 +1,242 @@
+;;; rdebug-gud.el --- rdebug interface to gud.
+
+;; Copyright (C) 2007, 2008 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2007, 2008 Anders Lindgren
+
+;; $Id: rdebug-gud.el 821 2008-04-25 02:54:44Z rockyb $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+
+;; See the manual and the file `rdebug.el' for more information.
+
+;; This file contains rdebug Emacs routines which interface with gud.
+
+;;; Code:
+
+;; -------------------------------------------------------------------
+;; Dependencies.
+;;
+
+(require 'gud)
+(require 'rdebug-error)
+(require 'rdebug-fns)
+(require 'rdebug-regexp)
+(require 'rdebug-vars)
+
+
+(defun gud-rdebug-massage-args (file args)
+  "Change FILE and list ARGS before running the debugger.
+
+gud requires this routine to be defined."
+  args)
+
+
+(defun gud-rdebug-find-file (file)
+  "`rdebug' and `gud' call this with FILE when they encounter a Ruby program file."
+
+  (find-file-noselect file 'nowarn))
+
+(defun rdebug-display-line (file line &optional move-arrow)
+  "Arrange for marker to appear in at FILE and LINE.
+The line marker might appear in the Emacs fringe or as an overlay arroe. 
+Optional argument MOVE-ARROW indicates whether to move any previous indicator."
+  (if file 
+      (let ((oldpos (and gud-overlay-arrow-position
+			 (marker-position gud-overlay-arrow-position)))
+	    (oldbuf (and gud-overlay-arrow-position
+			 (marker-buffer gud-overlay-arrow-position))))
+	(gud-display-line file line)
+	(unless move-arrow
+	  (when gud-overlay-arrow-position
+	    (set-marker gud-overlay-arrow-position oldpos oldbuf))))))
+
+(defun rdebug-stepping (step-or-next &optional arg)
+  (or arg (setq arg 1))
+  ;;(if (not (member '('rdebug-next 'rdebug-step 'digit-argument) last-command))
+  ;; (setq rdebug-stepping-prefix ""))
+  (unless (member rdebug-stepping-prefix '("" "+" "-"))
+    (setq rdebug-stepping-prefix ""))
+  (rdebug-call (format "%s%s %d" step-or-next rdebug-stepping-prefix arg)))
+
+
+
+;; -------------------------------------------------------------------
+;; Rdebug commands.
+;;
+
+(defun rdebug-call (cmd)
+  "Run a debugger command with some error checking."
+  (if (rdebug-dead-process-p)
+      (rdebug-errmsg 
+       "Can't find a live debugger process buffer to feed the command to.")
+    (gud-call cmd)))
+
+(defun rdebug-call-return (cmd &rest options)
+  "Register a debugger command whose output should be handled specially.
+
+OPTIONS is zero or more indicators what should happen with the
+output. The following are supported:
+ * :tooltip -- Show the result in a tool-tip.
+ * :info    -- Show the result in the info secondary buffer."
+  (if (rdebug-dead-process-p)
+      (rdebug-errmsg 
+       "Can't find a live debugger process buffer to feed the command to.")
+    (with-current-buffer gud-comint-buffer
+      (setq rdebug-call-queue
+	    (append rdebug-call-queue (list (cons cmd options))))
+      (gud-call cmd))))
+
+(defun rdebug-continue (&optional arg)
+  "Run a debugger \"continue\" command.
+
+With a numeric ARG, continue to that line number of the current file."
+  (interactive "p")
+  (if arg
+      (rdebug-call (format "continue %d" arg))
+    (rdebug-call (format "continue"))))
+
+
+(defun rdebug-next (&optional arg)
+  "Run a debugger \"next\" command, respecting `rdebug-stepping-prefix'.
+
+With a numeric ARG, continue to that line number of the current file."
+  (interactive "p")
+  (rdebug-stepping "next" arg))
+
+(defvar rdebug-stepping-prefix ""
+  "The kind of stepping modifier that is desired.
+
+This variable will have a string value which is either \"\",
+\"+\", or \"-\"; this string is be appended to the debugger
+stepping commands (\"next\", or \"step\").")
+
+(defun rdebug-print-cmd (expr &optional cmd)
+  "Run a debugger print (pl, ps, pp, p) command on `EXPR'; `CMD' is the command to run."
+  (interactive "s")
+  (unless cmd (setq cmd "pp"))
+  (rdebug-call-return (format "%s %s " cmd expr) :tooltip))
+
+(defun rdebug-print-list-region (from to)
+  "Run a debugger \"pl\" command on the marked region."
+  (interactive "r")
+  (if (> from to)
+      (let ((tem to))
+	(setq to from from tem)))
+  (rdebug-print-cmd (buffer-substring from to) "pl"))
+
+(defun rdebug-print-region (from to)
+  "Run a debugger \"p\" command on the marked region."
+  (interactive "r")
+  (if (> from to)
+      (let ((tem to))
+	(setq to from from tem)))
+  (rdebug-print-cmd (buffer-substring from to) "p"))
+
+(defun rdebug-print-sorted-region (from to)
+  "Run a debugger \"ps\" command on the marked region."
+  (interactive "r")
+  (if (> from to)
+      (let ((tem to))
+	(setq to from from tem)))
+  (rdebug-print-cmd (buffer-substring from to) "ps"))
+
+(defun rdebug-pretty-print-region (from to)
+  "Run a debugger \"pp\" command on the marked region."
+  (interactive "r")
+  (if (> from to)
+      (let ((tem to))
+	(setq to from from tem)))
+  (rdebug-print-cmd (buffer-substring from to) "pp"))
+
+
+;;
+;; The following two commands should be seen as proof-of-concept
+;; functions for the info buffer.
+;;
+
+(defun rdebug-pretty-print-to-buffer (s)
+  "Pretty print expression to the info buffer."
+  (interactive "sPretty print: ")
+  (rdebug-call-return (format "pp %s" s) :info))
+
+(defun rdebug-pretty-print-region-to-buffer (from to)
+  "Pretty print expression in region to the info buffer."
+  (interactive "r")
+  (rdebug-call-return (format "pp %s" (buffer-substring from to)) :info))
+
+
+
+(defun rdebug-quit ()
+  "Kill the debugger process associated with the current buffer.
+
+When `rdebug-many-windows' is active, the original window layout
+is restored."
+  (interactive)
+  (if (yes-or-no-p "Really quit? ")
+      (rdebug-call "quit unconditionally")))
+
+(defun rdebug-restart ()
+  "Restart the debugged Ruby script.
+
+An exec restart is used."
+  (interactive)
+  (if (yes-or-no-p "Restart? ")
+      (rdebug-call "restart")))
+
+(defun rdebug-set-stepping-prefix ()
+  "Set the granularity of stepping on the subsequent 'next' or 'step' command.
+As long as repeated next or step commands are given, they inherit this setting."
+  (interactive)
+  (setq rdebug-stepping-prefix (this-command-keys)))
+
+(defun rdebug-step (&optional arg)
+  "Run a debugger \"next\" command, respecting `rdebug-stepping-prefix'.
+
+With a numeric ARG, continue to that line number of the current file."
+  (interactive "p")
+  (rdebug-stepping "step" arg))
+
+(defun rdebug-newer-frame ()
+  "Run a debugger \"down\" command to an newer frame. 
+
+If we try to go down from frame 0, wrap to the end of the file"
+  (interactive)
+  (let* ((buf-name (rdebug-get-secondary-buffer-name "frame"))
+         (buf (or (get-buffer buf-name) (current-buffer))))
+    (with-current-buffer buf
+      ;; Should we add a mode to disable wrapping?
+      (if (equal rdebug-frames-current-frame-number 0)
+	  (rdebug-call "frame -1")
+	(rdebug-call "down 1")))))
+
+(defun rdebug-older-frame ()
+  "Run a debugger \"up\" command to an older frame."
+  (interactive)
+  (let* ((buf-name (rdebug-get-secondary-buffer-name "frame"))
+         (buf (or (get-buffer buf-name) (current-buffer))))
+    (with-current-buffer buf
+      ;; Should we add a mode to disable wrapping? 
+      (rdebug-call "up 1"))))
+
+(provide 'rdebug-gud)
+
+;;; Local variables:
+;;; eval:(put 'rdebug-debug-enter 'lisp-indent-hook 1)
+;;; End:
+
+;;; rdebug-gud.el ends here

data/emacs/rdebug-help.el

@@ -0,0 +1,104 @@
+;;; rdebug-help.el --- Ruby debugger help 
+
+;; Copyright (C) 2008 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2008 Anders Lindgren
+
+;; $Id: rdebug-help.el 711 2008-02-20 07:09:17Z andersl $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+
+;; See the manual and the file `rdebug.el' for more information.
+
+;; This file contains code dealing with the help buffer.
+
+;;; Code:
+
+(defvar rdebug-secondary-window-help-mode-map
+  (let ((map (make-sparse-keymap)))
+    (suppress-keymap map)
+    (rdebug-populate-secondary-buffer-map map)
+    map)
+  "Keymap used in the help buffer in the `rdebug' Ruby debugger.")
+
+(defun rdebug-secondary-window-help-mode ()
+  "Major mode for the secondary buffer help text in the `rdebug' Ruby debugger.
+
+\\{rdebug-secondary-window-help-mode-map}"
+  (interactive)
+  (kill-all-local-variables)
+  (setq major-mode 'rdebug-secondary-window-help-mode)
+  (setq mode-name "RDEBUG Help")
+  (setq buffer-read-only t)
+  (set (make-local-variable 'rdebug-secondary-buffer) t)
+  (setq mode-line-process 'rdebug-mode-line-process)
+  (use-local-map rdebug-secondary-window-help-mode-map)
+  (run-mode-hooks 'rdebug-secondary-window-help-mode-hook))
+
+(defun rdebug-display-secondary-window-help-buffer ()
+  "Display the rdebug help buffer."
+  (interactive)
+  (rdebug-display-secondary-buffer "help"))
+
+(defun rdebug-setup-secondary-window-help-buffer (buf comint-buffer)
+  (rdebug-debug-enter "rdebug-setup-secondary-window-help-buffer"
+    (with-current-buffer buf
+      (rdebug-secondary-window-help-mode)
+      (set (make-local-variable 'gud-comint-buffer) comint-buffer)
+      (insert "\
+
+This is a rdebug secondary window, you can use it to watch a
+number of help buffers. Use capital letters to switch between the
+available buffers. Lower case letters (and other key
+combinations) are used to issue buffer-specific commands.
+
+Press `C-h m' for more help, when the individual buffers are visible.
+
+ B - Breakpoints buffer.
+ C - Command buffer (the debugger shell)
+ O - Output window
+ S - go to source frame
+ T - Stack trace buffer
+ V - Variables buffer
+ W - Watch buffer
+
+ SPC - step (into)
+ +   - set for step+ and next+
+ -   - set for step- and next-
+ _   - set to remove +/-
+ c   - continue
+ f   - finish (step out)
+ n   - next (step over)
+ p   - print
+ q   - quit
+ r   - run (restart)
+ R   - run (restart)
+ s   - step (into)
+
+ > - go down frame (with numeric argument goes down that many frames)
+ < - go up one frame (with numeric argument goes down that many frames)
+
+ ? - This help text.
+"))))
+
+(provide 'rdebug-help)
+
+;;; Local variables:
+;;; eval:(put 'rdebug-debug-enter 'lisp-indent-hook 1)
+;;; End:
+
+;;; rdebug-help.el ends here

data/emacs/rdebug-info.el

@@ -0,0 +1,83 @@
+;;; rdebug-info.el --- This file contains code dealing with the Ruby
+;;; debugger's info secondary buffer.
+
+;; Copyright (C) 2008 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2008 Anders Lindgren
+
+;; $Id: rdebug-breaks.el 670 2008-02-06 18:15:28Z rockyb $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+
+;; See the manual and the file `rdebug.el' for more information.
+
+
+;;; Code:
+
+(require 'rdebug-dbg)
+(require 'rdebug-gud)
+(require 'rdebug-regexp)
+(require 'rdebug-secondary)
+(require 'rdebug-source)
+(require 'rdebug-vars)
+
+(defun rdebug-display-info-buffer ()
+  "Display the rdebug breakpoints buffer."
+  (interactive)
+  (rdebug-display-secondary-buffer "info"))
+
+(defvar rdebug-info-mode-map
+  (let ((map (make-sparse-keymap)))
+    (rdebug-populate-secondary-buffer-map map)
+    map)
+  "Keymap for the Rdebug info secondary buffer.")
+
+(defun rdebug-info-mode ()
+  "Major mode for Ruby debugger info buffer.
+
+\\{rdebug-info-mode-map}"
+  (kill-all-local-variables)
+  (setq major-mode 'rdebug-info-mode)
+  (setq mode-name "RDEBUG Info")
+  (use-local-map rdebug-info-mode-map)
+  (setq buffer-read-only t)
+  (set (make-local-variable 'rdebug-secondary-buffer) t)
+  (setq mode-line-process 'rdebug-mode-line-process)
+  (run-mode-hooks 'rdebug-info-mode-hook))
+
+(defun rdebug-setup-info-buffer (buf comint-buffer)
+  "Setup the Rdebug debugger info buffer."
+  (rdebug-debug-enter "rdebug-setup-info-buffer"
+    (with-current-buffer buf
+      (let ((inhibit-read-only t)
+	    (old-line-number (buffer-local-value 'rdebug-current-line-number
+						 buf)))
+        (rdebug-info-mode)
+	(goto-line old-line-number)))))
+
+
+;; -------------------------------------------------------------------
+;; The end.
+;;
+
+(provide 'rdebug-info)
+
+;;; Local variables:
+;;; eval:(put 'rdebug-debug-enter 'lisp-indent-hook 1)
+;;; End:
+
+;;; rdebug-info.el ends here

data/emacs/rdebug-layouts.el

@@ -0,0 +1,180 @@
+;;; rdebug-layouts.el --- Ruby debugger window layouts.
+
+;; Copyright (C) 2008 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2008 Anders Lindgren
+
+;; $Id: rdebug-layouts.el 723 2008-02-24 04:51:39Z rockyb $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+
+;; This is file contains the window layouts that come with rdebug; the
+;; code where can be consulted as a guide for creating other window
+;; layouts.
+
+;; See the manual and the file `rdebug.el' for overall information on
+;; the ruby debugger rdebug.
+
+;;; Code:
+
+(defun rdebug-get-buffer (name script-name)
+  "Return a rdebug buffer for displaying NAME when debugging SCRIPT-NAME.
+If the buffer doesn't exists it is created."
+  (get-buffer-create (format "*rdebug-%s-%s*" name script-name)))
+
+
+(defun rdebug-get-existing-buffer (name script-name)
+  "Return a rdebug buffer for displaying NAME when debugging SCRIPT-NAME.
+Return nil if the buffer doesn't exists."
+  (get-buffer (format "*rdebug-%s-%s*" name script-name)))
+
+
+(defun rdebug-window-layout-conservative (src-buf name)
+  "A conservative rdebug window layout with three windows.
+
+This window layout mimics the traditional debugger shell and
+source window layout, it only add one secondary window.
+Initially, the secondary window displays output of the debugged
+process, but any secondary buffer can be displayed, press `?' in
+the window for more details.
+Argument SRC-BUF the buffer containing the Ruby source program that was initially run.  NAME is the name of that buffer."
+  (delete-other-windows)
+  (split-window-horizontally)
+  (other-window 1)
+  (switch-to-buffer src-buf)
+  (other-window 1)
+  (when rdebug-use-separate-io-buffer
+    (split-window nil 20)
+    (set-window-buffer
+     (selected-window) (rdebug-get-buffer "output" name)))
+  (other-window 1))
+
+(defun rdebug-window-layout-rocky (src-buf name)
+  "Rocky's window layout.
+
+3 windows.  The source window is on top 4/5 of height.  The
+bottom is split between the command windows and a stack window.
+
+See `rdebug' for more information.
+Argument SRC-BUF the buffer containing the Ruby source program that was initially run.  NAME is the name of that buffer."
+  (delete-other-windows)
+  (split-window nil ( / ( * (window-height) 4) 5))
+  (set-window-buffer
+   (selected-window) src-buf)
+  (other-window 1)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "frame" name))
+  (split-window-horizontally)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "cmd" name))
+  (goto-char (point-max)))
+
+(defun rdebug-window-layout-rocky2 (src-buf name)
+  "This layout is standard window without the output window, see `rdebug'.
+for more information.
+Argument SRC-BUF is the NAME of the buffer containing the Ruby source program that was initially run."
+  (delete-other-windows)
+  (split-window nil ( / ( * (window-height) 3) 4))
+  (set-window-buffer
+   (selected-window) src-buf)
+  (split-window nil ( / (window-height) 3))
+  (split-window-horizontally)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "frame" name))
+  (other-window 1)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "variables" name))
+  (other-window 1)
+  (switch-to-buffer src-buf)
+  (other-window 1)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "cmd" name))
+  (goto-char (point-max)))
+
+(defun rdebug-window-layout-stack-of-windows (src-buf name)
+  "A rdebug window layout with several secondary windows to the right.
+The debugger shell and the source code window is to the left.
+Argument SRC-BUF the buffer containing the Ruby source program that was initially run.  NAME is the name of that buffer."
+  (delete-other-windows)
+  (split-window-horizontally)
+  (split-window nil 20)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "cmd" name))
+  (other-window 1)
+  (switch-to-buffer src-buf)
+  (other-window 1)
+  (split-window)
+  (split-window)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "variables" name))
+  (other-window 1)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "frame" name))
+  (when rdebug-use-separate-io-buffer
+    (other-window 1)
+    (split-window)
+    (set-window-buffer
+     (selected-window) (rdebug-get-buffer "output" name)))
+  (other-window 1)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "breakpoints" name))
+  (other-window 1))
+
+;; The default layout
+(defun rdebug-window-layout-standard (src-buf name)
+  "The default rdebug window layout, see `rdebug' for more information.
+Argument SRC-BUF the buffer containing the Ruby source program that was initially run.  NAME is the name of that buffer."
+  (delete-other-windows)
+  (split-window nil ( / ( * (window-height) 3) 4))
+  (split-window nil ( / (window-height) 3))
+  (split-window-horizontally)
+  (other-window 1)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "variables" name))
+  (other-window 1)
+  (switch-to-buffer src-buf)
+  (when rdebug-use-separate-io-buffer
+    (split-window-horizontally)
+    (other-window 1)
+    (set-window-buffer
+     (selected-window) (rdebug-get-buffer "output" name)))
+  (other-window 1)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "frame" name))
+  (split-window-horizontally)
+  (other-window 1)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "breakpoints" name))
+  (other-window 1)
+  (goto-char (point-max)))
+
+
+(defun rdebug-window-layout-no-shell (src-buf name)
+  "A rdebug window layout without a shell window.
+Argument SRC-BUF the buffer containing the Ruby source program that was initially run.  NAME is the name of that buffer."
+  (delete-other-windows)
+  (set-window-buffer
+   (selected-window) (rdebug-get-buffer "watch" name))
+  (rdebug-window-layout-standard src-buf name))
+
+(provide 'rdebug-layouts)
+
+;;; Local variables:
+;;; eval:(put 'rdebug-debug-enter 'lisp-indent-hook 1)
+;;; End:
+
+;;; rdebug-layouts.el ends here