exiftool_vendored 10.04.0 → 10.23.0

data/bin/Image-ExifTool-10.23/lib/Image/ExifTool/AFCP.pm

@@ -0,0 +1,286 @@
+#------------------------------------------------------------------------------
+# File:         AFCP.pm
+#
+# Description:  Read/write AFCP trailer
+#
+# Revisions:    12/26/2005 - P. Harvey Created
+#
+# References:   1) http://web.archive.org/web/20080828211305/http://www.tocarte.com/media/axs_afcp_spec.pdf
+#------------------------------------------------------------------------------
+
+package Image::ExifTool::AFCP;
+
+use strict;
+use vars qw($VERSION);
+use Image::ExifTool qw(:DataAccess :Utils);
+
+$VERSION = '1.07';
+
+sub ProcessAFCP($$);
+
+%Image::ExifTool::AFCP::Main = (
+    PROCESS_PROC => \&ProcessAFCP,
+    NOTES => q{
+AFCP stands for AXS File Concatenation Protocol, and is a poorly designed
+protocol for appending information to the end of files.  This can be used as
+an auxiliary technique to store IPTC information in images, but is
+incompatible with some file formats.
+
+ExifTool will read and write (but not create) AFCP IPTC information in JPEG
+and TIFF images.
+
+See
+L<http://web.archive.org/web/20080828211305/http://www.tocarte.com/media/axs_afcp_spec.pdf>
+for the AFCP specification.
+    },
+    IPTC => { SubDirectory => { TagTable => 'Image::ExifTool::IPTC::Main' } },
+    TEXT => 'Text',
+    Nail => {
+        Name => 'ThumbnailImage',
+        Groups => { 2 => 'Preview' },
+        # (the specification allows for a variable amount of padding before
+        #  the image after a 10-byte header, so look for the JPEG SOI marker,
+        #  otherwise assume a fixed 8 bytes of padding)
+        RawConv => q{
+            pos($val) = 10;
+            my $start = ($val =~ /\xff\xd8\xff/g) ? pos($val) - 3 : 18;
+            my $img = substr($val, $start);
+            return $self->ValidateImage(\$img, $tag);
+        },
+    },
+    PrVw => {
+        Name => 'PreviewImage',
+        Groups => { 2 => 'Preview' },
+        RawConv => q{
+            pos($val) = 10;
+            my $start = ($val =~ /\xff\xd8\xff/g) ? pos($val) - 3 : 18;
+            my $img = substr($val, $start);
+            return $self->ValidateImage(\$img, $tag);
+        },
+    },
+);
+
+#------------------------------------------------------------------------------
+# Read/write AFCP information in a file
+# Inputs: 0) ExifTool object reference, 1) dirInfo reference
+# (Set 'ScanForAFCP' member in dirInfo to scan from current position for AFCP)
+# Returns: 1 on success, 0 if this file didn't contain AFCP information
+#          -1 on write error or if the offsets were incorrect on reading
+# - updates DataPos to point to actual AFCP start if ScanForAFCP is set
+# - updates DirLen to trailer length
+# - returns Fixup reference in dirInfo hash when writing
+sub ProcessAFCP($$)
+{
+    my ($et, $dirInfo) = @_;
+    my $raf = $$dirInfo{RAF};
+    my $curPos = $raf->Tell();
+    my $offset = $$dirInfo{Offset} || 0;    # offset from end of file
+    my $rtnVal = 0;
+
+NoAFCP: for (;;) {
+        my ($buff, $fix, $dirBuff, $valBuff, $fixup, $vers);
+        # look for AXS trailer
+        last unless $raf->Seek(-12-$offset, 2) and
+                    $raf->Read($buff, 12) == 12 and
+                    $buff =~ /^(AXS(!|\*))/;
+        my $endPos = $raf->Tell();
+        my $hdr = $1;
+        SetByteOrder($2 eq '!' ? 'MM' : 'II');
+        my $startPos = Get32u(\$buff, 4);
+        if ($raf->Seek($startPos, 0) and $raf->Read($buff, 12) == 12 and $buff =~ /^$hdr/) {
+            $fix = 0;
+        } else {
+            $rtnVal = -1;
+            # look for start of AXS trailer if 'ScanForAFCP'
+            last unless $$dirInfo{ScanForAFCP} and $raf->Seek($curPos, 0);
+            my $actualPos = $curPos;
+            # first look for header right at current position
+            for (;;) {
+                last if $raf->Read($buff, 12) == 12 and $buff =~ /^$hdr/;
+                last NoAFCP if $actualPos != $curPos;
+                # scan for AXS header (could be after preview image)
+                for (;;) {
+                    my $buf2;
+                    $raf->Read($buf2, 65536) or last NoAFCP;
+                    $buff .= $buf2;
+                    if ($buff =~ /$hdr/g) {
+                        $actualPos += pos($buff) - length($hdr);
+                        last;   # ok, now go back and re-read header
+                    }
+                    $buf2 = substr($buf2, -3);  # only need last 3 bytes for next test
+                    $actualPos += length($buff) - length($buf2);
+                    $buff = $buf2;
+                }
+                last unless $raf->Seek($actualPos, 0);  # seek to start of AFCP
+            }
+            # calculate shift for fixing AFCP offsets
+            $fix = $actualPos - $startPos;
+        }
+        # set variables returned in dirInfo hash
+        $$dirInfo{DataPos} = $startPos + $fix;  # actual start position
+        $$dirInfo{DirLen} = $endPos - ($startPos + $fix);
+
+        $rtnVal = 1;
+        my $verbose = $et->Options('Verbose');
+        my $out = $et->Options('TextOut');
+        my $outfile = $$dirInfo{OutFile};
+        if ($outfile) {
+            # allow all AFCP information to be deleted
+            if ($$et{DEL_GROUP}{AFCP}) {
+                $verbose and print $out "  Deleting AFCP\n";
+                ++$$et{CHANGED};
+                last;
+            }
+            $dirBuff = $valBuff = '';
+            require Image::ExifTool::Fixup;
+            $fixup = $$dirInfo{Fixup};
+            $fixup or $fixup = $$dirInfo{Fixup} = new Image::ExifTool::Fixup;
+            $vers = substr($buff, 4, 2); # get version number
+        } else {
+            $et->DumpTrailer($dirInfo) if $verbose or $$et{HTML_DUMP};
+        }
+        # read AFCP directory data
+        my $numEntries = Get16u(\$buff, 6);
+        my $dir;
+        unless ($raf->Read($dir, 12 * $numEntries) == 12 * $numEntries) {
+            $et->Error('Error reading AFCP directory', 1);
+            last;
+        }
+        if ($verbose > 2 and not $outfile) {
+            my $dat = $buff . $dir;
+            print $out "  AFCP Directory:\n";
+            HexDump(\$dat, undef,
+                Addr   => $$dirInfo{DataPos},
+                Width  => 12,
+                Prefix => $$et{INDENT},
+                Out => $out,
+            );
+        }
+        $fix and $et->Warn("Adjusted AFCP offsets by $fix", 1);
+#
+# process AFCP directory
+#
+        my $tagTablePtr = GetTagTable('Image::ExifTool::AFCP::Main');
+        my ($index, $entry);
+        for ($index=0; $index<$numEntries; ++$index) {
+            my $entry = 12 * $index;
+            my $tag = substr($dir, $entry, 4);
+            my $size = Get32u(\$dir, $entry + 4);
+            my $offset = Get32u(\$dir, $entry + 8);
+            if ($size < 0x80000000 and
+                $raf->Seek($offset+$fix, 0) and
+                $raf->Read($buff, $size) == $size)
+            {
+                if ($outfile) {
+                    # rewrite this information
+                    my $tagInfo = $et->GetTagInfo($tagTablePtr, $tag);
+                    if ($tagInfo and $$tagInfo{SubDirectory}) {
+                        my %subdirInfo = (
+                            DataPt => \$buff,
+                            DirStart => 0,
+                            DirLen => $size,
+                            DataPos => $offset + $fix,
+                            Parent => 'AFCP',
+                        );
+                        my $subTable = GetTagTable($tagInfo->{SubDirectory}->{TagTable});
+                        my $newDir = $et->WriteDirectory(\%subdirInfo, $subTable);
+                        if (defined $newDir) {
+                            $size = length $newDir;
+                            $buff = $newDir;
+                        }
+                    }
+                    $fixup->AddFixup(length($dirBuff) + 8);
+                    $dirBuff .= $tag . Set32u($size) . Set32u(length $valBuff);
+                    $valBuff .= $buff;
+                } else {
+                    # extract information
+                    $et->HandleTag($tagTablePtr, $tag, $buff,
+                        DataPt => \$buff,
+                        Size => $size,
+                        Index => $index,
+                        DataPos => $offset + $fix,
+                    );
+                }
+            } else {
+                $et->Warn("Bad AFCP directory");
+                $rtnVal = -1 if $outfile;
+                last;
+            }
+        }
+        if ($outfile and length($dirBuff)) {
+            my $outPos = Tell($outfile);    # get current outfile position
+            # apply fixup to directory pointers
+            my $valPos = $outPos + 12;      # start of value data
+            $fixup->{Shift} += $valPos + length($dirBuff);
+            $fixup->ApplyFixup(\$dirBuff);
+            # write the AFCP header, directory, value data and EOF record (with zero checksums)
+            Write($outfile, $hdr, $vers, Set16u(length($dirBuff)/12), Set32u(0),
+                  $dirBuff, $valBuff, $hdr, Set32u($outPos), Set32u(0)) or $rtnVal = -1;
+            # complete fixup so the calling routine can apply further shifts
+            $fixup->AddFixup(length($dirBuff) + length($valBuff) + 4);
+            $fixup->{Start} += $valPos;
+            $fixup->{Shift} -= $valPos;
+        }
+        last;
+    }
+    return $rtnVal;
+}
+
+1;  # end
+
+__END__
+
+=head1 NAME
+
+Image::ExifTool::AFCP - Read/write AFCP trailer
+
+=head1 SYNOPSIS
+
+This module is used by Image::ExifTool
+
+=head1 DESCRIPTION
+
+This module contains definitions required by Image::ExifTool to extract
+information from the AFCP trailer.  Although the AFCP specification is
+compatible with various file formats, ExifTool currently only processes AFCP
+in JPEG images.
+
+=head1 NOTES
+
+AFCP is a specification which allows meta information (including IPTC) to be
+appended to the end of a file.
+
+It is a poorly designed protocol because (like TIFF) it uses absolute
+offsets to specify data locations.  This is a huge blunder because it makes
+the AFCP information dependent on the file length, so it is easily
+invalidated by image editing software which doesn't recognize the AFCP
+trailer to fix up these offsets when the file length changes.  ExifTool will
+attempt to fix these invalid offsets if possible.
+
+Scanning for AFCP information may be time consuming, especially when reading
+from a sequential device, since the information is at the end of the file.
+In these instances, the ExifTool FastScan option may be used to disable
+scanning for AFCP information.
+
+=head1 AUTHOR
+
+Copyright 2003-2016, Phil Harvey (phil at owl.phy.queensu.ca)
+
+This library is free software; you can redistribute it and/or modify it
+under the same terms as Perl itself.
+
+=head1 REFERENCES
+
+=over 4
+
+=item L<http://www.tocarte.com/media/axs_afcp_spec.pdf>
+
+=back
+
+=head1 SEE ALSO
+
+L<Image::ExifTool::TagNames/AFCP Tags>,
+L<Image::ExifTool(3pm)|Image::ExifTool>
+
+=cut
+

data/bin/Image-ExifTool-10.23/lib/Image/ExifTool/AIFF.pm

@@ -0,0 +1,289 @@
+#------------------------------------------------------------------------------
+# File:         AIFF.pm
+#
+# Description:  Read AIFF meta information
+#
+# Revisions:    01/06/2006 - P. Harvey Created
+#               09/22/2008 - PH Added DjVu support
+#
+# References:   1) http://developer.apple.com/documentation/QuickTime/INMAC/SOUND/imsoundmgr.30.htm#pgfId=3190
+#               2) http://astronomy.swin.edu.au/~pbourke/dataformats/aiff/
+#               3) http://www.mactech.com/articles/mactech/Vol.06/06.01/SANENormalized/
+#------------------------------------------------------------------------------
+
+package Image::ExifTool::AIFF;
+
+use strict;
+use vars qw($VERSION);
+use Image::ExifTool qw(:DataAccess :Utils);
+use Image::ExifTool::ID3;
+
+$VERSION = '1.07';
+
+# information for time/date-based tags (time zero is Jan 1, 1904)
+my %timeInfo = (
+    Groups => { 2 => 'Time' },
+    ValueConv => 'ConvertUnixTime($val - ((66 * 365 + 17) * 24 * 3600))',
+    PrintConv => '$self->ConvertDateTime($val)',
+);
+
+# AIFF info
+%Image::ExifTool::AIFF::Main = (
+    GROUPS => { 2 => 'Audio' },
+    NOTES => q{
+        Tags extracted from Audio Interchange File Format (AIFF) files.  See
+        L<http://www-mmsp.ece.mcgill.ca/Documents/AudioFormats/AIFF/AIFF.html> for
+        the AIFF specification.
+    },
+#    FORM => 'Format',
+    FVER => {
+        Name => 'FormatVersion',
+        SubDirectory => { TagTable => 'Image::ExifTool::AIFF::FormatVers' },
+    },
+    COMM => {
+        Name => 'Common',
+        SubDirectory => { TagTable => 'Image::ExifTool::AIFF::Common' },
+    },
+    COMT => {
+        Name => 'Comment',
+        SubDirectory => { TagTable => 'Image::ExifTool::AIFF::Comment' },
+    },
+    NAME => {
+        Name => 'Name',
+        ValueConv => '$self->Decode($val, "MacRoman")',
+    },
+    AUTH => {
+        Name => 'Author',
+        Groups => { 2 => 'Author' },
+        ValueConv => '$self->Decode($val, "MacRoman")',
+    },
+   '(c) ' => {
+        Name => 'Copyright',
+        Groups => { 2 => 'Author' },
+        ValueConv => '$self->Decode($val, "MacRoman")',
+    },
+    ANNO => {
+        Name => 'Annotation',
+        ValueConv => '$self->Decode($val, "MacRoman")',
+    },
+   'ID3 ' => {
+        Name => 'ID3',
+        SubDirectory => {
+            TagTable => 'Image::ExifTool::ID3::Main',
+            ProcessProc => \&Image::ExifTool::ID3::ProcessID3,
+        },
+    },
+#    SSND => 'SoundData',
+#    MARK => 'Marker',
+#    INST => 'Instrument',
+#    MIDI => 'MidiData',
+#    AESD => 'AudioRecording',
+#    APPL => 'ApplicationSpecific',
+);
+
+%Image::ExifTool::AIFF::Common = (
+    PROCESS_PROC => \&Image::ExifTool::ProcessBinaryData,
+    GROUPS => { 2 => 'Audio' },
+    FORMAT => 'int16u',
+    0 => 'NumChannels',
+    1 => { Name => 'NumSampleFrames', Format => 'int32u' },
+    3 => 'SampleSize',
+    4 => { Name => 'SampleRate', Format => 'extended' }, #3
+    9 => {
+        Name => 'CompressionType',
+        Format => 'string[4]',
+        PrintConv => {
+            NONE => 'None',
+            ACE2 => 'ACE 2-to-1',
+            ACE8 => 'ACE 8-to-3',
+            MAC3 => 'MAC 3-to-1',
+            MAC6 => 'MAC 6-to-1',
+            sowt => 'Little-endian, no compression',
+        },
+    },
+    11 => { #PH
+        Name => 'CompressorName',
+        Format => 'pstring',
+        ValueConv => '$self->Decode($val, "MacRoman")',
+    },
+);
+
+%Image::ExifTool::AIFF::FormatVers = (
+    PROCESS_PROC => \&Image::ExifTool::ProcessBinaryData,
+    FORMAT => 'int32u',
+    0 => { Name => 'FormatVersionTime', %timeInfo },
+);
+
+%Image::ExifTool::AIFF::Comment = (
+    PROCESS_PROC => \&Image::ExifTool::AIFF::ProcessComment,
+    GROUPS => { 2 => 'Audio' },
+    0 => { Name => 'CommentTime', %timeInfo },
+    1 => 'MarkerID',
+    2 => {
+        Name => 'Comment',
+        ValueConv => '$self->Decode($val, "MacRoman")',
+    },
+);
+
+%Image::ExifTool::AIFF::Composite = (
+    Duration => {
+        Require => {
+            0 => 'AIFF:SampleRate',
+            1 => 'AIFF:NumSampleFrames',
+        },
+        RawConv => '($val[0] and $val[1]) ? $val[1] / $val[0] : undef',
+        PrintConv => 'ConvertDuration($val)',
+    },
+);
+
+# add our composite tags
+Image::ExifTool::AddCompositeTags('Image::ExifTool::AIFF');
+
+
+#------------------------------------------------------------------------------
+# Process AIFF Comment chunk
+# Inputs: 0) ExifTool object reference, 1) DirInfo reference, 2) tag table ref
+# Returns: 1 on success
+sub ProcessComment($$$)
+{
+    my ($et, $dirInfo, $tagTablePtr) = @_;
+    my $dataPt = $$dirInfo{DataPt};
+    my $dirLen = $$dirInfo{DirLen};
+    my $verbose = $et->Options('Verbose');
+    return 0 unless $dirLen > 2;
+    my $numComments = unpack('n',$$dataPt);
+    my $pos = 2;
+    my $i;
+    $verbose and $et->VerboseDir('Comment', $numComments);
+    for ($i=0; $i<$numComments; ++$i) {
+        last if $pos + 8 > $dirLen;
+        my ($time, $markerID, $size) = unpack("x${pos}Nnn", $$dataPt);
+        $et->HandleTag($tagTablePtr, 0, $time);
+        $et->HandleTag($tagTablePtr, 1, $markerID) if $markerID;
+        $pos += 8;
+        last if $pos + $size > $dirLen;
+        my $val = substr($$dataPt, $pos, $size);
+        $et->HandleTag($tagTablePtr, 2, $val);
+        ++$size if $size & 0x01;    # account for padding byte if necessary
+        $pos += $size;
+    }
+}
+
+#------------------------------------------------------------------------------
+# Extract information from a AIFF file
+# Inputs: 0) ExifTool object reference, 1) DirInfo reference
+# Returns: 1 on success, 0 if this wasn't a valid AIFF file
+sub ProcessAIFF($$)
+{
+    my ($et, $dirInfo) = @_;
+    my $raf = $$dirInfo{RAF};
+    my ($buff, $err, $tagTablePtr, $page, $type);
+
+    # verify this is a valid AIFF file
+    return 0 unless $raf->Read($buff, 12) == 12;
+    my $fast3 = $$et{OPTIONS}{FastScan} && $$et{OPTIONS}{FastScan} == 3;
+    my $pos = 12;
+    # check for DjVu image
+    if ($buff =~ /^AT&TFORM/) {
+        # http://www.djvu.org/
+        # http://djvu.sourceforge.net/specs/djvu3changes.txt
+        my $buf2;
+        return 0 unless $raf->Read($buf2, 4) == 4 and $buf2 =~ /^(DJVU|DJVM)/;
+        $pos += 4;
+        $buff = substr($buff, 4) . $buf2;
+        $et->SetFileType('DJVU');
+        return 1 if $fast3;
+        $tagTablePtr = GetTagTable('Image::ExifTool::DjVu::Main');
+        # modifiy FileType to indicate a multi-page document
+        $$et{VALUE}{FileType} .= " (multi-page)" if $buf2 eq 'DJVM';
+        $type = 'DjVu';
+    } else {
+        return 0 unless $buff =~ /^FORM....(AIF(F|C))/s;
+        $et->SetFileType($1);
+        return 1 if $fast3;
+        $tagTablePtr = GetTagTable('Image::ExifTool::AIFF::Main');
+        $type = 'AIFF';
+    }
+    SetByteOrder('MM');
+    my $verbose = $et->Options('Verbose');
+#
+# Read through the IFF chunks
+#
+    for (;;) {
+        $raf->Read($buff, 8) == 8 or last;
+        $pos += 8;
+        my ($tag, $len) = unpack('a4N', $buff);
+        my $tagInfo = $et->GetTagInfo($tagTablePtr, $tag);
+        $et->VPrint(0, "AIFF '$tag' chunk ($len bytes of data):\n");
+        # AIFF chunks are padded to an even number of bytes
+        my $len2 = $len + ($len & 0x01);
+        if ($tagInfo) {
+            if ($$tagInfo{TypeOnly}) {
+                $len = $len2 = 4;
+                $page = ($page || 0) + 1;
+                $et->VPrint(0, $$et{INDENT} . "Page $page:\n");
+            }
+            $raf->Read($buff, $len2) >= $len or $err=1, last;
+            unless ($$tagInfo{SubDirectory} or $$tagInfo{Binary}) {
+                $buff =~ s/\0+$//;  # remove trailing nulls
+            }
+            $et->HandleTag($tagTablePtr, $tag, $buff,
+                DataPt => \$buff,
+                DataPos => $pos,
+                Start => 0,
+                Size => $len,
+            );
+        } elsif ($verbose > 2 and $len2 < 1024000) {
+            $raf->Read($buff, $len2) == $len2 or $err = 1, last;
+            HexDump(\$buff, undef, MaxLen => 512);
+        } else {
+            $raf->Seek($len2, 1) or $err=1, last;
+        }
+        $pos += $len2;
+    }
+    $err and $et->Warn("Error reading $type file (corrupted?)");
+    return 1;
+}
+
+1;  # end
+
+__END__
+
+=head1 NAME
+
+Image::ExifTool::AIFF - Read AIFF meta information
+
+=head1 SYNOPSIS
+
+This module is used by Image::ExifTool
+
+=head1 DESCRIPTION
+
+This module contains routines required by Image::ExifTool to extract
+information from AIFF (Audio Interchange File Format) audio files.
+
+=head1 AUTHOR
+
+Copyright 2003-2016, Phil Harvey (phil at owl.phy.queensu.ca)
+
+This library is free software; you can redistribute it and/or modify it
+under the same terms as Perl itself.
+
+=head1 REFERENCES
+
+=over 4
+
+=item L<http://developer.apple.com/documentation/QuickTime/INMAC/SOUND/imsoundmgr.30.htm#pgfId=3190>
+
+=item L<http://astronomy.swin.edu.au/~pbourke/dataformats/aiff/>
+
+=item L<http://www.mactech.com/articles/mactech/Vol.06/06.01/SANENormalized/>
+
+=back
+
+=head1 SEE ALSO
+
+L<Image::ExifTool::TagNames/AIFF Tags>,
+L<Image::ExifTool(3pm)|Image::ExifTool>
+
+=cut