web3 6.20.2__py3-none-any.whl → 7.0.0__py3-none-any.whl

ethpm/assets/registry/contracts/ReleaseDB.sol

@@ -1,309 +0,0 @@
-pragma solidity ^0.4.24;
-pragma experimental "v0.5.0";
-
-
-import {IndexedOrderedSetLib} from "./IndexedOrderedSetLib.sol";
-import {Authorized} from "./Authority.sol";
-
-
-/// @title Database contract for a package index.
-/// @author Tim Coulter <tim.coulter@consensys.net>, Piper Merriam <pipermerriam@gmail.com>
-contract ReleaseDB is Authorized {
-  using IndexedOrderedSetLib for IndexedOrderedSetLib.IndexedOrderedSet;
-
-  struct Release {
-    bool exists;
-    uint createdAt;
-    uint updatedAt;
-    bytes32 nameHash;
-    bytes32 versionHash;
-    string manifestURI;
-  }
-
-  // Release Data: (releaseId => value)
-  mapping (bytes32 => Release) _recordedReleases;
-  mapping (bytes32 => bool) _removedReleases;
-  IndexedOrderedSetLib.IndexedOrderedSet _allReleaseIds;
-  mapping (bytes32 => IndexedOrderedSetLib.IndexedOrderedSet) _releaseIdsByNameHash;
-
-  // Version Data: (versionHash => value)
-  mapping (bytes32 => string) _recordedVersions;
-  mapping (bytes32 => bool) _versionExists;
-
-  // Events
-  event ReleaseCreate(bytes32 indexed releaseId);
-  event ReleaseUpdate(bytes32 indexed releaseId);
-  event ReleaseDelete(bytes32 indexed releaseId, string reason);
-
-  /*
-   *  Modifiers
-   */
-  modifier onlyIfVersionExists(bytes32 versionHash) {
-    require(versionExists(versionHash), "escape:ReleaseDB:version-not-found");
-    _;
-  }
-
-  modifier onlyIfReleaseExists(bytes32 releaseId) {
-    require(releaseExists(releaseId), "escape:ReleaseDB:release-not-found");
-    _;
-  }
-
-  //
-  // +-------------+
-  // |  Write API  |
-  // +-------------+
-  //
-
-  /// @dev Creates or updates a release for a package.  Returns success.
-  /// @param nameHash The name hash of the package.
-  /// @param versionHash The version hash for the release version.
-  /// @param manifestURI The URI for the release manifest for this release.
-  function setRelease(
-    bytes32 nameHash,
-    bytes32 versionHash,
-    string manifestURI
-  )
-    public
-    auth
-    returns (bool)
-  {
-    bytes32 releaseId = hashRelease(nameHash, versionHash);
-
-    Release storage release = _recordedReleases[releaseId];
-
-    // If this is a new version push it onto the array of version hashes for
-    // this package.
-    if (release.exists) {
-      emit ReleaseUpdate(releaseId);
-    } else {
-      // Populate the basic release data.
-      release.exists = true;
-      release.createdAt = block.timestamp; // solium-disable-line security/no-block-members
-      release.nameHash = nameHash;
-      release.versionHash = versionHash;
-
-      // Push the release hash into the array of all release hashes.
-      _allReleaseIds.add(releaseId);
-      _releaseIdsByNameHash[nameHash].add(releaseId);
-
-      emit ReleaseCreate(releaseId);
-    }
-
-    // Record the last time the release was updated.
-    release.updatedAt = block.timestamp; // solium-disable-line security/no-block-members
-
-    // Save the release manifest URI
-    release.manifestURI = manifestURI;
-
-    return true;
-  }
-
-  /// @dev Removes a release from a package.  Returns success.
-  /// @param releaseId The release hash to be removed
-  /// @param reason Explanation for why the removal happened.
-  function removeRelease(bytes32 releaseId, string reason)
-    public
-    auth
-    onlyIfReleaseExists(releaseId)
-    returns (bool)
-  {
-    bytes32 nameHash;
-    bytes32 versionHash;
-
-    (nameHash, versionHash,,) = getReleaseData(releaseId);
-
-    // Zero out the release data.
-    delete _recordedReleases[releaseId];
-    delete _recordedVersions[versionHash];
-
-    // Remove the release hash from the list of all release hashes
-    _allReleaseIds.remove(releaseId);
-    _releaseIdsByNameHash[nameHash].remove(releaseId);
-
-    // Add the release hash to the map of removed releases
-    _removedReleases[releaseId] = true;
-
-    // Log the removal.
-    emit ReleaseDelete(releaseId, reason);
-
-    return true;
-  }
-
-
-  /// @dev Adds the given version to the local version database.  Returns the versionHash for the provided version.
-  /// @param version Version string (ex: '1.0.0')
-  function setVersion(string version)
-    public
-    auth
-    returns (bytes32)
-  {
-    bytes32 versionHash = hashVersion(version);
-
-    if (!_versionExists[versionHash]) {
-      _recordedVersions[versionHash] = version;
-      _versionExists[versionHash] = true;
-    }
-    return versionHash;
-  }
-
-  //
-  // +------------+
-  // |  Read API  |
-  // +------------+
-  //
-
-  /// @dev Returns a slice of the array of all releases hashes for the named package.
-  /// @param offset The starting index for the slice.
-  /// @param limit  The length of the slice
-  function getAllReleaseIds(bytes32 nameHash, uint _offset, uint limit)
-    public
-    view
-    returns (
-      bytes32[] releaseIds,
-      uint offset
-    )
-  {
-    bytes32[] memory hashes;                                  // Release ids to return
-    uint cursor = _offset;                                    // Index counter to traverse DB array
-    uint remaining;                                           // Counter to collect `limit` packages
-    uint totalReleases = getNumReleasesForNameHash(nameHash); // Total number of packages in registry
-
-    // Is request within range?
-    if (cursor < totalReleases){
-
-      // Get total remaining records
-      remaining = totalReleases - cursor;
-
-      // Number of records to collect is lesser of `remaining` and `limit`
-      if (remaining > limit ){
-        remaining = limit;
-      }
-
-      // Allocate return array
-      hashes = new bytes32[](remaining);
-
-      // Collect records. (IndexedOrderedSet manages deletions.)
-      while(remaining > 0){
-        bytes32 hash = getReleaseIdForNameHash(nameHash, cursor);
-        hashes[remaining - 1] = hash;
-        remaining--;
-        cursor++;
-      }
-    }
-    return (hashes, cursor);
-  }
-
-  /// @dev Get the total number of releases
-  /// @param nameHash the name hash to lookup.
-  function getNumReleasesForNameHash(bytes32 nameHash)
-    public
-    view
-    returns (uint)
-  {
-    return _releaseIdsByNameHash[nameHash].size();
-  }
-
-  /// @dev Release hash for a Package at a given index
-  /// @param nameHash the name hash to lookup.
-  /// @param idx The index of the release hash to retrieve.
-  function getReleaseIdForNameHash(bytes32 nameHash, uint idx)
-    public
-    view
-    returns (bytes32)
-  {
-    return _releaseIdsByNameHash[nameHash].get(idx);
-  }
-
-  /// @dev Query the existence of a release at the provided version for a package.  Returns boolean indicating whether such a release exists.
-  /// @param releaseId The release hash to query.
-  function releaseExists(bytes32 releaseId)
-    public
-    view
-    returns (bool)
-  {
-    return _recordedReleases[releaseId].exists;
-  }
-
-  /// @dev Query the past existence of a release at the provided version for a package.  Returns boolean indicating whether such a release ever existed.
-  /// @param releaseHash The release hash to query.
-  function releaseExisted(bytes32 releaseHash)
-    public
-    view
-    returns (bool)
-  {
-    return _removedReleases[releaseHash];
-  }
-
-  /// @dev Query the existence of the provided version in the recorded versions.  Returns boolean indicating whether such a version exists.
-  /// @param versionHash the version hash to check.
-  function versionExists(bytes32 versionHash)
-    public
-    view
-    returns (bool)
-  {
-    return _versionExists[versionHash];
-  }
-
-  /// @dev Returns the releaseData for the given release has a package.
-  /// @param releaseId The release hash.
-  function getReleaseData(bytes32 releaseId)
-    public
-    view
-    onlyIfReleaseExists(releaseId)
-    returns (
-      bytes32 nameHash,
-      bytes32 versionHash,
-      uint createdAt,
-      uint updatedAt
-    )
-  {
-    Release storage release = _recordedReleases[releaseId];
-    return (release.nameHash, release.versionHash, release.createdAt, release.updatedAt);
-  }
-
-  /// @dev Returns string version identifier from the version of the given release hash.
-  /// @param versionHash the version hash
-  function getVersion(bytes32 versionHash)
-    public
-    view
-    onlyIfVersionExists(versionHash)
-    returns (string)
-  {
-    return _recordedVersions[versionHash];
-  }
-
-  /// @dev Returns the URI of the release manifest for the given release hash.
-  /// @param releaseId Release hash
-  function getManifestURI(bytes32 releaseId)
-    public
-    view
-    onlyIfReleaseExists(releaseId)
-    returns (string)
-  {
-    return _recordedReleases[releaseId].manifestURI;
-  }
-
-  /*
-   *  Hash Functions
-   */
-  /// @dev Returns version hash for the given semver version.
-  /// @param version Version string
-  function hashVersion(string version)
-    public
-    pure
-    returns (bytes32)
-  {
-    return keccak256(abi.encodePacked(version));
-  }
-
-  /// @dev Returns release hash for the given release
-  /// @param nameHash The name hash of the package name.
-  /// @param versionHash The version hash for the release version.
-  function hashRelease(bytes32 nameHash, bytes32 versionHash)
-    public
-    pure
-    returns (bytes32)
-  {
-    return keccak256(abi.encodePacked(nameHash, versionHash));
-  }
-}

ethpm/assets/registry/contracts/ReleaseValidator.sol

@@ -1,152 +0,0 @@
-pragma solidity ^0.4.24;
-pragma experimental "v0.5.0";
-
-import {PackageDB} from "./PackageDB.sol";
-import {ReleaseDB} from "./ReleaseDB.sol";
-
-/// @title Database contract for a package index.
-/// @author Piper Merriam <pipermerriam@gmail.com>
-contract ReleaseValidator {
-  /// @dev Runs validation on all of the data needed for releasing a package.  Returns success.
-  /// @param packageDb The address of the PackageDB
-  /// @param releaseDb The address of the ReleaseDB
-  /// @param callerAddress The address which is attempting to create the release.
-  /// @param name The name of the package.
-  /// @param version The version string of the package (ex: `1.0.0`)
-  /// @param manifestURI The URI of the release manifest.
-  function validateRelease(
-    PackageDB packageDb,
-    ReleaseDB releaseDb,
-    address callerAddress,
-    string name,
-    string version,
-    string manifestURI
-  )
-    public
-    view
-    returns (bool)
-  {
-    if (address(packageDb) == 0x0){
-      // packageDb address is null
-      revert("escape:ReleaseValidator:package-db-not-set");
-    } else if (address(releaseDb) == 0x0){
-      // releaseDb address is null
-      revert("escape:ReleaseValidator:release-db-not-set");
-    } else if (!validateAuthorization(packageDb, callerAddress, name)) {
-      // package exists and msg.sender is not the owner not the package owner.
-      revert("escape:ReleaseValidator:caller-not-authorized");
-    } else if (!validateIsNewRelease(packageDb, releaseDb, name, version)) {
-      // this version has already been released.
-      revert("escape:ReleaseValidator:version-previously-published");
-    } else if (!validatePackageName(packageDb, name)) {
-      // invalid package name.
-      revert("escape:ReleaseValidator:invalid-package-name");
-    } else if (!validateStringIdentifier(manifestURI)) {
-      // disallow empty release manifest URI
-      revert("escape:ReleaseValidator:invalid-manifest-uri");
-    } else if (!validateStringIdentifier(version)) {
-      // disallow version 0.0.0
-      revert("escape:ReleaseValidator:invalid-release-version");
-    }
-    return true;
-  }
-
-  /// @dev Validate whether the callerAddress is authorized to make this release.
-  /// @param packageDb The address of the PackageDB
-  /// @param callerAddress The address which is attempting to create the release.
-  /// @param name The name of the package.
-  function validateAuthorization(
-    PackageDB packageDb,
-    address callerAddress,
-    string name
-  )
-    public
-    view
-    returns (bool)
-  {
-    bytes32 nameHash = packageDb.hashName(name);
-    if (!packageDb.packageExists(nameHash)) {
-      return true;
-    }
-    address packageOwner;
-
-    (packageOwner,,) = packageDb.getPackageData(nameHash);
-
-    if (packageOwner == callerAddress) {
-      return true;
-    }
-    return false;
-  }
-
-  /// @dev Validate that the version being released has not already been released.
-  /// @param packageDb The address of the PackageDB
-  /// @param releaseDb The address of the ReleaseDB
-  /// @param name The name of the package.
-  /// @param version The version string for the release
-  function validateIsNewRelease(
-    PackageDB packageDb,
-    ReleaseDB releaseDb,
-    string name,
-    string version
-  )
-    public
-    view
-    returns (bool)
-  {
-    bytes32 nameHash = packageDb.hashName(name);
-    bytes32 versionHash = releaseDb.hashVersion(version);
-    bytes32 releaseHash = releaseDb.hashRelease(nameHash, versionHash);
-    return !releaseDb.releaseExists(releaseHash) && !releaseDb.releaseExisted(releaseHash);
-  }
-
-  uint constant DIGIT_0 = uint(bytes1("0"));
-  uint constant DIGIT_9 = uint(bytes1("9"));
-  uint constant LETTER_a = uint(bytes1("a"));
-  uint constant LETTER_z = uint(bytes1("z"));
-  bytes1 constant DASH = bytes1("-");
-
-  /// @dev Returns boolean whether the provided package name is valid.
-  /// @param packageDb The address of the PackageDB
-  /// @param name The name of the package.
-  function validatePackageName(PackageDB packageDb, string name)
-    public
-    view
-    returns (bool)
-  {
-    bytes32 nameHash = packageDb.hashName(name);
-
-    if (packageDb.packageExists(nameHash)) {
-      // existing names are always valid.
-      return true;
-    }
-
-    if (bytes(name).length < 2 || bytes(name).length > 255) {
-      return false;
-    }
-    for (uint i = 0; i < bytes(name).length; i++) {
-      if (bytes(name)[i] == DASH && i > 0) {
-        continue;
-      } else if (i > 0 && uint(bytes(name)[i]) >= DIGIT_0 && uint(bytes(name)[i]) <= DIGIT_9) {
-        continue;
-      } else if (uint(bytes(name)[i]) >= LETTER_a && uint(bytes(name)[i]) <= LETTER_z) {
-        continue;
-      } else {
-        return false;
-      }
-    }
-    return true;
-  }
-
-  /// @dev Returns boolean whether the input string has a length
-  /// @param value The string to validate.
-  function validateStringIdentifier(string value)
-    public
-    pure
-    returns (bool)
-  {
-    if (bytes(value).length == 0) {
-      return false;
-    }
-    return true;
-  }
-}

ethpm/assets/registry/solc_input.json

@@ -1 +0,0 @@
-{"language": "Solidity", "settings": {"outputSelection": {"*": {"*": ["abi", "evm.bytecode.object", "evm.deployedBytecode", "metadata", "devdoc"]}}}, "sources": {"PackageRegistryInterface.sol": {"urls": ["/Users/nickgheorghita/ethereum/ethpm-cli/projects/registry/contracts/PackageRegistryInterface.sol"]}, "PackageRegistry.sol": {"urls": ["/Users/nickgheorghita/ethereum/ethpm-cli/projects/registry/contracts/PackageRegistry.sol"]}, "PackageDB.sol": {"urls": ["/Users/nickgheorghita/ethereum/ethpm-cli/projects/registry/contracts/PackageDB.sol"]}, "ReleaseDB.sol": {"urls": ["/Users/nickgheorghita/ethereum/ethpm-cli/projects/registry/contracts/ReleaseDB.sol"]}, "Authority.sol": {"urls": ["/Users/nickgheorghita/ethereum/ethpm-cli/projects/registry/contracts/Authority.sol"]}, "ReleaseValidator.sol": {"urls": ["/Users/nickgheorghita/ethereum/ethpm-cli/projects/registry/contracts/ReleaseValidator.sol"]}, "IndexedOrderedSetLib.sol": {"urls": ["/Users/nickgheorghita/ethereum/ethpm-cli/projects/registry/contracts/IndexedOrderedSetLib.sol"]}}}