agt 0.0.1

data/app/assets/javascripts/agt/object.coffee

@@ -0,0 +1,9 @@
+unless Object.getPropertyDescriptor?
+  if Object.getPrototypeOf? and Object.getOwnPropertyDescriptor?
+    Object.getPropertyDescriptor = (o, name) ->
+      proto = o
+      descriptor = undefined
+      proto = Object.getPrototypeOf?(proto) or proto.__proto__ while proto and not (descriptor = Object.getOwnPropertyDescriptor(proto, name))
+      descriptor
+  else
+    Object.getPropertyDescriptor = -> undefined

data/app/assets/javascripts/agt/particles/actions/base_action.coffee

@@ -0,0 +1,7 @@
+namespace('agt.particles.actions')
+# Public:
+class agt.particles.actions.BaseAction
+
+  ### Public ###
+
+  prepare: (@bias, @biasInSeconds, @time) ->

data/app/assets/javascripts/agt/particles/actions/die_on_surface.coffee

@@ -0,0 +1,14 @@
+namespace('agt.particles.actions')
+# Public:
+class agt.particles.actions.DieOnSurface
+
+  ### Public ###
+
+  constructor: (@surfaces) ->
+    if Object::toString.call(@surface).indexOf('Array') is -1
+      @surfaces = [@surfaces]
+
+  prepare: ->
+
+  process: (p) ->
+    return p.die() for surface in @surfaces when surface.contains p.position

data/app/assets/javascripts/agt/particles/actions/force.coffee

@@ -0,0 +1,11 @@
+namespace('agt.particles.actions')
+# Public:
+class agt.particles.actions.Force extends agt.particles.actions.BaseAction
+
+  ### Public ###
+
+  constructor: (@vector=new agt.geom.Point) ->
+
+  process: (particle) ->
+    particle.velocity.x += @vector.x * @biasInSeconds
+    particle.velocity.y += @vector.y * @biasInSeconds

data/app/assets/javascripts/agt/particles/actions/friction.coffee

@@ -0,0 +1,14 @@
+namespace('agt.particles.actions')
+# Public:
+class agt.particles.actions.Friction extends agt.particles.actions.BaseAction
+
+  ### Public ###
+
+  constructor: (@amount=1) ->
+
+  process: (particle) ->
+    fx = particle.velocity.x * @biasInSeconds * @amount
+    fy = particle.velocity.y * @biasInSeconds * @amount
+
+    particle.velocity.x -= fx
+    particle.velocity.y -= fy

data/app/assets/javascripts/agt/particles/actions/live.coffee

@@ -0,0 +1,9 @@
+namespace('agt.particles.actions')
+# Public:
+class agt.particles.actions.Live extends agt.particles.actions.BaseAction
+
+  ### Public ###
+
+  process: (particle) ->
+    particle.life += @bias
+    particle.die() if particle.life >= particle.maxLife

data/app/assets/javascripts/agt/particles/actions/macro_action.coffee

@@ -0,0 +1,13 @@
+namespace('agt.particles.actions')
+# Public:
+class agt.particles.actions.MacroAction extends agt.particles.actions.BaseAction
+
+  ### Public ###
+
+  constructor: (@actions=[]) ->
+
+  prepare: (bias, biasInSeconds, time) ->
+    action.prepare bias, biasInSeconds, time for action in @actions
+
+  process: (particle) ->
+    action.process particle for action in @actions

data/app/assets/javascripts/agt/particles/actions/move.coffee

@@ -0,0 +1,11 @@
+namespace('agt.particles.actions')
+# Public:
+class agt.particles.actions.Move extends agt.particles.actions.BaseAction
+
+  ### Public ###
+
+  process: (particle) ->
+    particle.lastPosition.x = particle.position.x
+    particle.lastPosition.y = particle.position.y
+    particle.position.x += particle.velocity.x * @biasInSeconds
+    particle.position.y += particle.velocity.y * @biasInSeconds

data/app/assets/javascripts/agt/particles/actions/null_action.coffee

@@ -0,0 +1,9 @@
+namespace('agt.particles.actions')
+# Public:
+class agt.particles.actions.NullAction
+
+  ### Public ###
+
+  prepare: ->
+
+  process: ->

data/app/assets/javascripts/agt/particles/counters/by_rate.coffee

@@ -0,0 +1,17 @@
+namespace('agt.particles.counters')
+# Public:
+class agt.particles.counters.ByRate
+
+  ### Public ###
+
+  constructor: (@rate=1) ->
+    @count = 0
+    @rest = 0
+    @offset = 1
+
+  prepare: (bias, biasInSeconds, time) ->
+    @rest += biasInSeconds * @rate
+    @count = Math.floor(@rest)
+    @rest -= @count
+    @count += @offset
+    @offset = 0

data/app/assets/javascripts/agt/particles/counters/fixed.coffee

@@ -0,0 +1,9 @@
+namespace('agt.particles.counters')
+# Public:
+class agt.particles.counters.Fixed
+
+  ### Public ###
+
+  constructor: (@count=1) ->
+
+  prepare: ->

data/app/assets/javascripts/agt/particles/counters/null_counter.coffee

@@ -0,0 +1,9 @@
+namespace('agt.particles.counters')
+# Public:
+class agt.particles.counters.NullCounter
+
+  ### Public ###
+
+  count: 0
+
+  prepare: ->

data/app/assets/javascripts/agt/particles/emission.coffee

@@ -0,0 +1,35 @@
+namespace('agt.particles')
+
+# Public:
+class agt.particles.Emission
+
+  ### Public ###
+
+  constructor: (@particleType=agt.particles.Particle,
+                @emitter=new agt.particles.timers.NullEmitter(),
+                @timer=new agt.particles.counters.NullTimer(),
+                @counter=new agt.particles.emitters.NullCounter(),
+                @initializer=null) ->
+
+  prepare: (bias, biasInSeconds, time) ->
+    @timer.prepare bias, biasInSeconds, time
+
+    nextTime = @timer.nextTime
+    @counter.prepare nextTime, nextTime / 1000, time
+
+    @currentCount = @counter.count
+    @currentTime = nextTime
+    @iterator = 0
+
+  hasNext: -> @iterator < @currentCount
+
+  next: ->
+    particle = @particleType.get position: @emitter.get()
+    @initializer?.initialize particle
+    @iterator++
+
+    particle
+
+  nextTime: -> @currentTime - @iterator / @currentCount * @currentTime
+
+  finished: -> @timer.finished()

data/app/assets/javascripts/agt/particles/emitters/null_emitter.coffee

@@ -0,0 +1,7 @@
+namespace('agt.particles.emitters')
+# Public:
+class agt.particles.emitters.NullEmitter
+
+  ### Public ###
+
+  get: -> new agt.geom.Point

data/app/assets/javascripts/agt/particles/emitters/path.coffee

@@ -0,0 +1,10 @@
+namespace('agt.particles.emitters')
+# Public:
+class agt.particles.emitters.Path
+  @include agt.particles.Randomizable
+
+  ### Public ###
+
+  constructor: (@path, @random) -> @initRandom()
+
+  get: -> @path.pathPointAt @random.get()

data/app/assets/javascripts/agt/particles/emitters/ponctual.coffee

@@ -0,0 +1,9 @@
+namespace('agt.particles.emitters')
+# Public:
+class agt.particles.emitters.Ponctual
+
+  ### Public ###
+
+  constructor: (@point=new agt.geom.Point) ->
+
+  get: -> @point.clone()

data/app/assets/javascripts/agt/particles/emitters/surface.coffee

@@ -0,0 +1,10 @@
+namespace('agt.particles.emitters')
+# Public:
+class agt.particles.emitters.Surface
+  @include agt.particles.Randomizable
+
+  ### Public ###
+
+  constructor: (@surface, @random) -> @initRandom()
+
+  get: -> @surface.randomPointInSurface @random

data/app/assets/javascripts/agt/particles/initializers/explosion.coffee

@@ -0,0 +1,19 @@
+namespace('agt.particles.initializers')
+# Public:
+class agt.particles.initializers.Explosion
+  @include agt.particles.Randomizable
+
+  ### Public ###
+
+  constructor: (@velocityMin=0,
+                @velocityMax=1,
+                @angleMin=0,
+                @angleMax=Math.PI*2,
+                @random) -> @initRandom()
+
+  initialize: (particle) ->
+    angle = @random.in @angleMin, @angleMax
+    velocity = @random.in @velocityMin, @velocityMax
+
+    particle.velocity.x = Math.cos(angle)*velocity
+    particle.velocity.y = Math.sin(angle)*velocity

data/app/assets/javascripts/agt/particles/initializers/life.coffee

@@ -0,0 +1,16 @@
+namespace('agt.particles.initializers')
+# Public:
+class agt.particles.initializers.Life
+  @include agt.particles.Randomizable
+
+  ### Public ###
+
+  constructor: (@lifeMin, @lifeMax, @random) ->
+    @lifeMax = @lifeMin unless @lifeMax?
+    @initRandom()
+
+  initialize: (particle) ->
+    if @lifeMin is @lifeMax
+      particle.maxLife = @lifeMin
+    else
+      particle.maxLife = @random.in @lifeMin, @lifeMax

data/app/assets/javascripts/agt/particles/initializers/macro_initializer.coffee

@@ -0,0 +1,10 @@
+namespace('agt.particles.initializers')
+# Public:
+class agt.particles.initializers.MacroInitializer
+
+  ### Public ###
+
+  constructor: (@initializers) ->
+
+  initialize: (particle) ->
+    initializer.initialize particle for initializer in @initializers

data/app/assets/javascripts/agt/particles/initializers/null_initializer.coffee

@@ -0,0 +1,7 @@
+namespace('agt.particles.initializers')
+# Public:
+class agt.particles.initializers.NullInitializer
+
+  ### Public ###
+
+  initialize: ->

data/app/assets/javascripts/agt/particles/initializers/particle_sub_system.coffee

@@ -0,0 +1,12 @@
+namespace('agt.particles.initializers')
+# Public:
+class agt.particles.initializers.ParticleSubSystem
+
+  ### Public ###
+
+  constructor: (initializer, action, emissionFactory, subSystem) ->
+    @subSystem = new agt.particles.SubSystem(
+      initializer, action, emissionFactory, subSystem
+    )
+
+  initialize: (particle) -> @subSystem.emitFor particle

data/app/assets/javascripts/agt/particles/initializers/stream.coffee

@@ -0,0 +1,20 @@
+namespace('agt.particles.initializers')
+# Public:
+class agt.particles.initializers.Stream
+  @include agt.particles.Randomizable
+
+  ### Public ###
+
+  constructor: (@direction=new agt.geom.Point(1,1),
+                @velocityMin=0,
+                @velocityMax=1,
+                @angleRandom=0,
+                @random) -> @initRandom()
+
+  initialize: (particle) ->
+    velocity = @random.in @velocityMin, @velocityMax
+    angle = @direction.angle()
+    angle += @random.pad @angleRandom if @angleRandom isnt 0
+
+    particle.velocity.x = Math.cos(angle) * velocity
+    particle.velocity.y = Math.sin(angle) * velocity

data/app/assets/javascripts/agt/particles/mixins/randomizable.coffee

@@ -0,0 +1,10 @@
+namespace('agt.particles')
+
+DEFAULT_RANDOM = new agt.random.Random new agt.random.MathRandom
+
+# Public:
+class agt.particles.Randomizable
+
+  ### Public ###
+
+  initRandom: -> @random ||= DEFAULT_RANDOM

data/app/assets/javascripts/agt/particles/particle.coffee

@@ -0,0 +1,32 @@
+namespace('agt.particles')
+
+# Public:
+class agt.particles.Particle
+  @concern agt.mixins.Poolable
+
+  ### Public ###
+
+  init: (options={}) ->
+    @dead = false
+    @life = 0
+    @maxLife = 0
+    @position = new agt.geom.Point
+    @lastPosition = new agt.geom.Point
+    @velocity = new agt.geom.Point
+    @parasite = {}
+
+    @[ k ] = v for k,v of options
+
+  dispose: ->
+    @position = null
+    @lastPosition = null
+    @velocity = null
+    @parasite = null
+
+  die: ->
+    @dead = true
+    @life = @maxLife
+
+  revive: ->
+    @dead = false
+    @life = 0

data/app/assets/javascripts/agt/particles/sub_system.coffee

@@ -0,0 +1,11 @@
+namespace('agt.particles')
+
+# Public:
+class agt.particles.SubSystem extends agt.particles.System
+
+  ### Public ###
+
+  constructor: (initializer, action, @emissionFactory, subSystem) ->
+    super initializer, action, subSystem
+
+  emitFor: (particle) -> @emit @emissionFactory particle

data/app/assets/javascripts/agt/particles/system.coffee

@@ -0,0 +1,103 @@
+namespace('agt.particles')
+
+# Public:
+class agt.particles.System
+
+  ### Public ###
+
+  constructor: (@initializer=new agt.particles.initializers.NullInitializer,
+                @action= new agt.particles.actions.NullAction, @subSystem) ->
+    @particlesCreated = new agt.Signal
+    @particlesDied = new agt.Signal
+    @emissionStarted = new agt.Signal
+    @emissionFinished = new agt.Signal
+    @particles = []
+    @emissions = []
+
+  emit: (emission) ->
+    @emissions.push emission
+    emission.system = this
+    @startEmission emission
+
+  startEmission: (emission) ->
+    emission.prepare 0, 0, @getTime()
+    @created = []
+    @died = []
+
+    @start() unless @running
+    @processEmission emission
+
+    @emissionStarted.dispatch this, emission
+    @particlesCreated.dispatch this, @created if @created.length > 0
+    @particlesDied.dispatch this, @died if @died.length > 0
+
+    @died = null
+    @created = null
+
+  start: ->
+    unless @running
+      agt.Impulse.instance().add @tick, this
+      @running = true
+
+  stop: ->
+    if @running
+      agt.Impulse.instance().remove @tick, this
+      @running = false
+
+  tick: (bias, biasInSeconds, time) ->
+    @died = []
+    @created = []
+
+    @processParticles bias, biasInSeconds, time
+    @processEmissions bias, biasInSeconds, time if @emitting()
+
+    @particlesCreated.dispatch this, @created if @created.length > 0
+    @particlesDied.dispatch this, @died if @died.length > 0
+
+    @died = null
+    @created = null
+
+  emitting: -> @emissions.length > 0
+
+  processEmissions: (bias, biasInSeconds, time) ->
+    for emission in @emissions.concat()
+      emission.prepare bias, biasInSeconds, time
+      @processEmission emission
+
+  processEmission: (emission) ->
+    while emission.hasNext()
+      time = emission.nextTime()
+      particle = emission.next()
+      @created.push particle
+      @registerParticle particle
+      @initializeParticle particle, time
+      if emission.finished()
+        @removeEmission emission
+        @emissionFinished.dispatch this, emission
+
+  removeEmission: (emission) ->
+    @emissions.splice @emissions.indexOf(emission), 1
+
+  processParticles: (bias, biasInSeconds, time) ->
+    @action.prepare bias, biasInSeconds, time
+    for particle in @particles.concat()
+      @action.process particle
+      @unregisterParticle particle if particle.dead
+
+  initializeParticle: (particle, time) ->
+    @initializer.initialize particle
+    @action.prepare time, time / 1000, @getTime()
+    @action.process particle
+
+    @unregisterParticle particle if particle.dead
+
+  registerParticle: (particle) ->
+    @particles.push particle
+
+  unregisterParticle: (particle) ->
+    @died.push particle
+    @subSystem?.emitFor particle
+    @particles.splice @particles.indexOf(particle), 1
+    particle.constructor.release particle
+
+  getTime: -> new Date().valueOf()