seed2lp 2.0.0__py3-none-any.whl

seed2lp/asp/atom_for_transfers.lp

@@ -0,0 +1,7 @@
+%%%%%%%%%%%%%%%%%%%%%%% COMMUNITY METABOLITES ACTIVATION %%%%%%%%%%%%%%%%%%%%%%%
+%*
+A metabolite is activated by transfer between networks.
+We choose the transferred metabolites that needed to be activate.
+*%
+activated(S) :- seed(S,_,_,_).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

seed2lp/asp/community_heuristic.lp

@@ -0,0 +1,3 @@
+% The priority on heuristic is given to the higher priority
+#heuristic seed(_,_,_,_). [2,false]
+#heuristic transferred(_,_,_,_,_). [1,false]

seed2lp/asp/community_search.lp

@@ -0,0 +1,14 @@
+%%%%%%%%%%%%%%%%%%%%%%% COMMUNITY METABOLITES ACTIVATION %%%%%%%%%%%%%%%%%%%%%%%
+%*
+A metabolite is activated by transfer between networks.
+We choose the transferred metabolites that needed to be activate.
+*%
+{transferred(N,B1,B2,M1,M2)} :- activated(M1), metabolite(M1,_,N,B1), metabolite(M2,_,N,B2),
+                        B1 != B2, B1 != "pool", B2 != "pool"; 
+                        not seed(M1,_,N,_), not transported_meta(M1).
+activated(M) :- metabolite(M,_,N,B2), transferred(N,B1,B2,_,_).
+
+% Contraintes a rajouté a partir du fichier de forbidden transfers rajouté a l'init dans l'instance
+% :- transferred()
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+

seed2lp/asp/constraints_targets.lp

@@ -0,0 +1,15 @@
+% Discard any model that is not activating all targets when not possible seeds 
+% given by the user.
+% This constraint is needed both for seed search (seed_solving.asp)
+% and for the second step of the bistep mode in community 
+% (where seed_solving.asp is not used anymore)
+:- target(N,M) ; not activated(M), subseed=0.
+
+% no_scope(N,M) :- target(N,M) ; not activated(M), subseed=0.
+% #show no_scope/2.
+% #show p_seed/2.
+% #show new_seed/1.
+% #show authorized_accu/1.
+% #show target/2.
+% #show can_reach/1.
+% #show forbidden/1.

seed2lp/asp/definition_atoms.lp

@@ -0,0 +1,87 @@
+#const subseed=0. % mode select sub seed amoung possible seeds given by user
+#const run_mode=target. % full/target/fba
+#const accu=0.
+
+%*
+A metabolite is a reactant or product.
+M: Metabolite composed ID
+X: Exchange tag of metabolite (exchange / transport / other / internal_exchange)
+N: Metabolite Real ID
+B: Species Name
+*%
+metabolite(M,X,N,B) :- reactant(M,_,_,X,N,B).
+metabolite(M,X,N,B) :- product(M,_,_,X,N,B). 
+
+%*
+Define which non exchange metabolite is an imported metabolite
+meaning, there is a reation that transport the metabolite frome extracellular (tagued exchange)
+into intracellular (tagued other)
+*%
+transported_meta(M) :- product(M,_,_,"transport",_,_).
+transported_meta(M) :- reactant(M,_,_,"transport",_,_).
+
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%% INITIAL COMPUTATION %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% An initial seed is activated    
+activated_initial(S) :- seed_user(S).    
+activated_initial(S) :- seed_external(S).
+                                  
+% Compute the initial scope from intial seeds                 
+activated_initial(M) :-  metabolite(M,_,_,_) ; product(M,_,R,_,_,_) ;        
+                        activated_initial(T): reactant(T,_,R,_,_,_);
+                        % We reject de reaction created for flux mode to not have
+                        % as activated initial the seed and the reaction
+                        % can creates problems for cycles
+                        not reac_import(M), not reac_export(M),
+                        not import_exch(R), not import_exch_created(M), not export_exch_created(M).  
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
+
+
+%%%%%%%%%%%%%%%%%%%% ACTIVATE METABOLITES %%%%%%%%%%%%%%%%%%%%%%%
+activated(M) :- activated_initial(M).
+activated(S) :- new_seed(S).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%% SCOPE DETERMINATION %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%*
+A metabolite is activated if produced by a reaction 
+with all its reactants activated.
+*%
+scopeR(R) :- reaction(R) ; activated(M): reactant(M,_,R,_,_,_).
+activated(M) :- product(M,_,R,_,_,_) ; scopeR(R).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% ACCUMULATION %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%* 
+Avoid metabolite accumulation for target and full network mode
+The authorized accumulation of metabolites are for compounds that are never
+consumed by any reaction in the sbml file
+If FBA mode, all compounds are allowed to be accumulated, the fba will select
+the model without accumulation by itself with flux calculation 
+*%
+authorized_accu(M) :- product(M,_,_,_,_,_), not reactant(M,_,R,_,_,_): reaction(R), 
+                      R != reac_export(M), R!= export_exch_created(M).
+
+%*
+Consumed at least one time
+%%%%%%% TARGET OR FULL NETWORK %%%%%%% 
+Target or Full mode, when accumulation not allowed
+*%
+is_conso(M) :- reactant(M,_,R,_,_,_), scopeR(R), activated(M), accu=0, 
+                R != reac_export(M), R!= export_exch_created(M); run_mode!=fba.
+:- product(M,_,R,_,_,_), activated(M), not is_conso(M), 
+    accu=0, not authorized_accu(M),  run_mode!=fba.
+
+
+%*
+%%%%%%% FBA %%%%%%% 
+FBA mode, for checking if a seed is here to create export reaction and avoid
+accumulation
+*%
+is_conso(M) :- reactant(M,_,R,_,_,_), scopeR(R), activated(M), 
+                R != reac_export(M), R!= export_exch_created(M); run_mode=fba.
+seed_accu(M) :- not is_conso(M), seed(M,_,_,_); run_mode=fba.
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

seed2lp/asp/enum-cc.lp

@@ -0,0 +1,50 @@
+% Enumeration of Connected Components.
+% INPUTS:
+%   - reaction(R): R is a reaction.
+%   - reactant(T,R): T is a reactant of reaction R.
+%   - product(P,R): P is a product of reaction R.
+reaction(R) :- dreaction(R).
+% OUTPUTS:
+#show scc/2.      % nodes in each SCC
+#show noinput/1.  % root SCC
+#show sccedge/2.  % link between SCC
+
+
+% the edges are linking reactants to products of each reaction.
+oedge(T,P) :- reactant(T,R) ; product(P,R).
+
+% the nodes
+node(M) :- reactant(M,_).
+node(M) :- product(M,_).
+
+% #show oedge/2.
+% #show node/1.
+
+
+% recursive definition of link between nodes
+link(A,B) :- oedge(A,B).
+link(A,C) :- oedge(A,B) ; link(B,C).
+
+% definitions of cycle
+% A is in a cycle
+cycle(A) :- link(A,A).
+% A and B are in the same cycle
+cycle(A,B) :- link(A,B) ; link(B,A) ; cycle(A) ; cycle(B) ; A<=B.
+
+% defining strongly connected components (scc)
+scc_(A,C) :- cycle(A,C) ; not cycle(B,A) : cycle(B), B<A.
+% singleton scc
+sscc(M) :- node(M) ; not scc_(_,M).
+
+
+scc(A,A) :- sscc(A).
+scc(A,C) :- scc_(A,C).
+
+
+% link between SCCs A and B.
+sccedge(A,B) :- oedge(Va, Vb) ; scc(A,Va) ; scc(B,Vb) ; A!=B.
+
+% a scc without an incoming edge is a root.
+noinput(A) :- sccedge(A,_) ; not sccedge(_,A).
+% a scc without any edge to other scc is also a root.
+noinput(A) :- scc(A,_) ; not sccedge(A,_) ; not sccedge(_,A).

seed2lp/asp/flux.lp

@@ -0,0 +1,70 @@
+%metabolite(M,X) :- reactant(M,_,_,X).
+%metabolite(M,X) :- product(M,_,_,X).  
+
+%%%%%%%%%%%%%%%%%%% IMPORTING SINK METABOLITES %%%%%%%%%%%%%%%%%%%%
+% Create import reactions for seeds not taggued as exchange
+% (meaning to involved in exchange reaction)
+% First create an import reaction forward with reactant 
+reac_import(M) :- seed(M,X,N,B), X!="exchange".
+reaction(reac_import(M)) :- reac_import(M).
+product(M,"1.0000",reac_import(M),X,N,B) :- reac_import(M), seed(M,X,N,B).
+bounds(reac_import(M),"0","1000") :- reac_import(M).
+
+% Because we are adding an import reaction reaction, this reaction become an exchange
+% reaction and has to be tggued as exchange for seed_external definition
+exchange(reac_import(M)) :- reac_import(M).
+
+% then create the export reaction
+reac_export(M) :- seed(M,X,N,B), X!="exchange".
+reaction(reac_export(M)) :- reac_export(M).
+reactant(M,"1.0000",reac_export(M),X,N,B) :- reac_export(M), seed(M,X,N,B).
+bounds(reac_export(M),"0","1000") :- reac_export(M).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+
+%%%%%%%%%%%%%%%%%%%% IMPORTING EXCHANGE METABOLITES %%%%%%%%%%%%%%%%%%%%
+% add the reverse of an already existing exchange reaction 
+% in order to do that, we need to create a reaction having the metabolite in product
+% we do that only if we remove import reaction and though the reversible does not exist
+% we do it only for reaction that are also exchange reaction
+% the boundary is [0,1000] because the forward reaction already exists
+import_exch(R) :- seed(M,"exchange",N,B), rm_product(M,_,R,"exchange",_,B).
+reaction(R) :- import_exch(R).
+product(M,S,R,X,N,B) :- rm_product(M,S,R,X,N,B), import_exch(R).
+bounds(R,"0","1000") :- import_exch(R).
+
+% if the sbml doesn't have an exchange reaction reversible, it is possible to have 
+% only the export reaction written and not the import, so there is no atom rm_product
+% or rm_reaction. So we create from scratch this import reaction for an exchange metabolite
+import_exch_created(M,B) :- seed(M,"exchange",N,B), not rm_product(M,_,_,"exchange",_,_).
+reaction(import_exch_created(B)) :- import_exch_created(M,B).
+product(M,"1.0000",import_exch_created(M),"exchange",M,B) :- import_exch_created(M,B).
+bounds(import_exch_created(M),"0","1000") :- import_exch_created(M,B).
+
+% if the sbml doesn't have an exchange reaction reversible, it is possible to have 
+% only the import reaction written and not the export, so there is an atom rm_product
+% for an exchange reaction, but the reversible doesn't exist.
+% We create an export reaction
+export_exch_created(M,B) :- seed(M,"exchange",N,B), rm_product(M,_,R,"exchange",_,_), exchange(R),
+                         not reversible(R,_), not reversible(_,R).
+reaction(export_exch_created(M)) :- export_exch_created(M,B).
+reactant(M,"1.0000",export_exch_created(M),"exchange",M,B) :- export_exch_created(M,B).
+bounds(export_exch_created(M),"0","1000") :- export_exch_created(M,B).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+
+%%%%%%%%%%%%%%%%%%%%%%% FLUX BALANCE ANALYSIS DEFINITION %%%%%%%%%%%%%%%%%%%%%%%%
+% domain definition; default dom{(x,0,inf)}
+&dom{L..U} = R :- bounds(R,L,U), reaction(R).
+
+% FBA definition
+%OS: Product stoicihiometry by producting reaction OR
+%IS: Consumed stoichiometry by consuming reaction IR
+
+&sum{ OS*OR   : reactant(M,OS,OR,_,_,_);
+    -IS*IR   : product(M,IS,IR,_,_,_)
+    } = 0 :- metabolite(M,_,_,_).
+
+% goal condition: target flux > 0
+&sum{ R :objective(R) } >= "0.0001".
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

seed2lp/asp/limit_transfers.lp

@@ -0,0 +1,9 @@
+#const limit_transfers=1.
+%%%%%%%%%%%%%%%%%%%%%%% COMMUNITY METABOLITES ACTIVATION %%%%%%%%%%%%%%%%%%%%%%%
+%*
+A metabolite is activated by transfer between networks.
+We choose the transferred metabolites that needed to be activate.
+*%
+nb_transfers(N) :- N=#count{M : transferred(M,_,_,_,_)}.
+:- nb_transfers(N), N>limit_transfers.
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

seed2lp/asp/maximize_flux.lp

@@ -0,0 +1,2 @@
+% Maximization 
+&maximize{ R : objective(R) }.

seed2lp/asp/maximize_produced_target.lp

@@ -0,0 +1,7 @@
+% Maximization 
+% When possible seeds given by the user, a subset of these seeds is choosen 
+% by maximizing the targets into the scope
+nb_produced_targets(X) :- X = #count{   M : target(N,M), activated(M) }.
+
+% maximize number produced target has a higher priority than minimize seed (from minimize.lp)
+#maximize{X@2, X:nb_produced_targets(X)}.

seed2lp/asp/minimize.lp

@@ -0,0 +1,8 @@
+% Add minimze option and show the total number of seeds in a set
+% Ensure the minimality of the set of seeds
+
+nb_seed(N) :- N=#count{M,X : seed(M,X,_,_)}.
+
+% minimize seed has a lower priority than maximize number produced target  (from maximize_produced_targets.lp)
+#minimize{N@1, N:nb_seed(N)}.
+%#show nb_seed/1.

seed2lp/asp/seed-solving.lp

@@ -0,0 +1,116 @@
+%* 
+Search of the minimal set of seeds in all graph activating all targets or specific targets.
+
+INPUTS:
+  - seed_user(S): node S is a seed given by users
+  - forbidden(S): node S cannot be a seed
+  - target(T): node T must be activated
+  - reaction(R): R is a reaction.
+  - reactant(T,_,R,_): T is a reactant of reaction R.
+  - product(P,_,R,_): P is a product of reaction R.
+
+OUTPUTS:  one model for each set of seed that activate all metabolites
+  - seed(S,_): node S is a seed
+*%
+%#const run_mode=target. % full/target/fba % Defined in definition_atoms
+%#const accu=0. % Defined in definition_atoms
+%#const subseed=0. % Defined in definition_atoms
+
+
+                                  
+%%%%%%%%%%%%%%%%%%%%%%% POSSIBLE SEEDS WHEN GIVEN BY USER %%%%%%%%%%%%%%%%%%%%%%% 
+%*
+When user gives a file of possible seeds, we want to find a subset of this seeds
+that respects the constraints (in any mode) 
+*%
+p_seed(M,N) :- sub_seed(N), metabolite(M,_,N,_), subseed=1.
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+
+%%%%%%%%%%%%%%%%%%%%%%%%% TARGET SPECIFIC SEEDS SEARCH %%%%%%%%%%%%%%%%%%%%%%%%%                               
+% Try to cut the set of possible seeds   
+can_reach(N) :- target(N,M), metabolite(M,_,N,_); run_mode=target, subseed=0,  accu=1.                   
+can_reach(N) :- reactant(M,_,R,_,N,_) ; product(P,_,R,_,O,_) ; can_reach(O) ; 
+                run_mode=target, subseed=0, accu=1.
+
+%*
+Possible seed detection when the user do not give them:
+Determine possible seeds when accumulation allowed
+Eliminate the metabolite imported (having an import reaction)
+Eliminate for example all the combination :
+M_S1_e, M_S2_e, M_S3_e with M_S1_C, M_S2_c, M_S3_c
+keep only M_S1_e, M_S2_e, M_S3_e
+*%
+p_seed(M,N) :- can_reach(N), metabolite(M,_,N,_), not seed_user(M),
+            not transported_meta(M); 
+            run_mode=target, accu=1, subseed=0.
+              
+
+%*
+Case accumulation not allowed, we need to reach more metabolite
+to access to solution without accumulation
+*%
+p_seed(M,N) :- metabolite(M,_,N,_), not seed_user(M), 
+            not transported_meta(M); 
+            run_mode=target, accu=0, subseed=0.
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%%%%%%%%%%%%%%%%%%%%%%%%%% FULL NETWORK SEEDS SEARCH %%%%%%%%%%%%%%%%%%%%%%%%%%    
+%*
+A metabolite which is not a product of any reaction except
+except his own exchange reaction is an external seed and must be a seed
+when the search is full network
+Also there is some cases when we have a reaction reversible where there is no
+exchange reaction. Such as B_m <-> B_c, then None -> A_c and B_c + A_c -> C_c
+We need to select one of the metabolite B as seed, but because of the reversibility
+it is not selected if we don't take the reversible reaction into account.
+*%
+seed_external(M) :- reactant(M,_,_,_,_,_), 
+                    not product(M,_,R,_,_,_): reaction(R), 
+                    not exchange(R), not reversible(_,R);
+                    not transported_meta(M);
+                    run_mode=full, subseed=0.
+seed_external(M) :- reactant(M,_,_,_,_,_), 
+                    not product(M,_,R,_,_,_): reaction(R), 
+                    not exchange(R), not reversible(R,_);
+                    not transported_meta(M);
+                    run_mode=full, subseed=0.
+
+% A metabolite which is only product of reaction cannot be a seed         
+impossible_seed(M) :- product(M,_,_,_,_,_) ; not reactant(M,_,_,_,_,_) ; run_mode=full, subseed=0.   
+                                  
+target(N,M) :- metabolite(M,_,N,_) ; run_mode=full.                   
+                                  
+% Determine possible seeds all the time (with or without accumulation)
+p_seed(M,N) :- metabolite(M,_,N,_); not transported_meta(M) ; 
+            not impossible_seed(M) ; not activated_initial(M) ; 
+            run_mode=full, subseed=0. 
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% FBA SEEDS SEARCH %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%  
+%*
+Determine possible seeds for FBA : All metabolites are possible seeds
+Randomly choose metabolites, excepts the metabolite that are never consumed
+otherwise the flux will create an import/Export reaction to avoid accumulation
+*%
+p_seed(M,N) :- metabolite(M,_,N,_), not transported_meta(M), 
+            not activated_initial(M), not authorized_accu(M), 
+            run_mode=fba, subseed=0. 
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+
+
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% SEED SELECTION %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% Choose a set of seed from the possible seeds
+{ new_seed(M): p_seed(M,N), not forbidden(N) }.
+
+
+% A seed is a seed given by the user, or an external seed 
+% or a new seed coming from the combinations of possible seeds 
+seed(M,X,N,B) :- seed_user(M), metabolite(M,X,N,B).
+seed(M,X,N,B) :- seed_external(M), metabolite(M,X,N,B).
+seed(M,X,N,B) :- new_seed(M), metabolite(M,X,N,B).
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

seed2lp/asp/seed_external.lp

@@ -0,0 +1 @@
+#external seed(A,B,C,D): metabolite(A,B,C,D).

seed2lp/asp/show_seeds.lp

@@ -0,0 +1,2 @@
+#show seed/4.
+#show seed_accu/1.

seed2lp/asp/show_tranfers.lp

@@ -0,0 +1 @@
+#show transferred/5.

seed2lp/asp/test.lp

@@ -0,0 +1,61 @@
+solseed("abc","A").
+solseed("abc","B").
+solseed("abc","C").
+
+solseed("abcde","A").
+solseed("abcde","B").
+solseed("abcde","C").
+solseed("abcde","D").
+solseed("abcde","E").
+
+solseed("efg","E").
+solseed("efg","F").
+solseed("efg","G").
+
+solseed("mnopq","M").
+solseed("mnopq","N").
+solseed("mnopq","O").
+solseed("mnopq","P").
+solseed("mnopq","Q").
+
+soltransfert("12345","1").
+soltransfert("12345","2").
+soltransfert("12345","3").
+soltransfert("12345","4").
+soltransfert("12345","5").
+
+soltransfert("678","6").
+soltransfert("678","7").
+soltransfert("678","8").
+
+soltransfert("5678","5").
+soltransfert("5678","6").
+soltransfert("5678","7").
+soltransfert("5678","8").
+
+psolseedname("abc").
+psolseedname("abcde").
+psolseedname("efg").
+psolseedname("mnopq").
+
+psoltransfertname("12345").
+psoltransfertname("678").
+psoltransfertname("5678").
+
+1{solseedname(A): psolseedname(A)}1.
+1{soltransfertname(A): psoltransfertname(A)}1.
+
+%seed(M) :- solseed(A,M), solseedname(A).
+seed("A"). seed("B"). seed("C").
+
+transfert(M) :- soltransfert(A,M), soltransfertname(A).
+
+
+#heuristic seed(_). [2,false]
+#heuristic transfert(_). [1,false]
+
+%#show solseedname/1.
+%#show soltransfertname/1.
+
+#show seed/1.
+#show transfert/1.