STLExtract 1.0.0

data/Slic3r/Linux/lib/std/utf8.pm

@@ -0,0 +1,214 @@
+package utf8;
+
+$utf8::hint_bits = 0x00800000;
+
+our $VERSION = '1.09';
+
+sub import {
+    $^H |= $utf8::hint_bits;
+    $enc{caller()} = $_[1] if $_[1];
+}
+
+sub unimport {
+    $^H &= ~$utf8::hint_bits;
+}
+
+sub AUTOLOAD {
+    require "utf8_heavy.pl";
+    goto &$AUTOLOAD if defined &$AUTOLOAD;
+    require Carp;
+    Carp::croak("Undefined subroutine $AUTOLOAD called");
+}
+
+1;
+__END__
+
+=head1 NAME
+
+utf8 - Perl pragma to enable/disable UTF-8 (or UTF-EBCDIC) in source code
+
+=head1 SYNOPSIS
+
+    use utf8;
+    no utf8;
+
+    # Convert the internal representation of a Perl scalar to/from UTF-8.
+
+    $num_octets = utf8::upgrade($string);
+    $success    = utf8::downgrade($string[, FAIL_OK]);
+
+    # Change each character of a Perl scalar to/from a series of
+    # characters that represent the UTF-8 bytes of each original character.
+
+    utf8::encode($string);  # "\x{100}"  becomes "\xc4\x80"
+    utf8::decode($string);  # "\xc4\x80" becomes "\x{100}"
+
+    $flag = utf8::is_utf8(STRING); # since Perl 5.8.1
+    $flag = utf8::valid(STRING);
+
+=head1 DESCRIPTION
+
+The C<use utf8> pragma tells the Perl parser to allow UTF-8 in the
+program text in the current lexical scope (allow UTF-EBCDIC on EBCDIC based
+platforms).  The C<no utf8> pragma tells Perl to switch back to treating
+the source text as literal bytes in the current lexical scope.
+
+B<Do not use this pragma for anything else than telling Perl that your
+script is written in UTF-8.> The utility functions described below are
+directly usable without C<use utf8;>.
+
+Because it is not possible to reliably tell UTF-8 from native 8 bit
+encodings, you need either a Byte Order Mark at the beginning of your
+source code, or C<use utf8;>, to instruct perl.
+
+When UTF-8 becomes the standard source format, this pragma will
+effectively become a no-op.  For convenience in what follows the term
+I<UTF-X> is used to refer to UTF-8 on ASCII and ISO Latin based
+platforms and UTF-EBCDIC on EBCDIC based platforms.
+
+See also the effects of the C<-C> switch and its cousin, the
+C<$ENV{PERL_UNICODE}>, in L<perlrun>.
+
+Enabling the C<utf8> pragma has the following effect:
+
+=over 4
+
+=item *
+
+Bytes in the source text that have their high-bit set will be treated
+as being part of a literal UTF-X sequence.  This includes most
+literals such as identifier names, string constants, and constant
+regular expression patterns.
+
+On EBCDIC platforms characters in the Latin 1 character set are
+treated as being part of a literal UTF-EBCDIC character.
+
+=back
+
+Note that if you have bytes with the eighth bit on in your script
+(for example embedded Latin-1 in your string literals), C<use utf8>
+will be unhappy since the bytes are most probably not well-formed
+UTF-X.  If you want to have such bytes under C<use utf8>, you can disable
+this pragma until the end the block (or file, if at top level) by
+C<no utf8;>.
+
+=head2 Utility functions
+
+The following functions are defined in the C<utf8::> package by the
+Perl core.  You do not need to say C<use utf8> to use these and in fact
+you should not say that  unless you really want to have UTF-8 source code.
+
+=over 4
+
+=item * $num_octets = utf8::upgrade($string)
+
+Converts in-place the internal representation of the string from an octet
+sequence in the native encoding (Latin-1 or EBCDIC) to I<UTF-X>. The
+logical character sequence itself is unchanged.  If I<$string> is already
+stored as I<UTF-X>, then this is a no-op. Returns the
+number of octets necessary to represent the string as I<UTF-X>.  Can be
+used to make sure that the UTF-8 flag is on, so that C<\w> or C<lc()>
+work as Unicode on strings containing characters in the range 0x80-0xFF
+(on ASCII and derivatives).
+
+B<Note that this function does not handle arbitrary encodings.>
+Therefore Encode is recommended for the general purposes; see also
+L<Encode>.
+
+=item * $success = utf8::downgrade($string[, FAIL_OK])
+
+Converts in-place the internal representation of the string from
+I<UTF-X> to the equivalent octet sequence in the native encoding (Latin-1
+or EBCDIC). The logical character sequence itself is unchanged. If
+I<$string> is already stored as native 8 bit, then this is a no-op.  Can
+be used to
+make sure that the UTF-8 flag is off, e.g. when you want to make sure
+that the substr() or length() function works with the usually faster
+byte algorithm.
+
+Fails if the original I<UTF-X> sequence cannot be represented in the
+native 8 bit encoding. On failure dies or, if the value of C<FAIL_OK> is
+true, returns false. 
+
+Returns true on success.
+
+B<Note that this function does not handle arbitrary encodings.>
+Therefore Encode is recommended for the general purposes; see also
+L<Encode>.
+
+=item * utf8::encode($string)
+
+Converts in-place the character sequence to the corresponding octet
+sequence in I<UTF-X>. That is, every (possibly wide) character gets
+replaced with a sequence of one or more characters that represent the
+individual I<UTF-X> bytes of the character.  The UTF8 flag is turned off.
+Returns nothing.
+
+    my $a = "\x{100}"; # $a contains one character, with ord 0x100
+    utf8::encode($a);  # $a contains two characters, with ords 0xc4 and 0x80
+
+B<Note that this function does not handle arbitrary encodings.>
+Therefore Encode is recommended for the general purposes; see also
+L<Encode>.
+
+=item * $success = utf8::decode($string)
+
+Attempts to convert in-place the octet sequence in I<UTF-X> to the
+corresponding character sequence. That is, it replaces each sequence of
+characters in the string whose ords represent a valid UTF-X byte
+sequence, with the corresponding single character.  The UTF-8 flag is
+turned on only if the source string contains multiple-byte I<UTF-X>
+characters.  If I<$string> is invalid as I<UTF-X>, returns false;
+otherwise returns true.
+
+    my $a = "\xc4\x80"; # $a contains two characters, with ords 0xc4 and 0x80
+    utf8::decode($a);   # $a contains one character, with ord 0x100
+
+B<Note that this function does not handle arbitrary encodings.>
+Therefore Encode is recommended for the general purposes; see also
+L<Encode>.
+
+=item * $flag = utf8::is_utf8(STRING)
+
+(Since Perl 5.8.1)  Test whether STRING is in UTF-8 internally.
+Functionally the same as Encode::is_utf8().
+
+=item * $flag = utf8::valid(STRING)
+
+[INTERNAL] Test whether STRING is in a consistent state regarding
+UTF-8.  Will return true is well-formed UTF-8 and has the UTF-8 flag
+on B<or> if string is held as bytes (both these states are 'consistent').
+Main reason for this routine is to allow Perl's testsuite to check
+that operations have left strings in a consistent state.  You most
+probably want to use utf8::is_utf8() instead.
+
+=back
+
+C<utf8::encode> is like C<utf8::upgrade>, but the UTF8 flag is
+cleared.  See L<perlunicode> for more on the UTF8 flag and the C API
+functions C<sv_utf8_upgrade>, C<sv_utf8_downgrade>, C<sv_utf8_encode>,
+and C<sv_utf8_decode>, which are wrapped by the Perl functions
+C<utf8::upgrade>, C<utf8::downgrade>, C<utf8::encode> and
+C<utf8::decode>.  Also, the functions utf8::is_utf8, utf8::valid,
+utf8::encode, utf8::decode, utf8::upgrade, and utf8::downgrade are
+actually internal, and thus always available, without a C<require utf8>
+statement.
+
+=head1 BUGS
+
+One can have Unicode in identifier names, but not in package/class or
+subroutine names.  While some limited functionality towards this does
+exist as of Perl 5.8.0, that is more accidental than designed; use of
+Unicode for the said purposes is unsupported.
+
+One reason of this unfinishedness is its (currently) inherent
+unportability: since both package names and subroutine names may need
+to be mapped to file and directory names, the Unicode capability of
+the filesystem becomes important-- and there unfortunately aren't
+portable answers.
+
+=head1 SEE ALSO
+
+L<perlunitut>, L<perluniintro>, L<perlrun>, L<bytes>, L<perlunicode>
+
+=cut

data/Slic3r/Linux/lib/std/utf8_heavy.pl

@@ -0,0 +1,550 @@
+package utf8;
+use strict;
+use warnings;
+
+sub DEBUG () { 0 }
+
+sub DESTROY {}
+
+my %Cache;
+
+sub croak { require Carp; Carp::croak(@_) }
+
+##
+## "SWASH" == "SWATCH HASH". A "swatch" is a swatch of the Unicode landscape.
+## It's a data structure that encodes a set of Unicode characters.
+##
+
+{
+    # If a floating point number is within this distance from the value of a
+    # fraction, it is considered to be that fraction, even if many more digits
+    # are specified that don't exactly match.
+    my $min_floating_slop;
+
+    # To guard against this program calling something that in turn ends up
+    # calling this program with the same inputs, and hence infinitely
+    # recursing, we keep a stack of the properties that are currently in
+    # progress, pushed upon entry, popped upon return.
+    my @recursed;
+
+    sub SWASHNEW {
+        my ($class, $type, $list, $minbits, $none) = @_;
+        local $^D = 0 if $^D;
+
+        $class = "" unless defined $class;
+        print STDERR __LINE__, ": class=$class, type=$type, list=",
+                                (defined $list) ? $list : ':undef:',
+                                ", minbits=$minbits, none=$none\n" if DEBUG;
+
+        ##
+        ## Get the list of codepoints for the type.
+        ## Called from swash_init (see utf8.c) or SWASHNEW itself.
+        ##
+        ## Callers of swash_init:
+        ##     op.c:pmtrans             -- for tr/// and y///
+        ##     regexec.c:regclass_swash -- for /[]/, \p, and \P
+        ##     utf8.c:is_utf8_common    -- for common Unicode properties
+        ##     utf8.c:to_utf8_case      -- for lc, uc, ucfirst, etc. and //i
+        ##
+        ## Given a $type, our goal is to fill $list with the set of codepoint
+        ## ranges. If $type is false, $list passed is used.
+        ##
+        ## $minbits:
+        ##     For binary properties, $minbits must be 1.
+        ##     For character mappings (case and transliteration), $minbits must
+        ##     be a number except 1.
+        ##
+        ## $list (or that filled according to $type):
+        ##     Refer to perlunicode.pod, "User-Defined Character Properties."
+        ##     
+        ##     For binary properties, only characters with the property value
+        ##     of True should be listed. The 3rd column, if any, will be ignored
+        ##
+        ## $none is undocumented, so I'm (khw) trying to do some documentation
+        ## of it now.  It appears to be if there is a mapping in an input file
+        ## that maps to 'XXXX', then that is replaced by $none+1, expressed in
+        ## hexadecimal.  The only place I found it possibly used was in
+        ## S_pmtrans in op.c.
+        ##
+        ## To make the parsing of $type clear, this code takes the a rather
+        ## unorthodox approach of last'ing out of the block once we have the
+        ## info we need. Were this to be a subroutine, the 'last' would just
+        ## be a 'return'.
+        ##
+        my $file; ## file to load data from, and also part of the %Cache key.
+        my $ListSorted = 0;
+
+        # Change this to get a different set of Unicode tables
+        my $unicore_dir = 'unicore';
+
+        if ($type)
+        {
+
+            # Verify that this isn't a recursive call for this property.
+            # Can't use croak, as it may try to recurse here itself.
+            my $class_type = $class . "::$type";
+            if (grep { $_ eq $class_type } @recursed) {
+                CORE::die "panic: Infinite recursion in SWASHNEW for '$type'\n";
+            }
+            push @recursed, $class_type;
+
+            $type =~ s/^\s+//;
+            $type =~ s/\s+$//;
+
+            # regcomp.c surrounds the property name with '__" and '_i' if this
+            # is to be caseless matching.
+            my $caseless = $type =~ s/^__(.*)_i$/$1/;
+
+            print STDERR __LINE__, ": type=$type, caseless=$caseless\n" if DEBUG;
+
+        GETFILE:
+            {
+                ##
+                ## It could be a user-defined property.  Look in current
+                ## package if no package given
+                ##
+
+                my $caller1 = $type =~ s/(.+)::// ? $1 : caller(1);
+
+                if (defined $caller1 && $type =~ /^I[ns]\w+$/) {
+                    my $prop = "${caller1}::$type";
+                    if (exists &{$prop}) {
+                        # stolen from Scalar::Util::PP::tainted()
+                        my $tainted;
+                        {
+                            local($@, $SIG{__DIE__}, $SIG{__WARN__});
+                            local $^W = 0;
+                            no warnings;
+                            eval { kill 0 * $prop };
+                            $tainted = 1 if $@ =~ /^Insecure/;
+                        }
+                        die "Insecure user-defined property \\p{$prop}\n"
+                            if $tainted;
+                        no strict 'refs';
+                        $list = &{$prop}($caseless);
+                        last GETFILE;
+                    }
+                }
+
+                # During Perl's compilation, this routine may be called before
+                # the tables are constructed.  If so, we have a chicken/egg
+                # problem.  If we die, the tables never get constructed, so
+                # keep going, but return an empty table so only what the code
+                # has compiled in internally (currently ASCII/Latin1 range
+                # matching) will work.
+                BEGIN {
+                    # Poor man's constant, to avoid a run-time check.
+                    $utf8::{miniperl}
+                        = \! defined &DynaLoader::boot_DynaLoader;
+                }
+                if (miniperl) {
+                    eval "require '$unicore_dir/Heavy.pl'";
+                    last GETFILE if $@;
+                }
+                else {
+                    require "$unicore_dir/Heavy.pl";
+                }
+                BEGIN { delete $utf8::{miniperl} }
+
+                # All property names are matched caselessly
+                my $property_and_table = CORE::lc $type;
+                print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
+
+                # See if is of the compound form 'property=value', where the
+                # value indicates the table we should use.
+                my ($property, $table, @remainder) =
+                                    split /\s*[:=]\s*/, $property_and_table, -1;
+                if (@remainder) {
+                    pop @recursed if @recursed;
+                    return $type;
+                }
+
+                my $prefix;
+                if (! defined $table) {
+                        
+                    # Here, is the single form.  The property becomes empty, and
+                    # the whole value is the table.
+                    $table = $property;
+                    $prefix = $property = "";
+                } else {
+                    print STDERR __LINE__, ": $property\n" if DEBUG;
+
+                    # Here it is the compound property=table form.  The property
+                    # name is always loosely matched, which means remove any of
+                    # these:
+                    $property =~ s/[_\s-]//g;
+
+                    # And convert to canonical form.  Quit if not valid.
+                    $property = $utf8::loose_property_name_of{$property};
+                    if (! defined $property) {
+                        pop @recursed if @recursed;
+                        return $type;
+                    }
+
+                    $prefix = "$property=";
+
+                    # If the rhs looks like it is a number...
+                    print STDERR __LINE__, ": table=$table\n" if DEBUG;
+                    if ($table =~ qr{ ^ [ \s 0-9 _  + / . -]+ $ }x) {
+                        print STDERR __LINE__, ": table=$table\n" if DEBUG;
+
+                        # Don't allow leading nor trailing slashes 
+                        if ($table =~ / ^ \/ | \/ $ /x) {
+                            pop @recursed if @recursed;
+                            return $type;
+                        }
+
+                        # Split on slash, in case it is a rational, like \p{1/5}
+                        my @parts = split qr{ \s* / \s* }x, $table, -1;
+                        print __LINE__, ": $type\n" if @parts > 2 && DEBUG;
+
+                        # Can have maximum of one slash
+                        if (@parts > 2) {
+                            pop @recursed if @recursed;
+                            return $type;
+                        }
+
+                        foreach my $part (@parts) {
+                            print __LINE__, ": part=$part\n" if DEBUG;
+
+                            $part =~ s/^\+\s*//;    # Remove leading plus
+                            $part =~ s/^-\s*/-/;    # Remove blanks after unary
+                                                    # minus
+
+                            # Remove underscores between digits.
+                            $part =~ s/( ?<= [0-9] ) _ (?= [0-9] ) //xg;
+
+                            # No leading zeros (but don't make a single '0'
+                            # into a null string)
+                            $part =~ s/ ^ ( -? ) 0+ /$1/x;
+                            $part .= '0' if $part eq '-' || $part eq "";
+
+                            # No trailing zeros after a decimal point
+                            $part =~ s/ ( \. .*? ) 0+ $ /$1/x;
+
+                            # Begin with a 0 if a leading decimal point
+                            $part =~ s/ ^ ( -? ) \. /${1}0./x;
+
+                            # Ensure not a trailing decimal point: turn into an
+                            # integer
+                            $part =~ s/ \. $ //x;
+
+                            print STDERR __LINE__, ": part=$part\n" if DEBUG;
+                            #return $type if $part eq "";
+                            
+                            # Result better look like a number.  (This test is
+                            # needed because, for example could have a plus in
+                            # the middle.)
+                            if ($part !~ / ^ -? [0-9]+ ( \. [0-9]+)? $ /x) {
+                                pop @recursed if @recursed;
+                                return $type;
+                            }
+                        }
+
+                        #  If a rational...
+                        if (@parts == 2) {
+
+                            # If denominator is negative, get rid of it, and ...
+                            if ($parts[1] =~ s/^-//) {
+
+                                # If numerator is also negative, convert the
+                                # whole thing to positive, or move the minus to
+                                # the numerator
+                                if ($parts[0] !~ s/^-//) {
+                                    $parts[0] = '-' . $parts[0];
+                                }
+                            }
+                            $table = join '/', @parts;
+                        }
+                        elsif ($property ne 'nv' || $parts[0] !~ /\./) {
+
+                            # Here is not numeric value, or doesn't have a
+                            # decimal point.  No further manipulation is
+                            # necessary.  (Note the hard-coded property name.
+                            # This could fail if other properties eventually
+                            # had fractions as well; perhaps the cjk ones
+                            # could evolve to do that.  This hard-coding could
+                            # be fixed by mktables generating a list of
+                            # properties that could have fractions.)
+                            $table = $parts[0];
+                        } else {
+
+                            # Here is a floating point numeric_value.  Try to
+                            # convert to rational.  First see if is in the list
+                            # of known ones.
+                            if (exists $utf8::nv_floating_to_rational{$parts[0]}) {
+                                $table = $utf8::nv_floating_to_rational{$parts[0]};
+                            } else {
+
+                                # Here not in the list.  See if is close
+                                # enough to something in the list.  First
+                                # determine what 'close enough' means.  It has
+                                # to be as tight as what mktables says is the
+                                # maximum slop, and as tight as how many
+                                # digits we were passed.  That is, if the user
+                                # said .667, .6667, .66667, etc.  we match as
+                                # many digits as they passed until get to
+                                # where it doesn't matter any more due to the
+                                # machine's precision.  If they said .6666668,
+                                # we fail.
+                                (my $fraction = $parts[0]) =~ s/^.*\.//;
+                                my $epsilon = 10 ** - (length($fraction));
+                                if ($epsilon > $utf8::max_floating_slop) {
+                                    $epsilon = $utf8::max_floating_slop;
+                                }
+
+                                # But it can't be tighter than the minimum
+                                # precision for this machine.  If haven't
+                                # already calculated that minimum, do so now.
+                                if (! defined $min_floating_slop) {
+
+                                    # Keep going down an order of magnitude
+                                    # until find that adding this quantity to
+                                    # 1 remains 1; but put an upper limit on
+                                    # this so in case this algorithm doesn't
+                                    # work properly on some platform, that we
+                                    # won't loop forever.
+                                    my $count = 0;
+                                    $min_floating_slop = 1;
+                                    while (1+ $min_floating_slop != 1
+                                           && $count++ < 50)
+                                    {
+                                        my $next = $min_floating_slop / 10;
+                                        last if $next == 0; # If underflows,
+                                                            # use previous one
+                                        $min_floating_slop = $next;
+                                        print STDERR __LINE__, ": min_float_slop=$min_floating_slop\n" if DEBUG;
+                                    }
+
+                                    # Back off a couple orders of magnitude,
+                                    # just to be safe.
+                                    $min_floating_slop *= 100;
+                                }
+                                    
+                                if ($epsilon < $min_floating_slop) {
+                                    $epsilon = $min_floating_slop;
+                                }
+                                print STDERR __LINE__, ": fraction=.$fraction; epsilon=$epsilon\n" if DEBUG;
+
+                                undef $table;
+
+                                # And for each possible rational in the table,
+                                # see if it is within epsilon of the input.
+                                foreach my $official
+                                        (keys %utf8::nv_floating_to_rational)
+                                {
+                                    print STDERR __LINE__, ": epsilon=$epsilon, official=$official, diff=", abs($parts[0] - $official), "\n" if DEBUG;
+                                    if (abs($parts[0] - $official) < $epsilon) {
+                                      $table =
+                                      $utf8::nv_floating_to_rational{$official};
+                                        last;
+                                    }
+                                }
+
+                                # Quit if didn't find one.
+                                if (! defined $table) {
+                                    pop @recursed if @recursed;
+                                    return $type;
+                                }
+                            }
+                        }
+                        print STDERR __LINE__, ": $property=$table\n" if DEBUG;
+                    }
+                }
+
+                # Combine lhs (if any) and rhs to get something that matches
+                # the syntax of the lookups.
+                $property_and_table = "$prefix$table";
+                print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
+
+                # First try stricter matching.
+                $file = $utf8::stricter_to_file_of{$property_and_table};
+
+                # If didn't find it, try again with looser matching by editing
+                # out the applicable characters on the rhs and looking up
+                # again.
+                if (! defined $file) {
+                    $table =~ s/ [_\s-] //xg;
+                    $property_and_table = "$prefix$table";
+                    print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
+                    $file = $utf8::loose_to_file_of{$property_and_table};
+                }
+
+                # Add the constant and go fetch it in.
+                if (defined $file) {
+                    if ($utf8::why_deprecated{$file}) {
+                        warnings::warnif('deprecated', "Use of '$type' in \\p{} or \\P{} is deprecated because: $utf8::why_deprecated{$file};");
+                    }
+
+                    if ($caseless
+                        && exists $utf8::caseless_equivalent{$property_and_table})
+                    {
+                        $file = $utf8::caseless_equivalent{$property_and_table};
+                    }
+                    $file= "$unicore_dir/lib/$file.pl";
+                    last GETFILE;
+                }
+                print STDERR __LINE__, ": didn't find $property_and_table\n" if DEBUG;
+
+                ##
+                ## See if it's a user-level "To".
+                ##
+
+                my $caller0 = caller(0);
+
+                if (defined $caller0 && $type =~ /^To(?:\w+)$/) {
+                    my $map = $caller0 . "::" . $type;
+
+                    if (exists &{$map}) {
+                        no strict 'refs';
+                        
+                        $list = &{$map};
+                        warnings::warnif('deprecated', "User-defined case-mapping '$type' is deprecated");
+                        last GETFILE;
+                    }
+                }
+
+                ##
+                ## Last attempt -- see if it's a standard "To" name
+                ## (e.g. "ToLower")  ToTitle is used by ucfirst().
+                ## The user-level way to access ToDigit() and ToFold()
+                ## is to use Unicode::UCD.
+                ##
+                if ($type =~ /^To(Digit|Fold|Lower|Title|Upper)$/) {
+                    $file = "$unicore_dir/To/$1.pl";
+                    ## would like to test to see if $file actually exists....
+                    last GETFILE;
+                }
+
+                ##
+                ## If we reach this line, it's because we couldn't figure
+                ## out what to do with $type. Ouch.
+                ##
+
+                pop @recursed if @recursed;
+                return $type;
+            }
+
+            if (defined $file) {
+                print STDERR __LINE__, ": found it (file='$file')\n" if DEBUG;
+
+                ##
+                ## If we reach here, it was due to a 'last GETFILE' above
+                ## (exception: user-defined properties and mappings), so we
+                ## have a filename, so now we load it if we haven't already.
+                ## If we have, return the cached results. The cache key is the
+                ## class and file to load.
+                ##
+                my $found = $Cache{$class, $file};
+                if ($found and ref($found) eq $class) {
+                    print STDERR __LINE__, ": Returning cached '$file' for \\p{$type}\n" if DEBUG;
+                    pop @recursed if @recursed;
+                    return $found;
+                }
+
+                local $@;
+                local $!;
+                $list = do $file; die $@ if $@;
+            }
+
+            $ListSorted = 1; ## we know that these lists are sorted
+        }
+
+        my $extras;
+        my $bits = $minbits;
+
+        if ($list) {
+            my $taint = substr($list,0,0); # maintain taint
+            my @tmp = split(/^/m, $list);
+            my %seen;
+            no warnings;
+            $extras = join '', $taint, grep /^[^0-9a-fA-F]/, @tmp;
+            $list = join '', $taint,
+                map  { $_->[1] }
+                sort { $a->[0] <=> $b->[0] }
+                map  { /^([0-9a-fA-F]+)/; [ CORE::hex($1), $_ ] }
+                grep { /^([0-9a-fA-F]+)/ and not $seen{$1}++ } @tmp; # XXX doesn't do ranges right
+        }
+
+        if ($none) {
+            my $hextra = sprintf "%04x", $none + 1;
+            $list =~ s/\tXXXX$/\t$hextra/mg;
+        }
+
+        if ($minbits != 1 && $minbits < 32) { # not binary property
+            my $top = 0;
+            while ($list =~ /^([0-9a-fA-F]+)(?:[\t]([0-9a-fA-F]+)?)(?:[ \t]([0-9a-fA-F]+))?/mg) {
+                my $min = CORE::hex $1;
+                my $max = defined $2 ? CORE::hex $2 : $min;
+                my $val = defined $3 ? CORE::hex $3 : 0;
+                $val += $max - $min if defined $3;
+                $top = $val if $val > $top;
+            }
+            my $topbits =
+                $top > 0xffff ? 32 :
+                $top > 0xff ? 16 : 8;
+            $bits = $topbits if $bits < $topbits;
+        }
+
+        my @extras;
+        if ($extras) {
+            for my $x ($extras) {
+                my $taint = substr($x,0,0); # maintain taint
+                pos $x = 0;
+                while ($x =~ /^([^0-9a-fA-F\n])(.*)/mg) {
+                    my $char = "$1$taint";
+                    my $name = "$2$taint";
+                    print STDERR __LINE__, ": char [$char] => name [$name]\n"
+                        if DEBUG;
+                    if ($char =~ /[-+!&]/) {
+                        my ($c,$t) = split(/::/, $name, 2);	# bogus use of ::, really
+                        my $subobj;
+                        if ($c eq 'utf8') {
+                            $subobj = utf8->SWASHNEW($t, "", $minbits, 0);
+                        }
+                        elsif (exists &$name) {
+                            $subobj = utf8->SWASHNEW($name, "", $minbits, 0);
+                        }
+                        elsif ($c =~ /^([0-9a-fA-F]+)/) {
+                            $subobj = utf8->SWASHNEW("", $c, $minbits, 0);
+                        }
+                        if (! ref $subobj) {
+                            pop @recursed if @recursed && $type;
+                            return $subobj;
+                        }
+                        push @extras, $name => $subobj;
+                        $bits = $subobj->{BITS} if $bits < $subobj->{BITS};
+                    }
+                }
+            }
+        }
+
+        if (DEBUG) {
+            print STDERR __LINE__, ": CLASS = $class, TYPE => $type, BITS => $bits, NONE => $none";
+            print STDERR "\nLIST =>\n$list" if defined $list;
+            print STDERR "\nEXTRAS =>\n$extras" if defined $extras;
+            print STDERR "\n";
+        }
+
+        my $SWASH = bless {
+            TYPE => $type,
+            BITS => $bits,
+            EXTRAS => $extras,
+            LIST => $list,
+            NONE => $none,
+            @extras,
+        } => $class;
+
+        if ($file) {
+            $Cache{$class, $file} = $SWASH;
+        }
+
+        pop @recursed if @recursed && $type;
+
+        return $SWASH;
+    }
+}
+
+# Now SWASHGET is recasted into a C function S_swash_get (see utf8.c).
+
+1;