arcadia 0.1.1 → 0.1.2

data/tcl/BWidget-1.8.0/bitmap.tcl

@@ -0,0 +1,94 @@
+# ------------------------------------------------------------------------------
+#  bitmap.tcl
+#  This file is part of Unifix BWidget Toolkit
+#  $Id: bitmap.tcl,v 1.4 2003/10/20 21:23:52 damonc Exp $
+# ------------------------------------------------------------------------------
+#  Index of commands:
+#     - Bitmap::get
+#     - Bitmap::_init
+# ----------------------------------------------------------------------------
+namespace eval Bitmap {
+    Widget::define Bitmap bitmap -classonly
+
+    variable path
+    variable _bmp
+    variable _types {
+        photo  .gif
+        photo  .ppm
+        bitmap .xbm
+        photo  .xpm
+    }
+
+    proc use {} {}
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Bitmap::get
+# ----------------------------------------------------------------------------
+proc Bitmap::get { name } {
+    variable path
+    variable _bmp
+    variable _types
+
+    if {[info exists _bmp($name)]} {
+        return $_bmp($name)
+    }
+
+    # --- Nom de fichier avec extension ---------------------------------
+    set ext [file extension $name]
+    if { $ext != "" } {
+        if { ![info exists _bmp($ext)] } {
+            error "$ext not supported"
+        }
+
+        if { [file exists $name] } {
+            if {[string equal $ext ".xpm"]} {
+                set _bmp($name) [xpm-to-image $name]
+                return $_bmp($name)
+            }
+            if {![catch {set _bmp($name) [image create $_bmp($ext) -file $name]}]} {
+                return $_bmp($name)
+            }
+        }
+    }
+
+    foreach dir $path {
+        foreach {type ext} $_types {
+            if { [file exists [file join $dir $name$ext]] } {
+                if {[string equal $ext ".xpm"]} {
+                    set _bmp($name) [xpm-to-image [file join $dir $name$ext]]
+                    return $_bmp($name)
+                } else {
+                    if {![catch {set _bmp($name) [image create $type -file [file join $dir $name$ext]]}]} {
+                        return $_bmp($name)
+                    }
+                }
+            }
+        }
+    }
+
+    return -code error "$name not found"
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Bitmap::_init
+# ----------------------------------------------------------------------------
+proc Bitmap::_init { } {
+    global   env
+    variable path
+    variable _bmp
+    variable _types
+
+    set path [list "." [file join $::BWIDGET::LIBRARY images]]
+    set supp [image types]
+    foreach {type ext} $_types {
+        if { [lsearch $supp $type] != -1} {
+            set _bmp($ext) $type
+        }
+    }
+}
+
+
+Bitmap::_init

data/tcl/BWidget-1.8.0/button.tcl

@@ -0,0 +1,324 @@
+# ----------------------------------------------------------------------------
+#  button.tcl
+#  This file is part of Unifix BWidget Toolkit
+# ----------------------------------------------------------------------------
+#  Index of commands:
+#   Public commands
+#     - Button::create
+#     - Button::configure
+#     - Button::cget
+#     - Button::invoke
+#   Private commands (event bindings)
+#     - Button::_destroy
+#     - Button::_enter
+#     - Button::_leave
+#     - Button::_press
+#     - Button::_release
+#     - Button::_repeat
+# ----------------------------------------------------------------------------
+
+namespace eval Button {
+    Widget::define Button button DynamicHelp
+
+    set remove [list -command -relief -text -textvariable -underline -state]
+    if {[info tclversion] > 8.3} {
+	lappend remove -repeatdelay -repeatinterval
+    }
+    Widget::tkinclude Button button :cmd remove $remove
+
+    Widget::declare Button {
+        {-name            String "" 0}
+        {-text            String "" 0}
+        {-textvariable    String "" 0}
+        {-underline       Int    -1 0 "%d >= -1"}
+        {-armcommand      String "" 0}
+        {-disarmcommand   String "" 0}
+        {-command         String "" 0}
+        {-state           TkResource "" 0 button}
+        {-repeatdelay     Int    0  0 "%d >= 0"}
+        {-repeatinterval  Int    0  0 "%d >= 0"}
+        {-relief          Enum   raised  0 {raised sunken flat ridge solid groove link}}
+    }
+
+    DynamicHelp::include Button balloon
+
+    Widget::syncoptions Button "" :cmd {-text {} -underline {}}
+
+    variable _current ""
+    variable _pressed ""
+
+    bind BwButton <Enter>           {Button::_enter %W}
+    bind BwButton <Leave>           {Button::_leave %W}
+    bind BwButton <ButtonPress-1>   {Button::_press %W}
+    bind BwButton <ButtonRelease-1> {Button::_release %W}
+    bind BwButton <Key-space>       {Button::invoke %W; break}
+    bind BwButton <Return>          {Button::invoke %W; break}
+    bind BwButton <Destroy>         {Widget::destroy %W}
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Button::create
+# ----------------------------------------------------------------------------
+proc Button::create { path args } {
+    array set maps [list Button {} :cmd {}]
+    array set maps [Widget::parseArgs Button $args]
+    eval [concat [list button $path] $maps(:cmd)]
+    Widget::initFromODB Button $path $maps(Button)
+
+    # Do some extra configuration on the button
+    set relief [Widget::getMegawidgetOption $path -relief]
+    if { [string equal $relief "link"] } {
+        set relief "flat"
+    }
+    set var [Widget::getMegawidgetOption $path -textvariable]
+    set st [Widget::getMegawidgetOption $path -state]
+    if {  ![string length $var] } {
+        set desc [BWidget::getname [Widget::getMegawidgetOption $path -name]]
+        if { [llength $desc] } {
+            set text  [lindex $desc 0]
+            set under [lindex $desc 1]
+            Widget::configure $path [list -text $text]
+            Widget::configure $path [list -underline $under]
+        } else {
+            set text  [Widget::getMegawidgetOption $path -text]
+            set under [Widget::getMegawidgetOption $path -underline]
+        }
+    } else {
+        set under -1
+        set text  ""
+        Widget::configure $path [list -underline $under]
+    }
+
+    $path configure -relief $relief -text $text -underline $under \
+	    -textvariable $var -state $st
+    bindtags $path [list $path BwButton [winfo toplevel $path] all]
+
+    set accel1 [string tolower [string index $text $under]]
+    set accel2 [string toupper $accel1]
+    if { $accel1 != "" } {
+        bind [winfo toplevel $path] <Alt-$accel1> [list Button::invoke $path]
+        bind [winfo toplevel $path] <Alt-$accel2> [list Button::invoke $path]
+    }
+
+    DynamicHelp::sethelp $path $path 1
+
+    return [Widget::create Button $path]
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Button::configure
+# ----------------------------------------------------------------------------
+proc Button::configure { path args } {
+    set oldunder [$path:cmd cget -underline]
+    if { $oldunder != -1 } {
+        set oldaccel1 [string tolower [string index [$path:cmd cget -text] $oldunder]]
+        set oldaccel2 [string toupper $oldaccel1]
+    } else {
+        set oldaccel1 ""
+        set oldaccel2 ""
+    }
+    set res [Widget::configure $path $args]
+
+    # Extract all the modified bits we're interested in
+    foreach {cr cs cv cn ct cu} [Widget::hasChangedX $path \
+	    -relief -state -textvariable -name -text -underline] break
+    if { $cr || $cs } {
+	set relief [Widget::cget $path -relief]
+	set state  [Widget::cget $path -state]
+        if { [string equal $relief "link"] } {
+            if { [string equal $state "active"] } {
+                set relief "raised"
+            } else {
+                set relief "flat"
+            }
+        }
+        $path:cmd configure -relief $relief -state $state
+    }
+
+    if { $cv || $cn || $ct || $cu } {
+	set var		[Widget::cget $path -textvariable]
+	set text	[Widget::cget $path -text]
+	set under	[Widget::cget $path -underline]
+        if {  ![string length $var] } {
+            set desc [BWidget::getname [Widget::cget $path -name]]
+            if { [llength $desc] } {
+                set text  [lindex $desc 0]
+                set under [lindex $desc 1]
+            }
+        } else {
+            set under -1
+            set text  ""
+        }
+        set top [winfo toplevel $path]
+        if { $oldaccel1 != "" } {
+            bind $top <Alt-$oldaccel1> {}
+            bind $top <Alt-$oldaccel2> {}
+        }
+        set accel1 [string tolower [string index $text $under]]
+        set accel2 [string toupper $accel1]
+        if { $accel1 != "" } {
+            bind $top <Alt-$accel1> [list Button::invoke $path]
+            bind $top <Alt-$accel2> [list Button::invoke $path]
+        }
+        $path:cmd configure -text $text -underline $under -textvariable $var
+    }
+    DynamicHelp::sethelp $path $path
+
+    set res
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Button::cget
+# ----------------------------------------------------------------------------
+proc Button::cget { path option } {
+    Widget::cget $path $option
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Button::invoke
+# ----------------------------------------------------------------------------
+proc Button::invoke { path } {
+    if { ![string equal [$path:cmd cget -state] "disabled"] } {
+	$path:cmd configure -state active -relief sunken
+	update idletasks
+	set cmd [Widget::getMegawidgetOption $path -armcommand]
+        if { $cmd != "" } {
+            uplevel \#0 $cmd
+        }
+	after 100
+        set relief [Widget::getMegawidgetOption $path -relief]
+        if { [string equal $relief "link"] } {
+            set relief flat
+        }
+	$path:cmd configure \
+            -state  [Widget::getMegawidgetOption $path -state] \
+            -relief $relief
+	set cmd [Widget::getMegawidgetOption $path -disarmcommand]
+        if { $cmd != "" } {
+            uplevel \#0 $cmd
+        }
+	set cmd [Widget::getMegawidgetOption $path -command]
+        if { $cmd != "" } {
+            uplevel \#0 $cmd
+        }
+    }
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Button::_enter
+# ----------------------------------------------------------------------------
+proc Button::_enter { path } {
+    variable _current
+    variable _pressed
+
+    set _current $path
+    if { ![string equal [$path:cmd cget -state] "disabled"] } {
+        $path:cmd configure -state active
+        if { $_pressed == $path } {
+            $path:cmd configure -relief sunken
+        } elseif { [string equal [Widget::cget $path -relief] "link"] } {
+            $path:cmd configure -relief raised
+        }
+    }
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Button::_leave
+# ----------------------------------------------------------------------------
+proc Button::_leave { path } {
+    variable _current
+    variable _pressed
+
+    set _current ""
+    if { ![string equal [$path:cmd cget -state] "disabled"] } {
+        $path:cmd configure -state [Widget::cget $path -state]
+        set relief [Widget::cget $path -relief]
+        if { $_pressed == $path } {
+            if { [string equal $relief "link"] } {
+                set relief raised
+            }
+            $path:cmd configure -relief $relief
+        } elseif { [string equal $relief "link"] } {
+            $path:cmd configure -relief flat
+        }
+    }
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Button::_press
+# ----------------------------------------------------------------------------
+proc Button::_press { path } {
+    variable _pressed
+
+    if { ![string equal [$path:cmd cget -state] "disabled"] } {
+        set _pressed $path
+	$path:cmd configure -relief sunken
+	set cmd [Widget::getMegawidgetOption $path -armcommand]
+        if { $cmd != "" } {
+            uplevel \#0 $cmd
+	    set repeatdelay [Widget::getMegawidgetOption $path -repeatdelay]
+	    set repeatint [Widget::getMegawidgetOption $path -repeatinterval]
+            if { $repeatdelay > 0 } {
+                after $repeatdelay "Button::_repeat $path"
+            } elseif { $repeatint > 0 } {
+                after $repeatint "Button::_repeat $path"
+	    }
+        }
+    }
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Button::_release
+# ----------------------------------------------------------------------------
+proc Button::_release { path } {
+    variable _current
+    variable _pressed
+
+    if { $_pressed == $path } {
+        set _pressed ""
+        set relief [Widget::getMegawidgetOption $path -relief]
+	after cancel "Button::_repeat $path"
+        if { [string equal $relief "link"] } {
+            set relief raised
+        }
+        $path:cmd configure -relief $relief
+	set cmd [Widget::getMegawidgetOption $path -disarmcommand]
+        if { $cmd != "" } {
+            uplevel \#0 $cmd
+        }
+        if { $_current == $path &&
+             ![string equal [$path:cmd cget -state] "disabled"] && \
+	     [set cmd [Widget::getMegawidgetOption $path -command]] != "" } {
+            uplevel \#0 $cmd
+        }
+    }
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command Button::_repeat
+# ----------------------------------------------------------------------------
+proc Button::_repeat { path } {
+    variable _current
+    variable _pressed
+
+    if { $_current == $path && $_pressed == $path &&
+         ![string equal [$path:cmd cget -state] "disabled"] &&
+         [set cmd [Widget::getMegawidgetOption $path -armcommand]] != "" } {
+        uplevel \#0 $cmd
+    }
+    if { $_pressed == $path &&
+         ([set delay [Widget::getMegawidgetOption $path -repeatinterval]] >0 ||
+          [set delay [Widget::getMegawidgetOption $path -repeatdelay]] > 0) } {
+        after $delay "Button::_repeat $path"
+    }
+}
+

data/tcl/BWidget-1.8.0/buttonbox.tcl

@@ -0,0 +1,403 @@
+# ----------------------------------------------------------------------------
+#  buttonbox.tcl
+#  This file is part of Unifix BWidget Toolkit
+# ----------------------------------------------------------------------------
+#  Index of commands:
+#     - ButtonBox::create
+#     - ButtonBox::configure
+#     - ButtonBox::cget
+#     - ButtonBox::add
+#     - ButtonBox::itemconfigure
+#     - ButtonBox::itemcget
+#     - ButtonBox::setfocus
+#     - ButtonBox::invoke
+#     - ButtonBox::index
+#     - ButtonBox::_destroy
+# ----------------------------------------------------------------------------
+
+namespace eval ButtonBox {
+    Widget::define ButtonBox buttonbox Button
+
+    Widget::declare ButtonBox {
+	{-background  TkResource ""	    0 frame}
+	{-orient      Enum	 horizontal 1 {horizontal vertical}}
+	{-state	      Enum	 "normal"   0 {normal disabled}}
+	{-homogeneous Boolean	 1	    1}
+	{-spacing     Int	 10	    0 "%d >= 0"}
+	{-padx	      TkResource ""	    0 button}
+	{-pady	      TkResource ""	    0 button}
+	{-default     Int	 -1	    0 "%d >= -1"}
+	{-bg	      Synonym	 -background}
+    }
+
+    Widget::addmap ButtonBox "" :cmd {-background {}}
+
+    bind ButtonBox <Destroy> [list ButtonBox::_destroy %W]
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::create
+# ----------------------------------------------------------------------------
+proc ButtonBox::create { path args } {
+    Widget::init ButtonBox $path $args
+
+    variable $path
+    upvar 0  $path data
+
+    eval [list frame $path] [Widget::subcget $path :cmd] \
+	[list -class ButtonBox -takefocus 0 -highlightthickness 0]
+    # For 8.4+ we don't want to inherit the padding
+    catch {$path configure -padx 0 -pady 0}
+
+    set data(max)      0
+    set data(nbuttons) 0
+    set data(buttons)  [list]
+    set data(default)  [Widget::getoption $path -default]
+
+    return [Widget::create ButtonBox $path]
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::configure
+# ----------------------------------------------------------------------------
+proc ButtonBox::configure { path args } {
+    variable $path
+    upvar 0  $path data
+
+    set res [Widget::configure $path $args]
+
+    if { [Widget::hasChanged $path -default val] } {
+        if { $data(default) != -1 && $val != -1 } {
+            set but $path.b$data(default)
+            if { [winfo exists $but] } {
+                $but configure -default normal
+            }
+            set but $path.b$val
+            if { [winfo exists $but] } {
+                $but configure -default active
+            }
+            set data(default) $val
+        } else {
+            Widget::setoption $path -default $data(default)
+        }
+    }
+
+    if {[Widget::hasChanged $path -state val]} {
+	foreach i $data(buttons) {
+	    $path.b$i configure -state $val
+	}
+    }
+
+    return $res
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::cget
+# ----------------------------------------------------------------------------
+proc ButtonBox::cget { path option } {
+    return [Widget::cget $path $option]
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::add
+# ----------------------------------------------------------------------------
+proc ButtonBox::add { path args } {
+    return [eval [linsert $args 0 insert $path end]]
+}
+
+
+proc ButtonBox::insert { path idx args } {
+    variable $path
+    upvar 0  $path data
+
+    set but     $path.b$data(nbuttons)
+    set spacing [Widget::getoption $path -spacing]
+
+    ## Save the current spacing setting for this button.  Buttons
+    ## appended to the end of the box have their spacing applied
+    ## to their left while all other have their spacing applied
+    ## to their right.
+    if {$idx == "end"} {
+	set data(spacing,$data(nbuttons)) [list left $spacing]
+	lappend data(buttons) $data(nbuttons)
+    } else {
+	set data(spacing,$data(nbuttons)) [list right $spacing]
+        set data(buttons) [linsert $data(buttons) $idx $data(nbuttons)]
+    }
+
+    if { $data(nbuttons) == $data(default) } {
+        set style active
+    } elseif { $data(default) == -1 } {
+        set style disabled
+    } else {
+        set style normal
+    }
+
+    array set flags $args
+    set tags ""
+    if { [info exists flags(-tags)] } {
+	set tags $flags(-tags)
+	unset flags(-tags)
+	set args [array get flags]
+    }
+
+    eval [list Button::create $but \
+	      -background [Widget::getoption $path -background]\
+	      -padx       [Widget::getoption $path -padx] \
+	      -pady       [Widget::getoption $path -pady]] \
+        $args [list -default $style]
+
+    # ericm@scriptics.com:  set up tags, just like the menu items
+    foreach tag $tags {
+	lappend data(tags,$tag) $but
+	if { ![info exists data(tagstate,$tag)] } {
+	    set data(tagstate,$tag) 0
+	}
+    }
+    set data(buttontags,$but) $tags
+    # ericm@scriptics.com
+
+    _redraw $path
+
+    incr data(nbuttons)
+
+    return $but
+}
+
+
+proc ButtonBox::delete { path idx } {
+    variable $path
+    upvar 0  $path data
+
+    set i [lindex $data(buttons) $idx]
+    set data(buttons) [lreplace $data(buttons) $idx $idx]
+    destroy $path.b$i
+}
+
+
+# ButtonBox::setbuttonstate --
+#
+#	Set the state of a given button tag.  If this makes any buttons
+#       enable-able (ie, all of their tags are TRUE), enable them.
+#
+# Arguments:
+#	path        the button box widget name
+#	tag         the tag to modify
+#	state       the new state of $tag (0 or 1)
+#
+# Results:
+#	None.
+
+proc ButtonBox::setbuttonstate {path tag state} {
+    variable $path
+    upvar 0  $path data
+    # First see if this is a real tag
+    if { [info exists data(tagstate,$tag)] } {
+	set data(tagstate,$tag) $state
+	foreach but $data(tags,$tag) {
+	    set expression "1"
+	    foreach buttontag $data(buttontags,$but) {
+		append expression " && $data(tagstate,$buttontag)"
+	    }
+	    if { [expr $expression] } {
+		set state normal
+	    } else {
+		set state disabled
+	    }
+	    $but configure -state $state
+	}
+    }
+    return
+}
+
+# ButtonBox::getbuttonstate --
+#
+#	Retrieve the state of a given button tag.
+#
+# Arguments:
+#	path        the button box widget name
+#	tag         the tag to modify
+#
+# Results:
+#	None.
+
+proc ButtonBox::getbuttonstate {path tag} {
+    variable $path
+    upvar 0  $path data
+    # First see if this is a real tag
+    if { [info exists data(tagstate,$tag)] } {
+	return $data(tagstate,$tag)
+    } else {
+	error "unknown tag $tag"
+    }
+}
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::itemconfigure
+# ----------------------------------------------------------------------------
+proc ButtonBox::itemconfigure { path index args } {
+    if { [set idx [lsearch $args -default]] != -1 } {
+        set args [lreplace $args $idx [expr {$idx+1}]]
+    }
+    return [eval [list Button::configure $path.b[index $path $index]] $args]
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::itemcget
+# ----------------------------------------------------------------------------
+proc ButtonBox::itemcget { path index option } {
+    return [Button::cget $path.b[index $path $index] $option]
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::setfocus
+# ----------------------------------------------------------------------------
+proc ButtonBox::setfocus { path index } {
+    set but $path.b[index $path $index]
+    if { [winfo exists $but] } {
+        focus $but
+    }
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::invoke
+# ----------------------------------------------------------------------------
+proc ButtonBox::invoke { path index } {
+    set but $path.b[index $path $index]
+    if { [winfo exists $but] } {
+        Button::invoke $but
+    }
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::index
+# ----------------------------------------------------------------------------
+proc ButtonBox::index { path index } {
+    variable $path
+    upvar 0  $path data
+
+    set n [expr {$data(nbuttons) - 1}]
+
+    if {[string equal $index "default"]} {
+        set res [Widget::getoption $path -default]
+    } elseif {$index == "end" || $index == "last"} {
+	set res $n
+    } elseif {![string is integer -strict $index]} {
+	## It's not an integer.  Search the text of each button
+	## in the box and return the index that matches.
+	foreach i $data(buttons) {
+	    set w $path.b$i
+	    lappend text  [$w cget -text]
+	    lappend names [$w cget -name]
+	}
+	set res [lsearch -exact [concat $names $text] $index]
+    } else {
+        set res $index
+	if {$index > $n} { set res $n }
+    }
+    return $res
+}
+
+
+# ButtonBox::gettags --
+#
+#	Return a list of all the tags on all the buttons in a buttonbox.
+#
+# Arguments:
+#	path      the buttonbox to query.
+#
+# Results:
+#	taglist   a list of tags on the buttons in the buttonbox
+
+proc ButtonBox::gettags {path} {
+    upvar ::ButtonBox::$path data
+    set taglist {}
+    foreach tag [array names data "tags,*"] {
+	lappend taglist [string range $tag 5 end]
+    }
+    return $taglist
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::_redraw
+# ----------------------------------------------------------------------------
+proc ButtonBox::_redraw { path } {
+    variable $path
+    upvar 0  $path data
+    Widget::getVariable $path buttons
+
+    ## We re-grid the buttons from left-to-right.  As we go through
+    ## each button, we check its spacing and which direction the
+    ## spacing applies to.  Once spacing has been applied to an index,
+    ## it is not changed.  This means spacing takes precedence from
+    ## left-to-right.
+
+    set idx  0
+    set idxs [list]
+    foreach i $data(buttons) {
+	set dir     [lindex $data(spacing,$i) 0]
+	set spacing [lindex $data(spacing,$i) 1]
+        set but $path.b$i
+        if {[string equal [Widget::getoption $path -orient] "horizontal"]} {
+            grid $but -column $idx -row 0 -sticky nsew
+            if { [Widget::getoption $path -homogeneous] } {
+                set req [winfo reqwidth $but]
+                if { $req > $data(max) } {
+                    grid columnconfigure $path [expr {2*$i}] -minsize $req
+                    set data(max) $req
+                }
+                grid columnconfigure $path $idx -weight 1
+            } else {
+                grid columnconfigure $path $idx -weight 0
+            }
+
+	    set col [expr {$idx - 1}]
+	    if {[string equal $dir "right"]} { set col [expr {$idx + 1}] }
+	    if {$col > 0 && [lsearch $idxs $col] < 0} {
+		lappend idxs $col
+		grid columnconfigure $path $col -minsize $spacing
+	    }
+        } else {
+            grid $but -column 0 -row $idx -sticky nsew
+            grid rowconfigure $path $idx -weight 0
+
+	    set row [expr {$idx - 1}]
+	    if {[string equal $dir "right"]} { set row [expr {$idx + 1}] }
+	    if {$row > 0 && [lsearch $idxs $row] < 0} {
+		lappend idxs $row
+		grid rowconfigure $path $row -minsize $spacing
+	    }
+        }
+        incr idx 2
+    }
+
+    # Now that the maximum size has been calculated, go back through
+    # and correctly set the size for homogeneous horizontal buttons.
+    if { [string equal [Widget::getoption $path -orient] "horizontal"] && [Widget::getoption $path -homogeneous] } {
+        set idx 0
+        foreach i $data(buttons) {
+            grid columnconfigure $path $idx -minsize $data(max)
+            incr idx 2
+        }
+    }
+}
+
+
+# ----------------------------------------------------------------------------
+#  Command ButtonBox::_destroy
+# ----------------------------------------------------------------------------
+proc ButtonBox::_destroy { path } {
+    variable $path
+    upvar 0  $path data
+    Widget::destroy $path
+    unset data
+}