pytrilogy 0.0.1.113__py3-none-any.whl → 0.0.1.114__py3-none-any.whl

{pytrilogy-0.0.1.113.dist-info → pytrilogy-0.0.1.114.dist-info}/METADATA

@@ -1,6 +1,6 @@
 Metadata-Version: 2.1
 Name: pytrilogy
-Version: 0.0.1.113
+Version: 0.0.1.114
 Summary: Declarative, typed query language that compiles to SQL.
 Home-page: 
 Author: 

{pytrilogy-0.0.1.113.dist-info → pytrilogy-0.0.1.114.dist-info}/RECORD

@@ -1,4 +1,4 @@
-trilogy/__init__.py,sha256=GrjKB68K39dNQdfawYh4NFxVquqj3q7CeFeviCNNfHA,292
+trilogy/__init__.py,sha256=YP6zBKlyJngff_YhDMqBqw9lNoE9wqou96KfaGJqzg4,292
 trilogy/compiler.py,sha256=47DEQpj8HBSa-_TImW-5JCeuQeRkm5NMpJWZG3hSuFU,0
 trilogy/constants.py,sha256=DJi3ESttmvqgy6fPRXiaQzqJVye6jYwf6XM89NHv0_M,735
 trilogy/engine.py,sha256=R5ubIxYyrxRExz07aZCUfrTsoXCHQ8DKFTDsobXdWdA,1102
@@ -67,11 +67,12 @@ trilogy/parsing/exceptions.py,sha256=92E5i2frv5hj9wxObJZsZqj5T6bglvPzvdvco_vW1Zk
 trilogy/parsing/helpers.py,sha256=AbpHGcgLb-kRsJGnwFEktk7uzpZOCcBY74-YBdrKVGs,1
 trilogy/parsing/parse_engine.py,sha256=A8sQVfVr5sGIgWvz_tPF0EQjxiQhF3UqOTkBDcOaSKg,56115
 trilogy/parsing/render.py,sha256=fxjpq2FZLgllw_d4cru-t_IXNPAz2DmYkT7v9ED0XRI,11540
+trilogy/parsing/trilogy.lark,sha256=GpjGQaDmK7GOTIqK1n4lMbDXqpt_w3EkqlYhlFw3HEA,10679
 trilogy/scripts/__init__.py,sha256=47DEQpj8HBSa-_TImW-5JCeuQeRkm5NMpJWZG3hSuFU,0
 trilogy/scripts/trilogy.py,sha256=PHxvv6f2ODv0esyyhWxlARgra8dVhqQhYl0lTrSyVNo,3729
-pytrilogy-0.0.1.113.dist-info/LICENSE.md,sha256=5ZRvtTyCCFwz1THxDTjAu3Lidds9WjPvvzgVwPSYNDo,1042
-pytrilogy-0.0.1.113.dist-info/METADATA,sha256=DYWhK3uHuFanDIgs8TbEIO7IhpPVQqSyv4muG0vluWU,7882
-pytrilogy-0.0.1.113.dist-info/WHEEL,sha256=Wyh-_nZ0DJYolHNn1_hMa4lM7uDedD_RGVwbmTjyItk,91
-pytrilogy-0.0.1.113.dist-info/entry_points.txt,sha256=0petKryjvvtEfTlbZC1AuMFumH_WQ9v8A19LvoS6G6c,54
-pytrilogy-0.0.1.113.dist-info/top_level.txt,sha256=cAy__NW_eMAa_yT9UnUNlZLFfxcg6eimUAZ184cdNiE,8
-pytrilogy-0.0.1.113.dist-info/RECORD,,
+pytrilogy-0.0.1.114.dist-info/LICENSE.md,sha256=5ZRvtTyCCFwz1THxDTjAu3Lidds9WjPvvzgVwPSYNDo,1042
+pytrilogy-0.0.1.114.dist-info/METADATA,sha256=TTpwsI8qmBYHFwu44PYUDEE-QIWWTIoKeqWGFM4s2us,7882
+pytrilogy-0.0.1.114.dist-info/WHEEL,sha256=Wyh-_nZ0DJYolHNn1_hMa4lM7uDedD_RGVwbmTjyItk,91
+pytrilogy-0.0.1.114.dist-info/entry_points.txt,sha256=0petKryjvvtEfTlbZC1AuMFumH_WQ9v8A19LvoS6G6c,54
+pytrilogy-0.0.1.114.dist-info/top_level.txt,sha256=cAy__NW_eMAa_yT9UnUNlZLFfxcg6eimUAZ184cdNiE,8
+pytrilogy-0.0.1.114.dist-info/RECORD,,

trilogy/__init__.py

@@ -4,6 +4,6 @@ from trilogy.executor import Executor
 from trilogy.parser import parse
 from trilogy.constants import CONFIG
 
-__version__ = "0.0.1.113"
+__version__ = "0.0.1.114"
 
 __all__ = ["parse", "Executor", "Dialects", "Environment", "CONFIG"]

trilogy/parsing/trilogy.lark

@@ -0,0 +1,300 @@
+ !start: ( block | show_statement )*
+    block: statement _TERMINATOR PARSE_COMMENT?
+    ?statement: concept
+    | datasource
+    | function
+    | multi_select_statement
+    | select_statement
+    | persist_statement
+    | rowset_derivation_statement
+    | import_statement
+    | merge_statement
+    
+    _TERMINATOR:  ";"i /\s*/
+    
+    PARSE_COMMENT.1:   /#.*(\n|$)/ |  /\/\/.*\n/  
+    
+    // property display_name string
+    concept_declaration: PURPOSE IDENTIFIER data_type concept_nullable_modifier? metadata?
+    //customer_id.property first_name STRING;
+    //<customer_id,country>.property local_alias STRING
+    concept_property_declaration: PROPERTY (prop_ident | IDENTIFIER) data_type concept_nullable_modifier? metadata?
+    //metric post_length <- len(post_text);
+    concept_derivation:  (PURPOSE | AUTO | PROPERTY ) (prop_ident | IDENTIFIER) "<-" expr
+
+    rowset_derivation_statement: ("rowset"i IDENTIFIER "<-" (multi_select_statement | select_statement)) | ("with"i IDENTIFIER "as"i (multi_select_statement | select_statement))
+    
+    constant_derivation: CONST IDENTIFIER "<-" (literal | _constant_functions)
+
+    concept_nullable_modifier: "?"
+    concept:  (concept_declaration | concept_derivation | concept_property_declaration | constant_derivation)
+    
+    //concept property
+    prop_ident: "<" IDENTIFIER ("," IDENTIFIER )* ","? ">" "." IDENTIFIER
+
+    // datasource concepts
+    datasource: "datasource" IDENTIFIER  "("  column_assignment_list ")"  grain_clause? (address | query)
+    
+    grain_clause: "grain" "(" column_list ")"
+    
+    address: "address" ADDRESS
+    
+    query: "query" MULTILINE_STRING
+    
+    concept_assignment: SHORTHAND_MODIFIER? IDENTIFIER 
+    
+    //column_assignment
+    //figure out if we want static
+    column_assignment: ((IDENTIFIER | _static_functions | raw_column_assignment ) ":" concept_assignment) 
+
+    raw_column_assignment: "raw" "(" MULTILINE_STRING ")"
+    
+    column_assignment_list : column_assignment (","  column_assignment)* ","?
+    
+    column_list : (IDENTIFIER "," )* IDENTIFIER ","?
+    
+    import_statement: "import" (IDENTIFIER ".") * IDENTIFIER "as" IDENTIFIER
+
+    // persist_statement
+    persist_statement: "persist"i IDENTIFIER "into"i IDENTIFIER "from"i select_statement grain_clause?
+
+    // select statement
+    select_statement: "select"i select_list  where?  order_by?  limit? 
+
+    // multiple_selects
+    multi_select_statement: select_statement ("merge" select_statement)+ "align"i align_clause  where? order_by?  limit? 
+
+    align_item: IDENTIFIER ":" IDENTIFIER ("," IDENTIFIER)*  ","?
+
+    align_clause: align_item ("AND"i align_item)*  "AND"i?
+
+    // merge statemment
+    merge_statement: "merge" IDENTIFIER ("," IDENTIFIER)* ","? 
+
+    // FUNCTION blocks
+    function: raw_function
+    function_binding_item: IDENTIFIER ":" data_type
+    function_binding_list: function_binding_item ("," function_binding_item )* ","?
+    raw_function: "bind" "sql"  IDENTIFIER  "("  function_binding_list ")" "->" data_type "as"i MULTILINE_STRING
+    
+    // user_id where state = Mexico
+    filter_item: "filter"i IDENTIFIER where
+
+    // rank/lag/lead
+    WINDOW_TYPE: ("row_number"i|"rank"i|"lag"i|"lead"i | "sum"i)  /[\s]+/
+    
+    window_item: WINDOW_TYPE int_lit? concept_lit  window_item_over? window_item_order?
+    
+    window_item_over: ("OVER"i over_list)
+    
+    window_item_order: ("ORDER"i? "BY"i order_list)
+    
+    select_hide_modifier: "--"
+    select_partial_modifier: "~"
+    select_item: (select_hide_modifier | select_partial_modifier)? (concept_lit  | select_transform  )
+    
+    select_list:  select_item ("," select_item )* ","?
+    
+    //  count(post_id) -> post_count
+    _assignment: ("->") | "as"i
+    select_transform : expr _assignment IDENTIFIER metadata?
+    
+    metadata: "metadata" "(" IDENTIFIER "=" _string_lit ")"
+    
+    limit: "LIMIT"i /[0-9]+/
+    
+    !window_order: ("TOP"i | "BOTTOM"i)
+    
+    window: window_order /[0-9]+/
+    
+    window_order_by: "BY"i column_list
+    
+    order_list: expr ordering (","  expr ordering)* ","?
+    
+    over_list: concept_lit (","  concept_lit )* ","?
+    
+    !ordering: ("ASC"i | "DESC"i ) ("NULLS"i ("FIRST"i | "LAST"i | "AUTO"i) )?
+    
+    order_by: "ORDER"i "BY"i order_list
+    
+    //WHERE STATEMENT
+    
+    !logical_operator: "and"i | "or"i
+    
+    conditional: expr logical_operator expr
+    
+    where: "WHERE"i expr+
+    
+    !array_comparison: ( ("NOT"i "IN"i) | "IN"i)
+
+    COMPARISON_OPERATOR: (/is[\s]+not/ | "is" |"=" | ">" | "<" | ">=" | "<=" | "!=")
+    
+    comparison: expr COMPARISON_OPERATOR expr
+
+    between_comparison: expr "between"i expr "and"i expr
+
+    subselect_comparison: expr array_comparison (literal | _constant_functions | _string_functions | concept_lit | filter_item | window_item | unnest | fgroup |  expr_tuple | parenthetical )
+    
+    expr_tuple: "("  expr ("," expr)+ ","?  ")"
+
+    parenthetical: "(" expr ")"
+
+    //unnesting is a function
+    _UNNEST.1: "UNNEST("i
+    unnest: _UNNEST expr ")"
+    //indexing into an expression is a function
+    index_access: expr "[" int_lit "]"
+    attr_access: expr  "[" _string_lit "]"
+
+    expr:  _constant_functions | window_item | filter_item | subselect_comparison | between_comparison |  fgroup |  aggregate_functions | unnest | _static_functions |  literal |  concept_lit  | index_access | attr_access | parenthetical | expr_tuple | comparison | conditional | alt_like 
+    
+    // functions
+    
+    fadd: ("add"i "(" expr "," expr ")" ) | ( expr "+" expr )
+    fsub: ("subtract"i "(" expr "," expr ")" ) | ( expr "-" expr )
+    fmul: ("multiply"i "(" expr "," expr ")" ) | ( expr "*" expr )
+    fdiv: ( "divide"i "(" expr "," expr ")") | ( expr "/" expr )
+    fmod: ( "mod"i "(" expr "," (int_lit | concept_lit ) ")") | ( expr "%" (int_lit | concept_lit ) )
+    fround: "round"i "(" expr "," expr ")"
+    fabs: "abs"i "(" expr ")"
+        
+    _math_functions: fmul | fdiv | fadd | fsub | fround | fmod | fabs
+    
+    //generic
+    fcast: "cast"i "(" expr "as"i data_type ")"
+    concat: ("concat"i "(" (expr ",")* expr ")") | (expr "||" expr)
+    fcoalesce: "coalesce"i "(" (expr ",")* expr ")"
+    fcase_when: "WHEN"i (expr | conditional) "THEN"i expr
+    fcase_else: "ELSE"i expr
+    fcase: "CASE"i (fcase_when)* (fcase_else)? "END"i
+    len: "len"i "(" expr ")"
+    fnot: "NOT"i expr
+
+    _generic_functions: fcast | concat | fcoalesce | fcase | len | fnot
+
+    //constant
+    CURRENT_DATE.1: /current_date\(\)/
+    CURRENT_DATETIME.1: /current_datetime\(\)/
+    fcurrent_date: CURRENT_DATE
+    fcurrent_datetime: CURRENT_DATETIME
+
+    _constant_functions: fcurrent_date | fcurrent_datetime
+    
+    //string
+    like: "like"i "(" expr "," _string_lit ")"
+    ilike: "ilike"i "(" expr "," _string_lit ")"
+    alt_like: expr "like"i expr
+    upper: "upper"i "(" expr ")"
+    lower: "lower"i "(" expr ")"    
+    fsplit: "split"i "(" expr "," _string_lit ")"
+    fstrpos: "strpos"i "(" expr "," expr ")"
+    _SUBSTRING.1: "substring("i
+    fsubstring: _SUBSTRING expr "," expr "," expr ")"
+    
+    _string_functions: like | ilike | upper | lower | fsplit | fstrpos | fsubstring 
+    
+    // special aggregate
+    fgroup: "group"i "(" expr ")" aggregate_over?
+    //aggregates
+    _COUNT.1: "count("i
+    count:   _COUNT  expr ")"
+    count_distinct: "count_distinct"i "(" expr ")"
+    
+    sum: "sum"i "(" expr ")"
+    avg: "avg"i "(" expr ")"
+    max: "max"i "(" expr ")"
+    min: "min"i "(" expr ")"
+    
+    //aggregates can force a grain
+    aggregate_all: "*"
+    aggregate_over: ("BY"i (aggregate_all | over_list))
+    aggregate_functions: (count | count_distinct | sum | avg | max | min) aggregate_over?
+
+    // date functions
+    _DATE.1: "date("i
+    fdate:  _DATE expr ")"
+    fdatetime: "datetime"i "(" expr ")"
+    ftimestamp: "timestamp"i "(" expr ")"
+    
+    _SECOND.1: "second("i
+    fsecond: _SECOND expr ")"
+    _MINUTE.1: "minute("i
+    fminute: _MINUTE expr ")"
+    _HOUR.1: "hour("i
+    fhour: _HOUR expr ")"
+    _DAY.1: "day("i
+    fday:  _DAY expr ")"
+    _DAY_OF_WEEK.1: "day_of_week("i
+    fday_of_week:  _DAY_OF_WEEK expr ")"
+    _WEEK.1: "week("i
+    fweek: _WEEK expr ")"
+    _MONTH.1: "month("i
+    fmonth: _MONTH expr ")"
+    _QUARTER.1: "quarter("i
+    fquarter: _QUARTER expr ")"
+    _YEAR.1: "year("i
+    fyear: _YEAR expr ")"
+    
+    DATE_PART: "DAY"i | "WEEK"i | "MONTH"i | "QUARTER"i | "YEAR"i | "MINUTE"i | "HOUR"i | "SECOND"i
+    fdate_trunc: "date_trunc"i "(" expr "," DATE_PART ")"
+    fdate_part: "date_part"i "(" expr "," DATE_PART ")"
+    fdate_add: "date_add"i "(" expr "," DATE_PART "," int_lit ")"
+    fdate_diff: "date_diff"i "(" expr "," expr "," DATE_PART ")"
+    
+    _date_functions: fdate | fdate_add | fdate_diff | fdatetime | ftimestamp | fsecond | fminute | fhour | fday | fday_of_week | fweek | fmonth | fquarter | fyear | fdate_part | fdate_trunc
+    
+    _static_functions:  _string_functions | _math_functions | _generic_functions |  _date_functions
+
+    // base language constructs
+    concept_lit: IDENTIFIER
+    IDENTIFIER: /[a-zA-Z\_][a-zA-Z0-9\_\-\.\-]*/
+    ADDRESS: IDENTIFIER | /`[a-zA-Z\_][a-zA-Z0-9\_\-\.\-\*]*`/
+
+    MULTILINE_STRING: /\'{3}(.*?)\'{3}/s
+    
+    DOUBLE_STRING_CHARS: /(?:(?!\${)([^"\\]|\\.))+/+ // any character except "
+    SINGLE_STRING_CHARS: /(?:(?!\${)([^'\\]|\\.))+/+ // any character except '
+    _single_quote: "'" ( SINGLE_STRING_CHARS )* "'" 
+    _double_quote: "\"" ( DOUBLE_STRING_CHARS )* "\"" 
+    _string_lit: _single_quote | _double_quote
+
+    MINUS: "-"
+
+    int_lit: MINUS? /[0-9]+/
+    
+    float_lit: /[0-9]*\.[0-9]+/
+
+    array_lit: "[" (literal ",")* literal ","? "]"()
+    
+    !bool_lit: "True"i | "False"i
+
+    !null_lit.1: "null"i
+    
+    literal: null_lit | _string_lit | int_lit | float_lit | bool_lit | array_lit
+
+    MODIFIER: "Optional"i | "Partial"i | "Nullable"i
+
+    SHORTHAND_MODIFIER: "~"
+
+    struct_type: "struct" "<" ((data_type | IDENTIFIER) ",")* (data_type | IDENTIFIER) ","? ">" 
+
+    list_type: "list" "<" data_type ">"
+
+
+    !data_type: "string"i | "number"i | "numeric"i | "map"i | "list"i | "array"i | "any"i | "int"i | "bigint" | "date"i | "datetime"i | "timestamp"i | "float"i | "bool"i | struct_type | list_type
+    
+    PURPOSE:  "key"i | "metric"i  | CONST
+    PROPERTY: "property"i
+    CONST: "const"i | "constant"i
+    AUTO: "AUTO"i 
+
+    // meta functions
+    CONCEPTS: "CONCEPTS"i
+    DATASOURCES: "DATASOURCES"i
+    show_category: CONCEPTS | DATASOURCES
+
+    show_statement: "show"i ( show_category | select_statement | persist_statement) _TERMINATOR
+   COMMENT: /#.*(\n|$)/ |  /\/\/.*\n/  
+    %import common.WS
+    %ignore WS
+    %ignore COMMENT