tree-sitter-gnuplot 2.0.1__cp310-abi3-win_arm64.whl

tree_sitter_gnuplot/__init__.py

@@ -0,0 +1,42 @@
+"""A tree-sitter grammar for gnuplot"""
+
+from importlib.resources import files as _files
+
+from ._binding import language
+
+
+def _get_query(name, file):
+    query = _files(f"{__package__}.queries") / file
+    globals()[name] = query.read_text()
+    return globals()[name]
+
+
+def __getattr__(name):
+    # NOTE: uncomment these to include any queries that this grammar contains:
+
+    # if name == "HIGHLIGHTS_QUERY":
+    #     return _get_query("HIGHLIGHTS_QUERY", "highlights.scm")
+    # if name == "INJECTIONS_QUERY":
+    #     return _get_query("INJECTIONS_QUERY", "injections.scm")
+    # if name == "LOCALS_QUERY":
+    #     return _get_query("LOCALS_QUERY", "locals.scm")
+    # if name == "TAGS_QUERY":
+    #     return _get_query("TAGS_QUERY", "tags.scm")
+
+    raise AttributeError(f"module {__name__!r} has no attribute {name!r}")
+
+
+__all__ = [
+    "language",
+    # "HIGHLIGHTS_QUERY",
+    # "INJECTIONS_QUERY",
+    # "LOCALS_QUERY",
+    # "TAGS_QUERY",
+]
+
+
+def __dir__():
+    return sorted(__all__ + [
+        "__all__", "__builtins__", "__cached__", "__doc__", "__file__",
+        "__loader__", "__name__", "__package__", "__path__", "__spec__",
+    ])

tree_sitter_gnuplot/__init__.pyi

@@ -0,0 +1,10 @@
+from typing import Final
+
+# NOTE: uncomment these to include any queries that this grammar contains:
+
+# HIGHLIGHTS_QUERY: Final[str]
+# INJECTIONS_QUERY: Final[str]
+# LOCALS_QUERY: Final[str]
+# TAGS_QUERY: Final[str]
+
+def language() -> object: ...

tree_sitter_gnuplot/binding.c

@@ -0,0 +1,35 @@
+#include <Python.h>
+
+typedef struct TSLanguage TSLanguage;
+
+TSLanguage *tree_sitter_gnuplot(void);
+
+static PyObject* _binding_language(PyObject *Py_UNUSED(self), PyObject *Py_UNUSED(args)) {
+    return PyCapsule_New(tree_sitter_gnuplot(), "tree_sitter.Language", NULL);
+}
+
+static struct PyModuleDef_Slot slots[] = {
+#ifdef Py_GIL_DISABLED
+    {Py_mod_gil, Py_MOD_GIL_NOT_USED},
+#endif
+    {0, NULL}
+};
+
+static PyMethodDef methods[] = {
+    {"language", _binding_language, METH_NOARGS,
+     "Get the tree-sitter language for this grammar."},
+    {NULL, NULL, 0, NULL}
+};
+
+static struct PyModuleDef module = {
+    .m_base = PyModuleDef_HEAD_INIT,
+    .m_name = "_binding",
+    .m_doc = NULL,
+    .m_size = 0,
+    .m_methods = methods,
+    .m_slots = slots,
+};
+
+PyMODINIT_FUNC PyInit__binding(void) {
+    return PyModuleDef_Init(&module);
+}

tree_sitter_gnuplot/queries/folds.scm

@@ -0,0 +1,8 @@
+; Block commands with explicit delimiters
+(cmd_do) @fold
+(cmd_if) @fold
+(cmd_while) @fold
+(def_datablock) @fold
+
+; set multiplot … unset multiplot region (one node in the grammar)
+(multiplot_block) @fold

tree_sitter_gnuplot/queries/highlights.scm

@@ -0,0 +1,434 @@
+; highlights.scm
+(comment) @comment @spell
+
+"variable" @variable.parameter
+
+; built-in named values (palette presets, special color names)
+; TODO: decide and collapse (bgnd & background same)
+; black/viridis constant?
+[
+  "viridis"
+  "black"
+  "bgnd"
+  "background"
+] @variable.parameter.builtin
+
+(identifier) @variable
+
+[
+  "["
+  "]"
+  "("
+  ")"
+  "{"
+  "}"
+] @punctuation.bracket
+
+(operator) @operator
+
+[
+  "="
+  ","
+  ":"
+] @operator
+
+(keyword_op) @keyword.operator
+
+(ternary_op) @keyword.conditional.ternary
+
+; TODO: collapse
+[
+  "for"
+  "in"
+  "do"
+  "while"
+] @keyword.repeat
+
+; -----------------------------------------------------------------------
+; Commands
+"cmd" @keyword
+
+; TODO: decide and collapse
+[
+  "newhistogram"
+  "newspiderplot"
+  "keyentry"
+] @keyword
+
+; TODO: decide inverse, sample
+[
+  "inverse"
+  "sample"
+  "kw_fn"
+] @keyword.function
+
+"kw_cond" @keyword.conditional
+
+; TODO: decide and collapse
+[
+  "front"
+  "back"
+  "depthorder"
+  "clip"
+  "font"
+  "filled"
+  "nofilled"
+  "parallel"
+  ; coordinate systems (first/second/graph/screen/character/polar) — alias "coord"
+  "coord"
+] @keyword.directive
+
+; on/off toggle flags ({no}X) — alias "flag" (@keyword.modifier)
+"flag" @keyword.directive
+
+; enumerated VALUES / modes (alias "mod") — @constant
+; TODO: decide, constant?
+"mod" @constant
+
+; plot/splot ELEMENT modifiers (alias "attr") — @property
+; (title/notitle/with/using/index/every/axes/smooth in a plot command;
+;  distinct from set-option names which are @variable.member)
+"attr" @property
+
+; -----------------------------------------------------------------------
+; TODO: decide and collapse
+[
+  ; Terminal output path
+  "name"
+  ; Style attribute shorthands (K constants + datafile keywords)
+  "sa"
+  "dt"
+  "fc"
+  "fs"
+  "lc"
+  "lt"
+  "ps"
+  "pt"
+  "tc"
+  "skip"
+  "expand"
+  "title"
+  ; set/show argument keywords (all key("...", n, "arg") aliases)
+  "arg"
+] @variable.member
+
+
+; -----------------------------------------------------------------------
+; Option keywords
+; TODO: decide and collapse
+[
+  ; coordinate systems / axes
+  "unit"
+  "axes_opts"
+  ; time units (set xdata time / timefmt)
+  "seconds"
+  "minutes"
+  "hours"
+  "days"
+  "weeks"
+  "months"
+  "years"
+  ; smooth subtypes still emitted as own token (value-modes csplines/bezier/… → "mod")
+  "kdensity"
+  "closed"
+  "between"
+  "above"
+  "below"
+  ; plot / datafile misc
+  "pixels"
+  "whiskerbars"
+  "beginning"
+  "long"
+  ; positioning / key
+  "base"
+  "begin"
+  "center"
+  "end"
+  ; pm3d / 3d options
+  "clip1in"
+  "clip4in"
+  "c2c"
+  "retrace"
+  ; data separators
+  "whitespace"
+  "tab"
+  "comma"
+  ; palette stack
+  "push"
+  "pop"
+  ; flip binary axes
+  "flipx"
+  "flipy"
+  "flipz"
+  ; binary datafile modifiers
+  "binary"
+  "format"
+  "filetype"
+  "record"
+  "array"
+  "origin"
+  "dx"
+  "dy"
+  "width"
+  "level"
+  "matrix"
+  "nonuniform"
+  "sparse"
+  "volatile"
+  "noautoscale"
+  "zsort"
+  "mask"
+  "transpose"
+  ; endian options (binary)
+  "endian"
+  "little"
+  "big"
+  "swap"
+  "swab"
+  "middle"
+  "pdp"
+  ; fit modifiers
+  "unitweights"
+  "errors"
+  ; pause endconditions
+  "mouse"
+  "keypress"
+  "button1"
+  "button2"
+  "button3"
+  "close"
+  "any"
+  ; history command options
+  "append"
+  "quiet"
+  "numbers"
+  "trim"
+  "full"
+  ; pixmap
+  ; coordinate axis-family prefix (the coord systems first/second/graph/screen/
+  ; character/polar are aliased to (coord) -> @keyword.directive below)
+  "axis"
+  ; position direction aliases
+  "cen"
+  "lef"
+  "rig"
+  ; geometry / arrow options
+  "angle"
+  "length"
+  "head"
+  "inout"
+  ; offset / scale
+  "offset"
+  "nooffset"
+  "scale"
+  ; orientation
+  ; angle units
+  ; contour / palette / axis
+  "range"
+  "missing"
+  "interpolate"
+  "autofreq"
+  "autojustify"
+  ; rotation
+  "rotate"
+  ; border / extend / range modifiers
+  "restore"
+  ; pm3d
+  "scanorder"
+  "position"
+  ; histogram subtypes
+  ; smooth additions
+  ; key/label placement
+  ; fill pattern
+  "pattern"
+  ; 3d / surface
+  "s"
+  ; data / fit extras
+  "variables"
+  "logfile"
+  "nologfile"
+  "datablocks"
+  "commentschars"
+  "functions"
+  ; misc
+  ; coordinate planes / walls
+  "version"
+  ; colorspec
+  "rgbcolor"
+  ; tics
+  ; set size
+  ; set fit
+  "maxiter"
+  "default"
+  ; label / style
+  ; set view
+  "map"
+  ; set theta direction
+  ; palette model / presets / cubehelix options
+  "model"
+  ; pm3d / lighting
+  "corners2color"
+  "primary"
+  "specular"
+  "spec2"
+  ; dgrid3d subtype (gauss/… value-modes → "mod")
+  "splines"
+  ; contour / cntrparam
+  ; tics axes / modifiers
+  "add"
+  ; text / font / encoding
+  "fontscale"
+  "utf8"
+  ; fill / size style
+  "empty"
+  ; layout / spacing / multiplot
+  "layout"
+  "spacing"
+  "frac"
+  ; color names in style contexts
+  "cb"
+  ; filledcurves axis coordinate (x1, x2, y1, y2 etc.)
+  "coordinate"
+  ; watch-label / surface options
+  "point"
+  ; tics keyword (grid / paxis — covers xtics, ytics, ztics contexts)
+  "tics"
+  ; histogram fill style
+  ; jitter options
+  ; key command options
+  ; paxis label keyword (key("label",3) with default aka="label")
+  "label"
+  ; polar coordinate system and grid option
+  ; polar grid axis ranges
+  "theta"
+  "r"
+  ; ellipses style
+  "units"
+  ; stats output prefix
+  "prefix"
+  ; palette formula option
+  ; pm3d z-clip
+  "z"
+  ; grid mode
+  ; datafile option
+  ; textbox / multiplot margins (anonymous "margins" string)
+  "margins"
+  ; datafile lc/fc palette shorthand
+  "palette"
+  ; set fit quiet / results / verbose / brief
+  "fit_out"
+] @variable.member
+
+; -----------------------------------------------------------------------
+; Presentation / style attributes
+; TODO: decide and collapse
+[
+  "size"
+  "monochrome"
+  "color"
+  "transparent"
+  ; palette colour models (set palette model)
+  "RGB"
+  "CMY"
+  "HSV"
+  "nobackground"
+  "separator"
+  (hull)
+  "units_opt"
+  ; fill / line style modes
+  "solid"
+  "dashed"
+  ; page orientation
+  "landscape"
+  "portrait"
+  ; terminal options
+  "animate"
+  "input"
+  "colortext"
+  "blacktext"
+  ; point type names (ps/tikz terminals)
+  "texpoints"
+  "normalpoints"
+  "mpoints"
+  "smallpoints"
+  "tinypoints"
+  "pspoints"
+  "nopspoints"
+  ; key alignment (capitalised)
+  ; layer / style misc
+
+  "st_opt"
+  "plt_st"
+] @attribute
+
+
+; binary filetype= value (png/jpg/gif/bin parsed as identifier in field)
+(binary_options
+  filetype: (identifier) @attribute)
+
+; -----------------------------------------------------------------------
+; Macro / datablock identifiers
+(macro) @function.macro
+
+(datablock) @module
+
+[
+  (datablock_start)
+  (datablock_end)
+] @label
+
+; -----------------------------------------------------------------------
+; Functions
+(function
+  name: (identifier) @function)
+
+((function
+  name: (identifier) @function.builtin)
+  (#any-of? @function.builtin
+    "abs" "acos" "acosh" "airy" "arg" "asin" "asinh" "atan" "atan2" "atanh" "besj0" "besj1" "besjn"
+    "besy0" "besy1" "besyn" "besi0" "besi1" "besin" "cbrt" "ceil" "conj" "cos" "cosh" "EllipticK"
+    "EllipticE" "EllipticPi" "erf" "erfc" "exp" "expint" "floor" "gamma" "ibeta" "inverf" "igamma"
+    "imag" "int" "invnorm" "invibeta" "invigamma" "LambertW" "lambertw" "lgamma" "lnGamma" "log"
+    "log10" "norm" "rand" "real" "round" "sgn" "sin" "sinh" "sqrt" "SynchrotronF" "tan" "tanh"
+    "uigamma" "voigt" "zeta" "cerf" "cdawson" "faddeva" "erfi" "FresnelC" "FresnelS" "VP" "VP_fwhm"
+    "Ai" "Bi" "BesselH1" "BesselH2" "BesselJ" "BesselY" "BesselI" "BesselK" "gprintf" "sprintf"
+    "strlen" "strstrt" "substr" "strptime" "srtftime" "system" "trim" "word" "words" "time"
+    "timecolumn" "tm_hour" "tm_mday" "tm_min" "tm_mon" "tm_sec" "tm_wday" "tm_week" "tm_yday"
+    "tm_year" "weekday_iso" "weekday_cdc" "column" "columnhead" "exists" "hsv2rgb" "index" "palette"
+    "rgbcolor" "stringcolumn" "valid" "value" "voxel"))
+
+; -----------------------------------------------------------------------
+; Built-in variables (stats output, GPVAL_*, etc.)
+((identifier) @variable.builtin
+  (#match? @variable.builtin
+    "^\\w+_(records|headers|outofrange|invalid|blank|blocks|columns|column_header|index_(min|max)(_x|_y)?|(min|max)(_x|_y)?|mean(_err)?(_x|_y)?|stddev(_err)?(_x|_y)?)$"))
+
+((identifier) @variable.builtin
+  (#match? @variable.builtin
+    "^\\w+_(sdd(_x|_y)?|(lo|up)_quartile(_x|_y)?|median(_x|_y)?|sum(sq)?(_x|_y)?|skewness(_err)?(_x|_y)?)$"))
+
+((identifier) @variable.builtin
+  (#match? @variable.builtin
+    "^\\w+_(kurtosis(_err)?(_x|_y)?|adev(_x|_y)?|correlation|slope(_err)?|intercept(_err)?|sumxy|pos_(min|max)_y|size(_x|_y))$"))
+
+((identifier) @variable.builtin
+  (#match? @variable.builtin
+    "^((GPVAL|MOUSE|FIT)_\\w+|GNUTERM|NaN|Inf|VoxelDistance|GridDistance|pi|ARG\\w+)$"))
+
+; -----------------------------------------------------------------------
+; Array definitions
+(def_array
+  "array" @keyword.function)
+
+(array
+  (identifier) @function)
+
+; -----------------------------------------------------------------------
+; Literals
+(number) @number
+
+(string_literal) @string
+
+(escape_sequence) @string.escape
+
+(format_specifier) @string.special

tree_sitter_gnuplot/queries/injections.scm

@@ -0,0 +1,17 @@
+((comment_content) @injection.content
+  (#set! injection.language "comment"))
+
+; system "command" / ! "command" → bash
+(cmd_system (string_literal) @injection.content
+  (#set! injection.language "bash"))
+
+; ! ls / system ls → bash (single identifier)
+(cmd_system (identifier) @injection.content
+  (#set! injection.language "bash"))
+
+; system("command") → bash
+((function
+    name: (identifier) @_name
+    parameters: (parameter_list (string_literal) @injection.content))
+  (#eq? @_name "system")
+  (#set! injection.language "bash"))

tree_sitter_gnuplot-2.0.1.dist-info/METADATA

@@ -0,0 +1,39 @@
+Metadata-Version: 2.4
+Name: tree-sitter-gnuplot
+Version: 2.0.1
+Summary: A tree-sitter grammar for gnuplot
+Author-email: Dai López Jacinto <dpezto@gmail.com>
+License: MIT
+Project-URL: Homepage, https://github.com/dpezto/tree-sitter-gnuplot
+Project-URL: Funding, https://github.com/dpezto/tree-sitter-gnuplot
+Keywords: incremental,parsing,tree-sitter,gnuplot
+Classifier: Intended Audience :: Developers
+Classifier: Topic :: Software Development :: Compilers
+Classifier: Topic :: Text Processing :: Linguistic
+Classifier: Typing :: Typed
+Requires-Python: >=3.10
+Description-Content-Type: text/markdown
+License-File: LICENSE
+Provides-Extra: core
+Requires-Dist: tree-sitter~=0.24; extra == "core"
+Dynamic: license-file
+
+# tree-sitter-gnuplot
+[![CI](https://github.com/dpezto/tree-sitter-gnuplot/actions/workflows/ci.yml/badge.svg)](https://github.com/dpezto/tree-sitter-gnuplot/actions/workflows/ci.yml)
+[![codecov](https://codecov.io/gh/dpezto/tree-sitter-gnuplot/branch/main/graph/badge.svg)](https://codecov.io/gh/dpezto/tree-sitter-gnuplot)
+[![npm](https://img.shields.io/npm/v/tree-sitter-gnuplot?logo=npm)](https://www.npmjs.com/package/tree-sitter-gnuplot)
+[![crates.io](https://img.shields.io/crates/v/tree-sitter-gnuplot?logo=rust)](https://crates.io/crates/tree-sitter-gnuplot)
+[![PyPI](https://img.shields.io/pypi/v/tree-sitter-gnuplot?logo=pypi)](https://pypi.org/project/tree-sitter-gnuplot/)
+[![License: MIT](https://img.shields.io/badge/License-MIT-blue.svg)](LICENSE)
+[![PRs Welcome][prs-badge]](https://makeapullrequest.com)
+
+A tree-sitter grammar for [gnuplot 6.x](http://gnuplot.info).
+
+Supports `.gnuplot`, `.gp`, `.plt`, `.plot`, `.gnu` files. Built with an external
+scanner for command disambiguation, comprehensive syntax highlighting queries, and
+92 corpus tests.
+
+This project is the next evolution of [gnuplot.vim](https://github.com/dpezto/gnuplot.vim),
+designed for accuracy to gnuplot 6 syntax and long-term maintainability.
+
+[prs-badge]: https://img.shields.io/badge/PRs-welcome-brightgreen.svg?style=flat&logo=data%3Aimage%2Fsvg%2Bxml%3Bbase64%2CPD94bWwgdmVyc2lvbj0iMS4wIiBlbmNvZGluZz0iVVRGLTgiPz48c3ZnIGlkPSJzdmcyIiB3aWR0aD0iNjQ1IiBoZWlnaHQ9IjU4NSIgdmVyc2lvbj0iMS4wIiB4bWxucz0iaHR0cDovL3d3dy53My5vcmcvMjAwMC9zdmciPiA8ZyBpZD0ibGF5ZXIxIj4gIDxwYXRoIGlkPSJwYXRoMjQxNyIgZD0ibTI5Ny4zIDU1MC44N2MtMTMuNzc1LTE1LjQzNi00OC4xNzEtNDUuNTMtNzYuNDM1LTY2Ljg3NC04My43NDQtNjMuMjQyLTk1LjE0Mi03Mi4zOTQtMTI5LjE0LTEwMy43LTYyLjY4NS01Ny43Mi04OS4zMDYtMTE1LjcxLTg5LjIxNC0xOTQuMzQgMC4wNDQ1MTItMzguMzg0IDIuNjYwOC01My4xNzIgMTMuNDEtNzUuNzk3IDE4LjIzNy0zOC4zODYgNDUuMS02Ni45MDkgNzkuNDQ1LTg0LjM1NSAyNC4zMjUtMTIuMzU2IDM2LjMyMy0xNy44NDUgNzYuOTQ0LTE4LjA3IDQyLjQ5My0wLjIzNDgzIDUxLjQzOSA0LjcxOTcgNzYuNDM1IDE4LjQ1MiAzMC40MjUgMTYuNzE0IDYxLjc0IDUyLjQzNiA2OC4yMTMgNzcuODExbDMuOTk4MSAxNS42NzIgOS44NTk2LTIxLjU4NWM1NS43MTYtMTIxLjk3IDIzMy42LTEyMC4xNSAyOTUuNSAzLjAzMTYgMTkuNjM4IDM5LjA3NiAyMS43OTQgMTIyLjUxIDQuMzgwMSAxNjkuNTEtMjIuNzE1IDYxLjMwOS02NS4zOCAxMDguMDUtMTY0LjAxIDE3OS42OC02NC42ODEgNDYuOTc0LTEzNy44OCAxMTguMDUtMTQyLjk4IDEyOC4wMy01LjkxNTUgMTEuNTg4LTAuMjgyMTYgMS44MTU5LTI2LjQwOC0yNy40NjF6IiBmaWxsPSIjZGQ1MDRmIi8%2BIDwvZz48L3N2Zz4%3D

tree_sitter_gnuplot-2.0.1.dist-info/RECORD

@@ -0,0 +1,13 @@
+tree_sitter_gnuplot/__init__.py,sha256=CAJjsYyj5nGeAwbqq4N5OLvuoz7Z_dJKmrC5E4XFMXc,1158
+tree_sitter_gnuplot/__init__.pyi,sha256=oixFm8lXsZZWYa5cRwj6brbqh37_fzN2rLE-dmX9_rA,247
+tree_sitter_gnuplot/_binding.pyd,sha256=2zfceZNWLrzD28YDAkyI4hskiYxdm7kk2LLkbSRIOvQ,9722368
+tree_sitter_gnuplot/binding.c,sha256=Oaun8hGMrnTMxNv2kaVsgsnLAAHYmyBrxoAUW5nBXjI,838
+tree_sitter_gnuplot/py.typed,sha256=47DEQpj8HBSa-_TImW-5JCeuQeRkm5NMpJWZG3hSuFU,0
+tree_sitter_gnuplot/queries/folds.scm,sha256=UzbJxDZv27jSTG1dFVdX6x6dLt6iDyAv0lm-ti3hA9o,206
+tree_sitter_gnuplot/queries/highlights.scm,sha256=oPtV43QJYVune6tS1qbtFbb98eyS0cJJlM5I7b3snT8,9007
+tree_sitter_gnuplot/queries/injections.scm,sha256=5tMAWf6xu4UKtA8UHmQr-iEgbFLv83cNqUztid1Il9E,539
+tree_sitter_gnuplot-2.0.1.dist-info/licenses/LICENSE,sha256=JicS0klC2zmi4MYqZ2l2O-RtiaDNmGZbB1b1R7SW3j8,1067
+tree_sitter_gnuplot-2.0.1.dist-info/METADATA,sha256=X5eenm6dFCh7-jkBj6rsbBLDsmAcvUVeiF-rcGPNG_0,3157
+tree_sitter_gnuplot-2.0.1.dist-info/WHEEL,sha256=XlJt-paDlwt9Vblfolqc_jr5kwZKZYFtPoH2cpntmEQ,100
+tree_sitter_gnuplot-2.0.1.dist-info/top_level.txt,sha256=_f58jJDLXI9UyucwwXKyMA0vHZ2aTtoLG5yg_LP2vHs,29
+tree_sitter_gnuplot-2.0.1.dist-info/RECORD,,

tree_sitter_gnuplot-2.0.1.dist-info/WHEEL

@@ -0,0 +1,5 @@
+Wheel-Version: 1.0
+Generator: setuptools (83.0.0)
+Root-Is-Purelib: false
+Tag: cp310-abi3-win_arm64
+

tree_sitter_gnuplot-2.0.1.dist-info/licenses/LICENSE

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2023 Dai López
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

tree_sitter_gnuplot-2.0.1.dist-info/top_level.txt

@@ -0,0 +1,2 @@
+_binding
+tree_sitter_gnuplot