iqvoc 4.8.1 → 4.8.2

data/vendor/assets/bower_components/jqtree/src/save_state_handler.coffee

@@ -0,0 +1,191 @@
+util = require './util'
+
+indexOf = util.indexOf
+isInt = util.isInt
+
+
+class SaveStateHandler
+    constructor: (tree_widget) ->
+        @tree_widget = tree_widget
+
+    saveState: ->
+        state = JSON.stringify(@getState())
+
+        if @tree_widget.options.onSetStateFromStorage
+            @tree_widget.options.onSetStateFromStorage(state)
+        else if @supportsLocalStorage()
+            localStorage.setItem(
+                @getCookieName(),
+                state
+            )
+        else if $.cookie
+            $.cookie.raw = true
+            $.cookie(
+                @getCookieName(),
+                state,
+                {path: '/'}
+            )
+
+    getStateFromStorage: ->
+        json_data = @_loadFromStorage()
+
+        if json_data
+            return @_parseState(json_data)
+        else
+            return null
+
+    _parseState: (json_data) ->
+        state = $.parseJSON(json_data)
+
+        # Check if selected_node is an int (instead of an array)
+        if state and state.selected_node and isInt(state.selected_node)
+            # Convert to array
+            state.selected_node = [state.selected_node]
+
+        return state
+
+    _loadFromStorage: ->
+        if @tree_widget.options.onGetStateFromStorage
+            return @tree_widget.options.onGetStateFromStorage()
+        else if @supportsLocalStorage()
+            return localStorage.getItem(
+                @getCookieName()
+            )
+        else if $.cookie
+            $.cookie.raw = true
+            return $.cookie(@getCookieName())
+        else
+            return null
+
+    getState: ->
+        getOpenNodeIds = =>
+            open_nodes = []
+
+            @tree_widget.tree.iterate((node) =>
+                if (
+                    node.is_open and
+                    node.id and
+                    node.hasChildren()
+                )
+                    open_nodes.push(node.id)
+                return true
+            )
+
+            return open_nodes
+
+        getSelectedNodeIds = =>
+            return (n.id for n in @tree_widget.getSelectedNodes())
+
+        return {
+            open_nodes: getOpenNodeIds(),
+            selected_node: getSelectedNodeIds()
+        }
+
+    # Set initial state
+    # Don't handle nodes that are loaded on demand
+    #
+    # result: must load on demand
+    setInitialState: (state) ->
+        if not state
+            return false
+        else
+            must_load_on_demand = @_openInitialNodes(state.open_nodes)
+
+            @_selectInitialNodes(state.selected_node)
+
+            return must_load_on_demand
+
+    _openInitialNodes: (node_ids) ->
+        must_load_on_demand = false
+
+        for node_id in node_ids
+            node = @tree_widget.getNodeById(node_id)
+
+            if node
+                if not node.load_on_demand
+                    node.is_open = true
+                else
+                    must_load_on_demand = true
+
+        return must_load_on_demand
+
+    _selectInitialNodes: (node_ids) ->
+        select_count = 0
+
+        for node_id in node_ids
+            node = @tree_widget.getNodeById(node_id)
+
+            if node
+                select_count += 1
+
+                @tree_widget.select_node_handler.addToSelection(node)
+
+        return select_count != 0
+
+    setInitialStateOnDemand: (state) ->
+        if state
+            @_setInitialStateOnDemand(state.open_nodes, state.selected_node)
+
+    _setInitialStateOnDemand: (node_ids, selected_nodes) ->
+        openNodes = =>
+            new_nodes_ids = []
+
+            for node_id in node_ids
+                node = @tree_widget.getNodeById(node_id)
+
+                if not node
+                    new_nodes_ids.push(node_id)
+                else
+                    if not node.is_loading
+                        if node.load_on_demand
+                            loadAndOpenNode(node)
+                        else
+                            @tree_widget._openNode(node, false)
+
+            node_ids = new_nodes_ids
+
+            if @_selectInitialNodes(selected_nodes)
+                @tree_widget._refreshElements()
+
+        loadAndOpenNode = (node) =>
+            @tree_widget._openNode(node, false, openNodes)
+
+        openNodes()
+
+    getCookieName: ->
+        if typeof @tree_widget.options.saveState is 'string'
+            return @tree_widget.options.saveState
+        else
+            return 'tree'
+
+    supportsLocalStorage: ->
+        testSupport = ->
+            # Is local storage supported?
+            if not localStorage?
+                return false
+            else
+                # Check if it's possible to store an item. Safari does not allow this in private browsing mode.
+                try
+                    key = '_storage_test'
+                    sessionStorage.setItem(key, true);
+                    sessionStorage.removeItem(key)
+                catch error
+                    return false
+
+                return true
+
+        if not @_supportsLocalStorage?
+            @_supportsLocalStorage = testSupport()
+
+        return @_supportsLocalStorage
+
+    getNodeIdToBeSelected: ->
+        state = @getStateFromStorage()
+
+        if state and state.selected_node
+            return state.selected_node[0]
+        else
+            return null
+
+
+module.exports = SaveStateHandler

data/vendor/assets/bower_components/jqtree/src/scroll_handler.coffee

@@ -0,0 +1,100 @@
+class ScrollHandler
+    constructor: (tree_widget) ->
+        @tree_widget = tree_widget
+        @previous_top = -1
+
+        @_initScrollParent()
+
+    _initScrollParent: ->
+        getParentWithOverflow = =>
+            css_values = ['overflow', 'overflow-y']
+
+            hasOverFlow = (el) ->
+                for css_value in css_values
+                    if $.css(el, css_value) in ['auto', 'scroll']
+                        return true
+
+                return false
+
+            if hasOverFlow(@tree_widget.$el[0])
+                return @tree_widget.$el
+
+            for el in @tree_widget.$el.parents()
+                if hasOverFlow(el)
+                    return $(el)
+
+            return null
+
+        setDocumentAsScrollParent = =>
+            @scroll_parent_top = 0
+            @$scroll_parent = null
+
+        if @tree_widget.$el.css('position') == 'fixed'
+            setDocumentAsScrollParent()
+
+        $scroll_parent = getParentWithOverflow()
+
+        if $scroll_parent and $scroll_parent.length and $scroll_parent[0].tagName != 'HTML'
+            @$scroll_parent = $scroll_parent
+            @scroll_parent_top = @$scroll_parent.offset().top
+        else
+            setDocumentAsScrollParent()
+
+    checkScrolling: ->
+        hovered_area = @tree_widget.dnd_handler.hovered_area
+
+        if hovered_area and hovered_area.top != @previous_top
+            @previous_top = hovered_area.top
+
+            if @$scroll_parent
+                @_handleScrollingWithScrollParent(hovered_area)
+            else
+                @_handleScrollingWithDocument(hovered_area)
+
+    _handleScrollingWithScrollParent: (area) ->
+        distance_bottom = @scroll_parent_top + @$scroll_parent[0].offsetHeight - area.bottom
+
+        if distance_bottom < 20
+            @$scroll_parent[0].scrollTop += 20
+            @tree_widget.refreshHitAreas()
+            @previous_top = -1
+        else if (area.top - @scroll_parent_top) < 20
+            @$scroll_parent[0].scrollTop -= 20
+            @tree_widget.refreshHitAreas()
+            @previous_top = -1
+
+    _handleScrollingWithDocument: (area) ->
+        distance_top = area.top - $(document).scrollTop()
+
+        if distance_top < 20
+            $(document).scrollTop($(document).scrollTop() - 20)
+        else if $(window).height() - (area.bottom - $(document).scrollTop()) < 20
+            $(document).scrollTop($(document).scrollTop() + 20)
+
+    scrollTo: (top) ->
+        if @$scroll_parent
+            @$scroll_parent[0].scrollTop = top
+        else
+            tree_top = @tree_widget.$el.offset().top
+            $(document).scrollTop(top + tree_top)
+
+    isScrolledIntoView: (element) ->
+        $element = $(element)
+
+        if @$scroll_parent
+            view_top = 0
+            view_bottom = @$scroll_parent.height()
+
+            element_top = $element.offset().top - @scroll_parent_top
+            element_bottom = element_top + $element.height()
+        else
+            view_top = $(window).scrollTop()
+            view_bottom = view_top + $(window).height()
+
+            element_top = $element.offset().top
+            element_bottom = element_top + $element.height()
+
+        return (element_bottom <= view_bottom) and (element_top >= view_top)
+
+
+module.exports = ScrollHandler

data/vendor/assets/bower_components/jqtree/src/select_node_handler.coffee

@@ -0,0 +1,76 @@
+class SelectNodeHandler
+    constructor: (tree_widget) ->
+        @tree_widget = tree_widget
+        @clear()
+
+    getSelectedNode: ->
+        selected_nodes = @getSelectedNodes()
+
+        if selected_nodes.length
+            return selected_nodes[0]
+        else
+            return  false
+
+    getSelectedNodes: ->
+        if @selected_single_node
+            return [@selected_single_node]
+        else
+            selected_nodes = []
+
+            for id of @selected_nodes
+                node = @tree_widget.getNodeById(id)
+                if node
+                    selected_nodes.push(node)
+
+            return selected_nodes
+
+    getSelectedNodesUnder: (parent) ->
+        if @selected_single_node
+            if parent.isParentOf(@selected_single_node)
+                return [@selected_single_node]
+            else
+                return []
+        else
+            selected_nodes = []
+
+            for id of @selected_nodes
+                node = @tree_widget.getNodeById(id)
+                if node and parent.isParentOf(node)
+                    selected_nodes.push(node)
+
+            return selected_nodes
+
+    isNodeSelected: (node) ->
+        if node.id
+            return @selected_nodes[node.id]
+        else if @selected_single_node
+            return @selected_single_node.element == node.element
+        else
+            return false
+
+    clear: ->
+        @selected_nodes = {}
+        @selected_single_node = null
+
+    removeFromSelection: (node, include_children=false) ->
+        if not node.id
+            if @selected_single_node && node.element == @selected_single_node.element
+                @selected_single_node = null
+        else
+            delete @selected_nodes[node.id]
+
+            if include_children
+                node.iterate(
+                    (n) =>
+                        delete @selected_nodes[node.id]
+                        return true
+                )
+
+    addToSelection: (node) ->
+        if node.id
+            @selected_nodes[node.id] = true
+        else
+            @selected_single_node = node
+
+
+module.exports = SelectNodeHandler

data/vendor/assets/bower_components/jqtree/src/simple.widget.coffee

@@ -0,0 +1,102 @@
+###
+Copyright 2013 Marco Braak
+
+Licensed under the Apache License, Version 2.0 (the "License");
+you may not use this file except in compliance with the License.
+You may obtain a copy of the License at
+
+    http://www.apache.org/licenses/LICENSE-2.0
+
+Unless required by applicable law or agreed to in writing, software
+distributed under the License is distributed on an "AS IS" BASIS,
+WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+See the License for the specific language governing permissions and
+limitations under the License.
+###
+
+class SimpleWidget
+    defaults: {}
+
+    constructor: (el, options) ->
+        @$el = $(el)
+        @options = $.extend({}, @defaults, options)
+
+    destroy: ->
+        @_deinit()
+
+    _init: ->
+        null
+
+    _deinit: ->
+        null
+
+    @register = (widget_class, widget_name) ->
+        getDataKey = ->
+            return "simple_widget_#{widget_name}"
+
+        getWidgetData = (el, data_key) ->
+            widget = $.data(el, data_key)
+
+            if widget and (widget instanceof SimpleWidget)
+                return widget
+            else
+                return null
+
+        createWidget = ($el, options) ->
+            data_key = getDataKey()
+
+            for el in $el
+                existing_widget = getWidgetData(el, data_key)
+
+                if not existing_widget
+                    widget = new widget_class(el, options)
+
+                    if not $.data(el, data_key)
+                        $.data(el, data_key, widget)
+
+                    # Call init after setting data, so we can call methods
+                    widget._init()
+
+            return $el
+
+        destroyWidget = ($el) ->
+            data_key = getDataKey()
+
+            for el in $el
+                widget = getWidgetData(el, data_key)
+
+                if widget
+                    widget.destroy()
+
+                $.removeData(el, data_key)
+
+        callFunction = ($el, function_name, args) ->
+            result = null
+
+            for el in $el
+                widget = $.data(el, getDataKey())
+
+                if widget and (widget instanceof SimpleWidget)
+                    widget_function = widget[function_name]
+
+                    if widget_function and (typeof widget_function == 'function')
+                        result = widget_function.apply(widget, args)
+
+            return result
+
+        $.fn[widget_name] = (argument1, args...) ->
+            $el = this
+
+            if argument1 is undefined or typeof argument1 == 'object'
+                options = argument1
+                return createWidget($el, options)
+            else if typeof argument1 == 'string' and argument1[0] != '_'
+                function_name = argument1
+
+                if function_name == 'destroy'
+                    return destroyWidget($el)
+                else
+                    return callFunction($el, function_name, args)
+
+
+module.exports = SimpleWidget