iqvoc 4.8.1 → 4.8.2

data/vendor/assets/bower_components/jqtree/src/elements_renderer.coffee

@@ -0,0 +1,198 @@
+node_element = require './node_element'
+NodeElement = node_element.NodeElement
+
+util = require './util'
+html_escape = util.html_escape
+
+
+class ElementsRenderer
+    constructor: (tree_widget) ->
+        @tree_widget = tree_widget
+
+        @opened_icon_element = @createButtonElement(tree_widget.options.openedIcon)
+        @closed_icon_element = @createButtonElement(tree_widget.options.closedIcon)
+
+    render: (from_node) ->
+        if from_node and from_node.parent
+            @renderFromNode(from_node)
+        else
+            @renderFromRoot()
+
+    renderFromRoot: ->
+        $element = @tree_widget.element
+        $element.empty()
+
+        @createDomElements($element[0], @tree_widget.tree.children, true, true)
+
+    renderFromNode: (node) ->
+        # remember current li
+        $previous_li = $(node.element)
+
+        # create element
+        parent_node_element = new NodeElement(node.parent, @tree_widget)
+
+        li = @createLi(node)
+        @attachNodeData(node, li)
+
+        # add element to dom
+        $previous_li.after(li)
+
+        # remove previous li
+        $previous_li.remove()
+
+        # create children
+        if node.children
+            @createDomElements(li, node.children, false, false)
+
+    createDomElements: (element, children, is_root_node, is_open) ->
+        ul = @createUl(is_root_node)
+        element.appendChild(ul)
+
+        for child in children
+            li = @createLi(child)
+            ul.appendChild(li)
+
+            @attachNodeData(child, li)
+
+            if child.hasChildren()
+                @createDomElements(li, child.children, false, child.is_open)
+
+        return null
+
+    attachNodeData: (node, li) ->
+        node.element = li
+        $(li).data('node', node)
+
+    createUl: (is_root_node) ->
+        if is_root_node
+            class_string = 'jqtree-tree'
+        else
+            class_string = ''
+
+        ul = document.createElement('ul')
+        ul.className = "jqtree_common #{ class_string }"
+
+        return ul
+
+    createLi: (node) ->
+        if node.isFolder()
+            li = @createFolderLi(node)
+        else
+            li = @createNodeLi(node)
+
+        if @tree_widget.options.onCreateLi
+            @tree_widget.options.onCreateLi(node, $(li))
+
+        return li
+
+    createFolderLi: (node) ->
+        button_classes = @getButtonClasses(node)
+        folder_classes = @getFolderClasses(node)
+
+        escaped_name = @escapeIfNecessary(node.name)
+
+        if node.is_open
+            icon_element = @opened_icon_element
+        else
+            icon_element = @closed_icon_element
+
+        # li
+        li = document.createElement('li')
+        li.className = "jqtree_common #{ folder_classes }"
+
+        # div
+        div = document.createElement('div')
+        div.className = "jqtree-element jqtree_common"
+
+        li.appendChild(div)
+
+        # button link
+        button_link = document.createElement('a')
+        button_link.className = "jqtree_common #{ button_classes }"
+
+        button_link.appendChild(
+            icon_element.cloneNode(false)
+        )
+
+        div.appendChild(button_link)
+
+        # title span
+        title_span = document.createElement('span')
+        title_span.className = "jqtree_common jqtree-title jqtree-title-folder"
+
+        div.appendChild(title_span)
+
+        title_span.innerHTML = escaped_name
+
+        return li
+
+    createNodeLi: (node) ->
+        li_classes = ['jqtree_common']
+
+        if @tree_widget.select_node_handler and @tree_widget.select_node_handler.isNodeSelected(node)
+            li_classes.push('jqtree-selected')
+
+        class_string = li_classes.join(' ')
+
+        escaped_name = @escapeIfNecessary(node.name)
+
+        # li
+        li = document.createElement('li')
+        li.className = class_string
+
+        # div
+        div = document.createElement('div')
+        div.className = "jqtree-element jqtree_common"
+
+        li.appendChild(div)
+
+        # title span
+        title_span = document.createElement('span')
+        title_span.className = "jqtree-title jqtree_common"
+
+        title_span.innerHTML = escaped_name
+
+        div.appendChild(title_span)
+
+        return li
+
+    getButtonClasses: (node) ->
+        classes = ['jqtree-toggler']
+
+        if not node.is_open
+            classes.push('jqtree-closed')
+
+        return classes.join(' ')
+
+    getFolderClasses: (node) ->
+        classes = ['jqtree-folder']
+
+        if not node.is_open
+            classes.push('jqtree-closed')
+
+        if @tree_widget.select_node_handler and @tree_widget.select_node_handler.isNodeSelected(node)
+            classes.push('jqtree-selected')
+
+        if node.is_loading
+            classes.push('jqtree-loading')
+
+        return classes.join(' ')
+
+    escapeIfNecessary: (value) ->
+        if @tree_widget.options.autoEscape
+            return html_escape(value)
+        else
+            return value
+
+    createButtonElement: (value) ->
+        if typeof value == 'string'
+            # convert value to html
+            div = document.createElement('div')
+            div.innerHTML = value
+
+            return document.createTextNode(div.innerHTML)
+        else
+            return $(value)[0]
+
+
+module.exports = ElementsRenderer

data/vendor/assets/bower_components/jqtree/src/key_handler.coffee

@@ -0,0 +1,92 @@
+class KeyHandler
+    LEFT = 37
+    UP = 38
+    RIGHT = 39
+    DOWN = 40
+
+    constructor: (tree_widget) ->
+        @tree_widget = tree_widget
+
+        if tree_widget.options.keyboardSupport
+            $(document).bind('keydown.jqtree', $.proxy(@handleKeyDown, this))
+
+    deinit: ->
+        $(document).unbind('keydown.jqtree')
+
+    moveDown: ->
+        node = @tree_widget.getSelectedNode()
+
+        if node
+            return @selectNode(node.getNextNode())
+        else
+            return false
+
+    moveUp: ->
+        node = @tree_widget.getSelectedNode()
+
+        if node
+            return @selectNode(node.getPreviousNode())
+        else
+            return false
+
+    moveRight: ->
+        node = @tree_widget.getSelectedNode()
+
+        if node and node.isFolder() and not node.is_open
+            @tree_widget.openNode(node)
+            return false
+        else
+            return true
+
+    moveLeft: ->
+        node = @tree_widget.getSelectedNode()
+
+        if node and node.isFolder() and node.is_open
+            @tree_widget.closeNode(node)
+            return false
+        else
+            return true
+
+    handleKeyDown: (e) ->
+        if not @tree_widget.options.keyboardSupport
+            return true
+
+        if $(document.activeElement).is('textarea,input,select')
+            return true
+
+        if not @tree_widget.getSelectedNode()
+            return true
+
+        key = e.which
+
+        switch key
+            when DOWN
+                return @moveDown()
+
+            when UP
+                return @moveUp()
+
+            when RIGHT
+                return @moveRight()
+
+            when LEFT
+                return @moveLeft()
+
+        return true
+
+    selectNode: (node) =>
+        if not node
+            return true
+        else
+            @tree_widget.selectNode(node)
+
+            if (
+                @tree_widget.scroll_handler and
+                (not @tree_widget.scroll_handler.isScrolledIntoView($(node.element).find('.jqtree-element')))
+            )
+                @tree_widget.scrollToNode(node)
+
+            return false
+
+
+module.exports = KeyHandler

data/vendor/assets/bower_components/jqtree/src/mouse.widget.coffee

@@ -0,0 +1,181 @@
+###
+This widget does the same a the mouse widget in jqueryui.
+###
+
+SimpleWidget = require './simple.widget'
+
+
+class MouseWidget extends SimpleWidget
+    @is_mouse_handled = false
+
+    _init: ->
+        @$el.bind('mousedown.mousewidget', $.proxy(@_mouseDown, this))
+        @$el.bind('touchstart.mousewidget', $.proxy(@_touchStart, this))
+
+        @is_mouse_started = false
+        @mouse_delay = 0
+        @_mouse_delay_timer = null
+        @_is_mouse_delay_met = true
+        @mouse_down_info = null
+
+    _deinit: ->
+        @$el.unbind('mousedown.mousewidget')
+        @$el.unbind('touchstart.mousewidget')
+
+        $document = $(document)
+        $document.unbind('mousemove.mousewidget')
+        $document.unbind('mouseup.mousewidget')
+
+    _mouseDown: (e) ->
+        # Is left mouse button?
+        if e.which != 1
+            return
+
+        result = @_handleMouseDown(
+            e,
+            @_getPositionInfo(e)
+        )
+
+        if result
+            e.preventDefault()
+
+        return result
+
+    _handleMouseDown: (e, position_info) ->
+        # Don't let more than one widget handle mouseStart
+        if MouseWidget.is_mouse_handled
+            return
+
+        # We may have missed mouseup (out of window)
+        if @is_mouse_started
+            @_handleMouseUp(position_info)
+
+        @mouse_down_info = position_info
+
+        if not @_mouseCapture(position_info)
+            return
+
+        @_handleStartMouse()
+
+        @is_mouse_handled = true
+        return true
+
+    _handleStartMouse: ->
+        $document = $(document)
+        $document.bind('mousemove.mousewidget', $.proxy(@_mouseMove, this))
+        $document.bind('touchmove.mousewidget', $.proxy(@_touchMove, this))
+        $document.bind('mouseup.mousewidget', $.proxy(@_mouseUp, this))
+        $document.bind('touchend.mousewidget', $.proxy(@_touchEnd, this))
+
+        if @mouse_delay
+            @_startMouseDelayTimer()
+
+    _startMouseDelayTimer: ->
+        if @_mouse_delay_timer
+            clearTimeout(@_mouse_delay_timer)
+
+        @_mouse_delay_timer = setTimeout(
+            =>
+                @_is_mouse_delay_met = true
+            , @mouse_delay
+        )
+
+        @_is_mouse_delay_met = false
+
+    _mouseMove: (e) ->
+        return @_handleMouseMove(
+            e,
+            @_getPositionInfo(e)
+        )
+
+    _handleMouseMove: (e, position_info) ->
+        if @is_mouse_started
+            @_mouseDrag(position_info)
+            return e.preventDefault()
+
+        if @mouse_delay and not @_is_mouse_delay_met
+            return true
+
+        @is_mouse_started = @_mouseStart(@mouse_down_info) != false
+
+        if @is_mouse_started
+            @_mouseDrag(position_info)
+        else
+            @_handleMouseUp(position_info)
+
+        return not @is_mouse_started
+
+    _getPositionInfo: (e) ->
+        return {
+            page_x: e.pageX,
+            page_y: e.pageY,
+            target: e.target,
+            original_event: e
+        }
+
+    _mouseUp: (e) ->
+        return @_handleMouseUp(
+            @_getPositionInfo(e)
+        )
+
+    _handleMouseUp: (position_info) ->
+        $document = $(document)
+        $document.unbind('mousemove.mousewidget')
+        $document.unbind('touchmove.mousewidget')
+        $document.unbind('mouseup.mousewidget')
+        $document.unbind('touchend.mousewidget')
+
+        if @is_mouse_started
+            @is_mouse_started = false
+            @_mouseStop(position_info)
+
+        return
+
+    _mouseCapture: (position_info) ->
+        return true
+
+    _mouseStart: (position_info) ->
+        null
+
+    _mouseDrag: (position_info) ->
+        null
+
+    _mouseStop: (position_info) ->
+        null
+
+    setMouseDelay: (mouse_delay) ->
+        @mouse_delay = mouse_delay
+
+    _touchStart: (e) ->
+        if e.originalEvent.touches.length > 1
+            return
+
+        touch = e.originalEvent.changedTouches[0]
+
+        return @_handleMouseDown(
+            e,
+            @_getPositionInfo(touch)
+        )
+
+    _touchMove: (e) ->
+        if e.originalEvent.touches.length > 1
+            return
+
+        touch = e.originalEvent.changedTouches[0]
+
+        return @_handleMouseMove(
+            e,
+            @_getPositionInfo(touch)
+        )
+
+    _touchEnd: (e) ->
+        if e.originalEvent.touches.length > 1
+            return
+
+        touch = e.originalEvent.changedTouches[0]
+
+        return @_handleMouseUp(
+            @_getPositionInfo(touch)
+        )
+
+module.exports = MouseWidget