sgtlib 3.3.9__py3-none-any.whl

StructuralGT/apps/sgt_qml/RightLoggingPanel.qml

@@ -0,0 +1,125 @@
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Controls.Basic as Basic
+import QtQuick.Layouts
+import QtQuick.Window
+
+Window {
+    id: loggingWindowPanel
+    width: 400
+    height: 764
+    x: 1024  // Exactly starts where your app ends
+    y: 40
+    //flags: Qt.Window | Qt.FramelessWindowHint
+    visible: false  // Only show when needed
+    title: "SGT Logs"
+
+    property string currentFilter: "All"
+    property var logEntries: []
+
+    function currentTimestamp() {
+        let now = new Date()
+        return now.toLocaleTimeString(Qt.locale(), "hh:mm:ss")
+    }
+
+    function appendLog(type, message, color = "black") {
+        let timestamp = currentTimestamp()
+        let html = "<font color='" + color + "'>[" + timestamp + "] " + message + "</font>"
+        logEntries.push({type: type, html: html})
+        refreshLogDisplay()
+    }
+
+    function refreshLogDisplay() {
+        lblTextLogs.text = ""
+        for (let i = 0; i < logEntries.length; ++i) {
+            let entry = logEntries[i]
+            if (currentFilter === "All" || entry.type === currentFilter)
+                lblTextLogs.append(entry.html)
+        }
+        lblTextLogs.cursorPosition = lblTextLogs.length
+    }
+
+    Rectangle {
+        id: loggingDataContainer
+        width: parent.width
+        height: parent.height
+        color: "transparent"
+
+        ColumnLayout {
+            anchors.fill: parent
+            spacing: 5
+
+            RowLayout {
+                Layout.fillWidth: true
+                Layout.topMargin: 10
+                Layout.alignment: Qt.AlignHCenter
+                spacing: 10
+
+                ComboBox {
+                    id: logFilter
+                    Layout.preferredWidth: 150
+                    model: ["All", "Info", "Error", "Success"]
+                    onCurrentTextChanged: {
+                        currentFilter = currentText
+                        refreshLogDisplay()
+                    }
+                }
+
+                Button {
+                    text: "Clear Logs"
+                    onClicked: {
+                        logEntries = []
+                        refreshLogDisplay()
+                    }
+                }
+            }
+
+            ScrollView {
+                Layout.fillWidth: true
+                Layout.fillHeight: true
+                Layout.topMargin: 5
+                Layout.bottomMargin: 10
+
+                Basic.TextArea {
+                    id: lblTextLogs
+                    wrapMode: Text.Wrap
+                    readOnly: true
+                    selectByMouse: true
+                    textFormat: TextEdit.RichText
+                    font.pixelSize: 10
+                    background: Rectangle {
+                        color: "white"
+                        radius: 4
+                    }
+                }
+            }
+        }
+
+    }
+
+    Connections {
+        target: mainController
+
+        function onUpdateProgressSignal(val, msg) {
+            let fullMsg = (val <= 100) ? val + "%: " + msg : msg
+            appendLog("Info", fullMsg, "blue")
+        }
+
+        function onErrorSignal(msg) {
+            appendLog("Error", msg, "red")
+        }
+
+        function onTaskTerminatedSignal(success_val, msg_data) {
+            if (success_val) {
+                appendLog("Success", "Task completed successfully!", "#2222bc")
+            } else {
+                appendLog("Error", "Task terminated due to an error. Try again.", "#bc2222")
+            }
+
+            if (msg_data.length >= 2) {
+                appendLog("Info", msg_data[0] + "<br>" + msg_data[1], "gray")
+            }
+        }
+    }
+
+}

StructuralGT/apps/sgt_qml/components/ImageFilters.qml

@@ -0,0 +1,82 @@
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import "../widgets"
+
+Rectangle {
+    color: "#f0f0f0"
+    border.color: "#c0c0c0"
+    Layout.fillWidth: true
+    Layout.fillHeight: true
+
+    property int lblWidthSize: 280
+
+    ScrollView {
+        id: scrollViewImgFilters
+        anchors.fill: parent
+        clip: true
+
+        ScrollBar.horizontal.policy: ScrollBar.AlwaysOff // Disable horizontal scrolling
+        ScrollBar.vertical.policy: ScrollBar.AsNeeded // Enable vertical scrolling only when needed
+
+        contentHeight: colImgFiltersLayout.implicitHeight
+
+        ColumnLayout {
+            id: colImgFiltersLayout
+            width: scrollViewImgFilters.width // Ensures it never exceeds parent width
+            Layout.preferredWidth: parent.width // Fills the available width
+
+            Text {
+                text: "Binary Filters"
+                font.pixelSize: 12
+                font.bold: true
+                Layout.topMargin: 10
+                Layout.bottomMargin: 5
+                Layout.alignment: Qt.AlignHCenter
+            }
+
+            Label {
+                id: lblNoImgFilters
+                Layout.alignment: Qt.AlignHCenter
+                Layout.topMargin: 20
+                text: "No image filters to show!\nCreate project/add image."
+                color: "#808080"
+                visible: !mainController.display_image();
+            }
+            BinaryFilterWidget{}
+
+            Rectangle {
+                height: 1
+                color: "#d0d0d0"
+                Layout.fillWidth: true
+                Layout.alignment: Qt.AlignHCenter
+                Layout.topMargin: 20
+                Layout.leftMargin: 20
+                Layout.rightMargin: 20
+            }
+
+            Text {
+                text: "Image Filters"
+                font.pixelSize: 12
+                font.bold: true
+                Layout.topMargin: 10
+                Layout.bottomMargin: 5
+                Layout.alignment: Qt.AlignHCenter
+            }
+
+
+            ImageFilterWidget{}
+
+        }
+    }
+
+    Connections {
+        target: mainController
+
+        function onImageChangedSignal() {
+            // Force refresh
+            lblNoImgFilters.visible = !mainController.display_image();
+        }
+
+    }
+}

StructuralGT/apps/sgt_qml/components/ImageProperties.qml

@@ -0,0 +1,112 @@
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import "../widgets"
+
+Rectangle {
+    color: "#f0f0f0"
+    border.color: "#c0c0c0"
+    Layout.fillWidth: true
+    Layout.fillHeight: true
+
+    ScrollView {
+        id: scrollViewImgProps
+        anchors.fill: parent
+        clip: true
+
+        ScrollBar.horizontal.policy: ScrollBar.AlwaysOff // Disable horizontal scrolling
+        ScrollBar.vertical.policy: ScrollBar.AsNeeded // Enable vertical scrolling only when needed
+        //contentHeight: colImgPropsLayout.implicitHeight
+
+        ColumnLayout {
+            id: colImgPropsLayout
+            width: scrollViewImgProps.width // Ensures it never exceeds parent width
+            Layout.preferredWidth: parent.width // Fills the available width
+            implicitHeight: colImgPropsLayout.implicitHeight
+
+            Text {
+                text: "Image Properties"
+                font.pixelSize: 12
+                font.bold: true
+                Layout.topMargin: 10
+                Layout.bottomMargin: 5
+                Layout.alignment: Qt.AlignHCenter
+            }
+
+            ImagePropertyWidget{}
+
+            Rectangle {
+                height: 1
+                color: "#d0d0d0"
+                Layout.fillWidth: true
+                Layout.alignment: Qt.AlignHCenter
+                Layout.topMargin: 20
+                Layout.leftMargin: 20
+                Layout.rightMargin: 20
+            }
+            Text {
+                text: "Graph Properties"
+                font.pixelSize: 12
+                font.bold: true
+                Layout.topMargin: 10
+                Layout.bottomMargin: 5
+                Layout.alignment: Qt.AlignHCenter
+            }
+
+            Label {
+                id: lblNoGraphProps
+                Layout.alignment: Qt.AlignHCenter
+                Layout.topMargin: 20
+                text: "No properties to show!"
+                color: "#808080"
+                visible: graphPropsModel.rowCount() > 0 ? false : true
+            }
+            GraphPropertyWidget{}
+
+
+            Rectangle {
+                height: 1
+                color: "#d0d0d0"
+                Layout.fillWidth: true
+                Layout.alignment: Qt.AlignHCenter
+                Layout.topMargin: 20
+                Layout.leftMargin: 20
+                Layout.rightMargin: 20
+            }
+            Text {
+                text: "Computation Metrics"
+                font.pixelSize: 12
+                font.bold: true
+                Layout.topMargin: 10
+                Layout.bottomMargin: 5
+                Layout.alignment: Qt.AlignHCenter
+            }
+
+            Label {
+                id: lblNoGraphParams
+                Layout.alignment: Qt.AlignHCenter
+                Layout.topMargin: 20
+                text: "No metrics to show!"
+                color: "#808080"
+                visible: graphComputeModel.rowCount() > 0 ? false : true
+            }
+            GraphComputeWidget{}
+        }
+    }
+
+    Connections {
+        target: mainController
+
+        function onImageChangedSignal() {
+            lblNoGraphProps.visible = graphPropsModel.rowCount() > 0 ? false : true;
+            lblNoGraphParams.visible = graphComputeModel.rowCount() > 0 ? false : true;
+        }
+
+        function onTaskTerminatedSignal(success_val, msg_data){
+            lblNoGraphProps.visible = graphPropsModel.rowCount() > 0 ? false : true;
+            lblNoGraphParams.visible = graphComputeModel.rowCount() > 0 ? false : true;
+        }
+
+    }
+
+}

StructuralGT/apps/sgt_qml/components/ProjectNav.qml

@@ -0,0 +1,127 @@
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Controls.Basic as Basic
+import QtQuick.Layouts
+//import QtQuick.Dialogs as QuickDialogs
+//import Qt.labs.platform as Platform
+import "../widgets"
+
+Rectangle {
+    color: "#f0f0f0"
+    border.color: "#c0c0c0"
+    Layout.fillWidth: true
+    Layout.fillHeight: true
+
+    ScrollView {
+        id: scrollViewProjNav
+        anchors.fill: parent
+        clip: true
+
+        ScrollBar.horizontal.policy: ScrollBar.AlwaysOff // Disable horizontal scrolling
+        ScrollBar.vertical.policy: ScrollBar.AsNeeded // Enable vertical scrolling only when needed
+
+        contentHeight: colImgProjNavLayout.implicitHeight
+
+        ColumnLayout {
+            id: colImgProjNavLayout
+            width: scrollViewProjNav.width // Ensures it never exceeds parent width
+            Layout.preferredWidth: parent.width // Fills the available width
+
+            RowLayout {
+                id: rowLayoutProject
+                Layout.topMargin: 10
+                Layout.leftMargin: 10
+                Layout.bottomMargin: 5
+                visible: mainController.is_project_open()
+
+                Label {
+                    text: "Project Name:"
+                    font.bold: true
+                }
+
+                Label {
+                    id: lblProjectName
+                    Layout.minimumWidth: 175
+                    Layout.fillWidth: true
+                    text: ""
+                }
+            }
+
+            RowLayout {
+                Layout.leftMargin: 10
+                Layout.bottomMargin: 5
+
+                Label {
+                    text: "Output Dir:"
+                    font.bold: true
+                }
+
+                TextField {
+                    id: txtOutputDir
+                    Layout.minimumWidth: 175
+                    Layout.fillWidth: true
+                    text: ""
+                }
+
+                Basic.Button {
+                    id: btnChangeOutDir
+                    //text: "Change"
+                    icon.source: "../assets/icons/edit_icon.png"
+                    icon.width: 21
+                    icon.height: 21
+                    background: Rectangle { color: "transparent"}
+                    enabled: mainController.display_image();
+                    onClicked: outFolderDialog.open()
+                }
+            }
+
+            Button {
+                id: btnImportImages
+                Layout.alignment: Qt.AlignHCenter
+                text: "Import image(s)"
+                enabled: mainController.display_image();
+                onClicked: imageFileDialog.open()
+            }
+
+            Rectangle {
+                height: 1
+                color: "#d0d0d0"
+                Layout.fillWidth: true
+                Layout.alignment: Qt.AlignHCenter
+                Layout.topMargin: 5
+                Layout.leftMargin: 20
+                Layout.rightMargin: 20
+            }
+            Text {
+                text: "Image List"
+                font.pixelSize: 12
+                font.bold: true
+                Layout.topMargin: 5
+                Layout.bottomMargin: 5
+                Layout.alignment: Qt.AlignHCenter
+                visible: true
+            }
+
+            ProjectWidget {}
+        }
+    }
+
+
+    Connections {
+        target: mainController
+
+        function onImageChangedSignal() {
+            // Force refresh
+            txtOutputDir.text = mainController.get_output_dir();
+            btnChangeOutDir.enabled = mainController.display_image();
+            btnImportImages.enabled = mainController.display_image() || mainController.is_project_open();
+        }
+
+        function onProjectOpenedSignal(name) {
+            lblProjectName.text = name;
+            rowLayoutProject.visible = mainController.is_project_open();
+            btnImportImages.enabled = mainController.display_image() || mainController.is_project_open();
+        }
+    }
+
+}

StructuralGT/apps/sgt_qml/widgets/BinaryFilterWidget.qml

@@ -0,0 +1,151 @@
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+
+ColumnLayout {
+    id:imgBinControls
+    Layout.preferredHeight: 120
+    Layout.preferredWidth: parent.width
+    Layout.fillWidth: true
+    Layout.leftMargin: 10
+    Layout.alignment: Qt.AlignLeft
+    visible: mainController.display_image();
+
+    property int idRole: Qt.UserRole + 1
+    property int valueRole: Qt.UserRole + 4
+    property int btnWidthSize: 100
+    property int spbWidthSize: 170
+    property int sldWidthSize: 140
+    property int lblWidthSize: 50
+
+    ButtonGroup {
+        id: btnGrpBinary
+        exclusive: true
+        //checkedButton: rdoGlobal
+        onCheckedButtonChanged: {
+            var val = checkedButton === rdoGlobal ? 0 : checkedButton === rdoAdaptive ? 1 : 2;
+            var index = imgBinFilterModel.index(0, 0);
+            imgBinFilterModel.setData(index, val, valueRole);
+            mainController.apply_img_bin_changes();
+        }
+    }
+
+
+    RowLayout {
+
+        RadioButton {
+            id:rdoAdaptive
+            text: "Adaptive"
+            Layout.preferredWidth: btnWidthSize
+            ButtonGroup.group: btnGrpBinary
+            onClicked: btnGrpBinary.checkedButton = this
+        }
+
+        SpinBox {
+            // ONLY ODD NUMBERS
+            id: spbAdaptive
+            Layout.minimumWidth: spbWidthSize
+            //Layout.fillWidth: true
+            from: 1
+            to: 999
+            stepSize: 2
+            value: 11 // "adaptive_local_threshold_value"
+            editable: true  // Allow user input
+            enabled: rdoAdaptive.checked
+            onValueChanged: {
+                if (value % 2 === 0) {
+                    value = value - 1;  // Convert even input to nearest odd
+                }
+
+                var index = imgBinFilterModel.index(2, 0);
+                imgBinFilterModel.setData(index, value, valueRole);
+                mainController.apply_img_bin_changes();
+            }
+            validator: IntValidator { bottom: spbAdaptive.from; top: spbAdaptive.to }
+        }
+    }
+
+    RowLayout {
+
+        RadioButton {
+            id: rdoGlobal
+            text: "Global"
+            Layout.preferredWidth: btnWidthSize
+            ButtonGroup.group: btnGrpBinary
+            onClicked: btnGrpBinary.checkedButton = this
+        }
+
+        Slider {
+            id: sldGlobal
+            Layout.minimumWidth: sldWidthSize
+            Layout.fillWidth: true
+            from: 1
+            to: 255
+            stepSize: 1
+            value: 127  //"global_threshold_value"
+            enabled: rdoGlobal.checked
+            onValueChanged: {
+                var index = imgBinFilterModel.index(1, 0);
+                imgBinFilterModel.setData(index, value, valueRole);
+                mainController.apply_img_bin_changes();
+            }
+        }
+
+        Label {
+            id: lblGlobal
+            Layout.preferredWidth: lblWidthSize
+            text: Number(sldGlobal.value).toFixed(0) // Display one decimal place
+            enabled: rdoGlobal.checked
+        }
+
+    }
+
+    RadioButton {
+        id: rdoOtsu
+        text: "OTSU"
+        Layout.preferredWidth: btnWidthSize
+        ButtonGroup.group: btnGrpBinary
+        onClicked: btnGrpBinary.checkedButton = this
+    }
+
+    CheckBox {
+        id: cbxDarkFg
+        text: "Apply Dark Foreground"
+        checked: false
+        onCheckedChanged: {
+            var val = checked === true ? 1 : 0;
+            var index = imgBinFilterModel.index(4, 0);
+            imgBinFilterModel.setData(index, val, valueRole);
+            mainController.apply_img_bin_changes();
+        }
+    }
+
+    function initializeSelections() {
+        for (let row = 0; row < imgBinFilterModel.rowCount(); row ++) {
+            var index = imgBinFilterModel.index(row, 0);
+            let item_id = imgBinFilterModel.data(index, idRole);  // IdRole
+            let item_val = imgBinFilterModel.data(index, valueRole); // ValueRole
+
+            if (item_id === "threshold_type") {
+                btnGrpBinary.checkedButton = item_val === 2 ? rdoOtsu : item_val === 1 ? rdoAdaptive : rdoGlobal;
+            } else if (item_id === "global_threshold_value") {
+                sldGlobal.value = item_val;
+            } else if (item_id === "adaptive_local_threshold_value") {
+                spbAdaptive.value = item_val;
+            } else if (item_id === "apply_dark_foreground") {
+                cbxDarkFg.checked = item_val === 1 ? true : false;
+            }
+        }
+    }
+
+    Connections {
+        target: mainController
+
+        function onImageChangedSignal() {
+            // Force refresh
+            imgBinControls.visible = mainController.display_image();
+            initializeSelections();
+        }
+
+    }
+}