arcadia 0.1.1 → 0.1.2

data/tcl/BWidget-1.8.0/demo/dnd.tcl

@@ -0,0 +1,42 @@
+
+namespace eval DemoDnd {
+}
+
+
+proc DemoDnd::create { nb } {
+
+    set frame [$nb insert end demoDnd -text "Drag and Drop"]
+
+    set titf1 [TitleFrame $frame.titf1 -text "Drag sources"]
+    set subf  [$titf1 getframe]
+
+    set ent1  [LabelEntry $subf.e1 -label "Entry" -labelwidth 14 -dragenabled 1 -dragevent 3]
+    set labf1 [LabelFrame $subf.f1 -text "Label (text)" -width 14]
+    set f     [$labf1 getframe]
+    set lab   [Label $f.l -text "Drag this text" -dragenabled 1 -dragevent 3]
+    pack $lab
+
+    set labf2 [LabelFrame $subf.f2 -text "Label (bitmap)" -width 14]
+    set f     [$labf2 getframe]
+    set lab   [Label $f.l -bitmap info -dragenabled 1 -dragevent 3]
+    pack $lab
+
+    pack $ent1 $labf1 $labf2 -side top -fill x -pady 4
+
+    set titf2 [TitleFrame $frame.titf2 -text "Drop targets"]
+    set subf  [$titf2 getframe]
+
+    set ent1  [LabelEntry $subf.e1 -label "Entry" -labelwidth 14 -dropenabled 1]
+    set labf1 [LabelFrame $subf.f1 -text "Label" -width 14]
+    set f     [$labf1 getframe]
+    set lab   [Label $f.l -dropenabled 1 -highlightthickness 1]
+    pack $lab -fill x
+
+    pack $ent1 $labf1 -side top -fill x -pady 4
+
+    pack $titf1 $titf2 -pady 4
+
+    return $frame
+}
+
+

data/tcl/BWidget-1.8.0/demo/manager.tcl

@@ -0,0 +1,141 @@
+
+
+namespace eval DemoManager {
+    variable _progress 0
+    variable _afterid  ""
+    variable _status "Compute in progress..."
+    variable _homogeneous 0
+}
+
+
+proc DemoManager::create { nb } {
+    set frame [$nb insert end demoManager -text "Manager"]
+
+    set topf  [frame $frame.topf]
+    set titf1 [TitleFrame $topf.titf1 -text "MainFrame"]
+    set titf2 [TitleFrame $topf.titf2 -text "NoteBook"]
+    set titf3 [TitleFrame $frame.titf3 -text "Paned & ScrolledWindow"]
+
+    _mainframe [$titf1 getframe]
+    _notebook  [$titf2 getframe]
+    _paned     [$titf3 getframe]
+
+    pack $titf1 $titf2 -padx 4 -side left -fill both -expand yes
+    pack $topf -fill x -pady 2
+    pack $titf3 -pady 2 -padx 4 -fill both -expand yes
+
+    return $frame
+}
+
+
+proc DemoManager::_mainframe { parent } {
+    set labf1 [LabelFrame $parent.labf1 -text "Toolbar" -side top -anchor w \
+                   -relief sunken -borderwidth 2]
+    set subf  [$labf1 getframe]
+    checkbutton $subf.chk1 -text "View toolbar 1" -variable Demo::toolbar1 \
+        -command {$Demo::mainframe showtoolbar 0 $Demo::toolbar1}
+    checkbutton $subf.chk2 -text "View toolbar 2" -variable Demo::toolbar2 \
+        -command {$Demo::mainframe showtoolbar 1 $Demo::toolbar2}
+    pack $subf.chk1 $subf.chk2 -anchor w -fill x
+    pack $labf1 -fill both
+
+    set labf2 [LabelFrame $parent.labf2 -text "Status bar" -side top -anchor w \
+                   -relief sunken -borderwidth 2]
+    set subf  [$labf2 getframe]
+    checkbutton $subf.chk1 -text "Show Progress\nindicator" -justify left \
+        -variable DemoManager::_progress \
+        -command  {DemoManager::_show_progress}
+    pack $subf.chk1 -anchor w -fill x
+
+    pack $labf1 $labf2 -side left -padx 4 -fill both
+}
+
+
+proc DemoManager::_notebook { parent } {
+    checkbutton $parent.chk1 -text "Homogeneous label" \
+        -variable DemoManager::_homogeneous \
+        -command  {$Demo::notebook configure -homogeneous $DemoManager::_homogeneous}
+    pack $parent.chk1 -side left -anchor n -fill x
+}
+
+
+
+proc DemoManager::_paned { parent } {
+    set pw1   [PanedWindow $parent.pw -side top]
+    set pane  [$pw1 add -minsize 100]
+
+    set pw2    [PanedWindow $pane.pw -side left]
+    set pane1  [$pw2 add -minsize 100]
+    set pane2  [$pw2 add -minsize 100]
+    set pane3  [$pw1 add -minsize 100]
+
+    foreach pane [list $pane1 $pane2] {
+        set sw    [ScrolledWindow $pane.sw]
+        set lb    [listbox $sw.lb -height 8 -width 20 -highlightthickness 0]
+        for {set i 1} {$i <= 8} {incr i} {
+            $lb insert end "Value $i"
+        }
+        $sw setwidget $lb
+        pack $sw -fill both -expand yes
+    }
+
+    set sw [ScrolledWindow $pane3.sw -relief sunken -borderwidth 2]
+    set sf [ScrollableFrame $sw.f]
+    $sw setwidget $sf
+    set subf [$sf getframe]
+    set lab [label $subf.lab -text "This is a ScrollableFrame"]
+    set chk [checkbutton $subf.chk -text "Constrained width" \
+                 -variable DemoManager::_constw \
+                 -command  "$sf configure -constrainedwidth \$DemoManager::_constw"]
+    pack $lab
+    pack $chk -anchor w
+    bind $chk <FocusIn> "$sf see $chk"
+    for {set i 0} {$i <= 20} {incr i} {
+        pack [entry $subf.ent$i -width 50]  -fill x -pady 4
+	bind $subf.ent$i <FocusIn> "$sf see $subf.ent$i"
+        $subf.ent$i insert end "Text field $i"
+    }
+
+    pack $sw $pw2 $pw1 -fill both -expand yes
+}
+
+
+proc DemoManager::_show_progress { } {
+    variable _progress
+    variable _afterid
+    variable _status
+
+    if { $_progress } {
+        set Demo::status   "Compute in progress..."
+        set Demo::prgindic 0
+        $Demo::mainframe showstatusbar progression
+        if { $_afterid == "" } {
+            set _afterid [after 30 DemoManager::_update_progress]
+        }
+    } else {
+        set Demo::status ""
+        $Demo::mainframe showstatusbar status
+        set _afterid ""
+    }
+}
+
+
+proc DemoManager::_update_progress { } {
+    variable _progress
+    variable _afterid
+
+    if { $_progress } {
+        if { $Demo::prgindic < 100 } {
+            incr Demo::prgindic 5
+            set _afterid [after 30 DemoManager::_update_progress]
+        } else {
+            set _progress 0
+            $Demo::mainframe showstatusbar status
+            set Demo::status "Done"
+            set _afterid ""
+            after 500 {set Demo::status ""}
+        }
+    } else {
+        set _afterid ""
+    }
+}

data/tcl/BWidget-1.8.0/demo/select.tcl

@@ -0,0 +1,59 @@
+namespace eval DemoSelect {
+    variable var
+}
+
+
+proc DemoSelect::create { nb } {
+    set frame [$nb insert end demoSelect -text "Spin & Combo"]
+
+    set titf1 [TitleFrame $frame.titf1 -text SpinBox]
+    set subf  [$titf1 getframe]
+    set spin  [SpinBox $subf.spin \
+                   -range {1 100 1} -textvariable DemoSelect::var(spin,var) \
+                   -helptext "This is the SpinBox"]
+    set ent   [LabelEntry $subf.ent -label "Linked var" -labelwidth 10 -labelanchor w \
+                   -textvariable DemoSelect::var(spin,var) -editable 0 \
+                   -helptext "This is an Entry reflecting\nthe linked var of SpinBox"]
+    set labf  [LabelFrame $subf.options -text "Options" -side top -anchor w \
+                   -relief sunken -borderwidth 1 \
+                   -helptext "Modify some options of SpinBox"]
+    set subf  [$labf getframe]
+    set chk1  [checkbutton $subf.chk1 -text "Non editable" \
+                   -variable DemoSelect::var(spin,editable) -onvalue false -offvalue true \
+                   -command "$spin configure -editable \$DemoSelect::var(spin,editable)"]
+    set chk2  [checkbutton $subf.chk2 -text "Disabled" \
+                   -variable DemoSelect::var(spin,state) -onvalue disabled -offvalue normal \
+                   -command "$spin configure -state \$DemoSelect::var(spin,state)"]
+
+    pack $chk1 $chk2 -side left -anchor w
+    pack $spin $ent $labf -pady 4 -fill x
+    pack $titf1
+
+    set titf2 [TitleFrame $frame.titf2 -text ComboBox]
+    set subf  [$titf2 getframe]
+    set combo [ComboBox $subf.combo \
+                   -textvariable DemoSelect::var(combo,var) \
+                   -values {"first value" "second value" "third value" "fourth value" "fifth value"} \
+                   -helptext "This is the ComboBox"]
+    set ent   [LabelEntry $subf.ent -label "Linked var" -labelwidth 10 -labelanchor w \
+                   -textvariable DemoSelect::var(combo,var) -editable 0 \
+                   -helptext "This is an Entry reflecting\nthe linked var of ComboBox"]
+    set labf  [LabelFrame $subf.options -text "Options" -side top -anchor w \
+                   -relief sunken -borderwidth 1 \
+                   -helptext "Modify some options of SpinBox"]
+    set subf  [$labf getframe]
+    set chk1  [checkbutton $subf.chk1 -text "Non editable" \
+                   -variable DemoSelect::var(combo,editable) -onvalue false -offvalue true \
+                   -command  "$combo configure -editable \$DemoSelect::var(combo,editable)"]
+    set chk2  [checkbutton $subf.chk2 -text "Disabled" \
+                   -variable DemoSelect::var(combo,state) -onvalue disabled -offvalue normal \
+                   -command  "$combo configure -state \$DemoSelect::var(combo,state)"]
+
+    pack $chk1 $chk2 -side left -anchor w
+    pack $combo $ent $labf -pady 4 -fill x
+
+    pack $titf1 $titf2 -pady 4
+
+    return $frame
+}
+

data/tcl/BWidget-1.8.0/demo/tmpldlg.tcl

@@ -0,0 +1,214 @@
+
+namespace eval DemoDlg {
+    variable tmpl
+    variable msg
+    variable progmsg
+    variable progval
+    variable resources "en"
+}
+
+
+proc DemoDlg::create { nb } {
+    set frame [$nb insert end demoDlg -text "Dialog"]
+
+    set titf1 [TitleFrame $frame.titf1 -text "Resources"]
+    set titf2 [TitleFrame $frame.titf2 -text "Template Dialog"]
+    set titf3 [TitleFrame $frame.titf3 -text "Message Dialog"]
+    set titf4 [TitleFrame $frame.titf4 -text "Other dialog"]
+
+    set subf [$titf1 getframe]
+    set cmd  {option read [file join $::BWIDGET::LIBRARY "lang" $DemoDlg::resources.rc]}
+    set rad1 [radiobutton $subf.rad1 -text "English" \
+                  -variable DemoDlg::resources -value en \
+                  -command  $cmd]
+    set rad2 [radiobutton $subf.rad2 -text "French" \
+                  -variable DemoDlg::resources -value fr \
+                  -command  $cmd]
+    set rad3 [radiobutton $subf.rad3 -text "German" \
+                  -variable DemoDlg::resources -value de \
+                  -command  $cmd]
+    pack $rad1 $rad2 $rad3 -side left
+
+    _tmpldlg [$titf2 getframe]
+    _msgdlg  [$titf3 getframe]
+    _stddlg  [$titf4 getframe]
+
+    pack $titf1 -fill x -pady 2 -padx 2
+    pack $titf4 -side bottom -fill x -pady 2 -padx 2
+    pack $titf2 $titf3 -side left -padx 2 -fill both -expand yes
+}
+
+
+proc DemoDlg::_tmpldlg { parent } {
+    variable tmpl
+
+    set tmpl(side)   bottom
+    set tmpl(anchor) c
+
+    set labf1 [LabelFrame $parent.labf1 -text "Button side" -side top \
+                   -anchor w -relief sunken -borderwidth 1]
+    set subf  [$labf1 getframe]
+    radiobutton $subf.rad1 -text "Bottom" \
+        -variable DemoDlg::tmpl(side) -value bottom -anchor w
+    radiobutton $subf.rad2 -text "Left" \
+        -variable DemoDlg::tmpl(side) -value left   -anchor w
+    radiobutton $subf.rad3 -text "Right" \
+        -variable DemoDlg::tmpl(side) -value right  -anchor w
+    radiobutton $subf.rad4 -text "Top" \
+        -variable DemoDlg::tmpl(side) -value top    -anchor w
+
+    pack $subf.rad1 $subf.rad2 $subf.rad3 $subf.rad4 -fill x -anchor w
+
+    set labf2 [LabelFrame $parent.labf2 -text "Button anchor" -side top \
+                   -anchor w -relief sunken -borderwidth 1]
+    set subf  [$labf2 getframe]
+    radiobutton $subf.rad1 -text "North" \
+        -variable DemoDlg::tmpl(anchor) -value n -anchor w
+    radiobutton $subf.rad2 -text "West" \
+        -variable DemoDlg::tmpl(anchor) -value w -anchor w
+    radiobutton $subf.rad3 -text "East" \
+        -variable DemoDlg::tmpl(anchor) -value e -anchor w
+    radiobutton $subf.rad4 -text "South" \
+        -variable DemoDlg::tmpl(anchor) -value s -anchor w
+    radiobutton $subf.rad5 -text "Center" \
+        -variable DemoDlg::tmpl(anchor) -value c -anchor w
+
+    pack $subf.rad1 $subf.rad2 $subf.rad3 $subf.rad4 $subf.rad5 -fill x -anchor w
+
+    set sep    [Separator  $parent.sep -orient horizontal]
+    set button [button $parent.but -text "Show" -command DemoDlg::_show_tmpldlg]
+
+    pack $button -side bottom
+    pack $sep -side bottom -fill x -pady 10
+    pack $labf1 $labf2 -side left -padx 4 -anchor n
+}
+
+
+proc DemoDlg::_msgdlg { parent } {
+    variable msg
+
+    set msg(type) ok
+    set msg(icon) info
+
+    set labf1 [LabelFrame $parent.labf1 -text "Type" -side top \
+                   -anchor w -relief sunken -borderwidth 1]
+    set subf  [$labf1 getframe]
+    radiobutton $subf.rad1 -text "Ok" -variable DemoDlg::msg(type) -value ok -anchor w
+    radiobutton $subf.rad2 -text "Ok, Cancel" -variable DemoDlg::msg(type) -value okcancel -anchor w
+    radiobutton $subf.rad3 -text "Retry, Cancel" -variable DemoDlg::msg(type) -value retrycancel -anchor w
+    radiobutton $subf.rad4 -text "Yes, No" -variable DemoDlg::msg(type) -value yesno -anchor w
+    radiobutton $subf.rad5 -text "Yes, No, Cancel" -variable DemoDlg::msg(type) -value yesnocancel -anchor w
+    radiobutton $subf.rad6 -text "Abort, Retry, Ignore" -variable DemoDlg::msg(type) -value abortretryignore -anchor w
+    radiobutton $subf.rad7 -text "User" -variable DemoDlg::msg(type) -value user -anchor w
+    Entry $subf.user -textvariable DemoDlg::msg(buttons)
+
+    pack $subf.rad1 $subf.rad2 $subf.rad3 $subf.rad4 $subf.rad5 $subf.rad6 -fill x -anchor w
+    pack $subf.rad7 $subf.user -side left
+
+    set labf2 [LabelFrame $parent.labf2 -text "Icon" -side top -anchor w -relief sunken -borderwidth 1]
+    set subf  [$labf2 getframe]
+    radiobutton $subf.rad1 -text "Information" -variable DemoDlg::msg(icon) -value info     -anchor w
+    radiobutton $subf.rad2 -text "Question"    -variable DemoDlg::msg(icon) -value question -anchor w
+    radiobutton $subf.rad3 -text "Warning"     -variable DemoDlg::msg(icon) -value warning  -anchor w
+    radiobutton $subf.rad4 -text "Error"       -variable DemoDlg::msg(icon) -value error    -anchor w
+    pack $subf.rad1 $subf.rad2 $subf.rad3 $subf.rad4 -fill x -anchor w
+
+
+    set sep    [Separator  $parent.sep -orient horizontal]
+    set button [button $parent.but -text "Show" -command DemoDlg::_show_msgdlg]
+
+    pack $button -side bottom
+    pack $sep -side bottom -fill x -pady 10
+    pack $labf1 $labf2 -side left -padx 4 -anchor n
+}
+
+
+proc DemoDlg::_stddlg { parent } {
+    set but0  [button $parent.but0 \
+                   -text "Select a color " \
+                   -command "DemoDlg::_show_color $parent.but0"]
+    set but1  [button $parent.but1 \
+                   -text    "Font selector dialog" \
+                   -command DemoDlg::_show_fontdlg]
+    set but2  [button $parent.but2 \
+                   -text    "Progression dialog" \
+                   -command DemoDlg::_show_progdlg]
+    set but3  [button $parent.but3 \
+                   -text    "Password dialog" \
+                   -command DemoDlg::_show_passdlg]
+
+    pack $but0 $but1 $but2 $but3 -side left -padx 5 -anchor w
+}
+
+proc DemoDlg::_show_color {w} {
+    set color [SelectColor::menu $w.color [list below $w] \
+                       -color [$w cget -background]]
+    if {[string length $color]} {
+        $w configure -background $color
+    }
+}
+
+proc DemoDlg::_show_tmpldlg { } {
+    variable tmpl
+
+    set dlg [Dialog .tmpldlg -parent . -modal local \
+                 -separator 1 \
+                 -title   "Template dialog" \
+                 -side    $tmpl(side)    \
+                 -anchor  $tmpl(anchor)  \
+                 -default 0 -cancel 1]
+    $dlg add -name ok
+    $dlg add -name cancel
+    set msg [message [$dlg getframe].msg -text "Template\nDialog" -justify center -anchor c]
+    pack $msg -fill both -expand yes -padx 100 -pady 100
+    $dlg draw
+    destroy $dlg
+}
+
+
+proc DemoDlg::_show_msgdlg { } {
+    variable msg
+
+    destroy .msgdlg
+    MessageDlg .msgdlg -parent . \
+        -message "Message for MessageBox" \
+        -type    $msg(type) \
+        -icon    $msg(icon) \
+        -buttons $msg(buttons)
+}
+
+
+proc DemoDlg::_show_fontdlg { } {
+    set font [SelectFont .fontdlg -parent . -font $Demo::font]
+    if { $font != "" } {
+        Demo::update_font $font
+    }
+}
+
+
+proc DemoDlg::_show_progdlg { } {
+    set DemoDlg::progmsg "Compute in progress..."
+    set DemoDlg::progval 0
+
+    ProgressDlg .progress -parent . -title "Wait..." \
+        -type         infinite \
+        -width        20 \
+        -textvariable DemoDlg::progmsg \
+        -variable     DemoDlg::progval \
+        -stop         "Stop" \
+        -command      {destroy .progress}
+    _update_progdlg
+}
+
+
+proc DemoDlg::_update_progdlg { } {
+    if { [winfo exists .progress] } {
+        set DemoDlg::progval 2
+        after 20 DemoDlg::_update_progdlg
+    }
+}
+
+proc DemoDlg::_show_passdlg { } {
+    PasswdDlg .passwd -parent .
+}
+