joosy 1.2.0.alpha.41 → 1.2.0.alpha.51

data/source/joosy/helpers/view.coffee

@@ -0,0 +1,115 @@
+#= require joosy/joosy
+
+#
+# Rendering and string representation helpers
+#
+Joosy.helpers 'Application', ->
+
+  # Little helpers for HTML escaping
+  DOMtext = document.createTextNode("test")
+  DOMnative = document.createElement("span")
+  DOMnative.appendChild(DOMtext)
+
+  #
+  # Escapes HTML string
+  #
+  # @param [String] html                     String to escape
+  # @return [String]                         Escaped string
+  #
+  @escapeOnce = (html) ->
+    DOMtext.nodeValue = html
+    DOMnative.innerHTML
+
+  #
+  # Generates HTML string
+  #
+  # @param [String]  name                    Tag name
+  # @param [Object]  options                 Tag attributes
+  # @param [Boolean] open                    Marks whether standalone tags (like <br>) should be kept open
+  # @param [Boolean] escape                  Marks whether atribute values should be escaped
+  # @return [String]                         Tag HTML string
+  #
+  @tag = (name, options={}, open=false, escape=true) ->
+    element = document.createElement name
+    temp    = document.createElement 'div'
+
+    for name, value of options
+      value = @escapeOnce(value) if escape
+      element.setAttribute name, value
+
+    temp.appendChild element
+    tag = temp.innerHTML
+
+    tag = tag.replace('/>', '>') if open
+    tag
+
+  #
+  # Generates HTML tag string with given content
+  #
+  # @param [String] name                     Tag name
+  # @param [Object] contentOrOptions         Tag attributes
+  # @param [String] contentOrOptions         String content
+  # @param [Object] options                  Tag attributes
+  # @param [Boolean] escape                  Marks whether attribute values should be escaped
+  # @return [String]                         Tag HTML string
+  #
+  # Possible arguments variations:
+  #   1. @contentTag 'name', 'content'
+  #   2. @contentTag 'name', {}, ->
+  #   3. @contentTag 'name', {}, false, ->
+  #   4. @contentTag 'name', ->
+  #
+  # Example
+  #   != @contentTag 'div', {class: 'foo'}, =>
+  #     != @contentTag 'hr'
+  #
+  @contentTag = (name, contentOrOptions=null, options=null, escape=true) ->
+    # This is a bit painfull but this is
+    # how we emulate Ruby block with lambda :(
+    if Object.isString(contentOrOptions)
+      options ||= {}
+      content   = contentOrOptions
+    else if Object.isObject(contentOrOptions)
+      if Object.isFunction(options)
+        escape = true
+        content = options()
+      else
+        escape = options
+        content = escape()
+      options = contentOrOptions
+    else
+      options = {}
+      content = contentOrOptions()
+
+    element = document.createElement name
+    temp    = document.createElement 'div'
+
+    for name, value of options
+      value = @escapeOnce(value) if escape
+      element.setAttribute name, value
+
+    try
+      element.innerHTML = content
+    catch e
+      # setting innerHTML fails in the IE for elements, which cann't have children (INPUT, for ex.)
+      # suppress this error unless content looks valuable
+      throw e if content
+
+    temp.appendChild element
+    temp.innerHTML
+
+  #
+  # Wraps the inline block into given template
+  # Request template will receive the inline block as @yield parameter
+  #
+  # Example
+  #   -# foo/baz template
+  #   != @renderWrapped 'foo/bar', ->
+  #     %b This string will be passed to 'foo/bar'
+  #
+  #   -# foo/bar template
+  #   %h1 I'm the wrapper here!
+  #     != @yield
+  #
+  @renderWrapped = (template, lambda) ->
+    @render template, Joosy.Module.merge(this, yield: lambda())

data/{src/joosy/core → source/joosy}/helpers/widgets.coffee

@@ -1,4 +1,4 @@
-#= require joosy/core/joosy
+#= require joosy/joosy
 
 #
 # Widgets manipulation

data/{src/joosy/core → source/joosy}/joosy.coffee

@@ -1,5 +1,5 @@
 #= require_self
-#= require joosy/core/module
+#= require joosy/module
 
 #
 # All the tiny core stuff
@@ -22,6 +22,40 @@
   #
   Templaters: {}
 
+  #
+  # Helpers container
+  #
+  Helpers: {}
+
+  #
+  # Events namespace
+  #
+  Events: {}
+
+  
+  ### Global settings ###
+
+  #
+  # Debug mode
+  #
+  debug: (value) ->
+    if value?
+      @__debug = value
+    else
+      !!@__debug
+
+  #
+  # Templating engine
+  #
+  templater: (value) ->
+    if value?
+      @__templater = value
+    else
+      throw new Error "No templater registered" unless @__templater
+      @__templater
+
+  ### Global helpers ###
+
   #
   # Registeres anything inside specified namespace (objects chain starting from `window`)
   #
@@ -54,7 +88,27 @@
   # @param [Boolean] generator      Helpers content
   #
   helpers: (name, generator) ->
-    Joosy.namespace "Joosy.Helpers.#{name}", generator
+    Joosy.Helpers[name] ||= {}
+    generator.apply Joosy.Helpers[name]
+
+  #
+  # Generates ID unique within current run
+  #
+  uid: ->
+    @__uid ||= 0
+    "__joosy#{@__uid++}"
+
+  #
+  # Generates UUID
+  #
+  uuid: ->
+    'xxxxxxxx-xxxx-4xxx-yxxx-xxxxxxxxxxxx'.replace /[xy]/g, (c) ->
+      r = Math.random() * 16 | 0
+      v = if c is 'x' then r else r & 3 | 8
+      v.toString 16
+    .toUpperCase()
+
+  ### Shortcuts ###
 
   #
   # Runs set of callbacks finializing with result callback
@@ -74,23 +128,6 @@
     else
       Joosy.Modules.Events.synchronize arguments...
 
-  #
-  # Generates ID unique within current run
-  #
-  uid: ->
-    @__uid ||= 0
-    "__joosy#{@__uid++}"
-
-  #
-  # Generates UUID
-  #
-  uuid: ->
-    'xxxxxxxx-xxxx-4xxx-yxxx-xxxxxxxxxxxx'.replace /[xy]/g, (c) ->
-      r = Math.random() * 16 | 0
-      v = if c is 'x' then r else r & 3 | 8
-      v.toString 16
-    .toUpperCase()
-
   #
   # Basic URI builder. Joins base path with params hash
   #
@@ -116,3 +153,6 @@
       paramsString = '&' + paramsString
 
     url + paramsString + hash
+
+if define?.amd?
+  define 'joosy', -> Joosy

data/source/joosy/layout.coffee

@@ -0,0 +1,73 @@
+#= require joosy/joosy
+#= require joosy/widget
+#= require joosy/helpers/view
+
+#
+# Base class for all Joosy Layouts.
+#
+# @example Sample application layout
+#   class @ApplicationLayout extends Joosy.Layout
+#     @view 'application'
+#
+class Joosy.Layout extends Joosy.Widget
+  @helper 'page'
+
+  #
+  # @param [Hash] params              Route params
+  # @param [Joosy.Layout] previous    Layout to replace on load
+  #
+  constructor: (@params, @previous) ->
+    @uid = Joosy.uid()
+
+  #
+  # Helper that outputs container tag for the page
+  #
+  # @param [String]  name             Tag name
+  # @param [Object]  options          Tag attributes
+  #
+  page: (tag, options={}) ->
+    options.id = @uid
+    Joosy.Helpers.Application.tag tag, options
+
+  #
+  # Gets DOM element that should be used as container for nested Page
+  #
+  # @return [jQuery]
+  #
+  content: ->
+    $("##{@uid}")
+
+  ######
+  ###### Widget extensions
+  ######
+
+  #
+  # This is required by {Joosy.Modules.Renderer}
+  # Sets the base template dir to app_name/templates/layouts
+  #
+  __renderSection: ->
+    'layouts'
+
+  #
+  # Extends list of registered nested widgets with page
+  #
+  __nestingMap: (page) ->
+    map = super()
+    map["##{@uid}"] =
+      instance: page
+      nested: page.__nestingMap()
+
+    map
+
+  #
+  # Adds page as first argument to default bootstrap
+  #
+  # @param [Joosy.Page] page                  Page to inject
+  # @param [jQuery] applicationContainer      The base container for the application to paint at
+  #
+  __bootstrapDefault: (page, applicationContainer) ->
+    @__bootstrap @__nestingMap(page), applicationContainer
+
+# AMD wrapper
+if define?.amd?
+  define 'joosy/layout', -> Joosy.Layout

data/{src/joosy/core → source/joosy}/module.coffee

@@ -2,7 +2,7 @@
 # Base Joosy class extending Coffee class with module-like injections
 #   and other tiny stuff.
 #
-class @Joosy.Module
+class Joosy.Module
   #
   # Sets the default namespace for all Joosy descendants.
   # This is used in {Joosy.namespace} magic.
@@ -43,7 +43,8 @@ class @Joosy.Module
     unless what? && klass?
       return false
 
-    [what, klass] = [what.prototype, klass.prototype]
+    what  = what.prototype
+    klass = klass.prototype
 
     while what
       if what == klass
@@ -133,3 +134,7 @@ class @Joosy.Module
 
     object.extended?.apply this
     null
+
+# AMD wrapper
+if define?.amd?
+  define 'joosy/module', -> Joosy.Module

data/{src/joosy/core/modules/container.coffee → source/joosy/modules/dom.coffee}

@@ -1,13 +1,13 @@
-#= require joosy/core/joosy
+#= require joosy/joosy
 
 #
 # DOM container handling, DOM elements and DOM events bindings
 #
-# @note Requires implementor to contain DOM node at @container propert
+# @note Requires implementor to contain DOM node at @$container propert
 #
 # @mixin
 #
-Joosy.Modules.Container =
+Joosy.Modules.DOM =
   eventSplitter: /^(\S+)\s*(.*)$/
 
   included: ->
@@ -41,18 +41,7 @@ Joosy.Modules.Container =
       Object.merge @::__events, map
 
   $: (selector) ->
-    $(selector, @container)
-
-  #
-  # Fills container with given data removing all events
-  #
-  # @param [jQuery] container       jQuery entity of container to update
-  # @param [String] data            HTML to inject
-  #
-  swapContainer: (container, data) ->
-    container.unbind().off()
-    container.html data
-    container
+    $(selector, @$container)
 
   #
   # Converts '$...' notation to selector from 'elements'
@@ -127,10 +116,28 @@ Joosy.Modules.Container =
       selector   = @__extractSelector match[2]
 
       if selector == ""
-        @container.bind eventName, callback
+        @$container.bind eventName, callback
         Joosy.Modules.Log.debugAs @, "#{eventName} binded on container"
       else if selector == undefined
         throw new Error "Unknown element #{match[2]} in #{Joosy.Module.__className @constructor} (maybe typo?)"
       else
-        @container.on eventName, selector, callback
+        @$container.on eventName, selector, callback
         Joosy.Modules.Log.debugAs @, "#{eventName} binded on #{selector}"
+
+  __clearContainer: ->
+    @$container?.unbind().off()
+    @$container = $()
+
+
+  # This is not clearly related for container management
+  # But it will be later common for all containers
+  # See https://github.com/joosy/joosy/issues/102
+  __loadData: (done) ->
+      @data = {}
+      @__runFetchs [], =>
+        @dataFetched = true
+        done()
+
+# AMD wrapper
+if define?.amd?
+  define 'joosy/modules/dom', -> Joosy.Modules.DOM

data/source/joosy/modules/events.coffee

@@ -0,0 +1,156 @@
+#= require joosy/joosy
+#= require_tree ../events
+
+class SynchronizationContext
+  constructor:    -> @actions = []
+  do: (action)    -> @actions.push action
+  after: (@after) ->
+
+#
+# Basic events implementation
+#
+# @mixin
+#
+Joosy.Modules.Events =
+
+  #
+  # Waits for the list of given events to happen at least once. Then runs callback.
+  #
+  # @param [String|Array] events        List of events to wait for separated by space
+  # @param [Function] callback          Action to run when all events were triggered at least once
+  # @param [Hash] options               Options
+  #
+  wait: (name, events, callback) ->
+    @__oneShotEvents = {} unless @hasOwnProperty('__oneShotEvents')
+
+    # unnamed binding
+    if Object.isFunction(events)
+      callback = events
+      events   = name
+      name     = Object.keys(@__oneShotEvents).length.toString()
+
+    events = @__splitEvents(events)
+
+    if events.length > 0
+      @__oneShotEvents[name] = [events, callback]
+    else
+      callback()
+
+    name
+
+  #
+  # Removes waiter action
+  #
+  # @param [Function] target            Name of waiter to unbind
+  #
+  unwait: (target) ->
+    delete @__oneShotEvents[target] if @hasOwnProperty '__oneShotEvents'
+
+  #
+  # Binds action to run each time any of given event was triggered
+  #
+  # @param [String|Array] events        List of events separated by space
+  # @param [Function] callback          Action to run on trigger
+  # @param [Hash] options               Options
+  #
+  bind: (name, events, callback) ->
+    @__boundEvents = {} unless @hasOwnProperty '__boundEvents'
+
+    # unnamed binding
+    if Object.isFunction(events)
+      callback = events
+      events   = name
+      name     = Object.keys(@__boundEvents).length.toString()
+
+    events = @__splitEvents(events)
+
+    if events.length > 0
+      @__boundEvents[name] = [events, callback]
+    else
+      callback()
+
+    name
+
+  #
+  # Unbinds action from runing on trigger
+  #
+  # @param [Function] target            Name of bind to unbind
+  #
+  unbind: (target) ->
+    delete @__boundEvents[target] if @hasOwnProperty '__boundEvents'
+
+  #
+  # Triggers event for {bind} and {wait}
+  #
+  # @param [String]           Name of event to trigger
+  #
+  trigger: (event, data...) ->
+    Joosy.Modules.Log.debugAs @, "Event #{event} triggered"
+
+    if Object.isObject event
+      remember = event.remember
+      event    = event.name
+    else
+      remember = false
+
+    if @hasOwnProperty '__oneShotEvents'
+      fire = []
+      for name, [events, callback] of @__oneShotEvents
+        events.remove event
+        if events.length == 0
+          fire.push name
+      fire.each (name) =>
+        callback = @__oneShotEvents[name][1]
+        delete @__oneShotEvents[name]
+        callback data...
+
+    if @hasOwnProperty '__boundEvents'
+      for name, [events, callback] of @__boundEvents
+        if events.any event
+          callback data...
+
+    if remember
+      @__triggeredEvents = {} unless @hasOwnProperty '__triggeredEvents'
+      @__triggeredEvents[event] = true
+
+  #
+  # Runs set of callbacks finializing with result callback
+  #
+  # @example Basic usage
+  #   @synchronize (context) ->
+  #     context.do (done) -> done()
+  #     context.do (done) -> done()
+  #     context.after ->
+  #       console.log 'Success!'
+  #
+  # @param [Function] block           Configuration block (see example)
+  #
+  synchronize: (block) ->
+    context = new SynchronizationContext
+    counter = 0
+
+    block(context)
+
+    if context.actions.length == 0
+      context.after.call(@)
+    else
+      context.actions.each (action) =>
+        action.call @, ->
+          if ++counter >= context.actions.length
+            context.after.call(@) 
+
+  __splitEvents: (events) ->
+    if Object.isString events
+      if events.isBlank()
+        events = []
+      else
+        events = events.trim().split /\s+/
+
+    if @hasOwnProperty '__triggeredEvents'
+      events = events.findAll (e) => !@__triggeredEvents[e]
+
+    events
+
+# AMD wrapper
+if define?.amd?
+  define 'joosy/modules/events', -> Joosy.Modules.Events

data/source/joosy/modules/filters.coffee

@@ -0,0 +1,67 @@
+#= require joosy/joosy
+
+#
+# Filters registration routines
+#
+# @mixin
+#
+Joosy.Modules.Filters =
+
+  #
+  # Defines static registration routines
+  #
+  # @example Set of methods
+  #   class Test
+  #     @beforeLoad ->  # supposed to run before load and control loading queue
+  #     @afterLoad ->   # supposed to run after load to finalize loading
+  #     @afterUnload -> # supposed to run after unload to collect garbage
+  #
+  #     # private
+  #
+  #     @__runBeforeLoads() # Runs filters registered as beforeLoad
+  #     @__runAfterLoads() # Runs filters registered as afterLoad
+  #     @__runAfterUnloads() # Runs filters registered as afterUnload
+  #
+  included: ->
+    @__registerFilterCollector = (filter) =>
+      @[filter] = (callback) ->
+        unless @::hasOwnProperty "__#{filter}s"
+          @::["__#{filter}s"] = [].concat @.__super__["__#{filter}s"] || []
+        @::["__#{filter}s"].push callback
+
+      filter.charAt(0).toUpperCase() + filter.slice(1)
+
+    @registerPlainFilters = (filters...) =>
+      filters.each (filter) =>
+        camelized = @__registerFilterCollector filter
+
+        @::["__run#{camelized}s"] = (params...) ->
+          return true unless @["__#{filter}s"]
+
+          @["__#{filter}s"].reduce (flag, callback) =>
+            callback = @[callback] unless Object.isFunction callback
+            flag && callback.apply(@, params) != false
+          , true
+
+    @registerSequencedFilters = (filters...) =>
+      filters.each (filter) =>
+        camelized = @__registerFilterCollector filter
+
+        @::["__run#{camelized}s"] = (params, callback) ->
+          return callback() unless @["__#{filter}s"]
+
+          runners  = @["__#{filter}s"]
+          filterer = @
+
+          if runners.length == 1
+            return runners[0].apply @, params.include(callback)
+
+          Joosy.synchronize (context) ->
+            runners.each (runner) ->
+              context.do (done) ->
+                runner.apply filterer, params.include(done)
+            context.after callback
+
+# AMD wrapper
+if define?.amd?
+  define 'joosy/modules/filters', -> Joosy.Modules.Filters

data/{src/joosy/core → source/joosy}/modules/log.coffee

@@ -1,4 +1,4 @@
-#= require joosy/core/joosy
+#= require joosy/joosy
 
 #
 # Wrappers for console.log
@@ -23,7 +23,7 @@ Joosy.Modules.Log =
   # Runs `log` if debug is active
   #
   debug: (args...) ->
-    return unless Joosy.Application.config.debug
+    return unless Joosy.debug()
     @log args...
 
   #
@@ -33,6 +33,10 @@ Joosy.Modules.Log =
   # @param [String] string            Message to log
   #
   debugAs: (context, string, args...) ->
-    return unless Joosy.Application.config.debug
+    return unless Joosy.debug()
     context = Joosy.Module.__className(context) || 'unknown context'
     @debug "#{context}> #{string}", args...
+
+# AMD wrapper
+if define?.amd?
+  define 'joosy/modules/log', -> Joosy.Modules.Log

data/source/joosy/modules/page/scrolling.coffee

@@ -0,0 +1,51 @@
+Joosy.Modules.Page_Scrolling =
+
+  included: ->
+    #
+    # Sets the position where page will be scrolled to after load.
+    #
+    # @note If you use animated scroll joosy will atempt to temporarily fix the
+    #   height of your document while scrolling to prevent jump effect.
+    #
+    # @param [jQuery] element         Element to scroll to
+    # @param [Hash] options
+    #
+    # @option options [Integer] speed       Sets the animation duration (500 is default)
+    # @option options [Integer] margin      Defines the margin from element position.
+    #   Can be negative.
+    #
+    @scroll = (element, options={}) ->
+      @::__scrollElement = element
+      @::__scrollSpeed = options.speed || 500
+      @::__scrollMargin = options.margin || 0
+
+    @paint (complete) ->
+      @__fixHeight() if @__scrollElement && @__scrollSpeed != 0
+      complete()
+
+    @afterLoad ->
+      @__performScrolling() if @__scrollElement
+
+  #
+  # Scrolls page to stored positions
+  #
+  __performScrolling: ->
+    scroll = $(@__extractSelector @__scrollElement).offset()?.top + @__scrollMargin
+    Joosy.Modules.Log.debugAs @, "Scrolling to #{@__extractSelector @__scrollElement}"
+    $('html, body').animate {scrollTop: scroll}, @__scrollSpeed, =>
+      if @__scrollSpeed != 0
+        @__releaseHeight()
+
+  #
+  # Freezes the page height through $(html).
+  #
+  # Required to implement better {Joosy.Page.scroll} behavior.
+  #
+  __fixHeight: ->
+    $('html').css 'min-height', $(document).height()
+
+  #
+  # Undo {#__fixHeight}
+  #
+  __releaseHeight: ->
+    $('html').css 'min-height', ''