pytrilogy 0.3.148__cp312-cp312-manylinux_2_17_aarch64.manylinux2014_aarch64.whl

trilogy/parsing/trilogy.lark

@@ -0,0 +1,544 @@
+ !start: ( block | show_statement | PARSE_COMMENT )*
+    block: statement _TERMINATOR LINE_SEPARATOR? PARSE_COMMENT*
+    ?statement: concept
+    | datasource
+    | function
+    | type_declaration
+    | multi_select_statement
+    | select_statement
+    | persist_statement
+    | rowset_derivation_statement
+    | import_statement
+    | copy_statement
+    | merge_statement
+    | rawsql_statement
+    | validate_statement
+    | mock_statement
+    | publish_statement
+    | create_statement
+    
+    _TERMINATOR:  ";"i
+    
+    PARSE_COMMENT.1:   /#.*(\n|$)/ |  /\/\/.*(\n|$)/  
+
+    // when whitespace matters - comment placement
+    LINE_SEPARATOR.1: /[ \t\r\f\v]*\n+/
+    
+    // property display_name string
+    concept_declaration: PURPOSE IDENTIFIER data_type concept_nullable_modifier? metadata?
+    //customer_id.property first_name STRING;
+    //<customer_id,country>.property local_alias STRING
+    UNIQUE: "UNIQUE"i
+    concept_property_declaration: UNIQUE? PROPERTY (prop_ident | IDENTIFIER) data_type concept_nullable_modifier? metadata?
+    //metric post_length <- len(post_text);
+    concept_derivation:  (PURPOSE | AUTO | PROPERTY ) (prop_ident | IDENTIFIER) "<-" expr
+
+    rowset_derivation_statement: ("rowset"i IDENTIFIER "<-" (multi_select_statement | select_statement)) | ("with"i IDENTIFIER "as"i (multi_select_statement | select_statement))
+    
+    constant_derivation: CONST IDENTIFIER "<-" (literal | _constant_functions)
+
+    concept_nullable_modifier: "?"
+    concept:  (concept_declaration | concept_derivation | concept_property_declaration | constant_derivation)
+    
+    //concept property
+    prop_ident: "<" IDENTIFIER ("," IDENTIFIER )* ","? ">" "." IDENTIFIER
+
+    // datasource concepts
+    DATASOURCE_STATUS: "published"i | "unpublished"i
+    DATASOURCE_ROOT: "root"i
+
+    datasource_status_clause: /state/i DATASOURCE_STATUS
+
+    datasource_increment_clause: "incremental"i "by"i column_list
+
+    datasource_partition_clause: "partition"i "by"i column_list
+
+    datasource: DATASOURCE_ROOT? "datasource" IDENTIFIER  "("  column_assignment_list ")"  grain_clause? whole_grain_clause? (address | query | file) where? datasource_increment_clause? datasource_partition_clause? datasource_status_clause?
+   
+    whole_grain_clause: "complete" where
+
+    grain_clause: "grain" "(" column_list ")"
+    
+    address: "address" (QUOTED_ADDRESS | ADDRESS)
+    
+    query: "query" MULTILINE_STRING
+
+    file: "file" FILE_PATH
+    
+    concept_assignment: SHORTHAND_MODIFIER* IDENTIFIER 
+    
+    //column_assignment
+    //figure out if we want static
+    column_assignment: ((raw_column_assignment | IDENTIFIER | QUOTED_IDENTIFIER |  expr  ) ":" concept_assignment) | concept_assignment
+    
+    RAW_ENTRY.1: /raw\s*\(/s
+
+    raw_column_assignment: RAW_ENTRY  MULTILINE_STRING ")"
+    
+    column_assignment_list : column_assignment (","  column_assignment)* ","?
+    
+    column_list : (IDENTIFIER "," )* IDENTIFIER ","?
+
+    IMPORT_DOT: "."
+    
+    import_statement: "import" IMPORT_DOT* IDENTIFIER ("."  IDENTIFIER)* ("as" IDENTIFIER)?
+
+    // persist_statement
+    PERSIST_MODE: "append"i | "overwrite"i | "persist"i
+    persist_partition_clause: "by"i column_list
+
+    // short persist with auto query
+    auto_persist: PERSIST_MODE IDENTIFIER where?
+
+    // full persist with query
+    full_persist: PERSIST_MODE IDENTIFIER? "into"i IDENTIFIER persist_partition_clause? "from"i select_statement
+
+    persist_statement: auto_persist | full_persist
+
+    // select statement
+    select_statement: where? "select"i select_list where?  having?  order_by?  limit? 
+
+    // multiple_selects
+    multi_select_statement: select_statement ("merge" select_statement)+ "align"i align_clause ("derive" derive_clause)?  where? order_by?  limit? 
+
+    align_item: IDENTIFIER ":" IDENTIFIER ("," IDENTIFIER)*  ","?
+
+    align_clause: align_item ("AND"i align_item)*  "AND"i?
+
+    derive_item: expr "->" IDENTIFIER
+
+    derive_clause: derive_item ("," derive_item)* ","?
+
+    merge_statement: "merge"i  WILDCARD_IDENTIFIER "into"i SHORTHAND_MODIFIER? WILDCARD_IDENTIFIER
+
+    // raw sql statement
+    rawsql_statement: "raw_sql"i "(" MULTILINE_STRING ")"
+
+    // validate_statement
+
+    VALIDATE_SCOPE: "concepts"i | "datasources"i | "datasource"i | "concept"i
+
+    validate_statement: ("validate"i "all"i) | ( "validate"i VALIDATE_SCOPE (IDENTIFIER ("," IDENTIFIER)* ","? )? )
+
+    // mock statement
+
+    mock_statement: "mock"i  VALIDATE_SCOPE (IDENTIFIER ("," IDENTIFIER)* ","? )?
+    
+    // publish statement
+    PUBLISH_ACTION : "publish"i | "unpublish"i
+    publish_statement: PUBLISH_ACTION VALIDATE_SCOPE IDENTIFIER
+
+    // create_statement
+    CREATE_IF_NOT_EXISTS: /if\s+not\s+exists/i
+    CREATE_OR_REPLACE: /or\s+replace/i
+
+    create_modifier_clause: CREATE_IF_NOT_EXISTS | CREATE_OR_REPLACE
+    create_statement: "create"i create_modifier_clause? VALIDATE_SCOPE IDENTIFIER
+    
+    // copy statement
+
+    COPY_TYPE: "csv"i | "parquet"i
+
+    copy_statement: "copy"i "into"i COPY_TYPE string_lit "from"i select_statement
+
+    // FUNCTION blocks
+    function: raw_function
+    function_binding_type: ":" data_type  
+    function_binding_default: /=/ expr
+    function_binding_item: IDENTIFIER function_binding_type? function_binding_default?
+    function_binding_list: (function_binding_item ",")* function_binding_item ","?
+    raw_function: "def"  IDENTIFIER  "("  function_binding_list ")" "->" expr
+
+    // TYPE blocks
+    type_drop_clause: "DROP"  IDENTIFIER ("|" IDENTIFIER)*
+    //type_add_clause: "ADD" IDENTIFIER ("|" IDENTIFIER)* type_add_clause?
+    type_declaration: "type" IDENTIFIER data_type ("|" data_type)* type_drop_clause? 
+
+    // user_id where state = Mexico
+    _filter_alt: (IDENTIFIER | literal | _static_functions | "(" expr ")") "?" conditional
+    _filter_base: "filter"i IDENTIFIER where
+    filter_item: _filter_base | _filter_alt
+
+    // rank/lag/lead
+    WINDOW_TYPE: ("row_number"i|"rank"i|"lag"i|"lead"i | "sum"i | "avg"i | "max"i | "min"i | "count"i  )  /[\s]+/
+
+    window_item_over: ("OVER"i over_list)
+   
+    window_item_order: ("ORDER"i? "BY"i order_list)
+
+    window_item: WINDOW_TYPE int_lit? expr window_item_over? window_item_order?
+    
+    select_hide_modifier: "--"
+    select_partial_modifier: "~"
+    select_item: (select_hide_modifier | select_partial_modifier)? (concept_lit  | select_transform  )
+    
+    select_list:  select_item ("," select_item )* ","?
+    
+    //  count(post_id) -> post_count
+    _assignment: ("->") | "as"i
+    select_transform : expr _assignment IDENTIFIER metadata?
+    
+    metadata: "metadata" "(" IDENTIFIER "=" string_lit ")"
+    
+    limit: "LIMIT"i /[0-9]+/
+
+    ORDER_IDENTIFIER.2: /(?!LIMIT)[a-zA-Z_][a-zA-Z0-9_\.]*\s+/
+    _order_atom: (ORDER_IDENTIFIER ordering) | (expr ordering)
+    
+    order_list: _order_atom (","  _order_atom)* ","?
+    
+    over_component: /,\s*[a-zA-Z\_][a-zA-Z0-9\_\.]*/ "END"?
+    
+    over_list: concept_lit  over_component* 
+    
+    ORDERING_DIRECTION: /ASC|DESC/i
+
+    !ordering: ORDERING_DIRECTION  ("NULLS"i /FIRST|LAST|AUTO/i )?
+    
+    order_by: "ORDER"i "BY"i order_list
+    
+    //WHERE STATEMENT
+    LOGICAL_OR: "or"i
+    LOGICAL_AND: "and"i
+    
+    conditional: _or_condition
+
+    _or_condition: _and_condition
+               | (_or_condition LOGICAL_OR _and_condition)
+
+    _and_condition: _condition_unit
+               | (_and_condition LOGICAL_AND _condition_unit)
+
+    CONDITION_NOT: "NOT"i
+    condition_parenthetical: CONDITION_NOT? "(" conditional ")"
+
+    _condition_unit: expr
+                  | condition_parenthetical
+    
+    where: "WHERE"i conditional
+    
+    having: "HAVING"i conditional
+
+    !array_comparison: ( ("NOT"i "IN"i) | "IN"i)
+
+    COMPARISON_OPERATOR: /(\s+is\s+not\s|\s+is\s|\s+in\s|\s+not\s+in\s|=|>=|<=|!=|>|<)/i
+    
+    between_comparison: "between"i expr "and"i expr
+
+    subselect_comparison: expr array_comparison (literal | _constant_functions | _string_functions | _array_functions | concept_lit | filter_item | window_item | unnest | fgroup |  expr_tuple | parenthetical )
+    
+    expr_tuple: ("("  expr ("," expr)+ ","?  ")") | ("("  expr "," ")")
+
+    parenthetical: "(" expr ")"
+
+    //unnesting is a function
+    _UNNEST.1: "UNNEST("i
+    unnest: _UNNEST expr ")"
+
+    // union statement
+    _UNION.1: "UNION("i
+    union: _UNION   (expr ",")* expr ")"
+
+    //indexing into an expression is a function
+    index_access: atom "[" int_lit "]"
+    map_key_access: atom "[" string_lit "]"
+    _ATTR_ACCESS.1 : "getattr("i
+    attr_access: ( _ATTR_ACCESS atom "," string_lit ")") | (atom  "." string_lit)
+
+    ?expr: comparison_root | between_root
+
+    ?comparison_root: sum_chain (COMPARISON_OPERATOR sum_chain)? -> comparison
+    ?between_root: sum_chain "between"i sum_chain "and"i sum_chain -> between_comparison
+
+    PLUS_OR_MINUS: ("+" | /-(?!>)/ | "||" | "like" ) 
+
+    ?sum_chain: product_chain (PLUS_OR_MINUS product_chain)* -> sum_operator
+    
+    MULTIPLY_DIVIDE_PERCENT: ("**" | "*" | "/" | "%")
+
+    ?product_chain: atom ( MULTIPLY_DIVIDE_PERCENT atom)* -> product_operator
+
+    ?atom: literal | concept_lit | parenthetical
+     | expr_tuple
+     | custom_function
+     | _constant_functions
+     | _static_functions
+     | _generic_functions
+     | _date_functions
+     | aggregate_functions
+     | window_item
+     | unnest
+     | union
+     | fgroup
+     | filter_item
+     | _access_expr
+     | aggregate_by
+
+
+   # Access patterns
+   _access_expr: index_access | map_key_access | attr_access
+    // functions
+    
+    fadd: (/add\(/ expr "," expr ")" ) 
+    fsub: ("subtract"i "(" expr "," expr ")" ) 
+    fmul: ("multiply"i "(" expr "," expr ")" ) 
+    fdiv: ( "divide"i "(" expr "," expr ")") 
+    fmod: ( "mod"i "(" expr "," (int_lit | concept_lit ) ")")  
+    _LOG.1: "log"i "("
+    flog: _LOG expr ("," expr)? ")"
+    _ROUND.1: "round"i "("
+    fround: _ROUND expr ("," expr)? ")"
+    _FLOOR.1: "floor"i "("
+    ffloor: _FLOOR expr ")"
+    _CEIL.1: "ceil"i "("
+    fceil:  _CEIL expr ")"
+    fabs: "abs"i "(" expr ")"
+    _SQRT.1: "sqrt("
+    fsqrt:  _SQRT expr ")"
+    _RANDOM.1: "random("i
+    frandom: _RANDOM expr ")"
+        
+    _math_functions: fmul | fdiv | fadd | fsub | fround | ffloor | fceil | fmod | flog | fabs | fsqrt | frandom
+    
+    //generic
+    _fcast_primary: "cast"i "(" expr "as"i data_type ")"
+    _fcast_alt: atom "::" data_type
+    fcast: _fcast_primary | _fcast_alt
+    concat: ("concat"i "(" (expr ",")* expr ")") 
+    fcoalesce: "coalesce"i "(" (expr ",")* expr ")"
+    fcase_when: "WHEN"i conditional "THEN"i expr
+    fcase_else: "ELSE"i expr
+    fcase: "CASE"i (fcase_when)* (fcase_else)? "END"i
+    len: "len"i "(" expr ")"
+    fnot: "NOT"i expr
+    fbool: "bool"i "(" expr ")"
+    fnullif: "nullif"i "(" expr "," expr ")"
+    _FRECURSE_EDGE.1: "recurse_edge("i
+    frecurse_edge: _FRECURSE_EDGE expr "," expr ")"
+
+    _generic_functions: fcast |  concat  | fcoalesce | fnullif | fcase  | len | fnot | fbool | frecurse_edge
+
+    //constant
+    CURRENT_DATE.1: /current_date\(\)/
+    CURRENT_DATETIME.1: /current_datetime\(\)/
+    CURRENT_TIMESTAMP.1: /current_timestamp\(\)/
+    fcurrent_date: CURRENT_DATE
+    fcurrent_datetime: CURRENT_DATETIME
+    fcurrent_timestamp: CURRENT_TIMESTAMP
+
+    _constant_functions: fcurrent_date | fcurrent_datetime | fcurrent_timestamp
+    
+    //string
+    _LIKE.1: "like("i
+    like:  _LIKE expr "," string_lit ")"
+    _ILIKE.1: "ilike("i
+    ilike:   _ILIKE expr "," string_lit ")"
+    alt_like: expr  "like"i expr
+    _UPPER.1: "upper("i
+    upper: _UPPER expr ")"
+    _LOWER.1: "lower("i
+    flower: _LOWER expr ")"  
+    _SPLIT.1: "split("i  
+    fsplit: _SPLIT expr "," string_lit ")"
+    _STRPOS.1: "strpos("i
+    fstrpos: _STRPOS expr "," expr ")"
+    _CONTAINS.1: "contains("i
+    fcontains: _CONTAINS expr "," expr ")"
+    _TRIM.1: "trim("i
+    ftrim: _TRIM expr ")"
+    _REPLACE.1: "replace("i
+    freplace: _REPLACE expr "," expr "," expr ")"
+    _SUBSTRING.1: "substring("i
+    fsubstring: _SUBSTRING expr "," expr "," expr ")"
+    _REGEXP_EXTRACT.1: "regexp_extract("
+    fregexp_extract: _REGEXP_EXTRACT expr "," expr ("," int_lit)? ")"
+    _REGEXP_CONTAINS.1: "regexp_contains("
+    fregexp_contains: _REGEXP_CONTAINS expr "," expr  ")"
+    _REGEXP_REPLACE.1: "regexp_replace("
+    fregexp_replace: _REGEXP_REPLACE expr "," expr "," expr   ")"
+    _HASH.1: "hash("
+    HASH_TYPE: "md5"i | "sha1"i | "sha256"i | "sha512"i
+    fhash: _HASH expr "," HASH_TYPE ")"
+
+    _string_functions: like | ilike | upper | flower | fsplit | fstrpos | fsubstring | fcontains | ftrim | freplace | fregexp_extract | fregexp_contains | fregexp_replace | fhash
+
+    //array_functions
+    _ARRAY_SUM.1: "array_sum("i
+    farray_sum: _ARRAY_SUM  expr  ")"
+    _ARRAY_DISTINCT.1: "array_distinct("i
+    farray_distinct: _ARRAY_DISTINCT expr ")"
+    _ARRAY_TO_STRING.1: "array_to_string("i
+    farray_to_string: _ARRAY_TO_STRING expr "," expr ")"
+    _ARRAY_SORT.1: "array_sort("i
+    farray_sort: _ARRAY_SORT expr ("," ordering )? ")"
+    _ARRAY_TRANSFORM.1: "array_transform("i
+    transform_lambda: "@" IDENTIFIER
+    farray_transform: _ARRAY_TRANSFORM expr ","  transform_lambda   ")"
+    _ARRAY_FILTER.1: "array_filter("i
+    farray_filter: _ARRAY_FILTER expr "," transform_lambda ")"
+    _GENERATE_ARRAY.1: "generate_array("i
+    fgenerate_array: _GENERATE_ARRAY expr "," expr "," expr ")"
+
+    _array_functions: farray_sum | farray_distinct | farray_sort | farray_transform | farray_to_string | farray_filter | fgenerate_array
+
+    //map_functions
+    _MAP_KEYS.1: "map_keys("i
+    fmap_keys: _MAP_KEYS expr ")"
+    _MAP_VALUES.1: "map_values("i
+    fmap_values: _MAP_VALUES expr ")"
+
+    _map_functions: fmap_keys | fmap_values
+    
+    // special aggregate
+    _GROUP.1: "group("i
+    fgroup: _GROUP expr ")" aggregate_over?
+
+    //by:  
+    aggregate_by: /(group)\s+([a-zA-Z\_][a-zA-Z0-9\_\.]*)/i "BY"i (IDENTIFIER ",")* IDENTIFIER
+
+    //aggregates
+    _COUNT.1: "count("i
+    count:   _COUNT  expr ")"
+    
+    count_distinct: "count_distinct"i "(" expr ")"
+    
+    // avoid conflicts with the window
+    _SUM.1: "sum("i
+    sum: _SUM expr ")"
+    _AVG.1: "avg("i
+    avg: _AVG expr ")"
+    _MAX.1: "max("i
+    max: _MAX expr ")"
+    _MIN.1: "min("i
+    min: _MIN expr ")"
+    _ARRAY_AGG.1: "array_agg("i
+    array_agg: _ARRAY_AGG expr ")"
+    _BOOL_OR.1: "bool_or("i
+    bool_or: _BOOL_OR expr ")"
+    _BOOL_AND.1: "bool_and("i
+    bool_and: _BOOL_AND expr ")"
+    _ANY.1: "any("i
+    any: _ANY expr ")"
+    
+    //aggregates can force a grain
+    aggregate_all: "*"
+    aggregate_over: ("BY"i (aggregate_all | over_list))
+    aggregate_functions: (count | count_distinct | sum | avg | max | min | array_agg | bool_and | bool_or | any) aggregate_over?
+
+    // date functions
+    _DATE.1: "date("i
+    fdate:  _DATE expr ")"
+    fdatetime: "datetime"i "(" expr ")"
+    _TIMESTAMP.1: "timestamp("i
+    ftimestamp: _TIMESTAMP expr ")"
+    
+    _SECOND.1: "second("i
+    fsecond: _SECOND expr ")"
+    _MINUTE.1: "minute("i
+    fminute: _MINUTE expr ")"
+    _HOUR.1: "hour("i
+    fhour: _HOUR expr ")"
+    _DAY.1: "day("i
+    fday:  _DAY expr ")"
+    _DAY_NAME.1: "day_name("i
+    fday_name:  _DAY_NAME expr ")"
+    _DAY_OF_WEEK.1: "day_of_week("i
+    fday_of_week:  _DAY_OF_WEEK expr ")"
+    _WEEK.1: "week("i
+    fweek: _WEEK expr ")"
+    _MONTH.1: "month("i
+    fmonth: _MONTH expr ")"
+    _MONTH_NAME.1: "month_name("i
+    fmonth_name: _MONTH_NAME expr ")"
+    _QUARTER.1: "quarter("i
+    fquarter: _QUARTER expr ")"
+    _YEAR.1: "year("i
+    fyear: _YEAR expr ")"
+    
+    DATE_PART: "DAY"i | "WEEK"i | "MONTH"i | "QUARTER"i | "YEAR"i | "MINUTE"i | "HOUR"i | "SECOND"i | "DAY_OF_WEEK"i
+    _DATE_TRUNC.1: "date_trunc("i | "date_truncate("i
+    fdate_trunc: _DATE_TRUNC expr "," DATE_PART ")"
+    _DATE_PART.1: "date_part("i
+    fdate_part: _DATE_PART expr "," DATE_PART ")"
+    _DATE_ADD.1: "date_add("i
+    fdate_add: _DATE_ADD expr "," DATE_PART "," expr ")"
+    _DATE_SUB.1: "date_sub("i
+    fdate_sub: _DATE_SUB expr "," DATE_PART "," expr ")"
+    _DATE_DIFF.1: "date_diff("i
+    fdate_diff: _DATE_DIFF expr "," expr "," DATE_PART ")"
+    _DATE_SPINE.1: "date_spine("i
+    fdate_spine: _DATE_SPINE expr "," expr  ")"
+    
+    _date_functions: fdate | fdate_add | fdate_sub | fdate_diff | fdatetime | ftimestamp | fsecond | fminute | fhour | fday |fday_name | fday_of_week | fweek | fmonth | fmonth_name | fquarter | fyear | fdate_part | fdate_trunc | fdate_spine
+    
+    _static_functions:  _string_functions | _math_functions | _array_functions | _map_functions
+
+    custom_function:  "@" IDENTIFIER  "(" (expr ",")* expr ")"
+
+    // base language constructs
+    concept_lit:  IDENTIFIER
+    IDENTIFIER: /[a-zA-Z\_][a-zA-Z0-9\_\.]*/
+    WILDCARD_IDENTIFIER: /[a-zA-Z\_][a-zA-Z0-9\_\-\.\*]*/
+    QUOTED_IDENTIFIER:  /`[a-zA-Z\_][a-zA-Z0-9\_\.\-\*\:\s]*`/
+    QUOTED_ADDRESS:  /`'?[a-zA-Z\_\\\/][a-zA-Z0-9\_\.\\\/\-\*\:\s]*'?`/
+    ADDRESS: IDENTIFIER
+
+    MULTILINE_STRING: /\'{3}(.*?)\'{3}/s
+    FILE_PATH: /`[^`]+\.(py|csv|parquet|tsv|sql)`/i
+    
+    DOUBLE_STRING_CHARS: /(?:(?!\${)([^"\\]|\\.))+/+ // any character except "
+    SINGLE_STRING_CHARS: /(?:(?!\${)([^'\\]|\\.))+/+ // any character except '
+    _single_quote: "'" ( SINGLE_STRING_CHARS )* "'" 
+    _double_quote: "\"" ( DOUBLE_STRING_CHARS )* "\"" 
+    string_lit: _single_quote | _double_quote | MULTILINE_STRING
+
+
+
+    int_lit:  /\-?[0-9]+/
+    
+    float_lit: /\-?[0-9]*\.[0-9]+/
+
+    array_lit: "[" (expr ",")* expr ","? "]"()
+
+    tuple_lit: "(" (literal ",")* literal ","? ")"
+
+    map_lit: "{" (literal ":" literal ",")* literal ":" literal ","? "}"
+
+    _STRUCT.1: "struct("i
+    _BINDING.1: "->"
+    struct_lit: _STRUCT expr _BINDING IDENTIFIER   ( "," expr _BINDING  IDENTIFIER  )* ","? ")"
+    
+    !bool_lit: "True"i | "False"i
+
+    !null_lit.1: "null"i
+    
+    literal: null_lit | string_lit | int_lit | float_lit | bool_lit | array_lit | map_lit | struct_lit | tuple_lit
+
+    MODIFIER: /OPTIONAL|PARTIAL|NULLABLE/i
+
+    SHORTHAND_MODIFIER: /~|\?/
+    struct_component: IDENTIFIER ":" data_type concept_nullable_modifier? metadata?
+    struct_type: "struct"i "<" ((struct_component | IDENTIFIER) ",")* (struct_component | IDENTIFIER) ","? ">" 
+
+    list_type: ("list"i | "array"i) "<" (data_type | IDENTIFIER) ">" 
+
+    numeric_type: "numeric"i "(" int_lit "," int_lit ")"
+
+    map_type: "map"i "<" (data_type | IDENTIFIER) "," (data_type | IDENTIFIER) ">"
+
+    !data_type:  ("string"i | "number"i | "numeric"i | "map"i | "list"i | "array"i | "any"i | "int"i | "bigint"i | "date"i | "datetime"i | "timestamp"i | "float"i | "bool"i | numeric_type | map_type | struct_type | list_type) ("::" IDENTIFIER)?
+    
+    PURPOSE:  "key"i | "metric"i | "parameter"i | "param"i  | CONST
+    PROPERTY: "property"i
+    CONST: "const"i | "constant"i
+    AUTO: "AUTO"i 
+    // meta functions
+    CONCEPTS: "CONCEPTS"i
+    DATASOURCES: "DATASOURCES"i
+    show_category: CONCEPTS | DATASOURCES
+
+    show_statement: "show"i ( show_category | validate_statement | select_statement | persist_statement) _TERMINATOR
+    COMMENT: /#.*(\n|$)/ |  /\/\/.*\n/  
+    %import common.WS
+    %ignore WS
+    %ignore COMMENT

trilogy/render.py

@@ -0,0 +1,45 @@
+from trilogy.constants import Rendering
+from trilogy.dialect.base import BaseDialect
+from trilogy.dialect.config import DialectConfig
+from trilogy.dialect.enums import Dialects
+
+
+def get_dialect_generator(
+    dialect: Dialects,
+    rendering: Rendering | None = None,
+    config: DialectConfig | None = None,
+) -> BaseDialect:
+    if dialect == Dialects.BIGQUERY:
+        from trilogy.dialect.bigquery import BigqueryDialect
+
+        return BigqueryDialect(rendering=rendering, config=config)
+    elif dialect == Dialects.SQL_SERVER:
+        from trilogy.dialect.sql_server import SqlServerDialect
+
+        return SqlServerDialect(rendering=rendering, config=config)
+    elif dialect == Dialects.DUCK_DB:
+        from trilogy.dialect.duckdb import DuckDBDialect
+
+        return DuckDBDialect(rendering=rendering, config=config)
+    elif dialect == Dialects.PRESTO:
+        from trilogy.dialect.presto import PrestoDialect
+
+        return PrestoDialect(rendering=rendering, config=config)
+    elif dialect == Dialects.TRINO:
+        from trilogy.dialect.presto import TrinoDialect
+
+        return TrinoDialect(rendering=rendering, config=config)
+    elif dialect == Dialects.POSTGRES:
+        from trilogy.dialect.postgres import PostgresDialect
+
+        return PostgresDialect(rendering=rendering, config=config)
+    elif dialect == Dialects.SNOWFLAKE:
+        from trilogy.dialect.snowflake import SnowflakeDialect
+
+        return SnowflakeDialect(rendering=rendering, config=config)
+    elif dialect == Dialects.DATAFRAME:
+        from trilogy.dialect.dataframe import DataframeDialect
+
+        return DataframeDialect(rendering=rendering, config=config)
+    else:
+        raise ValueError(f"Unsupported dialect {dialect}")

trilogy/scripts/README.md

@@ -0,0 +1,9 @@
+# Trilogy CLI
+
+Core entrypoint for CLI functions. 
+
+## Local Testing
+
+```bash
+python -m trilogy.scripts.trilogy unit C:\Users\ethan\coding_projects\pypreql\tests\scripts\validation_failure.preql
+```

trilogy/scripts/agent.py

@@ -0,0 +1,41 @@
+"""Agent command for Trilogy CLI - AI-powered orchestration tasks."""
+
+from click import argument, option, pass_context
+
+
+@argument("command", type=str)
+@option(
+    "--context",
+    "-c",
+    multiple=True,
+    help="Additional context files or paths for the agent",
+)
+@option("--model", "-m", type=str, help="AI model to use (if configured)")
+@option(
+    "--interactive", "-i", is_flag=True, help="Run in interactive mode with feedback"
+)
+@pass_context
+def agent(
+    ctx, command: str, context: tuple[str, ...], model: str | None, interactive: bool
+):
+    """Pass off a multi-step orchestration task to an AI agent.
+
+    This command allows you to delegate complex, multi-step tasks to a configured
+    AI agent. The agent can understand natural language commands and execute
+    a series of Trilogy operations to accomplish the goal.
+
+    Examples:
+        trilogy agent "analyze sales trends and create a dashboard"
+        trilogy agent "ingest new data and run validation tests"
+        trilogy agent "optimize query performance for customer reports"
+
+    Args:
+        command: Natural language command describing the task
+        context: Additional context files or paths to inform the agent
+        model: Specific AI model to use (requires configuration)
+        interactive: Enable interactive mode for step-by-step feedback
+    """
+    raise NotImplementedError(
+        "The 'agent' command is not yet implemented. "
+        "Configure an AI agent in your trilogy.toml to use this feature."
+    )