tree-sitter-sdml 0.4.14__cp38-abi3-macosx_11_0_arm64.whl

tree_sitter_sdml/__init__.py

@@ -0,0 +1,5 @@
+"Sdml grammar for tree-sitter"
+
+from ._binding import language
+
+__all__ = ["language"]

tree_sitter_sdml/__init__.pyi

@@ -0,0 +1 @@
+def language() -> int: ...

tree_sitter_sdml/binding.c

@@ -0,0 +1,27 @@
+#include <Python.h>
+
+typedef struct TSLanguage TSLanguage;
+
+TSLanguage *tree_sitter_sdml(void);
+
+static PyObject* _binding_language(PyObject *self, PyObject *args) {
+    return PyLong_FromVoidPtr(tree_sitter_sdml());
+}
+
+static PyMethodDef methods[] = {
+    {"language", _binding_language, METH_NOARGS,
+     "Get the tree-sitter language for this grammar."},
+    {NULL, NULL, 0, NULL}
+};
+
+static struct PyModuleDef module = {
+    .m_base = PyModuleDef_HEAD_INIT,
+    .m_name = "_binding",
+    .m_doc = NULL,
+    .m_size = -1,
+    .m_methods = methods
+};
+
+PyMODINIT_FUNC PyInit__binding(void) {
+    return PyModule_Create(&module);
+}

tree_sitter_sdml/queries/folds.scm

@@ -0,0 +1,31 @@
+[
+ (datatype_def)
+ (dimension_def)
+ (entity_def)
+ (enum_def)
+ (event_def)
+ (property_def)
+ (rdf_def)
+ (structure_def)
+ (type_class_def)
+ (union_def)
+ ;; ----------------
+ (annotation_only_body)
+ (dimension_body)
+ (entity_body)
+ (enum_body)
+ (event_body)
+ (structure_body)
+ (type_class_body)
+ (union_body)
+ (datatype_type_restrictions)
+ ;; ----------------
+ (formal_constraint)
+ (sentence_with_environment)
+ (function_body)
+ (constraint_sentence)
+ (sequence_builder)
+ ;; ----------------
+ (sequence_of_values)
+ (sequence_of_predicate_values)
+ ] @fold

tree_sitter_sdml/queries/highlights.scm

@@ -0,0 +1,377 @@
+;; ---------------------------------------------------------------------------
+;; Comments
+;; ---------------------------------------------------------------------------
+
+(line_comment) @comment
+
+;; ---------------------------------------------------------------------------
+;; Global Reserved Keywords
+;; ---------------------------------------------------------------------------
+
+[
+ "as"
+ "assert"
+ "class"
+ "datatype"
+ "dimension"
+ "end"
+ "entity"
+ "enum"
+ "event"
+ "from"
+ "group"
+ "import"
+ "is"
+ "metric"
+ "module"
+ "of"
+ "property"
+ "rdf"
+ "structure"
+ "union"
+ (unknown_type)
+ ] @keyword
+
+;; ---------------------------------------------------------------------------
+;; Global Operators
+;; ---------------------------------------------------------------------------
+
+[
+ ;; has_type
+ "->" "→"
+ ;; has_base_type
+ "<-" "←"
+ ;; cardinality_range
+ ".."
+ "="
+ (op_equality)
+ ] @operator
+
+;; ---------------------------------------------------------------------------
+;; Global Punctuation
+;; ---------------------------------------------------------------------------
+
+[
+ "["
+ "]"
+ "("
+ ")"
+ "{"
+ "}"
+ ] @punctuation.bracket
+
+;; ---------------------------------------------------------------------------
+;; Module & Imports
+;; ---------------------------------------------------------------------------
+
+(module name: (identifier) @module.definition)
+(module_version "version" @keyword)
+
+;; ---------------------------------------------------------------------------
+;; Module ❱ Imports
+;; ---------------------------------------------------------------------------
+
+(module_path_absolute "::" @punctuation.separator)
+(module_path_absolute segment: (identifier) @module)
+
+(module_path_relative "::" @punctuation.separator)
+(module_path_relative segment: (identifier) @module)
+
+(member_import name: (qualified_identifier) @type)
+(member_import rename: (identifier) @type)
+
+(module_import name: (identifier) @module)
+(module_import rename: (identifier) @module)
+
+;; ---------------------------------------------------------------------------
+;; Annotation ❱ Properties
+;; ---------------------------------------------------------------------------
+
+(annotation_property "@" @property name: (identifier_reference) @property)
+
+(annotation_property value: (value (identifier_reference) @type))
+
+;; ---------------------------------------------------------------------------
+;; Annotation ❱ Constraints
+;; ---------------------------------------------------------------------------
+
+(constraint name: (identifier) @property)
+
+(informal_constraint (quoted_string) @embedded)
+(informal_constraint language: (controlled_language_tag) @property)
+
+;; ---------------------------------------------------------------------------
+;; Annotation ❱ Constraints ❱ Formal
+;; ---------------------------------------------------------------------------
+
+(inequation
+ (inequality_relation) @operator)
+
+(unary_boolean_sentence
+ (logical_op_negation) @operator)
+
+(binary_boolean_sentence
+ (logical_connective) @operator)
+
+(quantified_variable_binding
+ (logical_quantifier) @operator)
+
+(quantified_variable (set_membership) @operator)
+
+(set_expression_sentence
+ (set_operator) @operator)
+
+(arithmetic_expression_sentence
+ (math_operator) @operator)
+
+(sentence_with_environment [ "with" "for" ] @keyword)
+
+(keyword_function_def "def" @keyword)
+
+(function_signature name: (identifier) @function.definition)
+(function_signature target: (_) @type)
+
+(function_parameter name: (identifier) @variable.parameter)
+(function_parameter target: (_) @type)
+
+(cardinality_reference_expression (sequence_ordering) @keyword)
+(cardinality_reference_expression (sequence_uniqueness) @keyword)
+
+(function_body [ ":=" "≔" ] @operator)
+
+(atomic_sentence
+ predicate: (term (identifier_reference) @function.call))
+(atomic_sentence
+ argument: (term (identifier_reference (identifier) @variable)))
+
+(equation (term (identifier_reference) @variable))
+(inequation (term (identifier_reference) @variable))
+
+(set_expression_sentence (term (identifier_reference) @variable))
+(arithmetic_expression_sentence (term (identifier_reference) @variable))
+
+(quantified_sentence "," @punctuation.separator)
+(variable (identifier) @variable)
+(variable range: (identifier_reference) @type)
+
+(sequence_builder
+ (seq_builder_separator) @punctuation.separator)
+
+(functional_term
+ function: (term (identifier_reference) @function.call))
+(functional_term
+ argument: (term (identifier_reference (identifier) @variable)))
+
+(function_composition subject: [ (reserved_self) (reserved_event) ] @variable.builtin)
+(function_composition subject: (identifier) @variable)
+(function_composition name: (identifier) @function.call)
+(function_composition [ "." "∘" ] @operator)
+
+(term [ (reserved_self) (reserved_event) ] @variable.builtin)
+(reserved_event "event"  @variable.builtin)
+
+(sequence_of_predicate_values (sequence_ordering) @keyword)
+(sequence_of_predicate_values (sequence_uniqueness) @keyword)
+(sequence_of_predicate_values (identifier_reference) @type)
+
+;; ---------------------------------------------------------------------------
+;; Types
+;; ---------------------------------------------------------------------------
+
+[
+ (builtin_types)
+ (unknown_type)
+ ] @type.builtin
+
+;; ---------------------------------------------------------------------------
+;; Definition
+;; ---------------------------------------------------------------------------
+
+(mixin_with_members "with" @keyword)
+(mixin_with_members wildcard: (_)  @type.builtin)
+(mixin_without_members "without" @keyword)
+(mixin_member member: (identifier)  @variable.field)
+(mixin_member rename: (identifier)  @variable.field)
+
+(from_definition_clause "from" @keyword from: (identifier_reference) @type)
+(source_entity "source" @keyword from: (identifier_reference) @type)
+
+;; ---------------------------------------------------------------------------
+;; Definition ❱ Datatype
+;; ---------------------------------------------------------------------------
+
+(datatype_def
+ "datatype" @keyword
+ name: (identifier) @type.definition)
+(datatype_def opaque: (opaque) @keyword)
+(datatype_base_type_reference (identifier_reference) @type)
+(datatype_base_type_reference (builtin_types) @type.builtin)
+
+(length_restriction_facet
+ [ "length" "maxLength" "minLength" ] @property)
+(digit_restriction_facet
+ [ "fractionDigits" "totalDigits" ] @property)
+(value_restriction_facet
+ [ "maxExclusive" "maxInclusive" "minExclusive" "minInclusive" ] @property)
+(tz_restriction_facet
+ "explicitTimezone" @property
+ (tz_restriction_value) @keyword)
+(pattern_restriction_facet
+ "pattern" @property
+ (quoted_string) @string)
+
+(kw_is_fixed) @keyword
+
+;; ---------------------------------------------------------------------------
+;; Definition ❱ Dimension
+;; ---------------------------------------------------------------------------
+
+(dimension_def name: (identifier) @type.definition)
+
+;; ---------------------------------------------------------------------------
+;; Definition ❱ Entity
+;; ---------------------------------------------------------------------------
+
+(entity_def name: (identifier) @type.definition)
+
+;; ---------------------------------------------------------------------------
+;; Definition ❱ Enum
+;; ---------------------------------------------------------------------------
+
+(enum_def name: (identifier) @type.definition)
+
+;; ---------------------------------------------------------------------------
+;; Definition ❱ Event
+;; ---------------------------------------------------------------------------
+
+(event_def name: (identifier) @type.definition)
+
+;; ---------------------------------------------------------------------------
+;; Definition ❱ Metrics
+;; ---------------------------------------------------------------------------
+
+(metric_group_def "group" @keyword)
+(metric_group_def name: (identifier) @type.definition)
+(metric_event_binding "on" @keyword)
+(metric_event_binding (identifier_reference) @type)
+
+(metric_ref "ref" @keyword)
+
+;; ---------------------------------------------------------------------------
+;; Definition ❱ Rdf
+;; ---------------------------------------------------------------------------
+
+(rdf_def "rdf" @keyword name: (identifier) @type.definition)
+(rdf_def [ "a" "type" ] @keyword)
+(rdf_def type: (identifier_reference) @type)
+
+;; ---------------------------------------------------------------------------
+;; Definition ❱ Structure
+;; ---------------------------------------------------------------------------
+
+(structure_def name: (identifier) @type.definition)
+
+;; ---------------------------------------------------------------------------
+;; Definition ❱ Type Class
+;; ---------------------------------------------------------------------------
+
+(type_class_def "class" @keyword name: (identifier) @type.definition)
+
+(type_parameter name: (identifier) @type.definition)
+(type_parameter (type_op_combiner) @operator)
+
+(type_parameter_restriction class: (identifier_reference) @type)
+
+(type_restriction_argument (identifier) @type.definition)
+
+(wildcard) @type.builtin
+
+;; ---------------------------------------------------------------------------
+;; Definition ❱ Union
+;; ---------------------------------------------------------------------------
+
+(union_def name: (identifier) @type.definition)
+
+;; ---------------------------------------------------------------------------
+;; Members
+;; ---------------------------------------------------------------------------
+
+(member_def
+ name: (identifier) @variable.field
+ target: (type_reference) @type)
+
+(annotation_member_def
+ "@" @property.definition
+ (member_def name: (identifier) @property.definition))
+
+(property_ref
+ "ref" @keyword
+ property: (identifier_reference) @variable.field)
+
+;; ---------------------------------------------------------------------------
+;; Members ❱ Specials
+;; ---------------------------------------------------------------------------
+
+(entity_identity "identity" @keyword)
+
+(dimension_parent
+ "parent" @keyword
+ name: (identifier) @variable.field
+ parent: (identifier_reference) @type)
+
+;; ---------------------------------------------------------------------------
+;; Members ❱ Variants
+;; ---------------------------------------------------------------------------
+
+(value_variant name: (identifier) @constant)
+
+(type_variant name: (identifier_reference) @type.definition)
+(type_variant rename: (identifier) @type)
+
+;; ---------------------------------------------------------------------------
+;; Members ❱ Cardinality
+;; ---------------------------------------------------------------------------
+
+(cardinality_expression (sequence_ordering) @keyword)
+(cardinality_expression (sequence_uniqueness) @keyword)
+
+;; ---------------------------------------------------------------------------
+;; Values
+;; ---------------------------------------------------------------------------
+
+(string (quoted_string) @string)
+(string language: (language_tag) @property)
+
+[
+ (binary)
+ (iri) ] @string.special
+
+[
+ (rational)
+ (decimal)
+ (double)
+ (integer)
+ (unsigned)
+ ] @number
+
+(boolean) @boolean
+
+(value_constructor name: (identifier_reference) @function.call)
+
+(value (identifier_reference) @type)
+
+(sequence_of_values (sequence_ordering) @keyword)
+(sequence_of_values (sequence_uniqueness) @keyword)
+(sequence_of_values (identifier_reference) @type)
+
+;; ---------------------------------------------------------------------------
+;; Errors
+;; ---------------------------------------------------------------------------
+
+;; Highlight errors in red. This is not very useful in practice, as text will
+;; be highlighted as user types, and the error could be elsewhere in the code.
+
+(
+ (ERROR) @error
+ (#set! "priority" 110)
+)

tree_sitter_sdml/queries/indent.scm

@@ -0,0 +1,38 @@
+[
+ "is"
+ "of"
+ ] @indent
+
+[
+ "end"
+ ] @indent.end
+
+[
+ (string)
+ (line_comment)
+ (function_body)
+ ] @indent.auto
+
+(import_statement "[" @indent "]" @indent.end)
+
+(datatype_type_restrictions "{" @indent "}" @indent.end)
+
+(mixin_with_members "[" @indent "]" @indent.end)
+(mixin_without_members "[" @indent "]" @indent.end)
+
+(sentence_with_environment [ "with" "for" ] @indent) @indent.end
+
+(function_signature "(" @indent ")" @indent.end)
+
+(constraint_sentence "(" @indent ")" @indent.end)
+
+(sequence_builder "{" @indent "}" @indent.end)
+
+(atomic_sentence "(" @indent ")" @indent.end)
+(functional_term "(" @indent ")" @indent.end)
+
+(sequence_of_predicate_values "[" @indent "]" @indent.end)
+
+(sequence_of_values "[" @indent "]" @indent.end)
+
+(sequence_builder (seq_builder_separator) @indent.branch)

tree_sitter_sdml/queries/tags.scm

@@ -0,0 +1,128 @@
+;; ---------------------------------------------------------------------------
+;; Modules and Imports
+;; ---------------------------------------------------------------------------
+
+(module
+ name: (identifier) @name) @definition.module
+
+(module_import name: (identifier) @name) @reference.module
+(module_import rename: (identifier) @name) @reference.module
+
+(member_import
+ name: (qualified_identifier
+        module: (identifier) @name)) @reference.module
+
+(module_path_absolute
+ segment: (identifier) @name) @reference.module
+
+(module_path_relative
+ segment: (identifier) @name) @reference.module
+
+(member_import
+ name: (qualified_identifier
+        member: (identifier) @name)) @reference.type
+(member_import rename: (identifier) @name) @reference.type
+
+;; ---------------------------------------------------------------------------
+;; Types
+;; ---------------------------------------------------------------------------
+
+(datatype_def name: (identifier) @name) @definition.datatype
+(datatype_def base: (_) @name) @reference.datatype
+(length_restriction_facet
+ ["length" "maxLength" "minLength"] @name) @reference.facet
+(digit_restriction_facet
+ ["fractionDigits" "totalDigits"] @name) @reference.facet
+(value_restriction_facet
+ ["maxExclusive" "maxInclusive" "minExclusive" "minInclusive"] @name)
+ @reference.facet
+(tz_restriction_facet
+ ["explicitTimezone"  ] @name) @reference.facet
+(pattern_restriction_facet
+ ["pattern"] @name) @reference.facet
+
+(dimension_def name: (identifier) @name) @definition.dimension
+
+(entity_def name: (identifier) @name) @definition.entity
+
+(enum_def name: (identifier) @name) @definition.enum
+
+(event_def name: (identifier) @name) @definition.event
+
+(rdf_def name: (identifier) @name) @definition.rdf
+
+(structure_def name: (identifier) @name) @definition.structure
+
+(type_class_def name: (identifier) @name) @definition.class
+(type_parameter name: (identifier) @name) @definition.class
+(type_parameter_restriction class: (identifier_reference) @name) @reference.class
+
+(type_restriction_argument (identifier) @name) @definition.class
+
+(union_def name: (identifier) @name) @definition.union
+
+(mixin_member member: (identifier)  @name) @reference.field
+(mixin_member rename: (identifier)  @name) @definition.field
+
+(from_definition_clause from: (identifier_reference) @name) @reference.type
+(source_entity from: (identifier_reference) @name) @reference.entity
+
+;; ---------------------------------------------------------------------------
+;; Members
+;; ---------------------------------------------------------------------------
+
+(dimension_parent name: (identifier) @name)  @definition.field
+(dimension_parent parent: (identifier_reference) @name)  @reference.dimension
+
+(member_def name: (identifier) @name) @definition.field
+
+(type_reference (identifier_reference) @name) @reference.type
+(type_reference (builtin_types) @name) @reference.type
+
+(property_ref property: (identifier_reference) @name) @reference.field
+
+(type_variant (identifier_reference) @name) @reference.type
+(type_variant rename: (identifier) @name) @definition.type
+
+(value_variant name: (identifier) @name) @definition.constant
+
+;; ---------------------------------------------------------------------------
+;; Annotations, Constraints, and Values
+;; ---------------------------------------------------------------------------
+
+(annotation_property
+ name: (identifier_reference) @name) @reference.type
+
+(value (identifier_reference) @name) @reference.type
+
+(value_constructor
+ name: (identifier_reference) @name) @reference.type
+
+(constraint name: (identifier) @name) @definition.constraint
+
+(term (identifier_reference) @name) @reference.variable
+
+(term (reserved_self) @name) @reference.variable
+
+(functional_term function: (term (identifier_reference) @name)) @reference.call
+
+(function_composition
+ subject: (reserved_self) @name) @reference.variable
+(function_composition
+ subject: (identifier) @name) @reference.call
+(function_composition
+ name: (identifier) @name) @reference.call
+
+(variable (identifier) @name) @definition.variable
+
+(value (identifier_reference) @name) @reference.type
+
+;; ---------------------------------------------------------------------------
+;;Methods/Functions
+;; ---------------------------------------------------------------------------
+
+(function_signature name: (identifier) @name) @definition.function
+(function_signature (function_type_reference) @name) @reference.type
+(function_parameter name: (identifier) @name) @definition.variable
+
+

tree_sitter_sdml-0.4.14.dist-info/METADATA

@@ -0,0 +1,119 @@
+Metadata-Version: 2.4
+Name: tree-sitter-sdml
+Version: 0.4.14
+Summary: SDML grammar for tree-sitter
+License-Expression: Apache-2.0
+Project-URL: Homepage, https://github.com/tree-sitter/tree-sitter-sdml
+Keywords: incremental,parsing,tree-sitter,sdml
+Classifier: Intended Audience :: Developers
+Classifier: Topic :: Software Development :: Compilers
+Classifier: Topic :: Text Processing :: Linguistic
+Classifier: Typing :: Typed
+Requires-Python: >=3.9
+Description-Content-Type: text/markdown
+License-File: LICENSE
+Provides-Extra: core
+Requires-Dist: tree-sitter~=0.24; extra == "core"
+Dynamic: license-file
+
+# Tree-Sitter grammar for SDML
+
+![SDML Logo Text](https://raw.githubusercontent.com/sdm-lang/.github/main/profile/horizontal-text.svg)
+
+A [tree-sitter](https://tree-sitter.github.io/tree-sitter/) grammar for the Simple Domain Modeling Language (SDML). For more
+information on the language, see the [documentation](https://sdml.io/).
+
+## Example
+
+```sdml
+module campaign <https://advertising.amazon.com/api-model> is
+
+  import [dc rdfs skos]
+
+  @skos:prefLabel = "Campaign sub-domain"@en
+  @skos:version = xsd:decimal(2)
+
+  datatype Name <- string {
+    minLength = 5
+    maxLength = 25
+  }
+
+  datatype Identifier <- opaque string {
+    length = 20
+  } is
+    @dc:description = "An opaque, general, entity identifier."@en
+  end
+
+  property CampaignId -> Identifier is
+    @skos:prefLabel = [
+      "Campaign Identifier"@en
+      "Identified de campagne"@fr
+    ]
+    @dc:description = "The globally unique identifier for a Campaign entity"@en
+  end
+
+  structure Tag is
+    key -> token
+    value -> {0..} rdfs:langString
+  end
+
+  entity Campaign is
+    identity ref CampaignId
+
+    name -> Name is
+      @skos:definition = "the name of the campaign"@en
+    end
+
+    tag -> {unordered unique 0..} Tag
+
+    target -> {1..} Target
+  end
+
+  entity Target
+
+end
+```
+
+## Bindings
+
+The following bindings are built and released along with any version upgrade of
+the source version. The tree-sitter tool also generates bindings for C, Go, and
+Swift that are not built and released to any repository.
+
+[Node](https://www.npmjs.com/package/tree-sitter-sdml) bindings are published to npmjs and can be installed using the
+npm command directly, or by making it a project dependency.
+
+```sh
+〉npm install -g tree_sitter_sdml
+```
+
+[Python](https://pypi.org/project/tree-sitter-sdml/) bindings are published to PyPI and can be installed using any
+standard tool, such as `pip`.
+
+```sh
+〉pip3 install tree_sitter_sdml
+```
+
+[Rust](https://crates.io/crates/tree-sitter-sdml) bindings are published to crates.io and can be installed via cargo in
+the usual manner.
+
+```sh
+〉cargo install tree_sitter_sdml
+```
+
+## License
+
+This package is released under the Apache License, Version 2.0. See LICENSE file
+for details.
+
+## Changes
+
+See [CHANGES.md](CHANGES.md).
+
+## Additional Links
+
+* Node bindings -- [npm.js](https://www.npmjs.com/package/tree-sitter-sdml)
+* Rust bindings -- [crates.io](https://crates.io/crates/tree-sitter-sdml)
+* Python bindings -- [PyPi.org](https://pypi.org/project/tree-sitter-sdml/)
+* Emacs -- [sdml-mode](https://github.com/johnstonskj/emacs-sdml-mode)
+* Command-line tool -- [rust-sdml](https://github.com/johnstonskj/rust-sdml)

tree_sitter_sdml-0.4.14.dist-info/RECORD

@@ -0,0 +1,16 @@
+tree_sitter_sdml/__init__.py,sha256=g0qr3eU5qacqFg6h3LRXWM-gR6DWB_2reNaa2e3YHGg,87
+tree_sitter_sdml/__init__.pyi,sha256=8xf7bY1szgDY9HRJ7FJ326So4SFgMiSRfCB4LADkTpU,27
+tree_sitter_sdml/_binding.abi3.so,sha256=oJ2aNjh5mK4fDHQ9Svf1cE5WdAF1kGj3t6BVSI9Zhys,334288
+tree_sitter_sdml/binding.c,sha256=hIOIfEB_EZtSOw-YXhtUC6hrjVcWu1dprH4Mqr_mQgA,632
+tree_sitter_sdml/py.typed,sha256=47DEQpj8HBSa-_TImW-5JCeuQeRkm5NMpJWZG3hSuFU,0
+tree_sitter_sdml/queries/folds.scm,sha256=EVxryE6mnvAaqcVk22558Yu_CZP9v2KuUz_riZULd-g,550
+tree_sitter_sdml/queries/highlights.scm,sha256=lIRp8I2FA-KFkhrni2cMnsyGVsQ1754jHpxHVGNIBAk,11681
+tree_sitter_sdml/queries/indent.scm,sha256=deoc6ympjOkPAJs7icybMz-UjsHGF155Zo_LMkkaMZA,797
+tree_sitter_sdml/queries/injections.scm,sha256=47DEQpj8HBSa-_TImW-5JCeuQeRkm5NMpJWZG3hSuFU,0
+tree_sitter_sdml/queries/locals.scm,sha256=47DEQpj8HBSa-_TImW-5JCeuQeRkm5NMpJWZG3hSuFU,0
+tree_sitter_sdml/queries/tags.scm,sha256=qO3FuV8HSx9KsarJHPRvY7HnIKJ0VFgxLmOQYHaqbus,4487
+tree_sitter_sdml-0.4.14.dist-info/licenses/LICENSE,sha256=z8d0m5b2O9McPEK1xHG_dWgUBT6EfBDz6wA0F7xSPTA,11358
+tree_sitter_sdml-0.4.14.dist-info/METADATA,sha256=NQXIthZ00h-cw_1z1JPs7vgIO-HhNwCixluFRK085cM,3240
+tree_sitter_sdml-0.4.14.dist-info/WHEEL,sha256=RxUjDmAUOiM8G0eRef23tQUtC5E-_2HJ9D_sESI72Ns,107
+tree_sitter_sdml-0.4.14.dist-info/top_level.txt,sha256=mjYcPEFKBqOfnZnvfs53_iiNcwLJ4gnYmgtQmFeY0i4,26
+tree_sitter_sdml-0.4.14.dist-info/RECORD,,

tree_sitter_sdml-0.4.14.dist-info/WHEEL

@@ -0,0 +1,5 @@
+Wheel-Version: 1.0
+Generator: setuptools (80.9.0)
+Root-Is-Purelib: false
+Tag: cp38-abi3-macosx_11_0_arm64
+

tree_sitter_sdml-0.4.14.dist-info/licenses/LICENSE

@@ -0,0 +1,202 @@
+
+                                 Apache License
+                           Version 2.0, January 2004
+                        http://www.apache.org/licenses/
+
+   TERMS AND CONDITIONS FOR USE, REPRODUCTION, AND DISTRIBUTION
+
+   1. Definitions.
+
+      "License" shall mean the terms and conditions for use, reproduction,
+      and distribution as defined by Sections 1 through 9 of this document.
+
+      "Licensor" shall mean the copyright owner or entity authorized by
+      the copyright owner that is granting the License.
+
+      "Legal Entity" shall mean the union of the acting entity and all
+      other entities that control, are controlled by, or are under common
+      control with that entity. For the purposes of this definition,
+      "control" means (i) the power, direct or indirect, to cause the
+      direction or management of such entity, whether by contract or
+      otherwise, or (ii) ownership of fifty percent (50%) or more of the
+      outstanding shares, or (iii) beneficial ownership of such entity.
+
+      "You" (or "Your") shall mean an individual or Legal Entity
+      exercising permissions granted by this License.
+
+      "Source" form shall mean the preferred form for making modifications,
+      including but not limited to software source code, documentation
+      source, and configuration files.
+
+      "Object" form shall mean any form resulting from mechanical
+      transformation or translation of a Source form, including but
+      not limited to compiled object code, generated documentation,
+      and conversions to other media types.
+
+      "Work" shall mean the work of authorship, whether in Source or
+      Object form, made available under the License, as indicated by a
+      copyright notice that is included in or attached to the work
+      (an example is provided in the Appendix below).
+
+      "Derivative Works" shall mean any work, whether in Source or Object
+      form, that is based on (or derived from) the Work and for which the
+      editorial revisions, annotations, elaborations, or other modifications
+      represent, as a whole, an original work of authorship. For the purposes
+      of this License, Derivative Works shall not include works that remain
+      separable from, or merely link (or bind by name) to the interfaces of,
+      the Work and Derivative Works thereof.
+
+      "Contribution" shall mean any work of authorship, including
+      the original version of the Work and any modifications or additions
+      to that Work or Derivative Works thereof, that is intentionally
+      submitted to Licensor for inclusion in the Work by the copyright owner
+      or by an individual or Legal Entity authorized to submit on behalf of
+      the copyright owner. For the purposes of this definition, "submitted"
+      means any form of electronic, verbal, or written communication sent
+      to the Licensor or its representatives, including but not limited to
+      communication on electronic mailing lists, source code control systems,
+      and issue tracking systems that are managed by, or on behalf of, the
+      Licensor for the purpose of discussing and improving the Work, but
+      excluding communication that is conspicuously marked or otherwise
+      designated in writing by the copyright owner as "Not a Contribution."
+
+      "Contributor" shall mean Licensor and any individual or Legal Entity
+      on behalf of whom a Contribution has been received by Licensor and
+      subsequently incorporated within the Work.
+
+   2. Grant of Copyright License. Subject to the terms and conditions of
+      this License, each Contributor hereby grants to You a perpetual,
+      worldwide, non-exclusive, no-charge, royalty-free, irrevocable
+      copyright license to reproduce, prepare Derivative Works of,
+      publicly display, publicly perform, sublicense, and distribute the
+      Work and such Derivative Works in Source or Object form.
+
+   3. Grant of Patent License. Subject to the terms and conditions of
+      this License, each Contributor hereby grants to You a perpetual,
+      worldwide, non-exclusive, no-charge, royalty-free, irrevocable
+      (except as stated in this section) patent license to make, have made,
+      use, offer to sell, sell, import, and otherwise transfer the Work,
+      where such license applies only to those patent claims licensable
+      by such Contributor that are necessarily infringed by their
+      Contribution(s) alone or by combination of their Contribution(s)
+      with the Work to which such Contribution(s) was submitted. If You
+      institute patent litigation against any entity (including a
+      cross-claim or counterclaim in a lawsuit) alleging that the Work
+      or a Contribution incorporated within the Work constitutes direct
+      or contributory patent infringement, then any patent licenses
+      granted to You under this License for that Work shall terminate
+      as of the date such litigation is filed.
+
+   4. Redistribution. You may reproduce and distribute copies of the
+      Work or Derivative Works thereof in any medium, with or without
+      modifications, and in Source or Object form, provided that You
+      meet the following conditions:
+
+      (a) You must give any other recipients of the Work or
+          Derivative Works a copy of this License; and
+
+      (b) You must cause any modified files to carry prominent notices
+          stating that You changed the files; and
+
+      (c) You must retain, in the Source form of any Derivative Works
+          that You distribute, all copyright, patent, trademark, and
+          attribution notices from the Source form of the Work,
+          excluding those notices that do not pertain to any part of
+          the Derivative Works; and
+
+      (d) If the Work includes a "NOTICE" text file as part of its
+          distribution, then any Derivative Works that You distribute must
+          include a readable copy of the attribution notices contained
+          within such NOTICE file, excluding those notices that do not
+          pertain to any part of the Derivative Works, in at least one
+          of the following places: within a NOTICE text file distributed
+          as part of the Derivative Works; within the Source form or
+          documentation, if provided along with the Derivative Works; or,
+          within a display generated by the Derivative Works, if and
+          wherever such third-party notices normally appear. The contents
+          of the NOTICE file are for informational purposes only and
+          do not modify the License. You may add Your own attribution
+          notices within Derivative Works that You distribute, alongside
+          or as an addendum to the NOTICE text from the Work, provided
+          that such additional attribution notices cannot be construed
+          as modifying the License.
+
+      You may add Your own copyright statement to Your modifications and
+      may provide additional or different license terms and conditions
+      for use, reproduction, or distribution of Your modifications, or
+      for any such Derivative Works as a whole, provided Your use,
+      reproduction, and distribution of the Work otherwise complies with
+      the conditions stated in this License.
+
+   5. Submission of Contributions. Unless You explicitly state otherwise,
+      any Contribution intentionally submitted for inclusion in the Work
+      by You to the Licensor shall be under the terms and conditions of
+      this License, without any additional terms or conditions.
+      Notwithstanding the above, nothing herein shall supersede or modify
+      the terms of any separate license agreement you may have executed
+      with Licensor regarding such Contributions.
+
+   6. Trademarks. This License does not grant permission to use the trade
+      names, trademarks, service marks, or product names of the Licensor,
+      except as required for reasonable and customary use in describing the
+      origin of the Work and reproducing the content of the NOTICE file.
+
+   7. Disclaimer of Warranty. Unless required by applicable law or
+      agreed to in writing, Licensor provides the Work (and each
+      Contributor provides its Contributions) on an "AS IS" BASIS,
+      WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or
+      implied, including, without limitation, any warranties or conditions
+      of TITLE, NON-INFRINGEMENT, MERCHANTABILITY, or FITNESS FOR A
+      PARTICULAR PURPOSE. You are solely responsible for determining the
+      appropriateness of using or redistributing the Work and assume any
+      risks associated with Your exercise of permissions under this License.
+
+   8. Limitation of Liability. In no event and under no legal theory,
+      whether in tort (including negligence), contract, or otherwise,
+      unless required by applicable law (such as deliberate and grossly
+      negligent acts) or agreed to in writing, shall any Contributor be
+      liable to You for damages, including any direct, indirect, special,
+      incidental, or consequential damages of any character arising as a
+      result of this License or out of the use or inability to use the
+      Work (including but not limited to damages for loss of goodwill,
+      work stoppage, computer failure or malfunction, or any and all
+      other commercial damages or losses), even if such Contributor
+      has been advised of the possibility of such damages.
+
+   9. Accepting Warranty or Additional Liability. While redistributing
+      the Work or Derivative Works thereof, You may choose to offer,
+      and charge a fee for, acceptance of support, warranty, indemnity,
+      or other liability obligations and/or rights consistent with this
+      License. However, in accepting such obligations, You may act only
+      on Your own behalf and on Your sole responsibility, not on behalf
+      of any other Contributor, and only if You agree to indemnify,
+      defend, and hold each Contributor harmless for any liability
+      incurred by, or claims asserted against, such Contributor by reason
+      of your accepting any such warranty or additional liability.
+
+   END OF TERMS AND CONDITIONS
+
+   APPENDIX: How to apply the Apache License to your work.
+
+      To apply the Apache License to your work, attach the following
+      boilerplate notice, with the fields enclosed by brackets "[]"
+      replaced with your own identifying information. (Don't include
+      the brackets!)  The text should be enclosed in the appropriate
+      comment syntax for the file format. We also recommend that a
+      file or class name and description of purpose be included on the
+      same "printed page" as the copyright notice for easier
+      identification within third-party archives.
+
+   Copyright [yyyy] [name of copyright owner]
+
+   Licensed under the Apache License, Version 2.0 (the "License");
+   you may not use this file except in compliance with the License.
+   You may obtain a copy of the License at
+
+       http://www.apache.org/licenses/LICENSE-2.0
+
+   Unless required by applicable law or agreed to in writing, software
+   distributed under the License is distributed on an "AS IS" BASIS,
+   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+   See the License for the specific language governing permissions and
+   limitations under the License.

tree_sitter_sdml-0.4.14.dist-info/top_level.txt

@@ -0,0 +1,2 @@
+_binding
+tree_sitter_sdml