cmis_server 1.0.3

data/lib/cmis_server/query/parser.racc

@@ -0,0 +1,222 @@
+class CmisServer::Query::Parser
+
+rule
+# dynamic sql
+
+    query_statement
+        : simple_table order_by_clause {result = CmisServer::Query::Statement::CmisQuery.new(val[0], val[1])}
+
+    simple_table
+        : SELECT select_list from_clause where_clause {result = CmisServer::Query::Statement::Select.new(val[1],val[2],val[3])}
+
+    select_list
+        : asterisk { result = CmisServer::Query::Statement::All.new }
+        | select_sublist { result = CmisServer::Query::Statement::SelectList.new(val[0]) }
+
+    select_sublist
+        : derived_column comma select_sublist { result = Array(val[0]) + Array(val[2]) }
+        | derived_column
+
+    derived_column
+        : qualifier period asterisk { result = CmisServer::Query::Statement::All.new(val[0]) }
+        | value_expression AS column_name { result = CmisServer::Query::Statement::As.new(val[0], val[2]) }
+        | value_expression column_name { result = CmisServer::Query::Statement::As.new(val[0], val[1]) }
+        | value_expression
+
+    value_expression
+        : numeric_value_function
+        | column_reference
+
+    numeric_value_function
+        : SCORE left_paren right_paren { result = CmisServer::Query::Statement::Score.new }
+
+    column_reference
+        : qualifier period column_name { result = CmisServer::Query::Statement::QualifiedColumn.new(val[0], val[2]) }
+        | column_name
+
+
+    from_clause
+        : FROM table_reference { result = CmisServer::Query::Statement::FromClause.new(val[1]) }
+
+    table_reference
+        : table_name AS correlation_name {result = CmisServer::Query::Statement::As.new(val[0], val[2]) }
+        | table_name correlation_name {result = CmisServer::Query::Statement::As.new(val[0], val[2]) }
+        | table_name
+        | joined_table
+
+    joined_table
+        : left_paren joined_table right_paren
+        | table_reference JOIN table_reference join_specification { result = CmisServer::Query::Statement::InnerJoin.new(val[0], val[3], val[4]) } #Default
+        | table_reference join_type JOIN table_reference join_specification { result = val[1].new(val[0], val[3], val[4]) }
+
+    join_type
+        : INNER { result = CmisServer::Query::Statement::InnerJoin}
+        | LEFT OUTER { result = CmisServer::Query::Statement::LeftOuterJoin }
+        | LEFT { result = CmisServer::Query::Statement::LeftJoin }
+
+    join_specification
+        : ON column_reference equals_operator column_reference {result = CmisServer::Query::Statement::Equals.new(val[1], val[3])}
+
+    where_clause
+        : #No_action
+        | WHERE search_condition { result = CmisServer::Query::Statement::WhereClause.new(val[1]) }
+
+    search_condition
+        : search_condition OR boolean_term { result = CmisServer::Query::Statement::Or.new(val[0], val[2]) }
+        | boolean_term
+
+    boolean_term
+        : boolean_term AND boolean_factor { result = CmisServer::Query::Statement::And.new(val[0], val[2]) }
+        | boolean_factor
+
+    boolean_factor
+        : NOT boolean_test { result = CmisServer::Query::Statement::Not.new(val[1]) }
+        | boolean_test
+
+    boolean_test
+        : boolean_primary
+
+     boolean_primary
+        : predicate
+        | left_paren search_condition right_paren { result = val[1] }
+
+    predicate
+        : quantified_comparison_predicate
+        | comparison_predicate
+        | folder_predicate
+        | in_predicate
+        | like_predicate
+        | null_predicate
+        | quantified_in_predicate
+        #TODO | text_search_predicate
+
+    comparison_predicate
+        : value_expression equals_operator literal { result = CmisServer::Query::Statement::Equals.new(val[0], val[2]) }
+        | value_expression not_equals_operator literal { result = CmisServer::Query::Statement::Not.new(CmisServer::Query::Statement::Equals.new(val[0], val[2])) }
+        | value_expression less_than_operator literal { result = CmisServer::Query::Statement::Less.new(val[0], val[2]) }
+        | value_expression greater_than_operator literal { result = CmisServer::Query::Statement::Greater.new(val[0], val[2]) }
+        | value_expression less_than_or_equals_operator literal { result = CmisServer::Query::Statement::LessOrEquals.new(val[0], val[2]) }
+        | value_expression greater_than_or_equals_operator literal { result = CmisServer::Query::Statement::GreaterOrEquals.new(val[0], val[2]) }
+
+    in_predicate
+        : column_reference NOT IN left_paren in_value_list right_paren { result = CmisServer::Query::Statement::Not.new(CmisServer::Query::Statement::In.new(val[0], val[4])) }
+        | column_reference IN left_paren in_value_list right_paren { result = CmisServer::Query::Statement::In.new(val[0], val[3]) }
+
+    in_value_list
+        : in_value_list comma literal  { result = Array(val[0]) + Array(val[2]) }
+        | literal
+
+    null_predicate
+        : column_reference IS NOT NULL { result = CmisServer::Query::Statement::Not.new(CmisServer::Query::Statement::Is.new(val[0], CmisServer::Query::Statement::Null.new)) }
+        | column_reference IS NULL { result = CmisServer::Query::Statement::Is.new(val[0], CmisServer::Query::Statement::Null.new) }
+
+    like_predicate
+        : column_reference NOT LIKE general_literal { result = CmisServer::Query::Statement::Not.new(CmisServer::Query::Statement::Like.new(val[0], val[3])) }
+        | column_reference LIKE general_literal { result = CmisServer::Query::Statement::Like.new(val[0], val[2]) }
+
+    quantified_comparison_predicate
+        : literal equals_operator ANY column_reference { result = CmisServer::Query::Statement::QuantifiedComparison.new(val[0], val[3]) }
+
+    quantified_in_predicate
+        : ANY column_reference NOT IN left_paren in_value_list right_paren { result = CmisServer::Query::Statement::Not.new(CmisServer::Query::Statement::QuantifiedIn.new(val[1], val[5])) }
+        | ANY column_reference IN left_paren in_value_list right_paren { result = CmisServer::Query::Statement::QuantifiedIn.new(val[1], val[4]) }
+
+    folder_predicate
+        : depth_selector left_paren qualifier comma folder_id right_paren { result = val[0].new(val[4], val[2]) }
+        | depth_selector left_paren folder_id right_paren { result = val[0].new(val[2], nil) }
+
+    depth_selector
+        : IN_FOLDER { result = CmisServer::Query::Statement::InFolder }
+        | IN_TREE { result = CmisServer::Query::Statement::InTree }
+
+    literal
+        : boolean_literal
+        | datetime_literal
+        | signed_numeric_literal
+        | general_literal
+
+    order_by_clause
+        : #No action
+        | ORDER BY sort_specification_list { result = CmisServer::Query::Statement::OrderBy.new(val[2]) }
+
+    sort_specification_list
+        : sort_specification comma sort_specification { result = Array(val[0]) + Array(val[2]) }
+        | sort_specification
+
+    sort_specification
+         : sort_key ordering_specification { result = val[1].new(val[0]) }
+
+    sort_key
+         : column_reference
+
+    ordering_specification
+        : { result = CmisServer::Query::Statement::Ascending } # defaultf
+        | ASC { result = CmisServer::Query::Statement::Ascending }
+        | DESC { result = CmisServer::Query::Statement::Descending }
+
+    qualifier
+        : table_name
+
+    correlation_name
+        : qualifier
+
+    folder_id
+        : identifier  {result = CmisServer::Query::Statement::FolderId.new(val[0])}
+
+    table_name
+        : identifier  {result = CmisServer::Query::Statement::Table.new(val[0])}
+
+    column_name
+        : identifier  {result = CmisServer::Query::Statement::Column.new(val[0])}
+
+    general_literal
+        : quote character_string_literal quote { result = CmisServer::Query::Statement::String.new(val[1]) }
+        | quote quote { result = CmisServer::Query::Statement::String.new('') }
+
+    datetime_literal
+        : TIMESTAMP date_string { result = CmisServer::Query::Statement::Date.new(val[1]) }
+
+    signed_numeric_literal
+        | sign unsigned_numeric_literal  { result = val[0].new(val[1]) }
+        | unsigned_numeric_literal
+
+    unsigned_numeric_literal
+        : exact_numeric_literal
+        | approximate_numeric_literal
+
+    exact_numeric_literal
+        : unsigned_integer period unsigned_integer { result = CmisServer::Query::Statement::Float.new("#{val[0]}.#{val[2]}".to_f) }
+        | unsigned_integer period { result = CmisServer::Query::Statement::Float.new(val[0]) }
+        | period unsigned_integer { result = CmisServer::Query::Statement::Float.new("0.#{val[1]}".to_f) }
+        | unsigned_integer { result = CmisServer::Query::Statement::Integer.new(val[0]) }
+
+    approximate_numeric_literal
+        : mantissa E exponent { result = CmisServer::Query::Statement::ApproximateFloat.new(val[0], val[2]) }
+
+    mantissa
+        : exact_numeric_literal
+
+    exponent
+        : signed_integer
+
+    signed_integer
+        : sign unsigned_integer { result = val[0].new(CmisServer::Query::Statement::Integer.new(val[1])) }
+        | unsigned_integer { result = CmisServer::Query::Statement::Integer.new(val[0]) }
+
+    sign
+        : plus_sign { result = CmisServer::Query::Statement::UnaryPlus }
+        | minus_sign { result = CmisServer::Query::Statement::UnaryMinus }
+
+    boolean_literal
+        : TRUE  { result = CmisServer::Query::Statement::True.new }
+        | FALSE { result = CmisServer::Query::Statement::False.new }
+
+
+---- header ----
+require File.dirname(__FILE__) + '/parser.rex.rb'
+
+---- inner ----
+
+def self.parse(sql)
+    new.scan_str(sql)
+end