joosy 1.2.0.alpha.41 → 1.2.0.alpha.51

data/spec/joosy/core/modules/container_spec.coffee

@@ -1,153 +0,0 @@
-describe "Joosy.Modules.Container", ->
-
-  beforeEach ->
-    @$ground.seed()
-    container = @$ground.find('#application')
-
-    class @Container extends Joosy.Module
-      @include Joosy.Modules.Container
-
-      @mapElements
-        posts: '.post'
-        content:
-          post1: '#post1'
-          post2: '#post2'
-        footer: '.footer'
-
-      @mapEvents
-        'test': 'onContainerTest'
-
-      container: container
-
-  it "swaps container", ->
-    initial = (new @Container).container
-    parent  = initial.parent()
-    event   = sinon.spy()
-
-    # Binded events trigger
-    initial.bind 'test', event
-    initial.trigger 'test'
-    expect(event.callCount).toEqual 1
-
-    swapped = Joosy.Modules.Container.swapContainer initial, 'new content'
-
-    # Injects into DOM properly
-    expect(swapped.html()).toEqual 'new content'
-    expect(swapped.parent().get 0).toEqual parent.get 0
-
-    # Binded events disappear
-    swapped.trigger 'test'
-    expect(event.callCount).toEqual 1
-
-  describe "elements assigner", ->
-
-    beforeEach ->
-      @container = new @Container
-      @container.__assignElements()
-
-    it "declares", ->
-      class A extends @Container
-        @mapElements
-          first: 'first'
-          second: 'second'
-
-      class B extends A
-        @mapElements
-          first: 'overrided'
-          third: 'third'
-
-      expect((new B).__elements).toEqual Object.extended
-        posts: '.post'
-        content: 
-          post1: '#post1'
-          post2: '#post2'
-        first: 'overrided'
-        second: 'second'
-        third: 'third'
-        footer: '.footer'
-
-      expect((new @Container).__elements).toEqual Object.extended
-        posts: '.post'
-        footer: '.footer'
-        content: 
-          post1: '#post1'
-          post2: '#post2'
-
-    describe "selector resolvance", ->
-
-      it "works for plane selectors", ->
-        expect(@container.__extractSelector '$footer').toEqual '.footer'
-
-      it "works for deep selectors", ->
-        expect(@container.__extractSelector '$content.$post1').toEqual '#post1'
-
-      it "works for plane extended selectors", ->
-        expect(@container.__extractSelector '$footer tr').toEqual '.footer tr'
-
-      it "works for deep extended selectors", ->
-        expect(@container.__extractSelector '$footer $content.$post1').toEqual '.footer #post1'
-
-    it "assigns", ->
-      target = @container.$footer().get 0
-      expect(target).toBeTruthy()
-      expect(target).toBe $('.footer', @container.container).get 0
-      expect(target).toBe @container.$('.footer').get 0
-
-    it "assigns nesteds", ->
-      expect(@container.$content.$post1().get 0).toBe $('#post1').get 0
-
-    it "filters assignation", ->
-      target = @container.$posts('#post1').get 0
-      expect(target).toBeTruthy()
-      expect(target).toBe $('#post1', @container.container).get 0
-
-    it "respects container boundaries", ->
-      @$ground.prepend('<div class="footer" />')  # out of container
-
-      target = @container.$footer().get 0
-      expect(target).toBeTruthy()
-      expect(target).toBe $('.footer', @container.container).get 0
-      expect(target).toBe @container.$('.footer').get 0
-
-  describe "events delegator", ->
-
-    it "declares", ->
-      class A extends @Container
-        @mapEvents
-          'test .post': 'callback2'
-          'custom' : 'method'
-
-      class B extends A
-        @mapEvents
-          'test $footer': 'onFooterTest'
-          'custom' : 'overrided'
-
-      expect((new B).__events).toEqual Object.extended
-        'test': 'onContainerTest'
-        'test .post': 'callback2'
-        'test $footer': 'onFooterTest'
-        'custom' : 'overrided'
-
-      expect((new @Container).__events).toEqual Object.extended
-        'test': 'onContainerTest'
-
-    it "delegates", ->
-      callbacks = 1.upto(3).map -> sinon.spy()
-
-      @Container.mapEvents
-        'test .post': callbacks[2]
-        'test $footer': 'onFooterTest'
-      @Container::onContainerTest = callbacks[0]
-      @Container::onFooterTest = callbacks[1]
-
-      container = new @Container
-      container.__assignElements()
-      container.__delegateEvents()
-
-      container.container.trigger 'test'
-      $('.footer', container.container).trigger 'test'
-      $('.post', container.container).trigger 'test'
-
-      expect(callbacks[0].callCount).toEqual 5
-      expect(callbacks[1].callCount).toEqual 1
-      expect(callbacks[2].callCount).toEqual 3

data/spec/joosy/core/modules/widget_manager_spec.coffee

@@ -1,96 +0,0 @@
-describe "Joosy.Modules.WidgetsManager", ->
-
-  beforeEach ->
-    class @Manager extends Joosy.Module
-      @include Joosy.Modules.Container
-      @include Joosy.Modules.WidgetsManager
-
-    class @Widget extends Joosy.Widget
-      constructor: (@argument) ->
-
-    @manager = new @Manager
-
-  describe "manager", ->
-
-    beforeEach ->
-      @widget = new @Widget
-
-      sinon.spy @widget, '__load'
-      sinon.spy @widget, '__unload'
-
-    it "registers widget", ->
-      result = @manager.registerWidget @$ground, @widget
-      expect(result instanceof @Widget).toBeTruthy()
-      expect(@manager.__activeWidgets).toEqual [result]
-      expect(@widget.__load.callCount).toEqual 1
-
-    it "unregisters widget", ->
-      @manager.registerWidget @$ground, @widget
-
-      expect(@manager.unregisterWidget @widget).toBeTruthy()
-      expect(@manager.__activeWidgets).toEqual []
-      expect(@widget.__unload.callCount).toEqual 1
-
-    it "unload all widgets properly", ->
-      3.times => @manager.registerWidget(@$ground, @widget)
-      @manager.__unloadWidgets()
-      expect(@widget.__unload.callCount).toEqual 3
-
-  describe 'declarator', ->
-
-    it "inherits widget declarations", ->
-      @Manager.mapWidgets
-        'test': 'widget'
-
-      class A extends @Manager
-        @mapWidgets
-          'selector': 'widget'
-
-      class B extends A
-        @mapWidgets
-          'widgets': 'widget'
-          'selector': 'overriden'
-
-      expect((new A).__widgets).toEqual Object.extended
-        'test': 'widget'
-        'selector': 'widget'
-
-      expect((new B).__widgets).toEqual Object.extended
-        'test': 'widget'
-        'widgets':  'widget'
-        'selector': 'overriden'
-
-    it "registers declared widgets", ->
-      @$ground.seed()
-
-      @Manager.mapElements
-        footer: '.footer'
-
-      @Manager.mapWidgets widgets =
-        '$container': Joosy.Widget
-        '$footer': Joosy.Widget
-        '.post': sinon.stub().returns new @Widget
-
-      @manager.container = $('#application')
-      @manager.__assignElements()
-      @manager.__setupWidgets()
-
-      expect(@manager.__activeWidgets.length).toEqual 5
-      expect(widgets['.post'].callCount).toEqual 3
-      expect(widgets['.post'].getCall(0).calledOn @manager).toBeTruthy()
-
-    it "bootstraps declared widgets properly", ->
-      @$ground.seed()
-
-      @Widget.view -> 'fluffy'
-      @Manager.mapWidgets
-        '#post1': @Widget
-        '#widget1': (i) => new @Widget i
-
-      @manager.container = $('#application')
-      @manager.__setupWidgets()
-
-      expect(@$ground.find('#post1').html()).toEqual 'fluffy'
-      expect(@$ground.find('#widget1').html()).toEqual 'fluffy'
-      expect(@manager.__activeWidgets[0].argument).toBeUndefined()
-      expect(@manager.__activeWidgets[1].argument).toEqual 0

data/src/joosy/core/application.coffee

@@ -1,59 +0,0 @@
-#= require joosy/core/joosy
-
-#
-# Joosy Application container
-#
-# @mixin
-#
-Joosy.Application =
-  Pages: {}
-  Layouts: {}
-  Controls: {}
-
-  loading: true
-  identity: true
-  debounceForms: false
-
-  config:
-    debug: false
-    router:
-      html5: false
-      base:  '/'
-
-  #
-  # Starts Joosy application by binding to element and bootstraping routes
-  #
-  # @param [String] name        Name of app (the dir its located in)
-  # @param [String] selector    jQuery-compatible selector of root application element
-  # @param [Object] options
-  #
-  initialize: (@name, @selector, options={}) ->
-    @mergeConfig(window.JoosyEnvironment) if window.JoosyEnvironment?
-    @mergeConfig(options)
-
-    @templater = new Joosy.Templaters.JST @name
-
-    Joosy.Router.__setupRoutes()
-
-  #
-  # Gets current application root node
-  #
-  content: ->
-    $(@selector)
-
-  #
-  # Switches to given page
-  #
-  # @param [Joosy.Page] page      The class (not object) of page to load
-  # @param [Object] params        Hash of page params
-  #
-  setCurrentPage: (page, params) ->
-    attempt = new page(params, @page)
-    @page = attempt unless attempt.halted
-
-  mergeConfig: (options) ->
-    for key, value of options
-      if Object.isObject @config[key]
-        Object.merge @config[key], value
-      else
-        @config[key] = value

data/src/joosy/core/helpers/view.coffee

@@ -1,52 +0,0 @@
-#= require joosy/core/joosy
-
-#
-# Rendering and string representation helpers
-#
-Joosy.helpers 'Application', ->
-
-  #
-  # Generates HTML tag string
-  #
-  # @param [String] name          Tag name
-  # @param [Object] options       Tag attributes
-  # @param [String] content       String content to inject
-  # @param [Function] content     Function that will be evaluated and the result will be taken as a content
-  #
-  # Example
-  #   != @tag 'div', {class: 'foo'}, =>
-  #     != @tag 'hr'
-  #
-  @tag = (name, options={}, content='') ->
-    content = content() if Object.isFunction(content)
-
-    element = document.createElement name
-    temp    = document.createElement 'div'
-
-    Object.each options, (name, value) -> element.setAttribute name, value
-
-    try
-      element.innerHTML = content
-    catch e
-      # setting innerHTML fails in the IE for elements, which cann't have children (INPUT, for ex.)
-      # suppress this error unless content looks valuable
-      throw e if content
-
-    temp.appendChild element
-    temp.innerHTML
-
-  #
-  # Wraps the inline block into given template
-  # Request template will receive the inline block as @yield parameter
-  #
-  # Example
-  #   -# foo/baz template
-  #   != @renderWrapped 'foo/bar', ->
-  #     %b This string will be passed to 'foo/bar'
-  #
-  #   -# foo/bar template
-  #   %h1 I'm the wrapper here!
-  #     != @yield
-  #
-  @renderWrapped = (template, lambda) ->
-    @render template, Joosy.Module.merge(this, yield: lambda())

data/src/joosy/core/layout.coffee

@@ -1,174 +0,0 @@
-#= require joosy/core/joosy
-#= require joosy/core/modules/log
-#= require joosy/core/modules/events
-#= require joosy/core/modules/container
-#= require joosy/core/modules/renderer
-#= require joosy/core/modules/time_manager
-#= require joosy/core/modules/widgets_manager
-#= require joosy/core/modules/filters
-
-#
-# Base class for all of your Joosy Layouts.
-# @see http://guides.joosy.ws/guides/layouts-pages-and-routing.html
-#
-# @example Sample application layout
-#   class @ApplicationLayout extends Joosy.Layout
-#     @view 'application'
-#
-# @include Joosy.Modules.Log
-# @include Joosy.Modules.Events
-# @include Joosy.Modules.Container
-# @include Joosy.Modules.Renderer
-# @include Joosy.Modules.TimeManager
-# @include Joosy.Modules.WidgetsManager
-# @include Joosy.Modules.Filters
-#
-class Joosy.Layout extends Joosy.Module
-  @include Joosy.Modules.Log
-  @include Joosy.Modules.Events
-  @include Joosy.Modules.Container
-  @include Joosy.Modules.Renderer
-  @include Joosy.Modules.TimeManager
-  @include Joosy.Modules.WidgetsManager
-  @include Joosy.Modules.Filters
-
-  @view 'default'
-  @helper 'page'
-
-  #
-  # Sets the method which will controll the painting preparation proccess.
-  #
-  # This method will be called right ater previous layout {Joosy.Layout.erase} and in parallel with
-  #   layout data fetching so you can use it to initiate preloader.
-  #
-  # @note Given method will be called with `complete` function as parameter. As soon as your
-  #   preparations are done you should call that function.
-  #
-  # @example Sample before painter
-  #   @beforePaint (container, page, complete) ->
-  #     if !@data # checks if parallel fetching finished
-  #       $('preloader').slideDown -> complete()
-  #
-  #
-  @beforePaint: (callback) ->
-    @::__beforePaint = callback
-
-  #
-  # Sets the method which will controll the painting proccess.
-  #
-  # This method will be called after fetching, erasing and beforePaint is complete.
-  # It should be used to setup appearance effects of layout.
-  #
-  # @note Given method will be called with `complete` function as parameter. As soon as your
-  #   preparations are done you should call that function.
-  #
-  # @example Sample painter
-  #   @paint (container, page, complete) ->
-  #     @container.fadeIn -> complete()
-  #
-  @paint: (callback) ->
-    @::__paint = callback
-
-  #
-  # Sets the method which will controll the erasing proccess.
-  #
-  # Use this method to setup hiding effect.
-  #
-  # @note Given method will be called with `complete` function as parameter. As soon as your
-  #   preparations are done you should call that function.
-  #
-  # @note This method will be caled _before_ unload routines so in theory you can
-  #   access layout data from that. Think twice if you are doing it right though.
-  #
-  # @example Sample eraser
-  #   @erase (container, page, complete) ->
-  #     @container.fadeOut -> complete()
-  #
-  @erase: (callback) ->
-    @::__erase = callback
-
-  #
-  # Sets the method which will controll the data fetching proccess.
-  #
-  # @note Given method will be called with `complete` function as parameter. As soon as your
-  #   preparations are done you should call that function.
-  #
-  # @note You are strongly encouraged to NOT fetch anything with Layout!
-  #   Use {Joosy.Page.fetch}
-  #
-  # @example Basic usage
-  #   @fetch (complete) ->
-  #     $.get '/rumbas', (@data) => complete()
-  #
-  @fetch: (callback) ->
-    @::__fetch = (complete) ->
-      @data = {}
-      callback.call this, =>
-        @dataFetched = true
-        complete()
-
-  #
-  # Prefetched page data.
-  #
-  data: false
-  dataFetched: false
-
-  #
-  # @param [Hash] params              List of route params
-  #
-  constructor: (@params) ->
-    @uid = Joosy.uid()
-
-  #
-  # @see Joosy.Router.navigate
-  #
-  navigate: (args...) ->
-    Joosy.Router.navigate(args...)
-
-  #
-  # This is required by {Joosy.Modules.Renderer}
-  # Sets the base template dir to app_name/templates/layouts
-  #
-  __renderSection: ->
-    'layouts'
-
-  #
-  # Layout bootstrap proccess.
-  #
-  #   * {Joosy.Modules.Container.__assignElements}
-  #   * {Joosy.Modules.Container.__delegateEvents}
-  #   * {Joosy.Modules.WidgetsManager.__setupWidgets}
-  #
-  __load: (@container) ->
-    @__assignElements()
-    @__delegateEvents()
-    @__setupWidgets()
-    @__runAfterLoads()
-
-  #
-  # Layout destruction proccess.
-  #
-  #   * {Joosy.Modules.TimeManager.__clearTime}
-  #   * {Joosy.Modules.WidgetsManager.__unloadWidgets}
-  #   * {Joosy.Modules.Renderer.__removeMetamorphs}
-  #
-  __unload: ->
-    @__clearTime()
-    @__unloadWidgets()
-    @__removeMetamorphs()
-    @__runAfterUnloads()
-
-  #
-  # Helpers that outputs container for the page
-  #
-  page: (tag, options={}) ->
-    options.id = @uid
-    Joosy.Helpers.Application.tag tag, options
-
-  #
-  # Gets layout element.
-  #
-  # @return [jQuery]
-  #
-  content: ->
-    $("##{@uid}")