agt 0.0.1

data/app/assets/javascripts/agt/widgets/widgets.coffee

@@ -0,0 +1,194 @@
+namespace('agt.widgets')
+
+#
+__widgets__ = {}
+
+# The `__instances__` object stores the returned instances of the various widgets,
+# stored by widget type and then mapped with their target DOM element as key.
+__instances__ = {}
+
+__subscriptions__ = {}
+
+### Public ###
+
+# The `widgets` function is both the main module and the function
+# used to register the widgets to apply on a page.
+widgets = agt.widgets = (name, selector, options={}, block) ->
+  unless __widgets__[name]?
+    throw new Error "Unable to find widget '#{name}'"
+
+  # The options specific to the widget registration and activation are
+  # extracted from the options object.
+  events = options.on or 'init'
+  ifCondition = options.if
+  unlessCondition = options.unless
+  mediaCondition = options.media
+
+  delete options.on
+  delete options.if
+  delete options.unless
+  delete options.media
+
+  # Events can be passed as a string with event names separated with spaces.
+  events = events.split /\s+/g if typeof events is 'string'
+
+  # The widgets instances are stored in a Hash with the DOM element they
+  # target as key. The instances hashes are stored per widget type.
+  instances = __instances__[name] ||= new agt.widgets.Hash
+
+  # This method execute a test condition for the given element. The condition
+  # can be either a function or a value converted to boolean.
+  testCondition = (condition, element) ->
+    if typeof condition is 'function' then condition(element) else !!condition
+
+  # The DOM elements handled by a widget will receive a handled class
+  # to differenciate them from unhandled elements.
+  handledClass = "#{name}-handled"
+
+  # This method will test if an element can be handled by the current widget.
+  # It will test for both the handled class presence and the widget
+  # conditions. Note that if both the `if` and `unless` conditions
+  # are passed in the options object they will be tested as both part
+  # of a single `&&` condition.
+  canBeHandled = (element) ->
+    res = !element.classList.contains(handledClass)
+    res &&= testCondition(ifCondition, element) if ifCondition?
+    res &&= not testCondition(unlessCondition, element) if unlessCondition?
+    res
+
+  # If a media condition have been specified, the widget activation will be
+  # conditionned based on the result of this condition. The condition is
+  # verified each time the `resize` event is triggered.
+  if mediaCondition?
+    # The media condition can be either a boolean value, a function, or,
+    # to simply the setup, an object with `min` and `max` property containing
+    # the minimal and maximal window width where the widget is activated.
+    if typeof mediaCondition is 'object'
+      {min, max} = mediaCondition
+      mediaCondition = ->
+        res = true
+        res &&= window.innerWidth >= min if min?
+        res &&= window.innerWidth <= max if max?
+        res
+
+    # The media handler is registered on the `resize` event of the `window`
+    # object.
+    mediaHandler = (element, widget) ->
+      return unless widget?
+
+      condition_matched = testCondition(mediaCondition, element)
+
+      if condition_matched and not widget.active
+        widget.activate()
+      else if not condition_matched and widget.active
+        widget.deactivate()
+
+    window.addEventListener 'resize', ->
+      instances.eachPair (element, widget) ->
+        mediaHandler element, widget
+
+  # The `handler` function is the function registered on specified event and
+  # will proceed to the creation of the widgets if the conditions are met.
+  handler = ->
+    elements = document.querySelectorAll selector
+
+    Array::forEach.call elements, (element) ->
+      return unless canBeHandled element
+
+      widget = new agt.widgets.Widget(element)
+      args = [widget, element, Object.create(options), elements]
+      __widgets__[name].call(args...)
+      element.classList.add handledClass
+      instances.set element, widget
+
+      # The widgets activation state are resolved at creation
+      if mediaCondition?
+        mediaHandler(element, widget)
+      else
+        widget.activate()
+
+      document.dispatchEvent agt.domEvent("#{name}:handled", {element, widget})
+
+      block?.call element, element, widget
+
+  # For each event specified, the handler is registered as listener.
+  # A special case is the `init` event that simply mean to trigger the
+  # handler as soon a the function is called.
+  events.forEach (event) ->
+    switch event
+      when 'init' then handler()
+      when 'load', 'resize'
+        widgets.subscribe name, window, event, handler
+      else
+        widgets.subscribe name, document, event, handler
+
+# The `widgets.define` is used to create a new widget usable through the
+# `widgets` method. Basically, a widget is defined using a `name`, and a
+# `block` function that will be called for each DOM elements targeted by
+# the widget.
+#
+# The `block` function should have the following signature:
+#
+#     function(element:HTMLElement, options:Object):Object
+#
+# The `options` object will contains all the options passed to the `widgets`
+# method except the `on`, `if`, `unless` and `media` ones.
+widgets.define = (name, block) -> __widgets__[name] = block
+
+# A shorthand method to register a jQuery widget.
+widgets.$define = (name, baseOptions={}, block) ->
+  [baseOptions, block] = [{}, baseOptions] if typeof baseOptions is 'function'
+  throw new Error "#{name} jquery widget isn't defined" unless $.fn[name]
+  __widgets__[name] = (element, options={}) ->
+    options[k] = v for k,v of baseOptions when not options[k]?
+    res = $(element)[name](options)
+    block?(res, options)
+
+widgets.delete = (name) ->
+  __subscriptions__[name]?.forEach (subscription) -> subscription.off()
+  widgets.release(name)
+  delete __widgets__[name]
+
+widgets.reset = (names...) ->
+  names = Object.keys(__instances__) if names.length is 0
+  widgets.delete(name) for name in names
+
+widgets.widgetsFor = (element, widget) ->
+  if widget?
+    __instances__[widget].get(element)
+  else
+    instances.get(element) for instances in __instances__ when instances.hasKey(element)
+
+widgets.subscribe = (name, to, evt, handler) ->
+  __subscriptions__[name] ||= []
+  to.addEventListener(evt, handler)
+  subscription = off: -> to.removeEventListener(evt, handler)
+  __subscriptions__[name].push subscription
+  subscription
+
+# The `widgets.release` method can be used to completely remove the widgets
+# of the given `name` from the page.
+# It's the widget responsibility to clean up its dependencies during
+# the `dispose` call.
+widgets.release = (names...) ->
+  names = Object.keys(__instances__) if names.length is 0
+  for name in names
+    __instances__[name].each (value) -> value.dispose()
+
+# Activates all the widgets instances of type `name`.
+widgets.activate = (names...) ->
+  names = Object.keys(__instances__) if names.length is 0
+  for name in names
+    __instances__[name].each (value) -> value.activate()
+
+# Deactivates all the widgets instances of type `name`.
+widgets.deactivate = (names...) ->
+  names = Object.keys(__instances__) if names.length is 0
+  for name in names
+    __instances__[name].each (value) -> value.deactivate()
+
+class agt.widgets.Widget
+  @include agt.mixins.Activable
+  @include agt.mixins.Disposable
+
+  constructor: (@element) ->

data/app/assets/javascripts/agt/widgets/widgets/checked_input.coffee

@@ -0,0 +1,7 @@
+# Public: Decorates an input that support the `checked` property with
+# a `checked` class whenever its property is `true`. It allows to have
+# css rules on checked input on IE versions that doesn't support
+# the `:checked` selector.
+agt.widgets.define 'checked_input', (element) ->
+  element.addEventListener 'change', ->
+    element.classList.toggle 'checked', element.checked

data/app/assets/javascripts/agt/widgets/widgets/focus_bubbling.coffee

@@ -0,0 +1,15 @@
+# Public: This widgets decorates all the dom path until the current
+# element with a `focus` class when the element have the focus.
+agt.widgets.define 'bubbling_focus', (element) ->
+  blur = ->
+    Array::forEach.call document.querySelectorAll('.focus'), (el) ->
+      el.classList.remove('.focus')
+
+  element.addEventListener 'blur', -> blur()
+  element.addEventListener 'focus', ->
+    blur()
+    node = element
+    node.classList.add('focus')
+    while node.nodeName.toLowerCase() isnt 'html'
+      node = node.parentNode
+      node.classList.add('focus')

data/lib/agt.rb

@@ -0,0 +1,8 @@
+require "agt/version"
+
+module Agt  
+  module Rails
+    class Engine < ::Rails::Engine
+    end
+  end
+end

data/lib/agt/version.rb

@@ -0,0 +1,5 @@
+module Agt
+  module Rails
+    VERSION = "0.0.1"
+  end
+end

metadata

@@ -0,0 +1,173 @@
+--- !ruby/object:Gem::Specification
+name: agt
+version: !ruby/object:Gem::Version
+  version: 0.0.1
+platform: ruby
+authors:
+- Cédric Néhémie
+autorequire: 
+bindir: bin
+cert_chain: []
+date: 2014-08-19 00:00:00.000000000 Z
+dependencies:
+- !ruby/object:Gem::Dependency
+  name: bundler
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - ~>
+      - !ruby/object:Gem::Version
+        version: '1.6'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - ~>
+      - !ruby/object:Gem::Version
+        version: '1.6'
+- !ruby/object:Gem::Dependency
+  name: rake
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - ~>
+      - !ruby/object:Gem::Version
+        version: '10.0'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - ~>
+      - !ruby/object:Gem::Version
+        version: '10.0'
+description: Some game tools
+email:
+- cedric.nehemie@gmail.com
+executables: []
+extensions: []
+extra_rdoc_files: []
+files:
+- lib/agt/version.rb
+- lib/agt.rb
+- app/assets/javascripts/agt/config.coffee
+- app/assets/javascripts/agt/dom.coffee
+- app/assets/javascripts/agt/function.coffee
+- app/assets/javascripts/agt/geom/circle.coffee
+- app/assets/javascripts/agt/geom/cubic_bezier.coffee
+- app/assets/javascripts/agt/geom/diamond.coffee
+- app/assets/javascripts/agt/geom/ellipsis.coffee
+- app/assets/javascripts/agt/geom/linear_spline.coffee
+- app/assets/javascripts/agt/geom/matrix.coffee
+- app/assets/javascripts/agt/geom/mixins/geometry.coffee
+- app/assets/javascripts/agt/geom/mixins/intersections.coffee
+- app/assets/javascripts/agt/geom/mixins/path.coffee
+- app/assets/javascripts/agt/geom/mixins/proxyable.coffee
+- app/assets/javascripts/agt/geom/mixins/spline.coffee
+- app/assets/javascripts/agt/geom/mixins/surface.coffee
+- app/assets/javascripts/agt/geom/mixins/triangulable.coffee
+- app/assets/javascripts/agt/geom/point.coffee
+- app/assets/javascripts/agt/geom/polygon.coffee
+- app/assets/javascripts/agt/geom/quad_bezier.coffee
+- app/assets/javascripts/agt/geom/quint_bezier.coffee
+- app/assets/javascripts/agt/geom/rectangle.coffee
+- app/assets/javascripts/agt/geom/spiral.coffee
+- app/assets/javascripts/agt/geom/transformation_proxy.coffee
+- app/assets/javascripts/agt/geom/triangle.coffee
+- app/assets/javascripts/agt/impulse.coffee
+- app/assets/javascripts/agt/index.coffee
+- app/assets/javascripts/agt/inflector/inflection.coffee
+- app/assets/javascripts/agt/inflector/inflections.coffee
+- app/assets/javascripts/agt/inflector/inflector.coffee
+- app/assets/javascripts/agt/inheritance.coffee
+- app/assets/javascripts/agt/math.coffee
+- app/assets/javascripts/agt/mixins/activable.coffee
+- app/assets/javascripts/agt/mixins/aliasable.coffee
+- app/assets/javascripts/agt/mixins/alternate_case.coffee
+- app/assets/javascripts/agt/mixins/cloneable.coffee
+- app/assets/javascripts/agt/mixins/delegation.coffee
+- app/assets/javascripts/agt/mixins/disposable.coffee
+- app/assets/javascripts/agt/mixins/equatable.coffee
+- app/assets/javascripts/agt/mixins/formattable.coffee
+- app/assets/javascripts/agt/mixins/globalizable.coffee
+- app/assets/javascripts/agt/mixins/has_ancestors.coffee
+- app/assets/javascripts/agt/mixins/has_collection.coffee
+- app/assets/javascripts/agt/mixins/has_nested_collection.coffee
+- app/assets/javascripts/agt/mixins/memoizable.coffee
+- app/assets/javascripts/agt/mixins/parameterizable.coffee
+- app/assets/javascripts/agt/mixins/poolable.coffee
+- app/assets/javascripts/agt/mixins/sourcable.coffee
+- app/assets/javascripts/agt/mixins/state_machine.coffee
+- app/assets/javascripts/agt/net/router.coffee
+- app/assets/javascripts/agt/object.coffee
+- app/assets/javascripts/agt/particles/actions/base_action.coffee
+- app/assets/javascripts/agt/particles/actions/die_on_surface.coffee
+- app/assets/javascripts/agt/particles/actions/force.coffee
+- app/assets/javascripts/agt/particles/actions/friction.coffee
+- app/assets/javascripts/agt/particles/actions/live.coffee
+- app/assets/javascripts/agt/particles/actions/macro_action.coffee
+- app/assets/javascripts/agt/particles/actions/move.coffee
+- app/assets/javascripts/agt/particles/actions/null_action.coffee
+- app/assets/javascripts/agt/particles/counters/by_rate.coffee
+- app/assets/javascripts/agt/particles/counters/fixed.coffee
+- app/assets/javascripts/agt/particles/counters/null_counter.coffee
+- app/assets/javascripts/agt/particles/emission.coffee
+- app/assets/javascripts/agt/particles/emitters/null_emitter.coffee
+- app/assets/javascripts/agt/particles/emitters/path.coffee
+- app/assets/javascripts/agt/particles/emitters/ponctual.coffee
+- app/assets/javascripts/agt/particles/emitters/surface.coffee
+- app/assets/javascripts/agt/particles/initializers/explosion.coffee
+- app/assets/javascripts/agt/particles/initializers/life.coffee
+- app/assets/javascripts/agt/particles/initializers/macro_initializer.coffee
+- app/assets/javascripts/agt/particles/initializers/null_initializer.coffee
+- app/assets/javascripts/agt/particles/initializers/particle_sub_system.coffee
+- app/assets/javascripts/agt/particles/initializers/stream.coffee
+- app/assets/javascripts/agt/particles/mixins/randomizable.coffee
+- app/assets/javascripts/agt/particles/particle.coffee
+- app/assets/javascripts/agt/particles/sub_system.coffee
+- app/assets/javascripts/agt/particles/system.coffee
+- app/assets/javascripts/agt/particles/timers/instant.coffee
+- app/assets/javascripts/agt/particles/timers/limited.coffee
+- app/assets/javascripts/agt/particles/timers/null_timer.coffee
+- app/assets/javascripts/agt/particles/timers/unlimited.coffee
+- app/assets/javascripts/agt/particles/timers/until_death.coffee
+- app/assets/javascripts/agt/promise.coffee
+- app/assets/javascripts/agt/random/random.coffee
+- app/assets/javascripts/agt/random/seeds/lagged_fibonnacci.coffee
+- app/assets/javascripts/agt/random/seeds/linear.coffee
+- app/assets/javascripts/agt/random/seeds/linear_congruential.coffee
+- app/assets/javascripts/agt/random/seeds/math_random.coffee
+- app/assets/javascripts/agt/random/seeds/mersenne_twister.coffee
+- app/assets/javascripts/agt/random/seeds/no_random.coffee
+- app/assets/javascripts/agt/random/seeds/paul_houle.coffee
+- app/assets/javascripts/agt/signal.coffee
+- app/assets/javascripts/agt/sprites/animation.coffee
+- app/assets/javascripts/agt/sprites/sprite.coffee
+- app/assets/javascripts/agt/widgets/hash.coffee
+- app/assets/javascripts/agt/widgets/widgets/checked_input.coffee
+- app/assets/javascripts/agt/widgets/widgets/focus_bubbling.coffee
+- app/assets/javascripts/agt/widgets/widgets.coffee
+- LICENSE.md
+- README.md
+homepage: https://github.com/abe33/agt.git
+licenses:
+- MIT
+metadata: {}
+post_install_message: 
+rdoc_options: []
+require_paths:
+- lib
+required_ruby_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+required_rubygems_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+requirements: []
+rubyforge_project: 
+rubygems_version: 2.0.3
+signing_key: 
+specification_version: 4
+summary: Some game tools
+test_files: []