laag-nasm 2.13.03.2

data/vendor/repo.or.cz/nasm/test/cofftest.asm

@@ -0,0 +1,85 @@
+;Cannot be automatically tested because it differs every time,
+;I guess because of a date/time field.
+
+; test source file for assembling to COFF
+; build with (under DJGPP, for example):
+;    nasm -f coff cofftest.asm
+;    gcc -o cofftest cofftest.c cofftest.o
+
+; This file should test the following:
+; [1] Define and export a global text-section symbol
+; [2] Define and export a global data-section symbol
+; [3] Define and export a global BSS-section symbol
+; [4] Define a non-global text-section symbol
+; [5] Define a non-global data-section symbol
+; [6] Define a non-global BSS-section symbol
+; [7] Define a COMMON symbol
+; [8] Define a NASM local label
+; [9] Reference a NASM local label
+; [10] Import an external symbol
+; [11] Make a PC-relative call to an external symbol
+; [12] Reference a text-section symbol in the text section
+; [13] Reference a data-section symbol in the text section
+; [14] Reference a BSS-section symbol in the text section
+; [15] Reference a text-section symbol in the data section
+; [16] Reference a data-section symbol in the data section
+; [17] Reference a BSS-section symbol in the data section
+
+	  BITS 32
+	  GLOBAL _lrotate	; [1]
+	  GLOBAL _greet		; [1]
+	  GLOBAL _asmstr	; [2]
+	  GLOBAL _textptr	; [2]
+	  GLOBAL _selfptr	; [2]
+	  GLOBAL _integer	; [3]
+	  EXTERN _printf	; [10]
+	  COMMON _commvar 4	; [7]
+
+	  SECTION .text
+
+; prototype: long lrotate(long x, int num);
+_lrotate:			; [1]
+	  push ebp
+	  mov ebp,esp
+	  mov eax,[ebp+8]
+	  mov ecx,[ebp+12]
+.label	  rol eax,1		; [4] [8]
+	  loop .label		; [9] [12]
+	  mov esp,ebp
+	  pop ebp
+	  ret
+
+; prototype: void greet(void);
+_greet	  mov eax,[_integer]	; [14]
+	  inc eax
+	  mov [localint],eax	; [14]
+	  push dword [_commvar]
+	  mov eax,[localptr]	; [13]
+	  push dword [eax]
+	  push dword [_integer]	; [1] [14]
+	  push dword _printfstr	; [13]
+	  call _printf		; [11]
+	  add esp,16
+	  ret
+
+	  SECTION .data
+
+; a string
+_asmstr	  db 'hello, world', 0	; [2]
+
+; a string for Printf
+_printfstr db "integer==%d, localint==%d, commvar=%d"
+	  db 10, 0
+
+; some pointers
+localptr  dd localint		; [5] [17]
+_textptr  dd _greet		; [15]
+_selfptr  dd _selfptr		; [16]
+
+	  SECTION .bss
+
+; an integer
+_integer  resd 1		; [3]
+
+; a local integer
+localint  resd 1		; [6]

data/vendor/repo.or.cz/nasm/test/cofftest.c

@@ -0,0 +1,35 @@
+/*
+ * test source file for assembling to COFF
+ * build with (under DJGPP, for example):
+ *    nasm -f coff cofftest.asm
+ *    gcc -o cofftest cofftest.c cofftest.o
+ */
+
+#include <stdio.h>
+#include <inttypes.h>
+
+extern int lrotate(int32_t, int);
+extern void greet(void);
+extern int8_t asmstr[];
+extern void *selfptr;
+extern void *textptr;
+extern int integer, commvar;
+
+int main(void)
+{
+
+    printf("Testing lrotate: should get 0x00400000, 0x00000001\n");
+    printf("lrotate(0x00040000, 4) = 0x%08lx\n", lrotate(0x40000, 4));
+    printf("lrotate(0x00040000, 14) = 0x%08lx\n", lrotate(0x40000, 14));
+
+    printf("This string should read `hello, world': `%s'\n", asmstr);
+
+    printf("The integers here should be 1234, 1235 and 4321:\n");
+    integer = 1234;
+    commvar = 4321;
+    greet();
+
+    printf("These pointers should be equal: %p and %p\n", &greet, textptr);
+
+    printf("So should these: %p and %p\n", selfptr, &selfptr);
+}

data/vendor/repo.or.cz/nasm/test/crc32.asm

@@ -0,0 +1,37 @@
+;Testname=test; Arguments=-fbin -ocrc32.bin; Files=stdout stderr crc32.bin
+
+	bits 16
+
+	crc32 eax,cl
+	crc32 eax,byte [di]
+	crc32 eax,cx
+	crc32 eax,word [di]
+	crc32 eax,ecx
+	crc32 eax,dword [di]
+
+	bits 32
+	align 16
+
+	crc32 eax,cl
+	crc32 eax,byte [edi]
+	crc32 eax,cx
+	crc32 eax,word [edi]
+	crc32 eax,ecx
+	crc32 eax,dword [edi]
+
+	bits 64
+	align 16
+
+	crc32 eax,cl
+	crc32 eax,byte [rdi]
+	crc32 eax,r9b
+	crc32 eax,cx
+	crc32 eax,word [rdi]
+	crc32 eax,ecx
+	crc32 eax,dword [rdi]
+	crc32 rax,cl
+	crc32 rax,byte [rdi]
+	crc32 rax,r9b
+	crc32 rax,rcx
+	crc32 rax,qword [rdi]
+	crc32 rax,r9

data/vendor/repo.or.cz/nasm/test/cv8struc.asm

@@ -0,0 +1,14 @@
+struc A_STRUC
+  ._a: resw 1
+endstruc
+
+a_struc:
+  istruc A_STRUC
+  at A_STRUC._a, dw 1
+  iend
+
+	section .data
+foo:
+	dd 0x11111111
+.bar:
+	dd 0x22222222

data/vendor/repo.or.cz/nasm/test/dtbcd.asm

@@ -0,0 +1,72 @@
+;
+; This is a macro to generate packed BCD constants.
+; It is obsoleted by "dt" with a packed BCD value with a "p"
+; suffix, but it is included here as a rest of nested %rep.
+;
+%macro dtbcd 1-*.nolist
+  %push dtbcd
+  %rep %0
+    %defstr %$abc %1
+    %substr %$sign %$abc 1
+    %if %$sign == '-'
+      %substr %$abc %$abc 2,-1
+      %xdefine %$sign 0x80
+    %elif %$sign == '+'
+      %substr %$abc %$abc 2,-1
+      %xdefine %$sign 0x00
+    %else
+      %xdefine %$sign 0x00
+    %endif
+    %strlen %$abclen %$abc
+    %defstr %$abclen_str %$abclen
+    %assign %$pos %$abclen
+    %assign %$bc 0
+    %assign %$ld -1
+    %rep %$abclen
+      %substr %$chr %$abc %$pos
+      %assign %$pos %$pos-1
+      %if %$chr >= '0' && %$chr <= '9'
+        %if %$ld < 0
+          %assign %$ld %$chr-'0'
+          %assign %$bc %$bc+1
+          %if %$bc > 9
+            %warning "too many digits in BCD constant"
+	    %exitrep
+          %endif
+        %else
+          db %$ld+((%$chr-'0') << 4)
+	  %assign %$ld -1
+        %endif
+      %elif %$chr == '_'
+        ; Do nothing...
+      %else
+        %error "invalid character in BCD constant"
+	%exitrep
+      %endif
+    %endrep
+    %if %$ld >= 0
+      db %$ld
+    %endif
+    %rep 9-%$bc
+      db 0
+    %endrep
+    db %$sign
+    %rotate 1
+  %endrep
+  %pop
+%endmacro
+
+	dtbcd 123, -456, +789
+	dt 123p, -456p, +789p
+	dtbcd 765432109876543210
+	dt 765432109876543210p
+	dtbcd -765432109876543210
+	dt -765432109876543210p
+	dtbcd +765_432_109_876_543_210
+	dt +765_432_109_876_543_210p
+	dtbcd -765_432_109_876_543_210
+	dt -765_432_109_876_543_210p
+
+	;; Both of these should warn...
+	dtbcd 8_765_432_109_876_543_210
+	dt 8_765_432_109_876_543_210p

data/vendor/repo.or.cz/nasm/test/elf64so.asm

@@ -0,0 +1,118 @@
+; test source file for assembling to ELF64 shared library
+; build with:
+;    nasm -f elf64 elf64so.asm
+;    ld -shared -o elf64so.so elf64so.o
+; test with:
+;    gcc -o elf64so elftest64.c ./elf64so.so
+;    ./elf64so
+
+; This file should test the following:
+; [1] Define and export a global text-section symbol
+; [2] Define and export a global data-section symbol
+; [3] Define and export a global BSS-section symbol
+; [4] Define a non-global text-section symbol
+; [5] Define a non-global data-section symbol
+; [6] Define a non-global BSS-section symbol
+; [7] Define a COMMON symbol
+; [8] Define a NASM local label
+; [9] Reference a NASM local label
+; [10] Import an external symbol
+; [11] Make a PC-relative call to an external symbol
+; [12] Reference a text-section symbol in the text section
+; [13] Reference a data-section symbol in the text section
+; [14] Reference a BSS-section symbol in the text section
+; [15] Reference a text-section symbol in the data section
+; [16] Reference a data-section symbol in the data section
+; [17] Reference a BSS-section symbol in the data section
+
+	  BITS 64
+	  GLOBAL lrotate:function ; [1]
+	  GLOBAL greet_s:function ; [1]
+	  GLOBAL greet_m:function ; [1]
+	  GLOBAL asmstr:data asmstr.end-asmstr ; [2]
+	  GLOBAL textptr:data 8	; [2]
+	  GLOBAL selfptr:data 8	; [2]
+	  GLOBAL useless:data 8	; [3]
+	  GLOBAL integer:data 8	; [3]
+	  EXTERN printf		; [10]
+	  COMMON commvar 8:8	; [7]
+	  EXTERN _GLOBAL_OFFSET_TABLE_
+
+	  SECTION .text
+
+; prototype: long lrotate(long x, int num);
+lrotate:			; [1]
+	  push rbp
+	  mov rbp,rsp
+	  mov rax,rdi
+	  mov rcx,rsi
+.label	  rol rax,1		; [4] [8]
+	  loop .label		; [9] [12]
+	  mov rsp,rbp
+	  pop rbp
+	  ret
+
+;; prototype: void greet_*(void);
+;; 
+;;  Arguments are:	rdi - rsi - rdx - rcx - r8 - r9
+;;  Registers:		rbx, rbp, r12-r15 are saved
+;; greet_s() is Small PIC model, greet_m() is Medium PIC model
+;; (Large model cannot be linked with other code)
+;;
+greet_s:
+	  ;;  This instruction is useless, this is only a test...
+	  cmp qword [rel integer wrt ..got],0
+	  mov rax,[rel commvar wrt ..got] ; &commvar
+	  mov rcx,[rax]			  ; commvar
+	  mov rax,[rel integer wrt ..got] ; &integer
+	  mov rsi,[rax]
+	  lea rdx,[rsi+1]
+	  mov [rel localint],rdx ; localint = integer+1
+	  mov rax,[rel localptr] ; localptr
+	  mov rdx,[rax]		 ; *localptr = localint
+	  lea rdi,[rel printfstr]
+	  xor eax,eax		; No fp arguments
+	  jmp printf wrt ..plt	; [10]
+
+greet_m:
+	  push r15		; Used by convention...
+	  lea r15,[rel _GLOBAL_OFFSET_TABLE_]
+	  mov rax,[rel commvar wrt ..got] ; &commvar
+	  mov rcx,[rax]			  ; commvar
+	  mov rax,[rel integer wrt ..got] ; &integer
+	  mov rsi,[rax]
+	  lea rdx,[rsi+1]
+	  mov rax,localint wrt ..gotoff	 ; &localint - r15
+	  mov [rax+r15],rdx	 ; localint = integer+1
+	  mov rax,localptr wrt ..gotoff ; &localptr - r15
+	  mov rax,[rax+r15]	 ; localptr
+	  mov rdx,[rax]		 ; *localptr = localint
+	  mov rdi,printfstr wrt ..gotoff ; &printfstr - r15
+	  add rdi,r15		; &printfstr 
+	  xor eax,eax		; No fp arguments
+	  pop r15
+	  jmp printf wrt ..plt	; [10]
+
+	  SECTION .data
+
+; a string
+asmstr	  db 'hello, world', 0	; [2]
+.end:
+
+; a string for Printf
+printfstr db "integer=%ld, localint=%ld, commvar=%ld", 10, 0
+
+; some pointers
+localptr  dq localint		; [5] [17]
+textptr	  dq greet_s wrt ..sym	; [15]
+selfptr	  dq selfptr wrt ..sym	; [16]
+
+	  SECTION .bss
+; a useless symbol
+useless	  resq 1
+	
+; an integer
+integer	  resq 1		; [3]
+
+; a local integer
+localint  resq 1		; [6]

data/vendor/repo.or.cz/nasm/test/elfso.asm

@@ -0,0 +1,100 @@
+;Testname=unoptimized; Arguments=-O0 -felf -oelfso.o; Files=stdout stderr elfso.o
+;Testname=optimized;   Arguments=-Ox -felf -oelfso.o; Files=stdout stderr elfso.o
+
+; test source file for assembling to ELF shared library
+; build with:
+;    nasm -f elf elfso.asm
+;    ld -shared -o elfso.so elfso.o
+; test with:
+;    gcc -o elfso elftest.c ./elfso.so
+;    ./elfso
+; (assuming your gcc is ELF, and you're running bash)
+
+; This file should test the following:
+; [1] Define and export a global text-section symbol
+; [2] Define and export a global data-section symbol
+; [3] Define and export a global BSS-section symbol
+; [4] Define a non-global text-section symbol
+; [5] Define a non-global data-section symbol
+; [6] Define a non-global BSS-section symbol
+; [7] Define a COMMON symbol
+; [8] Define a NASM local label
+; [9] Reference a NASM local label
+; [10] Import an external symbol
+; [11] Make a PC-relative call to an external symbol
+; [12] Reference a text-section symbol in the text section
+; [13] Reference a data-section symbol in the text section
+; [14] Reference a BSS-section symbol in the text section
+; [15] Reference a text-section symbol in the data section
+; [16] Reference a data-section symbol in the data section
+; [17] Reference a BSS-section symbol in the data section
+
+	  BITS 32
+	  GLOBAL lrotate:function ; [1]
+	  GLOBAL greet:function	; [1]
+	  GLOBAL asmstr:data asmstr.end-asmstr ; [2]
+	  GLOBAL textptr:data 4	; [2]
+	  GLOBAL selfptr:data 4	; [2]
+	  GLOBAL integer:data 4	; [3]
+	  EXTERN printf		; [10]
+	  COMMON commvar 4:4	; [7]
+	  EXTERN _GLOBAL_OFFSET_TABLE_
+
+	  SECTION .text
+
+; prototype: long lrotate(long x, int num);
+lrotate:			; [1]
+	  push ebp
+	  mov ebp,esp
+	  mov eax,[ebp+8]
+	  mov ecx,[ebp+12]
+.label	  rol eax,1		; [4] [8]
+	  loop .label		; [9] [12]
+	  mov esp,ebp
+	  pop ebp
+	  ret
+
+; prototype: void greet(void);
+greet	  push ebx		; we'll use EBX for GOT, so save it
+	  call .getgot
+.getgot:  pop ebx
+	  add ebx,_GLOBAL_OFFSET_TABLE_ + $$ - .getgot wrt ..gotpc
+	  mov eax,[ebx+integer wrt ..got] ; [14]
+	  mov eax,[eax]
+	  inc eax
+	  mov [ebx+localint wrt ..gotoff],eax ; [14]
+	  mov eax,[ebx+commvar wrt ..got]
+	  push dword [eax]
+	  mov eax,[ebx+localptr wrt ..gotoff] ; [13]
+	  push dword [eax]
+	  mov eax,[ebx+integer wrt ..got] ; [1] [14]
+	  push dword [eax]
+	  lea eax,[ebx+printfstr wrt ..gotoff]
+	  push eax		; [13]
+	  call printf wrt ..plt	; [11]
+	  add esp,16
+	  pop ebx
+	  ret
+
+	  SECTION .data
+
+; a string
+asmstr	  db 'hello, world', 0	; [2]
+.end
+
+; a string for Printf
+printfstr db "integer==%d, localint==%d, commvar=%d"
+	  db 10, 0
+
+; some pointers
+localptr  dd localint		; [5] [17]
+textptr	  dd greet wrt ..sym	; [15]
+selfptr	  dd selfptr wrt ..sym	; [16]
+
+	  SECTION .bss
+
+; an integer
+integer	  resd 1		; [3]
+
+; a local integer
+localint  resd 1		; [6]