fannypack 0.2

data/fannypack.gemspec

@@ -0,0 +1,22 @@
+# -*- encoding: utf-8 -*-
+require File.expand_path('../lib/fanny_pack/version', __FILE__)
+
+Gem::Specification.new do |s|
+  s.name        = "fannypack"
+  s.version     = FannyPack::VERSION
+  s.authors     = ["Matt Diebolt", "Steel Fu", "Brad Gessler"]
+  s.email       = ["matt@polleverywhere.com", "steel@polleverywhere.com", "brad@polleverywhere.com"]
+  s.homepage    = "http://getfannypack.com"
+  s.summary     = %q{A simple set of base views to help develop Backbone applications.}
+  s.description = %q{A simple set of base views to help develop Backbone applications.}
+
+  # Manifest
+  s.files         = `git ls-files`.split("\n")
+  s.test_files    = `git ls-files -- {test,spec,features}/*`.split("\n")
+  s.executables   = `git ls-files -- bin/*`.split("\n").map{ |f| File.basename(f) }
+  s.require_paths = ["lib"]
+
+  s.add_development_dependency 'middleman', '~> 3.3'
+  s.add_development_dependency 'growl'
+  s.add_development_dependency 'rb-fsevent'
+end

data/lib/assets/javascripts/fanny_pack.coffee

@@ -0,0 +1,21 @@
+# Handle lots of commond URL parsing concerns so that we can easily
+# do stuff like URI('google.com/hi').params({search: 'football'})
+#= require uri
+
+# IE8 JSON parsing compatability.
+# TODO - Remove when we no longer care about IE8.
+#= require json2
+
+# Provides $.os support, which jQuery ditched.
+#= require zepto-detect
+
+# Fanny Pack prerequisites
+#= require fanny_pack/namespace
+#= require fanny_pack/version
+#= require fanny_pack/models/environment
+#= require fanny_pack/env
+
+# Fanny Pack assets
+#= require_tree ./fanny_pack/routers
+#= require_tree ./fanny_pack/models
+#= require_tree ./fanny_pack/views

data/lib/assets/javascripts/fanny_pack/ajax.js.coffee

@@ -0,0 +1,58 @@
+#= require ppx
+
+FannyPack.namespace "FannyPack", (FannyPack) ->
+  FannyPack.BasicAuth =
+    setCredentials: (username, password) ->
+      FannyPack.BasicAuth.username = username
+      FannyPack.BasicAuth.password = password
+      FannyPack.AJAX_DEFAULTS.headers['Authorization'] = "Basic #{btoa(FannyPack.BasicAuth.username + ':' + FannyPack.BasicAuth.password)}"
+
+  FannyPack.AJAX_DEFAULTS =
+    xhrFields:  {}
+    headers: {}
+    dataType: 'json'
+    type: 'GET'
+
+  # Deep clone the ajax defaults
+  ajaxDefaults = ->
+    clone = _.clone FannyPack.AJAX_DEFAULTS
+    clone.xhrFields = _.clone FannyPack.AJAX_DEFAULTS.xhrFields
+    clone.headers = _.clone FannyPack.AJAX_DEFAULTS.headers
+    clone
+
+  # Cross Domain polyfill for IE8
+  # ---
+  # IMPORTANT: We MUST call toString() on this method or IE will barf on allow
+  # other URLS to access the domain. For example, IE would request the URL
+  # 'multiple_choice_polls/[object]' without throwing an error message.
+
+  # PPX Proxy JS will determine whether iframe needs SSL or not
+  polyfillCORS = (options, xhr) ->
+    # A PPX end-point lives in our rails_app server at the /ppx location.
+    path = FannyPack.env.get('api_url').path()
+    ppxUrl = FannyPack.env.get('api_url').path("/ppx#{path}")
+
+    FannyPack.PPXRequest ||= PPX.buildClientConstructor ppxUrl.toString()
+
+    if (options.crossDomain && !$.support.cors) || options.usePostMessage
+      options.xhr = FannyPack.PPXRequest
+      options.crossDomain = false
+      xhr.isProxiedThroughPostMessage = true
+
+  $.ajaxPrefilter (options, originalOptions, xhr) ->
+    _.defaults options, ajaxDefaults()
+
+    # Only set this up if we're given a relative path. Paths with domains
+    # should just flow through to the next uri mutations.
+    url = URI(options.url).absoluteTo(FannyPack.env.get('api_url'))
+    url.setQuery 'cache_buster', (new Date).getTime().toString() if $.os?.android
+    options.url = url.toString()
+
+    # Check if this is a cross domain request.
+    # CORS PPX polyfill uses this to determine if PPX should be used.
+    options.crossDomain = !url.absoluteTo('/').equals(URI(window.location.href).absoluteTo('/'))
+
+    # We need this for CORS + Cookies to work when using jQuery
+    options.xhrFields.withCredentials ?= true
+
+    polyfillCORS(options, xhr)

data/lib/assets/javascripts/fanny_pack/env.js.coffee

@@ -0,0 +1,4 @@
+# Setup an environment class for all Poll Everywhere applications to access and store global state.
+
+FannyPack.namespace "FannyPack", (FannyPack) ->
+  FannyPack.env = new FannyPack.Model.Environment

data/lib/assets/javascripts/fanny_pack/models/environment.js.coffee

@@ -0,0 +1,15 @@
+FannyPack.namespace "FannyPack.Model", (Model) ->
+  class Model.Environment extends Backbone.Model
+    currentHost = window?.location?.host
+    protocol = window?.location?.protocol
+    defaults:
+      api_url: "//#{currentHost}"
+      ssl: protocol is 'https:'
+
+    get: (key) ->
+      switch
+        # When a key ends with _url, wrap it in an URI.js object so we can mutate it.
+        when key.match(/_url$/)
+          URI(super(key))
+        else
+          super(key)

data/lib/assets/javascripts/fanny_pack/namespace.coffee

@@ -0,0 +1,10 @@
+if module?.exports?
+  global.FannyPack ||= {}
+else
+  window.FannyPack ||= {}
+
+FannyPack.namespace = (target, name, block) ->
+  [target, name, block] = [(if global? then global else window), arguments...]
+  top    = target
+  target = target[item] or= {} for item in name.split '.'
+  block target, name

data/lib/assets/javascripts/fanny_pack/routers/base.coffee

@@ -0,0 +1,82 @@
+# The FannyPack.Router.Base is considered our most global application
+# state for applications. Its assumed that only one router should
+# be running at a given time within the context of a single runtime.
+#
+# Views and Templates all have access to the router via the `@app`
+# method.
+FannyPack.namespace "FannyPack.Router", (Router) ->
+  {Model} = FannyPack
+
+  class Router.Base extends Backbone.Router
+    # Default app name. Sets the default <title> on the page and
+    # is used in error messaging.
+    appName: "FannyPack App"
+
+    constructor: ->
+      # Lets prevent confusion for the clowns out there who try
+      # initializing 2 routers in the same runtime.
+      throw Error "FannyPack.app already initialized with '#{@appName}'" if FannyPack.app
+      FannyPack.app = @
+
+      # Convient access to the FannyPack.env from
+      # applications
+      @env = FannyPack.env
+
+      # What's that? You turned logging on? SWEET! You
+      # get to hear about everything that's happening in the
+      # event bus.
+      if @env.get('logging_enabled')
+        @on 'all', =>
+          @log 'App Event', arguments
+
+      # View manager responsible for de-activating old views and activating new ones
+      @view = new View.App
+
+      # We call super last since this calls the `initialize` method,
+      # which assumes everything above is all set and ready to go.
+      super
+
+    # Take care of all the messy bootstrapping of browser globals and singletons to
+    # the router, render a view, bootstrap user data from the server, and start
+    # Backbone.history routing. Basically all of the gross browser bootstrapping should
+    # go here.
+    #
+    # If you're trying to setup the router for testing, you should either decompose this
+    # method or manually start the browser's history.
+    start: (opts={pushState: true}) =>
+      throw Error "Specify a view property in the initialize method of the router" unless @view
+
+      {pushState, el} = opts
+
+      # Render the view first on the element since the login state could
+      # change what's rendered.
+      el.append @view.render().$el
+
+      # Start the router
+      Backbone.history.start(pushState: pushState)
+
+      @
+
+    # Returns the current location of the application.
+    location: ->
+      # This assumes that we're in a web browser context.
+      window.location.pathname.substring(1)
+
+    # Go "back" through the browsers history.
+    navigateBack: ->
+      Backbone.history.history.back()
+
+    # Default in backbone is to *not* trigger to execute the route handler,
+    # which is undesirable and feels like unexpected behavior for our devs.
+    navigate: (fragment, options = {trigger: true}) ->
+      super fragment, options
+
+    # Log tracing messages to a logging device if enabled.
+    log: =>
+      console.log(arguments...) if @env.get('logging_enabled')
+
+    # Change the title of the page and notify views/models that
+    # care about a title change what's up.
+    title: (title = @appName) =>
+      document?.title = title
+      @trigger "change:title", title

data/lib/assets/javascripts/fanny_pack/version.js.coffee

@@ -0,0 +1,2 @@
+FannyPack.namespace "FannyPack", (Package) ->
+  Package.version = '0.2' # This updates the fanny_pack.gemspec version

data/lib/assets/javascripts/fanny_pack/views/app.coffee

@@ -0,0 +1,19 @@
+#= require_tree ../views
+
+FannyPack.namespace "FannyPack.View", (View) ->
+  class View.App extends View.Base
+    className: 'fannypack'
+
+    initialize: (opts = {}) ->
+      @currentView = null
+
+    activate: (view) =>
+      @currentView?.remove()
+      @currentView = view
+      @$el.append view.render().$el
+
+    currentPage: =>
+      @currentView
+
+    render: =>
+      @

data/lib/assets/javascripts/fanny_pack/views/base.coffee

@@ -0,0 +1,90 @@
+FannyPack.namespace 'FannyPack.View', (View) ->
+  class View.Base extends Backbone.View
+    include: (modules...) ->
+      for module in modules
+        _.extend this, module(this)
+
+    constructor: (options = {}) ->
+      # Set the app for this view to the base application
+      # that FannyPack.Router.Base sets up in its initialize method.
+      @app ||= FannyPack.app
+
+      {title, template} = options
+
+      # Set the page title if we're given one.
+      @title = title if title?
+
+      # Override the template if specified
+      @template = template if template?
+
+      # TODO - Figure out how to show the full namespace
+      # of the view that's being rendered (and not just the prototype name)
+      # Make it easier for non-lib devs to find views.
+      @app.log "Constructing View", @
+
+      # Tell the router what the title of our window should be.
+      @app.title @title if @title
+
+      # make sure we have an external events hash
+      # if the child class hasn't defined one
+      @appEvents ?= {}
+
+      # Setup Backbone.View last since it fires the
+      # subclasses' `initialize` method, which assumes
+      # everything above is setup.
+      super
+
+    # Listen to a list of events and fire callback only once
+    # e.g. @listenToChanges @poll, "max_votes web_enabled sms_enabled", @refreshPage
+    # The above will call @refreshPage only once instead of 3 times for each attribute
+    # change event
+    listenToChanges: (model, attributes, callback) =>
+      attributes = attributes.split /\s+/
+      @listenTo model, 'change', (model) ->
+        changedAttributes = _.keys model.changed
+
+        if _.intersection(changedAttributes, attributes).length
+          callback.apply(@, model)
+
+    pageTitle: =>
+      if _.isFunction(@title)
+        @title.apply(@)
+      else
+        @title
+
+    _configureAppEvents: =>
+      for action, handler of @appEvents
+        try
+          method = @[handler]
+          method = handler if _.isFunction(handler)
+          boundMethod = _.bind(method, @)
+
+          @app.on action, boundMethod
+        catch
+          name = "'#{@constructor?.name || ''}'"
+          message = "View #{name} has no method named '#{handler}'. It cannot be registered as a handler for application events."
+          throw new Error(message)
+
+      @
+
+    delegateEvents: (events) =>
+      super
+      @_configureAppEvents()
+      @
+
+    undelegateEvents: =>
+      super
+      for action, handler of @appEvents
+        @app.off action, _.bind @[handler], @
+      @
+
+    renderTemplate: (template = @template) =>
+      @app.log "Rendering Template", template
+      @$el.html JST[template]()
+
+    renderTitle: =>
+      @$(".title").text @pageTitle()
+      @app.title @pageTitle()
+
+    pageClass: =>
+      ""

data/lib/assets/javascripts/fanny_pack/views/list.coffee

@@ -0,0 +1,29 @@
+#= require ../namespace
+
+FannyPack.namespace 'FannyPack.View', (View) ->
+  class View.List extends View.Base
+    initialize: (options={}) ->
+      @collection = options.collection
+      @subView = options.subView
+
+      @subViews = []
+
+    # always blow away existing subViews.
+    # call this only if you want a full re-render
+    render: =>
+      @remove()
+
+      @collection.each (item) =>
+        v = new @subView
+          model: item
+
+        @subViews.push v
+
+        @$el.append v.render().$el
+
+      @
+
+    remove: =>
+      _.invoke @subViews, 'remove'
+
+      super

data/lib/fanny_pack.rb

@@ -0,0 +1,4 @@
+require "fanny_pack/version"
+require "fanny_pack/assets"
+
+FannyPack::Assets::Sprockets.auto_detect

data/lib/fanny_pack/assets.rb

@@ -0,0 +1,24 @@
+module FannyPack
+  # Deal with bundling Sprocket assets into environments (like Rails or Sprockets)
+  module Assets
+    def self.path(*segs)
+      File.join File.expand_path('../../assets', __FILE__), segs
+    end
+
+    # Integrate FannyPack ./lib/assets files into a sprocket-enabled environment.
+    module Sprockets
+      # Drop flash and javascript paths to FannyPack assets into a sprockets environment.
+      def self.configure(env)
+        env.append_path FannyPack::Assets.path('javascripts')
+        env
+      end
+
+      # Try to automatically configure Sprockets if its detected in the project.
+      def self.auto_detect
+        if defined? ::Sprockets and ::Sprockets.respond_to? :append_path
+          FannyPack::Assets::Sprockets.configure ::Sprockets
+        end
+      end
+    end
+  end
+end

data/lib/fanny_pack/version.rb

@@ -0,0 +1,4 @@
+module FannyPack
+  # Read the FannyPack.version attribute from lib/assets/javascripts/fanny_pack/version.js.coffee
+  VERSION = File.read(File.expand_path('../../assets/javascripts/fanny_pack/version.js.coffee', __FILE__)).match(/Package.version \= '(.+)'/m).captures.first
+end

data/source/index.html.haml

@@ -0,0 +1,9 @@
+---
+title: Middleman is Watching
+body_class: index
+---
+
+.welcome
+  %h1 Middleman is Watching
+  %p.doc
+    = link_to 'Read Online Documentation', 'http://middlemanapp.com/', title: 'Read Online Documentation', target: '_blank'

data/source/javascripts/application.js.coffee

@@ -0,0 +1,2 @@
+#= require_tree ./vendor
+#= require_tree ./lib

data/source/layouts/layout.html.haml

@@ -0,0 +1,49 @@
+!!! 5
+/[if lt IE 7]   <html class="no-js lt-ie10 lt-ie9 lt-ie8 lt-ie7" lang="en-us">
+/[if IE 7]      <html class="no-js lt-ie10 lt-ie9 lt-ie8" lang="en-us">
+/[if IE 8]      <html class="no-js lt-ie10 lt-ie9" lang="en-us">
+/[if IE 9]      <html class="no-js lt-ie10 lt-ie9" lang="en-us">
+/[if lt IE 10]  <html class="no-js lt-ie10" lang="en-us">
+/[if !IE]>
+%html{lang: 'en', class: 'no-js'}
+  /<![endif]
+  %head
+    %title #{data.page.title || "The Middleman"}
+    %meta(http-equiv="content-type" content="text/html" charset="utf-8")
+    %meta(http-equiv="x-ua-compatible" content="ie=edge,chrome=1")
+    %meta(name="description" content="")
+    %meta(name="author" content="")
+    
+    -# Standard viewport tag to set the viewport to the device's width, 
+    -# Android 2.3 devices need this so 100% width works properly and 
+    -# doesn't allow children to blow up the viewport width
+    %meta{content: "initial-scale=1.0,user-scalable=no,maximum-scale=1,width=device-width", name: "viewport"}
+    
+    -# Fix for iPhone 5 fullscreen web apps
+    %meta(name="viewport" content="initial-scale=1.0,user-scalable=no,maximum-scale=1" media="(device-height: 568px)")
+    %meta(name='apple-mobile-web-app-capable' content='yes')
+    %meta(name='apple-mobile-web-app-status-bar-style' content='translucent-black')
+
+    -# App Icons
+    %link(rel="shortcut icon" href="/images/favicon.ico")
+    %link(rel="apple-touch-icon-precomposed" href="/images/apple-touch-icon-precomposed.png")
+    %link(rel="apple-touch-icon-precomposed" sizes="57x57" href="/images/apple-touch-icon-57x57-precomposed.png")
+    %link(rel="apple-touch-icon-precomposed" sizes="72x72" href="/images/apple-touch-icon-72x72-precomposed.png")
+    %link(rel="apple-touch-icon-precomposed" sizes="114x114" href="/images/apple-touch-icon-114x114-precomposed.png")
+    
+    -# Stylesheets
+    = stylesheet_link_tag 'application'
+  %body{class: current_page.data.body_class || 'page'}
+    = yield
+    -# Javascripts
+    = javascript_include_tag '//cdnjs.cloudflare.com/ajax/libs/modernizr/2.6.2/modernizr.min.js'
+    = javascript_include_tag '//cdnjs.cloudflare.com/ajax/libs/jquery/2.0.3/jquery.min.js'
+    = javascript_include_tag 'application'
+
+    - if build?
+      -# Google Analytics
+      :javascript
+        var _gaq=[['_setAccount','UA-XXXXX-X'],['_trackPageview']];
+        (function(d,t){var g=d.createElement(t),s=d.getElementsByTagName(t)[0];
+        g.src=('https:'==location.protocol?'//ssl':'//www')+'.google-analytics.com/ga.js';
+        s.parentNode.insertBefore(g,s)}(document,'script'));